[meta-cloud-services][PATCH] libibverbs: add back from meta-virtualization

["kai" <kai.kang@windriver.com>]

From: Kai Kang <kai.kang@windriver.com>

libibverbs has been removed from meta-virtualization but it is still required
by librdmacm and glusterfs. So add it back from meta-virtualization.

Signed-off-by: Kai Kang <kai.kang@windriver.com>
---
 .../libibverbs/libibverbs_1.2.1.bb            | 34 +++++++++++++++++++
 1 file changed, 34 insertions(+)
 create mode 100644 recipes-extended/libibverbs/libibverbs_1.2.1.bb

diff --git a/recipes-extended/libibverbs/libibverbs_1.2.1.bb b/recipes-extended/libibverbs/libibverbs_1.2.1.bb
new file mode 100644
index 00000000..90c424ec
--- /dev/null
+++ b/recipes-extended/libibverbs/libibverbs_1.2.1.bb
@@ -0,0 +1,34 @@
+SUMMARY = "Support InfiniBand verbs"
+DESCRIPTION = "Libibverbs is a library that allows userspace processes to use InfiniBand/RDMA 'verbs' directly."
+HOMEPAGE = "http://www.openfabrics.org/downloads/verbs/"
+SECTION = "libs/devel"
+
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://COPYING;md5=7c557f27dd795ba77cc419dddc656b51"
+
+# Official repo is at git://git.kernel.org/pub/scm/libs/infiniband/libibverbs.git
+SRC_URI = "https://www.openfabrics.org/downloads/verbs/${BPN}-${PV}.tar.gz"
+
+SRC_URI[md5sum] = "1544ebb89d861ce84057ab43dfcd22a0"
+SRC_URI[sha256sum] = "c352a7f24e9a9d30ea74faa35d1b721d78d770506a0c03732e3132b7c85ac330"
+
+inherit autotools
+
+DEPENDS = "libnl pkgconfig-native"
+PACKAGES += "${PN}-utils"
+FILES:${PN} = "${sysconfdir} ${libdir}/*.so.*"
+FILES:${PN}-utils = "${bindir}"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[valgrind] = "--with-valgrind,--without-valgrind,valgrind,"
+
+do_install:append() {
+        mkdir -p ${D}${sysconfdir}/libibverbs.d
+        rm -f ${D}${libdir}/libibverbs.la
+}
+
+PROVIDES = "virtual/libibverbs"
+RPROVIDES:${PN} = "virtual-libibverbs"
+
+COMPATIBLE_HOST:mipsarch = "none"
+COMPATIBLE_HOST:arm = "none"
-- 
2.33.0