[master/thud/ti2019.03 3/4] tiovx-app-host: TI OpenVX IPC HOST implementation and sample applications

[Hongmei Gou <a0271529@ti.com>]

* The sample applications include running OpenVX conformance tests
  as well as a Khronos tutorial example

Signed-off-by: Djordje Senicic <x0157990@ti.com>
Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
Signed-off-by: Hongmei Gou <a0271529@ti.com>
---
 .../recipes-ti/tiovx/files/setenv.sh          |  8 +++
 .../recipes-ti/tiovx/tiovx-app-host.bb        | 56 +++++++++++++++++++
 2 files changed, 64 insertions(+)
 create mode 100644 meta-arago-extras/recipes-ti/tiovx/files/setenv.sh
 create mode 100644 meta-arago-extras/recipes-ti/tiovx/tiovx-app-host.bb

diff --git a/meta-arago-extras/recipes-ti/tiovx/files/setenv.sh b/meta-arago-extras/recipes-ti/tiovx/files/setenv.sh
new file mode 100644
index 00000000..dc7bcea3
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/tiovx/files/setenv.sh
@@ -0,0 +1,8 @@
+#!/bin/bash
+
+export PROC_LIST='host khronos_example'
+
+export LINUX_SYSROOT_DIR=/
+export TIOVXPATH=/usr/include/VX
+export IPCPATH=/usr/share/ti/ti-ipc-tree
+export SDKPLATFORMIFPATH=/usr/share/ti/ti-tiovx-lib-tree/sys-iface
diff --git a/meta-arago-extras/recipes-ti/tiovx/tiovx-app-host.bb b/meta-arago-extras/recipes-ti/tiovx/tiovx-app-host.bb
new file mode 100644
index 00000000..91286dc7
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/tiovx/tiovx-app-host.bb
@@ -0,0 +1,56 @@
+SUMMARY = "TI OpenVX HOST (Linux A15) conformance verification application, Khronos tutorial example, and Host side IPC implementation "
+DESCRIPTION = "TI OpenVX implementation, TIOVX, includes Khronos defined conformance test and tutorial example, as well as additional TI specific tests. This package creates application which runs all the conformance tests (7K-8K) and Khronos tutorial exercise1. Same package includes IPC implementation (MessageQ based) needed for communication with DSP firmware (loaded at boot time) "
+
+LICENSE = "BSD-3-Clause & MIT"
+LIC_FILES_CHKSUM = "file://docs/manifest/TIOVX-APP-HOST_01.00.01.00_manifest.html;md5=247d7c56d783f583bf802490d5c93db3"
+
+FILESEXTRAPATHS_prepend := "${THISDIR}/files:"
+
+SRC_URI_append += "\
+     file://setenv.sh \
+"
+
+inherit pkgconfig
+
+require recipes-ti/includes/tisdk-paths.inc
+require tiovx-sys.inc
+
+DEPENDS = " tiovx-sys-iface tiovx-lib-host ti-ipc cmem opencv udev"
+RDEPENDS_${PN} = " tiovx-sys-iface tiovx-sys-iface-firmware tiovx-lib-host ti-ipc cmem"
+
+PR = "r3"
+
+COMPATIBLE_MACHINE = "dra7xx"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+PROCLIST = "host khronos_example"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE += " TARGET_ROOTDIR=${STAGING_DIR_HOST} "
+EXTRA_OEMAKE += " GCCLINARO=${TOOLCHAIN_PATH} TIOVXPATH=${TIOVX_INSTALL_DIR} IPCPATH=${IPC_INSTALL_DIR} "
+EXTRA_OEMAKE += " SDKPLATFORMIFPATH=${TIOVX_INSTALL_DIR}/sys-iface "
+EXTRA_OEMAKE += " PROC_LIST='${PROCLIST}' "
+
+do_install () {
+    install -d ${D}${bindir}/
+    install -m 0755 ${S}/host/bin/debug/app_host ${D}${bindir}/tiovx-app_host
+    install -m 0755 ${S}/khronos_example/bin/debug/opticalflow ${D}${bindir}/tiovx-opticalflow
+
+    oe_runmake clean
+    install -d ${D}${datadir}/ti/examples/openvx
+    install -m 644 ${S}/products.mak ${D}${datadir}/ti/examples/openvx
+    install -m 644 ${S}/makefile ${D}${datadir}/ti/examples/openvx
+    install -m 644 ${WORKDIR}/setenv.sh ${D}${datadir}/ti/examples/openvx
+    cp -r ${S}/host ${D}${datadir}/ti/examples/openvx
+    cp -r ${S}/khronos_example  ${D}${datadir}/ti/examples/openvx
+    cp -r ${S}/shared ${D}${datadir}/ti/examples/openvx
+}
+
+PACKAGES += "${PN}-examples"
+FILES_${PN}-examples = "${datadir}/ti/examples/openvx"
+RDEPENDS_${PN}-examples = "tiovx-lib-host-staticdev tiovx-lib-host-dev"
+
+FILES_${PN} += "${bindir}/*"
+INSANE_SKIP_${PN} = "ldflags"
+INSANE_SKIP_${PN}-examples = "dev-deps"
-- 
2.17.1