[meta-freescale-distro][PATCH 0/5] ] add new packagegroups, demo images and distro file

[meta-freescale-distro][PATCH 0/5] ] add new packagegroups, demo images and distro file

[Zhenhua Luo]

* add packagegroup for networking and virtualization
* add demo images of networking and networking-full
* add fsl-qoriq distro conf file

Revision history:
v1: add new packagegroups, demo images and distro file
v2: fix typo in bb of packagegroup, demo images and distro file
v3: fix typo in fsl-qoriq distro file
v4: fix mixture changes in patch of adding fsl-qoriq distro file
v5: rebase for master

Zhenhua Luo (5):
  packagegroup-fsl-networking: add recipe
  packagegroup-fsl-virtualization: add recipe
  add fsl-image-networking demo image
  add fsl-image-networking-full demo image
  add fsl-qoriq distro conf file

 conf/distro/fsl-qoriq.conf                         |  33 ++++
 recipes-fsl/images/fsl-image-networking-full.bb    |  25 +++
 recipes-fsl/images/fsl-image-networking.bb         |  14 ++
 .../packagegroups/packagegroup-fsl-networking.bb   | 173 +++++++++++++++++++++
 .../packagegroup-fsl-virtualization.bb             |  27 ++++
 5 files changed, 272 insertions(+)
 create mode 100644 conf/distro/fsl-qoriq.conf
 create mode 100644 recipes-fsl/images/fsl-image-networking-full.bb
 create mode 100644 recipes-fsl/images/fsl-image-networking.bb
 create mode 100644 recipes-fsl/packagegroups/packagegroup-fsl-networking.bb
 create mode 100644 recipes-fsl/packagegroups/packagegroup-fsl-virtualization.bb

-- 
2.9.3

[meta-freescale-distro][PATCH 1/5] packagegroup-fsl-networking: add recipe

[Zhenhua Luo]

packagegroup-fsl-networking defines the packages group for networking
support.

Signed-off-by: Zhenhua Luo <zhenhua.luo@nxp.com>
---
 .../packagegroups/packagegroup-fsl-networking.bb   | 173 +++++++++++++++++++++
 1 file changed, 173 insertions(+)
 create mode 100644 recipes-fsl/packagegroups/packagegroup-fsl-networking.bb

diff --git a/recipes-fsl/packagegroups/packagegroup-fsl-networking.bb b/recipes-fsl/packagegroups/packagegroup-fsl-networking.bb
new file mode 100644
index 0000000..d03f980
--- /dev/null
+++ b/recipes-fsl/packagegroups/packagegroup-fsl-networking.bb
@@ -0,0 +1,173 @@
+# Copyright (C) 2017 NXP Semiconductors
+# Released under the MIT license (see COPYING.MIT for the terms)
+DESCRIPTION = "Package group used by NXP Community to provide networking packages"
+SUMMARY = "NXP Community Package group - networking"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit packagegroup
+
+PACKAGES = "${PN}-core ${PN}-core-extend \
+    ${PN}-client ${PN}-server \
+    ${PN}-extend"
+
+QORIQ-PKGS = ""
+# NOTE: Remove the conditional pkc-host inclusion and all traces of c29x_pkc
+# DISTRO_FEATURE if pkc-host no longer requires customized cryptodev patches
+QORIQ-PKGS_qoriq = "asf merge-files udev-rules-qoriq \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'c29x_pkc', 'pkc-host', '', d)} \
+"
+
+QORIQ-PKGS_append_qoriq-ppc = " \
+    apptrk \
+    dpa-offload \
+    eth-config \
+    usdpaa-apps \
+    hypervisor-partman \
+"
+QORIQ-PKGS_append_fsl-lsch3 = " restool"
+QORIQ-PKGS_append_e500v2 = "apptrk testfloat"
+QORIQ-PKGS_append_e6500-64b = " kernel-module-ceetm"
+
+# e6500 only support 64bit hypervisor
+QORIQ-PKGS_remove_e6500 = "hypervisor-partman"
+QORIQ-PKGS_append_e6500 = " lib64-hypervisor-partman"
+
+QORIQ-PKGS_append_c293pcie = " skmm-ep"
+QORIQ-PKGS_append_ls1043ardb = " eth-config usdpaa usdpaa-apps dpa-offload"
+QORIQ-PKGS_append_ls1046rrdb = " eth-config usdpaa usdpaa-apps dpa-offload"
+QORIQ-PKGS_append_p1023rdb = " fmc eth-config"
+QORIQ-PKGS_append_b4860qds = "\
+    ipc-ust \
+    kernel-module-ipc-multi \
+    kernel-module-ipc-single \
+"
+QORIQ-PKGS_append_b4420qds = "\
+    ipc-ust \
+    kernel-module-ipc-multi \
+    kernel-module-ipc-single \
+"
+QORIQ-PKGS__append_p4080ds = "\
+    skmm-ep \
+    skmm-host \
+"
+QORIQ-PKGS_append_t4240qds = "\
+    skmm-ep \
+    skmm-host \
+"
+QORIQ-PKGS_append_t1040 = " \
+    ceetm \
+    kernel-module-ar \
+    kernel-module-uio-seville \
+"
+QORIQ-PKGS_append_t1042 = " \
+    ceetm \
+    kernel-module-ar \
+"
+
+RDEPENDS_${PN}-core_qoriq = " \
+    coreutils \
+    elfutils \
+    e2fsprogs \
+    e2fsprogs-badblocks \
+    e2fsprogs-e2fsck \
+    e2fsprogs-tune2fs  \
+    file \
+    i2c-tools \
+    kmod \
+    libhugetlbfs \
+    lmsensors-sensors \
+    memtester \
+    minicom \
+    pkgconfig \
+    python-subprocess \
+    python-datetime \
+    python-json \
+    procps \
+    psmisc \
+    sysfsutils \
+    sysklogd \
+    sysstat \
+    ${QORIQ-PKGS} \
+"
+
+RDEPENDS_${PN}-core-extend_qoriq = " \
+    bc \
+    chkconfig \
+    cronie \
+    db \
+    debianutils \
+    dtc \
+    lsof \
+    man \
+    man-pages \
+    oprofile \
+    parted \
+    perf \
+    rng-tools \
+    rt-tests \
+    sqlite3 \
+    strongswan \
+    texinfo \
+    u-boot-mkimage \
+    unzip \
+    usbutils \
+    watchdog \
+    which \
+    xz  \
+    zip \
+"
+
+RDEPENDS_${PN}-client_qoriq = " \
+    bridge-utils \
+    ethtool \
+    iproute2 \
+    iproute2-tc \
+    iptables \
+    iputils \
+    inetutils \
+    inetutils-ftp \
+    inetutils-hostname \
+    inetutils-ifconfig \
+    inetutils-logger \
+    inetutils-ping \
+    inetutils-ping6 \
+    inetutils-rsh \
+    inetutils-syslogd \
+    inetutils-telnet \
+    inetutils-tftp \
+    inetutils-traceroute \
+    ipsec-tools \
+    ipsec-demo \
+    net-tools \
+    tcpdump \
+"
+
+RDEPENDS_${PN}-server_qoriq = " \
+    inetutils-inetd \
+    inetutils-ftpd \
+    inetutils-rshd \
+    inetutils-tftpd \
+    inetutils-telnetd \
+"
+
+RDEPENDS_${PN}-client_append_qoriq = "\
+    packagegroup-fsl-networking-server \
+"
+
+RDEPENDS_${PN}-extend_qoriq = " \
+    bind \
+    curl \
+    dhcp-client \
+    libnfnetlink \
+    linuxptp \
+    ntpdate \
+    ppp \
+    ppp-dialin \
+    ptpd \
+    resolvconf \
+    rp-pppoe \
+    samba \
+    wget \
+    xinetd \
+"
-- 
2.9.3

[meta-freescale-distro][PATCH 2/5] packagegroup-fsl-virtualization: add recipe

[Zhenhua Luo]

packagegroup-fsl-virtualization defines the packages group for virtualization
support.

Signed-off-by: Zhenhua Luo <zhenhua.luo@nxp.com>
---
 .../packagegroup-fsl-virtualization.bb             | 27 ++++++++++++++++++++++
 1 file changed, 27 insertions(+)
 create mode 100644 recipes-fsl/packagegroups/packagegroup-fsl-virtualization.bb

diff --git a/recipes-fsl/packagegroups/packagegroup-fsl-virtualization.bb b/recipes-fsl/packagegroups/packagegroup-fsl-virtualization.bb
new file mode 100644
index 0000000..774cf0b
--- /dev/null
+++ b/recipes-fsl/packagegroups/packagegroup-fsl-virtualization.bb
@@ -0,0 +1,27 @@
+# Copyright (C) 2017 NXP Semiconductors
+# Released under the MIT license (see COPYING.MIT for the terms)
+DESCRIPTION = "Package group used by NXP Community to provide virtualization packages"
+SUMMARY = "NXP Community Package group - virtualization, virtualization is \
+the creation of a virtual -- rather than actual -- version of something, such \
+as an operating system, it is an important feature of NXP QorIQ platforms, the \
+major virtualization technique supported by QorIQ includes docker, qemu and lxc"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit packagegroup
+
+PACKAGES = "${PN}"
+
+DOCKER-PKGS = ""
+DOCKER-PKGS_qoriq-arm = "docker docker-registry"
+DOCKER-PKGS_qoriq-arm64 = "docker docker-registry"
+
+RDEPENDS_${PN}_qoriq = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', \
+    'libvirt \
+    libvirt-libvirtd \
+    libvirt-virsh \
+    lxc \
+    qemu', \
+    '', d)} \
+    ${DOCKER-PKGS} \
+" 
-- 
2.9.3

[meta-freescale-distro][PATCH 3/5] add fsl-image-networking demo image

[Zhenhua Luo]

fsl-image-networking is the small demo image for networking core features
support.

Signed-off-by: Zhenhua Luo <zhenhua.luo@nxp.com>
---
 recipes-fsl/images/fsl-image-networking.bb | 14 ++++++++++++++
 1 file changed, 14 insertions(+)
 create mode 100644 recipes-fsl/images/fsl-image-networking.bb

diff --git a/recipes-fsl/images/fsl-image-networking.bb b/recipes-fsl/images/fsl-image-networking.bb
new file mode 100644
index 0000000..cca5b4a
--- /dev/null
+++ b/recipes-fsl/images/fsl-image-networking.bb
@@ -0,0 +1,14 @@
+require recipes-core/images/core-image-minimal.bb
+
+SUMMARY = "Minimal networking image used for evaluating the NXP SOCs"
+DESCRIPTION = "The mininal networking image which includes some useful \
+networking, benchmark and NXP specific packages. It is used for evaluating \
+the NXP QorIQ SOCs."
+
+LICENSE = "MIT"
+
+IMAGE_INSTALL_append_qoriq = " \
+    packagegroup-fsl-networking-core \
+    packagegroup-fsl-networking-client \
+    packagegroup-fsl-tools-benchmark \
+"
-- 
2.9.3

[meta-freescale-distro][PATCH 4/5] add fsl-image-networking-full demo image

[Zhenhua Luo]

fsl-image-networking-full is a large demo image to support silicon evaluation,
software development and debug on target boards.

Signed-off-by: Zhenhua Luo <zhenhua.luo@nxp.com>
---
 recipes-fsl/images/fsl-image-networking-full.bb | 25 +++++++++++++++++++++++++
 1 file changed, 25 insertions(+)
 create mode 100644 recipes-fsl/images/fsl-image-networking-full.bb

diff --git a/recipes-fsl/images/fsl-image-networking-full.bb b/recipes-fsl/images/fsl-image-networking-full.bb
new file mode 100644
index 0000000..7341d54
--- /dev/null
+++ b/recipes-fsl/images/fsl-image-networking-full.bb
@@ -0,0 +1,25 @@
+require fsl-image-networking.bb
+
+SUMMARY = "Large image to be used for development and evaluation"
+DESCRIPTION = "Large image which includes all the tested tools and \
+NXP specific packages. It is a full Linux system for development and \
+evaluation tasks."
+
+LICENSE = "MIT"
+
+# copy the manifest and the license text for each package to image
+COPY_LIC_MANIFEST = "1"
+
+IMAGE_INSTALL_append_qoriq = " \
+    packagegroup-core-buildessential \
+    packagegroup-core-eclipse-debug \
+    packagegroup-core-full-cmdline \
+    packagegroup-core-nfs-server \
+    packagegroup-core-tools-debug \
+    packagegroup-fsl-networking-core-extend \
+    packagegroup-fsl-networking-server \
+    packagegroup-fsl-networking-extend \
+    packagegroup-fsl-virtualization \
+"
+
+IMAGE_FSTYPES_qoriq = "tar.gz"
-- 
2.9.3

[meta-freescale-distro][PATCH 5/5] add fsl-qoriq distro conf file

[Zhenhua Luo]

Signed-off-by: Zhenhua Luo <zhenhua.luo@nxp.com>
---
 conf/distro/fsl-qoriq.conf | 33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)
 create mode 100644 conf/distro/fsl-qoriq.conf

diff --git a/conf/distro/fsl-qoriq.conf b/conf/distro/fsl-qoriq.conf
new file mode 100644
index 0000000..ef4e057
--- /dev/null
+++ b/conf/distro/fsl-qoriq.conf
@@ -0,0 +1,33 @@
+# FSL distro for QorIQ SDK
+
+require conf/distro/poky.conf
+
+DISTRO = "fsl-qoriq"
+DISTRO_NAME = "QorIQ SDK (FSL Reference Distro)"
+SDK_VENDOR = "-fsl"
+MAINTAINER = "Zhenhua Luo <zhenhua.luo@nxp.com>"
+
+TARGET_VENDOR = "-fsl"
+
+# Customize the DISTRO_FEATURES for QorIQ platforms
+POKY_DEFAULT_DISTRO_FEATURES_remove = " ptest"
+DISTRO_FEATURES_DEFAULT_remove = " pcmcia 3g"
+DISTRO_FEATURES_DEFAULT_append = " benchmark vfat ext2 mtd pam \
+    alsa pulseaudio perl ppp python usbhost virtualization db"
+
+# When meta-openenbedded layer is included, bitbake will complain that
+# multiple providers are available for jpeg (jpeg, libjpeg-turbo).
+PREFERRED_PROVIDER_jpeg ?= "jpeg"
+PREFERRED_PROVIDER_jpeg-native ?= "jpeg-native"
+
+QEMU_TARGETS_append_pn-qemu-native = " ppc64"
+
+# Set the preferred provider of some native java packages which can support
+# QorIQ targets well.
+PREFERRED_PROVIDER_virtual/java-initial-native = "cacao-initial-native"
+PREFERRED_PROVIDER_virtual/java-native = "jamvm-native"
+PREFERRED_PROVIDER_virtual/javac-native = "ecj-bootstrap-native"
+
+# whitelist restricted license to ensure netperf can be included in QorIQ
+# demo images by default.
+LICENSE_FLAGS_WHITELIST = "non-commercial_netperf commercial_lame"
-- 
2.9.3

Re: [meta-freescale-distro][PATCH 1/5] packagegroup-fsl-networking: add recipe

[Otavio Salvador]

On Tue, Mar 21, 2017 at 12:30 AM, Zhenhua Luo <zhenhua.luo@nxp.com> wrote:
> packagegroup-fsl-networking defines the packages group for networking
> support.
>
> Signed-off-by: Zhenhua Luo <zhenhua.luo@nxp.com>

I understand you are trying to include the most common set of packages
you guys use for development and test however this does not belongs to
a package group. Instead, it would be better if we have a validation
image which could include those.

The main goal of the packagegroup should be allow for /features/ to be
added on customer images. We should be careful to not contaminate the
packagegroup with personal preference and choices as it ends making it
harder to be reused and customers end not using it.

-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750

Re: [meta-freescale-distro][PATCH 2/5] packagegroup-fsl-virtualization: add recipe

[Otavio Salvador]

On Tue, Mar 21, 2017 at 12:30 AM, Zhenhua Luo <zhenhua.luo@nxp.com> wrote:
> packagegroup-fsl-virtualization defines the packages group for virtualization
> support.
>
> Signed-off-by: Zhenhua Luo <zhenhua.luo@nxp.com>
> ---
>  .../packagegroup-fsl-virtualization.bb             | 27 ++++++++++++++++++++++
>  1 file changed, 27 insertions(+)
>  create mode 100644 recipes-fsl/packagegroups/packagegroup-fsl-virtualization.bb
>
> diff --git a/recipes-fsl/packagegroups/packagegroup-fsl-virtualization.bb b/recipes-fsl/packagegroups/packagegroup-fsl-virtualization.bb
> new file mode 100644
> index 0000000..774cf0b
> --- /dev/null
> +++ b/recipes-fsl/packagegroups/packagegroup-fsl-virtualization.bb
> @@ -0,0 +1,27 @@
> +# Copyright (C) 2017 NXP Semiconductors
> +# Released under the MIT license (see COPYING.MIT for the terms)
> +DESCRIPTION = "Package group used by NXP Community to provide virtualization packages"
> +SUMMARY = "NXP Community Package group - virtualization, virtualization is \
> +the creation of a virtual -- rather than actual -- version of something, such \
> +as an operating system, it is an important feature of NXP QorIQ platforms, the \
> +major virtualization technique supported by QorIQ includes docker, qemu and lxc"
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +inherit packagegroup
> +
> +PACKAGES = "${PN}"
> +
> +DOCKER-PKGS = ""
> +DOCKER-PKGS_qoriq-arm = "docker docker-registry"
> +DOCKER-PKGS_qoriq-arm64 = "docker docker-registry"
> +
> +RDEPENDS_${PN}_qoriq = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', \
> +    'libvirt \
> +    libvirt-libvirtd \
> +    libvirt-virsh \
> +    lxc \
> +    qemu', \
> +    '', d)} \
> +    ${DOCKER-PKGS} \
> +"

Maybe we could rework this and upstream it?

Think about we having:

packagegroup-virtualization-libvirt
packagegroup-virtualization-lxc
packagegroup-virtualization-qemu
packagegroup-virtualization-docker

and people could add them as their needs raise. This has nothing qoriq
specific (well, docker is generic too) and so it seems to be better to
move to meta-virtualization, no?



-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750