On 4/19/21 2:00 AM, Alexander Kanavin wrote:
> This is required to enable debuginfod in elfutils.
>

Don't forget to send a patch to remove  it from meta-openembedded once
merged in core.

> Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com>
> ---
>   .../libmicrohttpd/libmicrohttpd_0.9.72.bb     | 31 +++++++++++++++++++
>   1 file changed, 31 insertions(+)
>   create mode 100644 meta/recipes-support/libmicrohttpd/libmicrohttpd_0.9.72.bb
>
> diff --git a/meta/recipes-support/libmicrohttpd/libmicrohttpd_0.9.72.bb b/meta/recipes-support/libmicrohttpd/libmicrohttpd_0.9.72.bb
> new file mode 100644
> index 0000000000..66c48da3b7
> --- /dev/null
> +++ b/meta/recipes-support/libmicrohttpd/libmicrohttpd_0.9.72.bb
> @@ -0,0 +1,31 @@
> +DESCRIPTION = "A small C library that is supposed to make it easy to run an HTTP server as part of another application"
> +HOMEPAGE = "http://www.gnu.org/software/libmicrohttpd/"
> +LICENSE = "LGPL-2.1+"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=57d09285feac8a64efa878e692b14f36"
> +SECTION = "net"
> +
> +DEPENDS = "file"
> +
> +SRC_URI = "${GNU_MIRROR}/libmicrohttpd/${BPN}-${PV}.tar.gz"
> +SRC_URI[md5sum] = "2a286193af88ab2ae3149748d4b46187"
> +SRC_URI[sha256sum] = "0ae825f8e0d7f41201fd44a0df1cf454c1cb0bc50fe9d59c26552260264c2ff8"
> +
> +inherit autotools lib_package pkgconfig gettext
> +
> +CFLAGS += "-pthread -D_REENTRANT"
> +
> +EXTRA_OECONF += "--disable-static --with-gnutls=${STAGING_LIBDIR}/../"
> +
> +PACKAGECONFIG ?= "curl https"
> +PACKAGECONFIG_append_class-target = "\
> +        ${@bb.utils.filter('DISTRO_FEATURES', 'largefile', d)} \
> +"
> +PACKAGECONFIG[largefile] = "--enable-largefile,--disable-largefile,,"
> +PACKAGECONFIG[curl] = "--enable-curl,--disable-curl,curl,"
> +PACKAGECONFIG[https] = "--enable-https,--disable-https,libgcrypt gnutls,"
> +
> +do_compile_append() {
> +    sed -i s:-L${STAGING_LIBDIR}::g libmicrohttpd.pc
> +}
> +
> +BBCLASSEXTEND = "native nativesdk"
>
>
>
>
>