From: Julia Lawall <Julia.Lawall@lip6.fr>
To: linux-kernel@vger.kernel.org
Cc: kernel-janitors@vger.kernel.org
Subject: [PATCH 0/7] fix error return code
Date: Wed, 29 Aug 2012 18:49:10 +0200 [thread overview]
Message-ID: <1346258957-7649-1-git-send-email-Julia.Lawall@lip6.fr> (raw)
These patches fix cases where the return code appears to be unintentially
nonnegative.
The complete semantic match that finds the problem is as follows:
(http://coccinelle.lip6.fr/)
// <smpl>
@ok exists@
identifier f,ret,i;
expression e;
constant c;
@@
f(...) {
<+...
(
return -c@i;
|
ret = -c@i;
... when != ret = e
return ret;
|
if (ret < 0) { ... return ret; }
)
...+> }
@r exists@
identifier ret,l,ok.f;
expression e1,e2,e3;
statement S;
position p1,p2,p3;
@@
f(...) {
... when any
(
if@p1 (\(ret < 0\|ret != 0\))
{ ... return ret; }
|
ret@p1 = 0
)
... when != ret = e1
when != &ret
(
if (<+... ret = e3 ...+>) S
|
if (<+... &ret ...+>) S
|
if@p2(...)
{
... when != ret = e2
when forall
return@p3 ret;
}
)
... when any
}
@bad exists@
position r.p1,r.p2;
statement S1,S2;
identifier r.ret;
expression e1;
@@
(
if@p1 (\(ret < 0\|ret != 0\)) S1
|
ret@p1 = 0
)
... when any
ret = e1
... when any
if@p2(...) S2
@bad2@
position r.p1,r.p2;
identifier r.ret;
expression e1;
statement S2;
@@
ret@p1 = 0
... when != if (...) { ... ret = e1 ... return ret; }
when any
if@p2(...) S2
@script:python depends on !bad && !bad2@
p1 << r.p1;
p2 << r.p2;
p3 << r.p3;
@@
cocci.print_main("",p1)
cocci.print_secs("",p2)
cocci.print_secs("",p3)
// </smpl>
next reply other threads:[~2012-08-29 16:49 UTC|newest]
Thread overview: 17+ messages / expand[flat|nested] mbox.gz Atom feed top
2012-08-29 16:49 Julia Lawall [this message]
2012-08-29 16:49 ` [PATCH 1/7] ipvs: fix error return code Julia Lawall
2012-08-30 1:12 ` Simon Horman
2012-08-30 1:34 ` Pablo Neira Ayuso
2012-08-29 16:49 ` [PATCH 2/7] net: ipv6: " Julia Lawall
2012-08-31 20:28 ` David Miller
2012-08-29 16:49 ` [PATCH 3/7] logfs: " Julia Lawall
2012-08-29 16:49 ` [PATCH 4/7] net/bluetooth/rfcomm/core.c: " Julia Lawall
2012-08-29 18:23 ` Marcel Holtmann
2012-08-29 16:49 ` [PATCH 5/7] net/xfrm/xfrm_state.c: " Julia Lawall
2012-08-31 20:28 ` David Miller
2012-08-29 16:49 ` [PATCH 7/7] net/netfilter/nf_conntrack_netlink.c: " Julia Lawall
2012-08-30 1:35 ` Pablo Neira Ayuso
2012-08-29 16:49 ` [PATCH 6/7] net/netfilter/nfnetlink_log.c: " Julia Lawall
2012-08-30 1:35 ` Pablo Neira Ayuso
2014-11-20 17:33 [PATCH 0/7] " Julia Lawall
2015-12-26 15:28 Julia Lawall
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1346258957-7649-1-git-send-email-Julia.Lawall@lip6.fr \
--to=julia.lawall@lip6.fr \
--cc=kernel-janitors@vger.kernel.org \
--cc=linux-kernel@vger.kernel.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).