[PATCH 17/21] kernel: add preempt-rt fetch recipes for v5.4.x, v5.10.x and 5.12.x

["Paul Gortmaker" <paul.gortmaker@windriver.com>]

Note that the v5.12 content currently is in the devel repo and will
eventually get moved over to the stable-rt repo.  When that move
happens, we'll need to update the SRC_URI accordingly.  [The v5.12-rt
content itself will remain fast-forward with respect to that which is
in devel currently.]

Also, since each reference their respective stable baseline repos,
which are still in maintenance and not static content, we use alternate
reference instead of pack reference back to stable.

Signed-off-by: Paul Gortmaker <paul.gortmaker@windriver.com>
---
 meta/recipes-kernel/linux/fetch-rt.inc     | 25 ++++++++++++++++++++++
 meta/recipes-kernel/linux/linux-rt-5.10.bb |  9 ++++++++
 meta/recipes-kernel/linux/linux-rt-5.12.bb | 12 +++++++++++
 meta/recipes-kernel/linux/linux-rt-5.4.bb  |  9 ++++++++
 4 files changed, 55 insertions(+)
 create mode 100644 meta/recipes-kernel/linux/fetch-rt.inc
 create mode 100644 meta/recipes-kernel/linux/linux-rt-5.10.bb
 create mode 100644 meta/recipes-kernel/linux/linux-rt-5.12.bb
 create mode 100644 meta/recipes-kernel/linux/linux-rt-5.4.bb

diff --git a/meta/recipes-kernel/linux/fetch-rt.inc b/meta/recipes-kernel/linux/fetch-rt.inc
new file mode 100644
index 000000000000..18dbf0628640
--- /dev/null
+++ b/meta/recipes-kernel/linux/fetch-rt.inc
@@ -0,0 +1,25 @@
+# Boilerplate to fetch a single branch of preempt-rt
+# There are two different repos, and two branching name patterns.
+
+require recipes-kernel/linux/fetch-only.inc
+
+python __anonymous () {
+    rt = d.getVar("RT")
+    rt_repo = d.getVar("RT_REPO")
+    if rt_repo.endswith("devel"):
+        d.setVar("RT_BRANCH", "linux-%s.y-rt" % rt)
+    else:
+        d.setVar("RT_BRANCH", "v%s-rt" % rt)
+    clonehost = d.getVar("KORG_SERVER")
+    d.setVar("KORG_REF", "%s.stable.linux-%s.y" % (clonehost, rt))
+    d.setVar("KORG_REFDEP", "stable-%s:do_fetch" % rt)
+}
+
+do_fetch[depends] += "${KORG_REFDEP}"
+
+RT_REV ?= "${RT_BRANCH}"
+RT_REPO ?= "linux-stable-rt"
+GITCLONEARGS = "--bare --single-branch --branch ${RT_BRANCH}"
+GITFETCHREFS ?= "refs/heads/${RT_BRANCH}:refs/heads/${RT_BRANCH}"
+DL_NAME = ".preempt-rt.linux-${RT}.y"
+SRC_URI = "${KORG_URLBASE}/rt/${RT_REPO};rev=${RT_REV};nobranch=1;dlname=${DL_NAME};altref=${KORG_REF}"
diff --git a/meta/recipes-kernel/linux/linux-rt-5.10.bb b/meta/recipes-kernel/linux/linux-rt-5.10.bb
new file mode 100644
index 000000000000..04520101a443
--- /dev/null
+++ b/meta/recipes-kernel/linux/linux-rt-5.10.bb
@@ -0,0 +1,9 @@
+SUMMARY = "Linux preempt-rt v5.10.y kernel source"
+DESCRIPTION = "Fetch source of the preempt-rt linux kernel up to the end of the v5.10.y series"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
+
+RT = "5.10"
+
+require recipes-kernel/linux/fetch-rt.inc
diff --git a/meta/recipes-kernel/linux/linux-rt-5.12.bb b/meta/recipes-kernel/linux/linux-rt-5.12.bb
new file mode 100644
index 000000000000..88f2daf92032
--- /dev/null
+++ b/meta/recipes-kernel/linux/linux-rt-5.12.bb
@@ -0,0 +1,12 @@
+SUMMARY = "Linux preempt-rt v5.12.y kernel source"
+DESCRIPTION = "Fetch source of the preempt-rt linux kernel up to the end of the v5.12.y series"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
+
+RT = "5.12"
+
+# Note: v5.12 RT will move to linux-stable-rt repo sometime
+RT_REPO = "linux-rt-devel"
+
+require recipes-kernel/linux/fetch-rt.inc
diff --git a/meta/recipes-kernel/linux/linux-rt-5.4.bb b/meta/recipes-kernel/linux/linux-rt-5.4.bb
new file mode 100644
index 000000000000..3d70be5aaa9b
--- /dev/null
+++ b/meta/recipes-kernel/linux/linux-rt-5.4.bb
@@ -0,0 +1,9 @@
+SUMMARY = "Linux preempt-rt v5.4.y kernel source"
+DESCRIPTION = "Fetch source of the preempt-rt linux kernel up to the end of the v5.4.y series"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
+
+RT = "5.4"
+
+require recipes-kernel/linux/fetch-rt.inc
-- 
2.25.1