[PATCH 1/5] graphviz(-native): initial add 2.40.1

* [PATCH 1/5] graphviz(-native): initial add 2.40.1
@ 2019-01-22  0:37 Andreas Müller
  2019-01-22  0:37 ` [PATCH 2/5] python(3)-html5lib: extend to native(sdk) Andreas Müller
                   ` (3 more replies)
  0 siblings, 4 replies; 5+ messages in thread
From: Andreas Müller @ 2019-01-22  0:37 UTC (permalink / raw)
  To: openembedded-devel

Graphviz is helpful for creating docs with doxygen (at least)

Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
---
 .../graphviz/0001-Use-native-mkdefs.patch     | 31 ++++++++++++
 .../graphviz/graphviz_2.40.1.bb               | 49 +++++++++++++++++++
 2 files changed, 80 insertions(+)
 create mode 100644 meta-oe/recipes-graphics/graphviz/graphviz/0001-Use-native-mkdefs.patch
 create mode 100644 meta-oe/recipes-graphics/graphviz/graphviz_2.40.1.bb

diff --git a/meta-oe/recipes-graphics/graphviz/graphviz/0001-Use-native-mkdefs.patch b/meta-oe/recipes-graphics/graphviz/graphviz/0001-Use-native-mkdefs.patch
new file mode 100644
index 000000000..eb51d03d2
--- /dev/null
+++ b/meta-oe/recipes-graphics/graphviz/graphviz/0001-Use-native-mkdefs.patch
@@ -0,0 +1,31 @@
+From 5e53b643615fd53f3ff960521bbe9d95641e5f68 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Andreas=20M=C3=BCller?= <schnitzeltony@gmail.com>
+Date: Sun, 20 Jan 2019 23:58:29 +0100
+Subject: [PATCH] Use native mkdefs
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+Upstream-Status: Inappropriate [embedded specific]
+
+Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
+---
+ lib/gvpr/Makefile.am | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/lib/gvpr/Makefile.am b/lib/gvpr/Makefile.am
+index ac3c098..4914854 100644
+--- a/lib/gvpr/Makefile.am
++++ b/lib/gvpr/Makefile.am
+@@ -57,7 +57,7 @@ endif
+ mkdefs_SOURCES = mkdefs.c
+ 
+ gdefs.h: $(top_srcdir)/lib/gvpr/gprdata mkdefs$(EXEEXT)
+-	./mkdefs$(EXEEXT) gdefs.h < $(top_srcdir)/lib/gvpr/gprdata
++	mkdefs$(EXEEXT) gdefs.h < $(top_srcdir)/lib/gvpr/gprdata
+ 
+ EXTRA_DIST = $(man_MANS) $(pdf_DATA) gprdata mkdefs.c gdefs.h trie.c gvprlib.vcxproj*
+ 
+-- 
+2.20.1
+
diff --git a/meta-oe/recipes-graphics/graphviz/graphviz_2.40.1.bb b/meta-oe/recipes-graphics/graphviz/graphviz_2.40.1.bb
new file mode 100644
index 000000000..96f1efc60
--- /dev/null
+++ b/meta-oe/recipes-graphics/graphviz/graphviz_2.40.1.bb
@@ -0,0 +1,49 @@
+SUMMARY = "Graph Visualization Tools"
+HOMEPAGE = "http://www.graphviz.org"
+LICENSE = "EPL-1.0"
+LIC_FILES_CHKSUM = "file://COPYING;md5=9109f5fc16cf963fb3cdd32781b3ce04"
+
+DEPENDS = " \
+    intltool-native \
+    bison-native \
+    groff-native \
+    libtool \
+    gdk-pixbuf \
+    librsvg \
+    cairo \
+    pango \
+    expat \
+    freetype \
+"
+DEPENDS_append_class-target = " ${BPN}-native"
+
+inherit autotools-brokensep pkgconfig gtk-doc gettext
+
+# The source tarball suggested at
+# https://graphviz.gitlab.io/_pages/Download/Download_source.html has no
+# version in its name. So once graphviz is updgraded, only first time users will
+# get checksum errors. Fedora people seem to expect same so they use a versioned
+# source - see https://src.fedoraproject.org/cgit/rpms/graphviz.git/tree/graphviz.spec
+
+SRC_URI = "https://gitlab.com/graphviz/graphviz/-/archive/stable_release_${PV}/graphviz-stable_release_${PV}.tar.gz"
+SRC_URI[md5sum] = "2acf30ca8e6cc8b001b0334db65fd072"
+SRC_URI[sha256sum] = "e6c3f8dbfde1c4523055403927bef29f97f9fc12715c1042b5dcf648a2c1c62a"
+# Use native mkdefs
+SRC_URI_append_class-target = " file://0001-Use-native-mkdefs.patch"
+
+S = "${WORKDIR}/${BPN}-stable_release_${PV}"
+
+do_configure_prepend() {
+    cd ${S}
+    # create version.m4 and ignore libtoolize errors
+    ./autogen.sh NOCONFIG || true
+}
+
+do_install_append_class-native() {
+    # install mkdefs for target build
+    install -m755 ${B}/lib/gvpr/mkdefs ${D}${bindir}
+}
+
+FILES_SOLIBSDEV_append = " ${libdir}/graphviz/lib*${SOLIBSDEV}"
+
+BBCLASSEXTEND = "native"
-- 
2.20.1



^ permalink raw reply related	[flat|nested] 5+ messages in thread