Re: [OE-core] [PATCH v4 3/3] python_mesonpy: New class

[Ross Burton <Ross.Burton@arm.com>]

Do you have a recipe in mind to demonstrate that this works as intended?

If there’s nothing in core that needs it, maybe it should sit in meta-python until then.

Ross

> On 3 Jun 2023, at 09:07, Zoltan Boszormenyi via lists.openembedded.org <zboszor=gmail.com@lists.openembedded.org> wrote:
> 
> This is a new PEP517 compatible build class for python modules
> that use pyproject.toml and this:
> 
> [build-system]
> build-backend = 'mesonpy'
> 
> The new class uses python3-meson-python-native.
> 
> Signed-off-by: Zoltán Böszörményi <zboszor@gmail.com>
> ---
> meta/classes-recipe/python_mesonpy.bbclass | 54 ++++++++++++++++++++++
> 1 file changed, 54 insertions(+)
> create mode 100644 meta/classes-recipe/python_mesonpy.bbclass
> 
> diff --git a/meta/classes-recipe/python_mesonpy.bbclass b/meta/classes-recipe/python_mesonpy.bbclass
> new file mode 100644
> index 0000000000..1da8b005ab
> --- /dev/null
> +++ b/meta/classes-recipe/python_mesonpy.bbclass
> @@ -0,0 +1,54 @@
> +#
> +# Copyright OpenEmbedded Contributors
> +#
> +# SPDX-License-Identifier: MIT
> +#
> +
> +inherit meson setuptools3-base python3targetconfig python_pep517
> +
> +# Filter out meson_do_qa_configure from do_configure[postfuncs]
> +DOCONFIGUREPOSTFUNCS := "${@d.getVarFlag('do_configure', 'postfuncs')}"
> +DOCONFIGUREPOSTFUNCS:remove = "meson_do_qa_configure"
> +do_configure[postfuncs] := "${@'' if d.getVar('DOCONFIGUREPOSTFUNCS') is None else d.getVar('DOCONFIGUREPOSTFUNCS') }"
> +
> +# This prevents the meson error:
> +# ERROR: Got argument buildtype as both -Dbuildtype and --buildtype. Pick one.
> +MESONOPTS:remove = "--buildtype ${MESON_BUILDTYPE}"
> +
> +CONFIGURE_FILES = "pyproject.toml"
> +
> +DEPENDS += "python3-wheel-native python3-meson-python-native"
> +
> +def mesonpy_get_args(d):
> +    vars = ['MESONOPTS', 'MESON_CROSS_FILE', 'EXTRA_OEMESON']
> +    varlist = []
> +    for var in vars:
> +        value = d.getVar(var)
> +        vallist = value.split()
> +        for elem in vallist:
> +            varlist.append("-Csetup-args=" + elem)
> +    return ' '.join(varlist)
> +
> +PEP517_BUILD_OPTS = "-Cbuilddir='${B}' ${@mesonpy_get_args(d)}"
> +
> +# Python pyx -> c -> so build leaves absolute build paths in the code
> +INSANE_SKIP:${PN} += "buildpaths"
> +INSANE_SKIP:${PN}-src += "buildpaths"
> +
> +python_mesonpy_do_configure () {
> +    python_pep517_do_configure
> +}
> +
> +python_mesonpy_do_compile () {
> +    python_pep517_do_compile
> +}
> +
> +python_mesonpy_do_install () {
> +    python_pep517_do_install
> +}
> +
> +python_mesonpy_do_bootstrap_install () {
> +    python_pep517_do_bootstrap_install
> +}
> +
> +EXPORT_FUNCTIONS do_configure do_compile do_install
> -- 
> 2.40.1
> 
> 
> -=-=-=-=-=-=-=-=-=-=-=-
> Links: You receive all messages sent to this group.
> View/Reply Online (#182349): https://lists.openembedded.org/g/openembedded-core/message/182349
> Mute This Topic: https://lists.openembedded.org/mt/99301645/6875888
> Group Owner: openembedded-core+owner@lists.openembedded.org
> Unsubscribe: https://lists.openembedded.org/g/openembedded-core/unsub [ross.burton@arm.com]
> -=-=-=-=-=-=-=-=-=-=-=-
>