From: Julia Lawall <julia.lawall@lip6.fr>
To: Johannes Thumshirn <jthumshirn@suse.de>
Cc: David Sterba <dsterba@suse.com>,
Linux BTRFS Mailinglist <linux-btrfs@vger.kernel.org>,
Masahiro Yamada <yamada.masahiro@socionext.com>
Subject: Re: [RFC PATCH 3/3] coccinelle: api: add offset_in_page.cocci
Date: Thu, 6 Dec 2018 21:15:47 +0100 (CET) [thread overview]
Message-ID: <alpine.DEB.2.21.1812062105180.2464@hadrien> (raw)
In-Reply-To: <e5f96762-d85f-72c0-8c16-696c2f3ae896@suse.de>
On Thu, 6 Dec 2018, Johannes Thumshirn wrote:
> On 05/12/2018 15:46, Julia Lawall wrote:
> [...]
> >> +@r_patch depends on !context && patch && !org && !report@
> >> +expression E;
> >> +type T;
> >> +@@
> >> +
> >> +(
> >> +- E & ~PAGE_MASK
> >> ++ offset_in_page(E)
> >> +|
> >> +- E & (PAGE_SIZE - 1)
> >> ++ offset_in_page(E)
> >
> > The two lines above should be subsumed by the two lines below. When there
> > is a type metavariable that has no other dependencies, an isomorphism will
> > consider that it is either present or absent.
>
> Oh OK, I'm sorry I'm not really into cocinelle so I guessed it might
> take some iterations.
>
> Do you have an example for this?
Expanation 1:
Coccinelle as a file standard.iso that shows the isomorphisms (rewrite
rules) that may be applied to semantic patches. One of the rules is:
Expression
@ not_ptr1 @
expression *X;
@@
!X => X == NULL
So if you have a pointer typed expression X and you write a transformation
on !X, it will also apply to occurrences of X == NULL in the source code.
In this way, you don't have to write so many variants.
Likewise there is an isomorphism:
Expression
@ drop_cast @
expression E;
pure type T;
@@
(T)E => E
That is, if you have a semantic patch with (T)X, then it will also apply
to code that matches just X, without the cast. The word pure means that
this isomorphism metavariable has to match a semantic patch term that is a
metavariable and this metavariable can't be used elsewhere. If you wrote
- (char)x
Then you would probably not want that to apply without the (char) cast.
But if you have just
- (T)x
for some randome unbound metavariable T, then perhaps you don't case about
the cast to T. If you actually do, then you can put disable drop_cast in
the header of your rule.
Explanation 2:
To see what your semantic patch is really doing, you can run
spatch --parse-cocci sp.cocci
Here is what I get for your patch rule, with some annotations added:
@@
expression E;
type T;
@@
(
-E
>>> offset_in_page(E)
-& -~-PAGE_MASK
|
-~
>>> offset_in_page(E)
-PAGE_MASK -& -E
|
// the following come from
// - E & (PAGE_SIZE - 1)
// + offset_in_page(E)
-E // 1
>>> offset_in_page(E)
-& -(-PAGE_SIZE -- -1-)
|
-E // 2
>>> offset_in_page(E)
-& -PAGE_SIZE -- -1
|
-( // 3
>>> offset_in_page(E)
-PAGE_SIZE -- -1-) -& -E
|
-PAGE_SIZE // 4
>>> offset_in_page(E)
-- -1 -& -E
|
// the following come from:
// - E & ((T)PAGE_SIZE - 1)
// + offset_in_page(E)
-E
>>> offset_in_page(E)
-& -(-(-T -)-PAGE_SIZE -- -1-)
|
-E // same as 1
>>> offset_in_page(E)
-& -(-PAGE_SIZE -- -1-)
|
-E
>>> offset_in_page(E)
-& -(-T -)-PAGE_SIZE -- -1
|
-E // same as 2
>>> offset_in_page(E)
-& -PAGE_SIZE -- -1
|
-(
>>> offset_in_page(E)
-(-T -)-PAGE_SIZE -- -1-) -& -E
|
-( // same as 3
>>> offset_in_page(E)
-PAGE_SIZE -- -1-) -& -E
|
-(
>>> offset_in_page(E)
-T -)-PAGE_SIZE -- -1 -& -E
|
-PAGE_SIZE // same as 4
>>> offset_in_page(E)
-- -1 -& -E
)
So all the transformation generated by
- E & (PAGE_SIZE - 1)
+ offset_in_page(E)
are also generated by
- E & ((T)PAGE_SIZE - 1)
+ offset_in_page(E)
I hope that is helpful.
julia
next prev parent reply other threads:[~2018-12-06 20:15 UTC|newest]
Thread overview: 10+ messages / expand[flat|nested] mbox.gz Atom feed top
2018-12-05 14:23 [PATCH 0/3] btrfs: use offset_in_page and PAGE_ALIGNED Johannes Thumshirn
2018-12-05 14:23 ` [PATCH 1/3] btrfs: use offset_in_page instead of open-coding it Johannes Thumshirn
2018-12-05 14:32 ` Nikolay Borisov
2018-12-05 14:23 ` [PATCH 2/3] btrfs: use PAGE_ALIGNED " Johannes Thumshirn
2018-12-05 14:31 ` Nikolay Borisov
2018-12-05 14:23 ` [RFC PATCH 3/3] coccinelle: api: add offset_in_page.cocci Johannes Thumshirn
2018-12-05 14:46 ` Julia Lawall
2018-12-06 17:11 ` Johannes Thumshirn
2018-12-06 20:15 ` Julia Lawall [this message]
2018-12-06 14:54 ` [PATCH 0/3] btrfs: use offset_in_page and PAGE_ALIGNED David Sterba
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=alpine.DEB.2.21.1812062105180.2464@hadrien \
--to=julia.lawall@lip6.fr \
--cc=dsterba@suse.com \
--cc=jthumshirn@suse.de \
--cc=linux-btrfs@vger.kernel.org \
--cc=yamada.masahiro@socionext.com \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).