[PATCH 0/3] Add efika MX support to OE

[PATCH 0/3] Add efika MX support to OE

[Khem Raj]

Hi

Following three patches will make OE support Efika MX smart computer.
The kernel and u-boot is used from powerdeveloper.org as all the changes
are not upstream yet.

Thanks

-Khem

[PATCH 1/3] efikamx.conf: Add config file for efika MX

[Khem Raj]

Signed-off-by: Khem Raj <raj.khem@gmail.com>
---
 conf/machine/efikamx.conf |   19 +++++++++++++++++++
 1 files changed, 19 insertions(+), 0 deletions(-)
 create mode 100644 conf/machine/efikamx.conf

diff --git a/conf/machine/efikamx.conf b/conf/machine/efikamx.conf
new file mode 100644
index 0000000..eceb87c
--- /dev/null
+++ b/conf/machine/efikamx.conf
@@ -0,0 +1,19 @@
+#@TYPE: Machine
+#@Name: Genisi EFIKA MX Development Platform
+#@DESCRIPTION: Machine configuration for the EFIKA development platform (http://www.powerdeveloper.org/platforms/efikamx)
+
+TARGET_ARCH = "arm"
+
+PREFERRED_PROVIDER_virtual/kernel ?= "linux-efikamx"
+
+MACHINE_FEATURES = "kernel26 usbhost ext2 alsa"
+
+#don't try to access tty1
+USE_VT = "0"
+
+SERIAL_CONSOLE = "115200 ttymxc0"
+
+PREFERRED_PROVIDER_virtual/bootloader = "u-boot-efikamx"
+
+#tune for ARMv7/Cortex A8
+require conf/machine/include/tune-cortexa8.inc
-- 
1.7.1

[PATCH 2/3] linux-efikamx_2.6.31.bb: Add recipe for linux kernel used for Efika MX

[Khem Raj]

Signed-off-by: Khem Raj <raj.khem@gmail.com>
---
 recipes/linux/linux-efikamx_2.6.31.bb |   47 +++++++++++++++++++++++++++++++++
 1 files changed, 47 insertions(+), 0 deletions(-)
 create mode 100644 recipes/linux/linux-efikamx_2.6.31.bb

diff --git a/recipes/linux/linux-efikamx_2.6.31.bb b/recipes/linux/linux-efikamx_2.6.31.bb
new file mode 100644
index 0000000..96eb682
--- /dev/null
+++ b/recipes/linux/linux-efikamx_2.6.31.bb
@@ -0,0 +1,47 @@
+require linux.inc
+
+DESCRIPTION = "Linux kernel for EfikaMX platform"
+KERNEL_IMAGETYPE = "uImage"
+
+COMPATIBLE_MACHINE = "efikamx"
+
+python do_fetch () {
+        import os,shutil
+        bb.build.exec_func("base_do_fetch", d)
+        if os.access(bb.data.expand("${DL_DIR}/73", d), os.R_OK):
+                shutil.copy(bb.data.expand("${DL_DIR}/73", d), bb.data.expand("${DL_DIR}/${PN}-${PV}.tar.lzma", d))
+
+        if os.access(bb.data.expand("${DL_DIR}/83", d), os.R_OK):
+                shutil.copy(bb.data.expand("${DL_DIR}/83", d), bb.data.expand("${DL_DIR}/patch-${PV}.tar.lzma", d))
+}
+
+python do_unpack () {
+       bb.build.exec_func('efikamx_kernel_do_unpack', d)
+}
+
+efikamx_kernel_do_unpack () {
+       mkdir -p ${S}
+       tar xf ${DL_DIR}/${PN}-${PV}.tar.lzma --strip-components=1 -C ${S}
+       tar xf ${DL_DIR}/patch-${PV}.tar.lzma -C ${S}
+}
+
+python do_patch () {
+       bb.build.exec_func('efikamx_kernel_do_patch', d)
+}
+
+efikamx_kernel_do_patch (){
+       ( cd ${S}/patches; ls *.patch >series;cp *.config ${S}/../defconfig)
+       ( cd ${S}; quilt push -a)
+}
+
+SRC_URI += "http://www.powerdeveloper.org/asset/by-id/73;name=kernel \
+            http://www.powerdeveloper.org/asset/by-id/83;name=patch \
+           "
+
+SRC_URI[kernel.md5sum] = "c70ce0549cf85de79d5b28db7b552868"
+SRC_URI[kernel.sha256sum] = "658395072352cd38477d80c105f00d824c73bf437f0843579d1e0bf41066617f"
+
+SRC_URI[patch.md5sum] = "6c04416bce74dd413f3e82cd17378419"
+SRC_URI[patch.sha256sum] = "5c15cffa02089d286fc07ba734b1f33a81d1f7ceaf70e596bd8b82ddd5e73ec2"
+
+S = "${WORKDIR}/${PN}-${PV}"
-- 
1.7.1

[PATCH 3/3] u-boot-efikamx_1.1.8.bb: Efika MX bootloader

[Khem Raj]

Signed-off-by: Khem Raj <raj.khem@gmail.com>
---
 recipes/u-boot/u-boot-efikamx_1.1.8.bb |   25 +++++++++++++++++++++++++
 1 files changed, 25 insertions(+), 0 deletions(-)
 create mode 100644 recipes/u-boot/u-boot-efikamx_1.1.8.bb

diff --git a/recipes/u-boot/u-boot-efikamx_1.1.8.bb b/recipes/u-boot/u-boot-efikamx_1.1.8.bb
new file mode 100644
index 0000000..2094bf7
--- /dev/null
+++ b/recipes/u-boot/u-boot-efikamx_1.1.8.bb
@@ -0,0 +1,25 @@
+require u-boot.inc
+PR ="r0"
+DEFAULT_PREFERENCE = "-1"
+
+SRC_URI = "http://www.powerdeveloper.org/asset/by-id/89;name=uboot-efikamx \
+          "
+SRC_URI[uboot-efikamx.md5sum] = "072fbd97b293ac96d3f166e261c56131"
+SRC_URI[uboot-efikamx.sha256sum] = "ee813d15e0e699340e5099641e01ac2952d42329d168deb48692a22a66d48965"
+
+S = "${WORKDIR}/uboot-efikamx-${PV}"
+
+python do_fetch () {
+        import os,shutil
+        bb.build.exec_func("base_do_fetch", d)
+        if os.access(bb.data.expand("${DL_DIR}/89", d), os.R_OK):
+                shutil.copy(bb.data.expand("${DL_DIR}/89", d), bb.data.expand("${DL_DIR}/${PN}-${PV}.tar.lzma", d))
+}
+
+python do_unpack () {
+        bb.build.exec_func('efikamx_uboot_do_unpack', d)
+}
+
+efikamx_uboot_do_unpack (){
+       (cd ${WORKDIR}; tar xf ${DL_DIR}/${PN}-${PV}.tar.lzma)
+}
-- 
1.7.1

Re: [PATCH 0/3] Add efika MX support to OE

[Frans Meulenbroeks]

2010/8/23 Khem Raj <raj.khem@gmail.com>:
> Hi
>
> Following three patches will make OE support Efika MX smart computer.
> The kernel and u-boot is used from powerdeveloper.org as all the changes
> are not upstream yet.
>
> Thanks
>
> -Khem

I have reviewed (but not build) the code.
The code looks good and as this does not interfere with other recipes
or systems I'm fine with getting this pushed.
Acked-by: Frans Meulenbroeks <fransmeulenbroeks@gmail.com>
This ack is for all 3 patches.

FM

Re: [PATCH 0/3] Add efika MX support to OE

[Leon Woestenberg]

Khem,

On Mon, Aug 23, 2010 at 5:13 AM, Khem Raj <raj.khem@gmail.com> wrote:
>
> Following three patches will make OE support Efika MX smart computer.
> The kernel and u-boot is used from powerdeveloper.org as all the changes
> are not upstream yet.
>
Thanks, it was on my to-do.  Do you have the Efika MX hardware?

I can send you one MX if it helps, it's not the newest board revision though.

Regards,
-- 
Leon