From: Denis Efremov <efremov@linux.com>
To: Julia Lawall <julia.lawall@inria.fr>
Cc: cocci@systeme.lip6.fr, linux-kernel@vger.kernel.org
Subject: [Cocci] [PATCH] coccinelle: misc: add swap script
Date: Tue, 16 Feb 2021 11:01:33 +0300 [thread overview]
Message-ID: <20210216080133.455456-1-efremov@linux.com> (raw)
Check for opencoded swap() implementation.
Signed-off-by: Denis Efremov <efremov@linux.com>
---
scripts/coccinelle/misc/swap.cocci | 77 ++++++++++++++++++++++++++++++
1 file changed, 77 insertions(+)
create mode 100644 scripts/coccinelle/misc/swap.cocci
diff --git a/scripts/coccinelle/misc/swap.cocci b/scripts/coccinelle/misc/swap.cocci
new file mode 100644
index 000000000000..38227a5d0855
--- /dev/null
+++ b/scripts/coccinelle/misc/swap.cocci
@@ -0,0 +1,77 @@
+// SPDX-License-Identifier: GPL-2.0-only
+///
+/// Check for opencoded swap() implementation.
+///
+// Confidence: High
+// Copyright: (C) 2021 Denis Efremov ISPRAS
+// Options: --no-includes --include-headers
+//
+// Keywords: swap
+//
+
+virtual patch
+virtual org
+virtual report
+virtual context
+
+@r depends on !patch@
+identifier tmp;
+expression a, b;
+type T;
+position p;
+@@
+
+(
+* T tmp;
+|
+* T tmp = 0;
+|
+* T *tmp = NULL;
+)
+... when != tmp
+* tmp = a;
+* a = b;@p
+* b = tmp;
+... when != tmp
+
+@depends on patch@
+identifier tmp;
+expression a, b;
+type T;
+@@
+
+(
+- T tmp;
+|
+- T tmp = 0;
+|
+- T *tmp = NULL;
+)
+... when != tmp
+- tmp = a;
+- a = b;
+- b = tmp;
++ swap(a, b);
+... when != tmp
+
+@depends on patch@
+identifier tmp;
+expression a, b;
+@@
+
+- tmp = a;
+- a = b;
+- b = tmp;
++ swap(a, b);
+
+@script:python depends on report@
+p << r.p;
+@@
+
+coccilib.report.print_report(p[0], "WARNING opportunity for swap()")
+
+@script:python depends on org@
+p << r.p;
+@@
+
+coccilib.org.print_todo(p[0], "WARNING opportunity for swap()")
--
2.26.2
_______________________________________________
Cocci mailing list
Cocci@systeme.lip6.fr
https://systeme.lip6.fr/mailman/listinfo/cocci
next reply other threads:[~2021-02-16 8:02 UTC|newest]
Thread overview: 15+ messages / expand[flat|nested] mbox.gz Atom feed top
2021-02-16 8:01 Denis Efremov [this message]
2021-02-16 18:05 ` [Cocci] [PATCH] coccinelle: misc: add swap script Markus Elfring
2021-02-17 21:31 ` Julia Lawall
2021-02-18 6:13 ` Denis Efremov
2021-02-18 10:17 ` Julia Lawall
2021-02-18 11:03 ` Denis Efremov
2021-02-18 11:29 ` Julia Lawall
2021-02-18 11:34 ` Denis Efremov
[not found] ` <50eb8319-a552-c749-6143-7e24a8778a04@web.de>
2021-02-18 20:03 ` Julia Lawall
2021-02-19 9:05 ` [Cocci] [PATCH v2] coccinelle: misc: add minmax script Denis Efremov
2021-02-19 9:07 ` Denis Efremov
2021-02-19 9:24 ` [Cocci] [PATCH v2] coccinelle: misc: add swap script Denis Efremov
2021-03-03 16:37 ` Julia Lawall
2021-03-05 10:09 ` [Cocci] [PATCH v3] " Denis Efremov
[not found] ` <afb06bbc-5c28-8a92-f205-c9a1c87c707c@linux.com>
2021-04-04 12:33 ` Julia Lawall
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20210216080133.455456-1-efremov@linux.com \
--to=efremov@linux.com \
--cc=cocci@systeme.lip6.fr \
--cc=julia.lawall@inria.fr \
--cc=linux-kernel@vger.kernel.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).