From: Stephen Boyd <swboyd@chromium.org>
To: Julia Lawall <Julia.Lawall@lip6.fr>,
Gilles Muller <Gilles.Muller@lip6.fr>,
Nicolas Palix <nicolas.palix@imag.fr>,
Michal Marek <michal.lkml@markovi.net>
Cc: linux-kernel@vger.kernel.org, cocci@systeme.lip6.fr,
Greg Kroah-Hartman <gregkh@linuxfoundation.org>,
Rob Herring <robh@kernel.org>,
Bartlomiej Zolnierkiewicz <b.zolnierkie@samsung.com>,
Javier Martinez Canillas <javierm@redhat.com>,
Andrzej Hajda <a.hajda@samsung.com>,
Mark Brown <broonie@kernel.org>,
Russell King - ARM Linux <linux@armlinux.org.uk>,
Marek Szyprowski <m.szyprowski@samsung.com>,
"Rafael J . Wysocki" <rafael.j.wysocki@intel.com>,
Andy Shevchenko <andy.shevchenko@gmail.com>,
Markus Elfring <Markus.Elfring@web.de>
Subject: [PATCH v5 3/3] coccinelle: Add script to check for platform_get_irq() excessive prints
Date: Mon, 29 Jul 2019 22:38:45 -0700 [thread overview]
Message-ID: <20190730053845.126834-4-swboyd@chromium.org> (raw)
In-Reply-To: <20190730053845.126834-1-swboyd@chromium.org>
Add a coccinelle script to check for the usage of dev_err() after a call
to platform_get_irq{,_byname}() as it's redundant now that the function
already prints an error when it fails.
Cc: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
Cc: Rob Herring <robh@kernel.org>
Cc: Bartlomiej Zolnierkiewicz <b.zolnierkie@samsung.com>
Cc: Javier Martinez Canillas <javierm@redhat.com>
Cc: Andrzej Hajda <a.hajda@samsung.com>
Cc: Mark Brown <broonie@kernel.org>
Cc: Russell King - ARM Linux <linux@armlinux.org.uk>
Cc: Marek Szyprowski <m.szyprowski@samsung.com>
Cc: Rafael J. Wysocki <rafael.j.wysocki@intel.com>
Cc: Andy Shevchenko <andy.shevchenko@gmail.com>
Cc: Markus Elfring <Markus.Elfring@web.de>
Signed-off-by: Stephen Boyd <swboyd@chromium.org>
---
I'm not sure this will be accepted or not given that Markus indicates a
similar patch was made for other error messages that this may be able
to be merged into. Just sending again anyway to keep things together.
scripts/coccinelle/api/platform_get_irq.cocci | 102 ++++++++++++++++++
1 file changed, 102 insertions(+)
create mode 100644 scripts/coccinelle/api/platform_get_irq.cocci
diff --git a/scripts/coccinelle/api/platform_get_irq.cocci b/scripts/coccinelle/api/platform_get_irq.cocci
new file mode 100644
index 000000000000..543ae11400e7
--- /dev/null
+++ b/scripts/coccinelle/api/platform_get_irq.cocci
@@ -0,0 +1,102 @@
+// SPDX-License-Identifier: GPL-2.0
+/// Remove dev_err() messages after platform_get_irq*() failures
+//
+// Confidence: Medium
+// Options: --include-headers
+
+virtual patch
+virtual context
+virtual org
+virtual report
+
+@depends on context@
+expression ret;
+struct platform_device *E;
+@@
+
+ret =
+(
+platform_get_irq
+|
+platform_get_irq_byname
+)(E, ...);
+
+if ( ret \( < \| <= \) 0 )
+{
+(
+if (ret != -EPROBE_DEFER)
+{ ...
+*dev_err(...);
+... }
+|
+...
+*dev_err(...);
+)
+...
+}
+
+@depends on patch@
+expression ret;
+struct platform_device *E;
+@@
+
+ret =
+(
+platform_get_irq
+|
+platform_get_irq_byname
+)(E, ...);
+
+if ( ret \( < \| <= \) 0 )
+{
+(
+-if (ret != -EPROBE_DEFER)
+-{ ...
+-dev_err(...);
+-... }
+|
+...
+-dev_err(...);
+)
+...
+}
+
+@r depends on org || report@
+position p1;
+expression ret;
+struct platform_device *E;
+@@
+
+ret =
+(
+platform_get_irq
+|
+platform_get_irq_byname
+)(E, ...);
+
+if ( ret \( < \| <= \) 0 )
+{
+(
+if (ret != -EPROBE_DEFER)
+{ ...
+dev_err@p1(...);
+... }
+|
+...
+dev_err@p1(...);
+)
+...
+}
+
+@script:python depends on org@
+p1 << r.p1;
+@@
+
+cocci.print_main(p1)
+
+@script:python depends on report@
+p1 << r.p1;
+@@
+
+msg = "line %s is redundant because platform_get_irq() already prints an error" % (p1[0].line)
+coccilib.report.print_report(p1[0],msg)
--
Sent by a computer through tubes
next prev parent reply other threads:[~2019-07-30 5:38 UTC|newest]
Thread overview: 20+ messages / expand[flat|nested] mbox.gz Atom feed top
2019-07-30 5:38 [PATCH v5 0/3] Add error message to platform_get_irq*() Stephen Boyd
2019-07-30 5:38 ` [PATCH v5 1/3] driver core: platform: Add an " Stephen Boyd
2019-07-30 9:44 ` Markus Elfring
2019-07-30 12:30 ` Markus Elfring
2019-07-30 5:38 ` [PATCH v5 2/3] treewide: Remove dev_err() usage after platform_get_irq() Stephen Boyd
2019-07-30 6:49 ` Greg Kroah-Hartman
2019-07-30 15:35 ` Stephen Boyd
2019-07-30 15:51 ` Greg Kroah-Hartman
2019-07-30 17:16 ` Andy Shevchenko
2019-07-30 17:17 ` Andy Shevchenko
2019-07-30 17:21 ` Stephen Boyd
2019-07-30 17:31 ` Andy Shevchenko
2019-07-30 10:00 ` [v5 " Markus Elfring
2019-07-30 10:00 ` Markus Elfring
2019-07-30 5:38 ` Stephen Boyd [this message]
2019-07-30 8:49 ` [PATCH v5 3/3] coccinelle: Add script to check for platform_get_irq() excessive prints Markus Elfring
2019-07-31 14:26 ` [Cocci] [PATCH v5 0/3] Add error message to platform_get_irq*() Wolfram Sang
2019-07-31 14:52 ` Stephen Boyd
2019-08-01 12:25 ` Wolfram Sang
2019-08-08 7:51 ` Geert Uytterhoeven
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20190730053845.126834-4-swboyd@chromium.org \
--to=swboyd@chromium.org \
--cc=Gilles.Muller@lip6.fr \
--cc=Julia.Lawall@lip6.fr \
--cc=Markus.Elfring@web.de \
--cc=a.hajda@samsung.com \
--cc=andy.shevchenko@gmail.com \
--cc=b.zolnierkie@samsung.com \
--cc=broonie@kernel.org \
--cc=cocci@systeme.lip6.fr \
--cc=gregkh@linuxfoundation.org \
--cc=javierm@redhat.com \
--cc=linux-kernel@vger.kernel.org \
--cc=linux@armlinux.org.uk \
--cc=m.szyprowski@samsung.com \
--cc=michal.lkml@markovi.net \
--cc=nicolas.palix@imag.fr \
--cc=rafael.j.wysocki@intel.com \
--cc=robh@kernel.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).