* [PATCH 1/9] arm/scp-firmware: merge bb/inc
@ 2020-07-29 10:11 Ross Burton
2020-07-29 10:11 ` [PATCH 2/9] arm/scp-firmware: oe_runmake already passes EXTRA_OEMAKE Ross Burton
` (8 more replies)
0 siblings, 9 replies; 12+ messages in thread
From: Ross Burton @ 2020-07-29 10:11 UTC (permalink / raw)
To: meta-arm
From: Ross Burton <ross.burton@arm.com>
There's no other recipe that uses scp-firmware.inc, so merge it into the
recipe for clarity.
Change-Id: Ife1874b54c8b2be2704e1d0f5a7013ff89b8ca6e
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
.../recipes-bsp/scp-firmware/scp-firmware.inc | 73 -------------------
.../scp-firmware/scp-firmware_git.bb | 73 ++++++++++++++++++-
2 files changed, 72 insertions(+), 74 deletions(-)
delete mode 100644 meta-arm/recipes-bsp/scp-firmware/scp-firmware.inc
diff --git a/meta-arm/recipes-bsp/scp-firmware/scp-firmware.inc b/meta-arm/recipes-bsp/scp-firmware/scp-firmware.inc
deleted file mode 100644
index 2db59d3..0000000
--- a/meta-arm/recipes-bsp/scp-firmware/scp-firmware.inc
+++ /dev/null
@@ -1,73 +0,0 @@
-SUMMARY = "SCP and MCP Firmware"
-
-PROVIDES += "virtual/control-processor-firmware"
-
-SCP_BUILD_RELEASE ?= "1"
-SCP_COMPILE_VERBOSE ?= "0"
-SCP_PLATFORM ?= "invalid"
-SCP_COMPILER ?= "arm-none-eabi"
-SCP_LOG_LEVEL ?= "WARN"
-
-DEPENDS += "virtual/arm-none-eabi-gcc-native"
-
-SCP_BUILD_STR = "${@bb.utils.contains('SCP_BUILD_RELEASE', '1', 'release', 'debug', d)}"
-SCP_COMP_STR = "${@bb.utils.contains('SCP_COMPILE_VERBOSE', '0', '', 'V=1', d)}"
-
-inherit python3native
-inherit deploy
-
-B = "${WORKDIR}/build"
-S = "${WORKDIR}/src"
-
-# Allow platform specific copying of only scp or both scp & mcp, default to both
-FW_TARGETS ?= "scp mcp"
-
-COMPATIBLE_MACHINE ?= "invalid"
-
-LDFLAGS[unexport] = "1"
-
-# The gcc-arm-none-eabi version does not support -fmacro-prefix-max
-DEBUG_PREFIX_MAP_pn-scp = "\
- -fdebug-prefix-map=${WORKDIR}=/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR} \
- -fdebug-prefix-map=${STAGING_DIR_HOST}= \
- -fdebug-prefix-map=${STAGING_DIR_NATIVE}= \
-"
-
-# No configure
-do_configure[noexec] = "1"
-
-EXTRA_OEMAKE = "${SCP_COMP_STR} \
- BUILD_PATH='${B}' \
- PRODUCT='${SCP_PLATFORM}' \
- MODE='${SCP_BUILD_STR}' \
- LOG_LEVEL='${SCP_LOG_LEVEL}' \
- CC='${SCP_COMPILER}-gcc' \
- AR='${SCP_COMPILER}-ar' \
- SIZE='${SCP_COMPILER}-size' \
- OBJCOPY='${SCP_COMPILER}-objcopy' \
- "
-
-do_compile() {
- oe_runmake -C "${S}" ${EXTRA_OEMAKE}
-}
-do_compile[cleandirs] += "${B}"
-
-do_install() {
- install -d ${D}/firmware
- for FW in ${FW_TARGETS}; do
- for TYPE in ramfw romfw; do
- install -D "${B}/product/${SCP_PLATFORM}/${FW}_${TYPE}/release/bin/${FW}_${TYPE}.bin" "${D}/firmware/"
- done
- done
-}
-
-FILES_${PN} = "/firmware"
-SYSROOT_DIRS += "/firmware"
-# Skip QA check for relocations in .text of elf binaries
-INSANE_SKIP_${PN} = "textrel"
-
-do_deploy() {
- # Copy the images to deploy directory
- cp -rf ${D}/firmware/* ${DEPLOYDIR}/
-}
-addtask deploy after do_install
diff --git a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
index 9cb8b64..e9d8057 100644
--- a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
+++ b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
@@ -1,3 +1,4 @@
+SUMMARY = "SCP and MCP Firmware"
DESCRIPTION = "Firmware for SCP and MCP software reference implementation"
HOMEPAGE = "https://github.com/ARM-software/SCP-firmware"
@@ -17,4 +18,74 @@ SRCREV_scp = "fd7c83561a7d76c7681d5d017fb23aa3664c028c"
SRCREV_cmsis = "refs/tags/5.2.0"
SRCREV_FORMAT = "scp_cmsis"
-require scp-firmware.inc
+PROVIDES += "virtual/control-processor-firmware"
+
+SCP_BUILD_RELEASE ?= "1"
+SCP_COMPILE_VERBOSE ?= "0"
+SCP_PLATFORM ?= "invalid"
+SCP_COMPILER ?= "arm-none-eabi"
+SCP_LOG_LEVEL ?= "WARN"
+
+DEPENDS += "virtual/arm-none-eabi-gcc-native"
+
+SCP_BUILD_STR = "${@bb.utils.contains('SCP_BUILD_RELEASE', '1', 'release', 'debug', d)}"
+SCP_COMP_STR = "${@bb.utils.contains('SCP_COMPILE_VERBOSE', '0', '', 'V=1', d)}"
+
+inherit python3native
+inherit deploy
+
+B = "${WORKDIR}/build"
+S = "${WORKDIR}/src"
+
+# Allow platform specific copying of only scp or both scp & mcp, default to both
+FW_TARGETS ?= "scp mcp"
+
+COMPATIBLE_MACHINE ?= "invalid"
+
+LDFLAGS[unexport] = "1"
+
+# The gcc-arm-none-eabi version does not support -fmacro-prefix-max
+DEBUG_PREFIX_MAP_pn-scp = "\
+ -fdebug-prefix-map=${WORKDIR}=/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR} \
+ -fdebug-prefix-map=${STAGING_DIR_HOST}= \
+ -fdebug-prefix-map=${STAGING_DIR_NATIVE}= \
+"
+
+# No configure
+do_configure[noexec] = "1"
+
+EXTRA_OEMAKE = "${SCP_COMP_STR} \
+ BUILD_PATH='${B}' \
+ PRODUCT='${SCP_PLATFORM}' \
+ MODE='${SCP_BUILD_STR}' \
+ LOG_LEVEL='${SCP_LOG_LEVEL}' \
+ CC='${SCP_COMPILER}-gcc' \
+ AR='${SCP_COMPILER}-ar' \
+ SIZE='${SCP_COMPILER}-size' \
+ OBJCOPY='${SCP_COMPILER}-objcopy' \
+ "
+
+do_compile() {
+ oe_runmake -C "${S}" ${EXTRA_OEMAKE}
+}
+do_compile[cleandirs] += "${B}"
+
+do_install() {
+ install -d ${D}/firmware
+ for FW in ${FW_TARGETS}; do
+ for TYPE in ramfw romfw; do
+ install -D "${B}/product/${SCP_PLATFORM}/${FW}_${TYPE}/release/bin/${FW}_${TYPE}.bin" "${D}/firmware/"
+ done
+ done
+}
+
+FILES_${PN} = "/firmware"
+SYSROOT_DIRS += "/firmware"
+# Skip QA check for relocations in .text of elf binaries
+INSANE_SKIP_${PN} = "textrel"
+
+do_deploy() {
+ # Copy the images to deploy directory
+ cp -rf ${D}/firmware/* ${DEPLOYDIR}/
+}
+addtask deploy after do_install
--
2.26.2
^ permalink raw reply related [flat|nested] 12+ messages in thread
* [PATCH 2/9] arm/scp-firmware: oe_runmake already passes EXTRA_OEMAKE
2020-07-29 10:11 [PATCH 1/9] arm/scp-firmware: merge bb/inc Ross Burton
@ 2020-07-29 10:11 ` Ross Burton
2020-07-29 10:11 ` [PATCH 3/9] arm/scp-firmware: always compile verbosely Ross Burton
` (7 subsequent siblings)
8 siblings, 0 replies; 12+ messages in thread
From: Ross Burton @ 2020-07-29 10:11 UTC (permalink / raw)
To: meta-arm
From: Ross Burton <ross.burton@arm.com>
oe_runmake adds EXTRA_OEMAKE to the arguments, so there's no need to do
it again.
Change-Id: Id8f078faecba72156a4626c960fc7113a70c8eba
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
index e9d8057..886d56c 100644
--- a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
+++ b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
@@ -66,7 +66,7 @@ EXTRA_OEMAKE = "${SCP_COMP_STR} \
"
do_compile() {
- oe_runmake -C "${S}" ${EXTRA_OEMAKE}
+ oe_runmake -C "${S}"
}
do_compile[cleandirs] += "${B}"
--
2.26.2
^ permalink raw reply related [flat|nested] 12+ messages in thread
* [PATCH 3/9] arm/scp-firmware: always compile verbosely
2020-07-29 10:11 [PATCH 1/9] arm/scp-firmware: merge bb/inc Ross Burton
2020-07-29 10:11 ` [PATCH 2/9] arm/scp-firmware: oe_runmake already passes EXTRA_OEMAKE Ross Burton
@ 2020-07-29 10:11 ` Ross Burton
2020-07-29 10:11 ` [PATCH 4/9] arm/scp-firmware: use gitsm fetcher Ross Burton
` (6 subsequent siblings)
8 siblings, 0 replies; 12+ messages in thread
From: Ross Burton @ 2020-07-29 10:11 UTC (permalink / raw)
To: meta-arm
From: Ross Burton <ross.burton@arm.com>
The only downside of verbose builds is that the compile logs are larger,
but non-verbose logs are useless for debugging mysterious build failures.
Remove the option and always do a verbose build.
Change-Id: Ibfd0414f0f6d0d69e20ec1fadcae8e86b516d3fc
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb | 4 +---
1 file changed, 1 insertion(+), 3 deletions(-)
diff --git a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
index 886d56c..d7d67e0 100644
--- a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
+++ b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
@@ -21,7 +21,6 @@ SRCREV_FORMAT = "scp_cmsis"
PROVIDES += "virtual/control-processor-firmware"
SCP_BUILD_RELEASE ?= "1"
-SCP_COMPILE_VERBOSE ?= "0"
SCP_PLATFORM ?= "invalid"
SCP_COMPILER ?= "arm-none-eabi"
SCP_LOG_LEVEL ?= "WARN"
@@ -29,7 +28,6 @@ SCP_LOG_LEVEL ?= "WARN"
DEPENDS += "virtual/arm-none-eabi-gcc-native"
SCP_BUILD_STR = "${@bb.utils.contains('SCP_BUILD_RELEASE', '1', 'release', 'debug', d)}"
-SCP_COMP_STR = "${@bb.utils.contains('SCP_COMPILE_VERBOSE', '0', '', 'V=1', d)}"
inherit python3native
inherit deploy
@@ -54,7 +52,7 @@ DEBUG_PREFIX_MAP_pn-scp = "\
# No configure
do_configure[noexec] = "1"
-EXTRA_OEMAKE = "${SCP_COMP_STR} \
+EXTRA_OEMAKE = "V=1 \
BUILD_PATH='${B}' \
PRODUCT='${SCP_PLATFORM}' \
MODE='${SCP_BUILD_STR}' \
--
2.26.2
^ permalink raw reply related [flat|nested] 12+ messages in thread
* [PATCH 4/9] arm/scp-firmware: use gitsm fetcher
2020-07-29 10:11 [PATCH 1/9] arm/scp-firmware: merge bb/inc Ross Burton
2020-07-29 10:11 ` [PATCH 2/9] arm/scp-firmware: oe_runmake already passes EXTRA_OEMAKE Ross Burton
2020-07-29 10:11 ` [PATCH 3/9] arm/scp-firmware: always compile verbosely Ross Burton
@ 2020-07-29 10:11 ` Ross Burton
2020-07-30 8:37 ` Ross Burton
2020-07-29 10:11 ` [PATCH 5/9] arm-bsp/scp-firmware: remove cmsis SRCREV Ross Burton
` (5 subsequent siblings)
8 siblings, 1 reply; 12+ messages in thread
From: Ross Burton @ 2020-07-29 10:11 UTC (permalink / raw)
To: meta-arm
From: Ross Burton <ross.burton@arm.com>
The standard git fetcher ignores submodules but as scp-firmware uses
submodules it should use the gitsm: fetcher to automatically fetch cmsis
instead of doing it manually.
Change-Id: I2f83100fa53070b6560be6fb7322383345224bb1
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
.../recipes-bsp/scp-firmware/scp-firmware_git.bb | 16 +++-------------
1 file changed, 3 insertions(+), 13 deletions(-)
diff --git a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
index d7d67e0..a211621 100644
--- a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
+++ b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
@@ -3,20 +3,10 @@ DESCRIPTION = "Firmware for SCP and MCP software reference implementation"
HOMEPAGE = "https://github.com/ARM-software/SCP-firmware"
LICENSE = "BSD-3-Clause & Apache-2.0"
-
-# SCP
LIC_FILES_CHKSUM = "file://license.md;beginline=5;md5=9db9e3d2fb8d9300a6c3d15101b19731"
-# CMSIS
-LIC_FILES_CHKSUM += "file://cmsis/LICENSE.txt;md5=e3fc50a88d0a364313df4b21ef20c29e"
-
-SRC_URI = "\
- git://github.com/ARM-software/SCP-firmware.git;protocol=https;name=scp;destsuffix=src;nobranch=1 \
- git://github.com/ARM-software/CMSIS_5.git;protocol=https;name=cmsis;destsuffix=src/cmsis;lfs=0;nobranch=1 \
-"
-SRCREV_scp = "fd7c83561a7d76c7681d5d017fb23aa3664c028c"
-SRCREV_cmsis = "refs/tags/5.2.0"
-SRCREV_FORMAT = "scp_cmsis"
+SRC_URI = "gitsm://github.com/ARM-software/SCP-firmware.git;protocol=https"
+SRCREV = "fd7c83561a7d76c7681d5d017fb23aa3664c028c"
PROVIDES += "virtual/control-processor-firmware"
@@ -33,7 +23,7 @@ inherit python3native
inherit deploy
B = "${WORKDIR}/build"
-S = "${WORKDIR}/src"
+S = "${WORKDIR}/git"
# Allow platform specific copying of only scp or both scp & mcp, default to both
FW_TARGETS ?= "scp mcp"
--
2.26.2
^ permalink raw reply related [flat|nested] 12+ messages in thread
* [PATCH 5/9] arm-bsp/scp-firmware: remove cmsis SRCREV
2020-07-29 10:11 [PATCH 1/9] arm/scp-firmware: merge bb/inc Ross Burton
` (2 preceding siblings ...)
2020-07-29 10:11 ` [PATCH 4/9] arm/scp-firmware: use gitsm fetcher Ross Burton
@ 2020-07-29 10:11 ` Ross Burton
2020-07-29 10:11 ` [PATCH 6/9] arm-bsp/scp-firmware: use wildcard bbappend Ross Burton
` (4 subsequent siblings)
8 siblings, 0 replies; 12+ messages in thread
From: Ross Burton @ 2020-07-29 10:11 UTC (permalink / raw)
To: meta-arm
From: Ross Burton <ross.burton@arm.com>
This repository is no longer fetched explicitly by bitbake so remove the SRCREVs.
Change-Id: I2de11d354f1f708de941485d5cc4463d53e6018e
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
.../recipes-bsp/scp-firmware/scp-firmware-n1sdp.inc | 3 +--
meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-tc0.inc | 6 ++----
2 files changed, 3 insertions(+), 6 deletions(-)
diff --git a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-n1sdp.inc b/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-n1sdp.inc
index ddbaac4..4886a44 100644
--- a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-n1sdp.inc
+++ b/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-n1sdp.inc
@@ -1,7 +1,6 @@
# N1SDP specific SCP configurations and build instructions
-SRCREV_scp = "fd7c83561a7d76c7681d5d017fb23aa3664c028c"
-SRCREV_cmsis = "refs/tags/5.2.0"
+SRCREV = "fd7c83561a7d76c7681d5d017fb23aa3664c028c"
SCP_PLATFORM = "n1sdp"
SCP_LOG_LEVEL = "INFO"
diff --git a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-tc0.inc b/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-tc0.inc
index 5b29305..b4e86fb 100644
--- a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-tc0.inc
+++ b/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-tc0.inc
@@ -1,9 +1,7 @@
-# TC0 specicif SCP configuration
+# TC0 specific SCP configuration
# Intermediate SHA with 2.6 baseline version
-SRCREV_scp = "ba1db5fb0ee4a520836722f7a694177d461ab716"
-# 5.2.0 tag commit
-SRCREV_cmsis = "80cc44bba16cb4c8f495b7aa9709d41ac50e9529"
+SRCREV = "ba1db5fb0ee4a520836722f7a694177d461ab716"
COMPATIBLE_MACHINE = "tc0"
--
2.26.2
^ permalink raw reply related [flat|nested] 12+ messages in thread
* [PATCH 6/9] arm-bsp/scp-firmware: use wildcard bbappend
2020-07-29 10:11 [PATCH 1/9] arm/scp-firmware: merge bb/inc Ross Burton
` (3 preceding siblings ...)
2020-07-29 10:11 ` [PATCH 5/9] arm-bsp/scp-firmware: remove cmsis SRCREV Ross Burton
@ 2020-07-29 10:11 ` Ross Burton
2020-07-29 10:11 ` [PATCH 7/9] arm/scp-firmware: move to 2.6.0 release tag Ross Burton
` (3 subsequent siblings)
8 siblings, 0 replies; 12+ messages in thread
From: Ross Burton @ 2020-07-29 10:11 UTC (permalink / raw)
To: meta-arm
From: Ross Burton <ross.burton@arm.com>
This doesn't care what specific version is being appended, so use a
wildcard.
Change-Id: I5e3a46c42616f8dfa62a20549c03b60e24fe8b20
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
.../{scp-firmware_git.bbappend => scp-firmware_%.bbappend} | 0
1 file changed, 0 insertions(+), 0 deletions(-)
rename meta-arm-bsp/recipes-bsp/scp-firmware/{scp-firmware_git.bbappend => scp-firmware_%.bbappend} (100%)
diff --git a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware_git.bbappend b/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware_%.bbappend
similarity index 100%
rename from meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware_git.bbappend
rename to meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware_%.bbappend
--
2.26.2
^ permalink raw reply [flat|nested] 12+ messages in thread
* [PATCH 7/9] arm/scp-firmware: move to 2.6.0 release tag
2020-07-29 10:11 [PATCH 1/9] arm/scp-firmware: merge bb/inc Ross Burton
` (4 preceding siblings ...)
2020-07-29 10:11 ` [PATCH 6/9] arm-bsp/scp-firmware: use wildcard bbappend Ross Burton
@ 2020-07-29 10:11 ` Ross Burton
2020-07-30 19:54 ` [meta-arm] " Jon Mason
2020-07-29 10:11 ` [PATCH 8/9] arm-bsp/scp-firmware: use full version number 2.6.0, not 2.6 Ross Burton
` (2 subsequent siblings)
8 siblings, 1 reply; 12+ messages in thread
From: Ross Burton @ 2020-07-29 10:11 UTC (permalink / raw)
To: meta-arm
From: Ross Burton <ross.burton@arm.com>
Instead of an arbitrary commit, set the base recipe to build the 2.6.0
release.
Change-Id: Iec78c6ed903edfd020cca1222770d8ec018ae78a
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
.../scp-firmware/{scp-firmware_git.bb => scp-firmware_2.6.0.bb} | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
rename meta-arm/recipes-bsp/scp-firmware/{scp-firmware_git.bb => scp-firmware_2.6.0.bb} (97%)
diff --git a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.6.0.bb
similarity index 97%
rename from meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
rename to meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.6.0.bb
index a211621..ab7d9bd 100644
--- a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
+++ b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.6.0.bb
@@ -6,7 +6,7 @@ LICENSE = "BSD-3-Clause & Apache-2.0"
LIC_FILES_CHKSUM = "file://license.md;beginline=5;md5=9db9e3d2fb8d9300a6c3d15101b19731"
SRC_URI = "gitsm://github.com/ARM-software/SCP-firmware.git;protocol=https"
-SRCREV = "fd7c83561a7d76c7681d5d017fb23aa3664c028c"
+SRCREV = "db19910aca6d1032eb0329e5fbb70a92b997f6f2"
PROVIDES += "virtual/control-processor-firmware"
--
2.26.2
^ permalink raw reply related [flat|nested] 12+ messages in thread
* [PATCH 8/9] arm-bsp/scp-firmware: use full version number 2.6.0, not 2.6
2020-07-29 10:11 [PATCH 1/9] arm/scp-firmware: merge bb/inc Ross Burton
` (5 preceding siblings ...)
2020-07-29 10:11 ` [PATCH 7/9] arm/scp-firmware: move to 2.6.0 release tag Ross Burton
@ 2020-07-29 10:11 ` Ross Burton
2020-07-29 10:11 ` [PATCH 9/9] arm-bsp/scp-firmware: bump TC0 SRCREV and fix PV Ross Burton
2020-07-30 19:55 ` [meta-arm] [PATCH 1/9] arm/scp-firmware: merge bb/inc Jon Mason
8 siblings, 0 replies; 12+ messages in thread
From: Ross Burton @ 2020-07-29 10:11 UTC (permalink / raw)
To: meta-arm
From: Ross Burton <ross.burton@arm.com>
Change-Id: I34928c09d89eb836cfef80d824b3c5a060af7491
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-n1sdp.inc | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-n1sdp.inc b/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-n1sdp.inc
index 4886a44..ce7acff 100644
--- a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-n1sdp.inc
+++ b/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-n1sdp.inc
@@ -6,7 +6,7 @@ SCP_LOG_LEVEL = "INFO"
COMPATIBLE_MACHINE_n1sdp = "n1sdp"
-PV = "2.6+git${SRCPV}"
+PV = "2.6.0+git${SRCPV}"
DEPENDS += "fiptool-native"
DEPENDS += "virtual/trusted-firmware-a"
--
2.26.2
^ permalink raw reply related [flat|nested] 12+ messages in thread
* [PATCH 9/9] arm-bsp/scp-firmware: bump TC0 SRCREV and fix PV
2020-07-29 10:11 [PATCH 1/9] arm/scp-firmware: merge bb/inc Ross Burton
` (6 preceding siblings ...)
2020-07-29 10:11 ` [PATCH 8/9] arm-bsp/scp-firmware: use full version number 2.6.0, not 2.6 Ross Burton
@ 2020-07-29 10:11 ` Ross Burton
2020-07-30 19:55 ` [meta-arm] [PATCH 1/9] arm/scp-firmware: merge bb/inc Jon Mason
8 siblings, 0 replies; 12+ messages in thread
From: Ross Burton @ 2020-07-29 10:11 UTC (permalink / raw)
To: meta-arm
From: Ross Burton <ross.burton@arm.com>
This is 2.6.0, not 2.6.
Also bump the SRCREV to match N1 SDP so that the core code is the same,
that BSP uses a newer commit.
Change-Id: I83168aa5973d83e4d93869019d91c05daf1e71e9
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-tc0.inc | 4 ++--
1 file changed, 2 insertions(+), 2 deletions(-)
diff --git a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-tc0.inc b/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-tc0.inc
index b4e86fb..a04f729 100644
--- a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-tc0.inc
+++ b/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-tc0.inc
@@ -1,11 +1,11 @@
# TC0 specific SCP configuration
# Intermediate SHA with 2.6 baseline version
-SRCREV = "ba1db5fb0ee4a520836722f7a694177d461ab716"
+SRCREV = "fd7c83561a7d76c7681d5d017fb23aa3664c028c"
COMPATIBLE_MACHINE = "tc0"
SCP_PLATFORM = "tc0"
FW_TARGETS = "scp"
-PV = "2.6+git${SRCPV}"
+PV = "2.6.0+git${SRCPV}"
--
2.26.2
^ permalink raw reply related [flat|nested] 12+ messages in thread
* Re: [PATCH 4/9] arm/scp-firmware: use gitsm fetcher
2020-07-29 10:11 ` [PATCH 4/9] arm/scp-firmware: use gitsm fetcher Ross Burton
@ 2020-07-30 8:37 ` Ross Burton
0 siblings, 0 replies; 12+ messages in thread
From: Ross Burton @ 2020-07-30 8:37 UTC (permalink / raw)
To: meta-arm
On Wed, 29 Jul 2020 at 11:11, Ross Burton <ross@burtonini.com> wrote:
> -
> -# SCP
> LIC_FILES_CHKSUM = "file://license.md;beginline=5;md5=9db9e3d2fb8d9300a6c3d15101b19731"
> -# CMSIS
> -LIC_FILES_CHKSUM += "file://cmsis/LICENSE.txt;md5=e3fc50a88d0a364313df4b21ef20c29e"
I got a bit keen removing things here, v2 incoming.
Ross
^ permalink raw reply [flat|nested] 12+ messages in thread
* Re: [meta-arm] [PATCH 7/9] arm/scp-firmware: move to 2.6.0 release tag
2020-07-29 10:11 ` [PATCH 7/9] arm/scp-firmware: move to 2.6.0 release tag Ross Burton
@ 2020-07-30 19:54 ` Jon Mason
0 siblings, 0 replies; 12+ messages in thread
From: Jon Mason @ 2020-07-30 19:54 UTC (permalink / raw)
To: Ross Burton; +Cc: meta-arm
On Wed, Jul 29, 2020 at 11:11:43AM +0100, Ross Burton wrote:
> From: Ross Burton <ross.burton@arm.com>
>
> Instead of an arbitrary commit, set the base recipe to build the 2.6.0
> release.
>
> Change-Id: Iec78c6ed903edfd020cca1222770d8ec018ae78a
> Signed-off-by: Ross Burton <ross.burton@arm.com>
For some reason, this patch did not apply cleanly via `git am`. I
applied it by hand, as it was faily trivial.
Thanks,
Jon
> ---
> .../scp-firmware/{scp-firmware_git.bb => scp-firmware_2.6.0.bb} | 2 +-
> 1 file changed, 1 insertion(+), 1 deletion(-)
> rename meta-arm/recipes-bsp/scp-firmware/{scp-firmware_git.bb => scp-firmware_2.6.0.bb} (97%)
>
> diff --git a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.6.0.bb
> similarity index 97%
> rename from meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
> rename to meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.6.0.bb
> index a211621..ab7d9bd 100644
> --- a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
> +++ b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.6.0.bb
> @@ -6,7 +6,7 @@ LICENSE = "BSD-3-Clause & Apache-2.0"
> LIC_FILES_CHKSUM = "file://license.md;beginline=5;md5=9db9e3d2fb8d9300a6c3d15101b19731"
>
> SRC_URI = "gitsm://github.com/ARM-software/SCP-firmware.git;protocol=https"
> -SRCREV = "fd7c83561a7d76c7681d5d017fb23aa3664c028c"
> +SRCREV = "db19910aca6d1032eb0329e5fbb70a92b997f6f2"
>
> PROVIDES += "virtual/control-processor-firmware"
>
> --
> 2.26.2
>
>
^ permalink raw reply [flat|nested] 12+ messages in thread
* Re: [meta-arm] [PATCH 1/9] arm/scp-firmware: merge bb/inc
2020-07-29 10:11 [PATCH 1/9] arm/scp-firmware: merge bb/inc Ross Burton
` (7 preceding siblings ...)
2020-07-29 10:11 ` [PATCH 9/9] arm-bsp/scp-firmware: bump TC0 SRCREV and fix PV Ross Burton
@ 2020-07-30 19:55 ` Jon Mason
8 siblings, 0 replies; 12+ messages in thread
From: Jon Mason @ 2020-07-30 19:55 UTC (permalink / raw)
To: Ross Burton; +Cc: meta-arm
On Wed, Jul 29, 2020 at 11:11:37AM +0100, Ross Burton wrote:
> From: Ross Burton <ross.burton@arm.com>
>
> There's no other recipe that uses scp-firmware.inc, so merge it into the
> recipe for clarity.
>
> Change-Id: Ife1874b54c8b2be2704e1d0f5a7013ff89b8ca6e
> Signed-off-by: Ross Burton <ross.burton@arm.com>
Series added to master.
Thanks,
Jon
> ---
> .../recipes-bsp/scp-firmware/scp-firmware.inc | 73 -------------------
> .../scp-firmware/scp-firmware_git.bb | 73 ++++++++++++++++++-
> 2 files changed, 72 insertions(+), 74 deletions(-)
> delete mode 100644 meta-arm/recipes-bsp/scp-firmware/scp-firmware.inc
>
> diff --git a/meta-arm/recipes-bsp/scp-firmware/scp-firmware.inc b/meta-arm/recipes-bsp/scp-firmware/scp-firmware.inc
> deleted file mode 100644
> index 2db59d3..0000000
> --- a/meta-arm/recipes-bsp/scp-firmware/scp-firmware.inc
> +++ /dev/null
> @@ -1,73 +0,0 @@
> -SUMMARY = "SCP and MCP Firmware"
> -
> -PROVIDES += "virtual/control-processor-firmware"
> -
> -SCP_BUILD_RELEASE ?= "1"
> -SCP_COMPILE_VERBOSE ?= "0"
> -SCP_PLATFORM ?= "invalid"
> -SCP_COMPILER ?= "arm-none-eabi"
> -SCP_LOG_LEVEL ?= "WARN"
> -
> -DEPENDS += "virtual/arm-none-eabi-gcc-native"
> -
> -SCP_BUILD_STR = "${@bb.utils.contains('SCP_BUILD_RELEASE', '1', 'release', 'debug', d)}"
> -SCP_COMP_STR = "${@bb.utils.contains('SCP_COMPILE_VERBOSE', '0', '', 'V=1', d)}"
> -
> -inherit python3native
> -inherit deploy
> -
> -B = "${WORKDIR}/build"
> -S = "${WORKDIR}/src"
> -
> -# Allow platform specific copying of only scp or both scp & mcp, default to both
> -FW_TARGETS ?= "scp mcp"
> -
> -COMPATIBLE_MACHINE ?= "invalid"
> -
> -LDFLAGS[unexport] = "1"
> -
> -# The gcc-arm-none-eabi version does not support -fmacro-prefix-max
> -DEBUG_PREFIX_MAP_pn-scp = "\
> - -fdebug-prefix-map=${WORKDIR}=/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR} \
> - -fdebug-prefix-map=${STAGING_DIR_HOST}= \
> - -fdebug-prefix-map=${STAGING_DIR_NATIVE}= \
> -"
> -
> -# No configure
> -do_configure[noexec] = "1"
> -
> -EXTRA_OEMAKE = "${SCP_COMP_STR} \
> - BUILD_PATH='${B}' \
> - PRODUCT='${SCP_PLATFORM}' \
> - MODE='${SCP_BUILD_STR}' \
> - LOG_LEVEL='${SCP_LOG_LEVEL}' \
> - CC='${SCP_COMPILER}-gcc' \
> - AR='${SCP_COMPILER}-ar' \
> - SIZE='${SCP_COMPILER}-size' \
> - OBJCOPY='${SCP_COMPILER}-objcopy' \
> - "
> -
> -do_compile() {
> - oe_runmake -C "${S}" ${EXTRA_OEMAKE}
> -}
> -do_compile[cleandirs] += "${B}"
> -
> -do_install() {
> - install -d ${D}/firmware
> - for FW in ${FW_TARGETS}; do
> - for TYPE in ramfw romfw; do
> - install -D "${B}/product/${SCP_PLATFORM}/${FW}_${TYPE}/release/bin/${FW}_${TYPE}.bin" "${D}/firmware/"
> - done
> - done
> -}
> -
> -FILES_${PN} = "/firmware"
> -SYSROOT_DIRS += "/firmware"
> -# Skip QA check for relocations in .text of elf binaries
> -INSANE_SKIP_${PN} = "textrel"
> -
> -do_deploy() {
> - # Copy the images to deploy directory
> - cp -rf ${D}/firmware/* ${DEPLOYDIR}/
> -}
> -addtask deploy after do_install
> diff --git a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
> index 9cb8b64..e9d8057 100644
> --- a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
> +++ b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_git.bb
> @@ -1,3 +1,4 @@
> +SUMMARY = "SCP and MCP Firmware"
> DESCRIPTION = "Firmware for SCP and MCP software reference implementation"
> HOMEPAGE = "https://github.com/ARM-software/SCP-firmware"
>
> @@ -17,4 +18,74 @@ SRCREV_scp = "fd7c83561a7d76c7681d5d017fb23aa3664c028c"
> SRCREV_cmsis = "refs/tags/5.2.0"
> SRCREV_FORMAT = "scp_cmsis"
>
> -require scp-firmware.inc
> +PROVIDES += "virtual/control-processor-firmware"
> +
> +SCP_BUILD_RELEASE ?= "1"
> +SCP_COMPILE_VERBOSE ?= "0"
> +SCP_PLATFORM ?= "invalid"
> +SCP_COMPILER ?= "arm-none-eabi"
> +SCP_LOG_LEVEL ?= "WARN"
> +
> +DEPENDS += "virtual/arm-none-eabi-gcc-native"
> +
> +SCP_BUILD_STR = "${@bb.utils.contains('SCP_BUILD_RELEASE', '1', 'release', 'debug', d)}"
> +SCP_COMP_STR = "${@bb.utils.contains('SCP_COMPILE_VERBOSE', '0', '', 'V=1', d)}"
> +
> +inherit python3native
> +inherit deploy
> +
> +B = "${WORKDIR}/build"
> +S = "${WORKDIR}/src"
> +
> +# Allow platform specific copying of only scp or both scp & mcp, default to both
> +FW_TARGETS ?= "scp mcp"
> +
> +COMPATIBLE_MACHINE ?= "invalid"
> +
> +LDFLAGS[unexport] = "1"
> +
> +# The gcc-arm-none-eabi version does not support -fmacro-prefix-max
> +DEBUG_PREFIX_MAP_pn-scp = "\
> + -fdebug-prefix-map=${WORKDIR}=/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR} \
> + -fdebug-prefix-map=${STAGING_DIR_HOST}= \
> + -fdebug-prefix-map=${STAGING_DIR_NATIVE}= \
> +"
> +
> +# No configure
> +do_configure[noexec] = "1"
> +
> +EXTRA_OEMAKE = "${SCP_COMP_STR} \
> + BUILD_PATH='${B}' \
> + PRODUCT='${SCP_PLATFORM}' \
> + MODE='${SCP_BUILD_STR}' \
> + LOG_LEVEL='${SCP_LOG_LEVEL}' \
> + CC='${SCP_COMPILER}-gcc' \
> + AR='${SCP_COMPILER}-ar' \
> + SIZE='${SCP_COMPILER}-size' \
> + OBJCOPY='${SCP_COMPILER}-objcopy' \
> + "
> +
> +do_compile() {
> + oe_runmake -C "${S}" ${EXTRA_OEMAKE}
> +}
> +do_compile[cleandirs] += "${B}"
> +
> +do_install() {
> + install -d ${D}/firmware
> + for FW in ${FW_TARGETS}; do
> + for TYPE in ramfw romfw; do
> + install -D "${B}/product/${SCP_PLATFORM}/${FW}_${TYPE}/release/bin/${FW}_${TYPE}.bin" "${D}/firmware/"
> + done
> + done
> +}
> +
> +FILES_${PN} = "/firmware"
> +SYSROOT_DIRS += "/firmware"
> +# Skip QA check for relocations in .text of elf binaries
> +INSANE_SKIP_${PN} = "textrel"
> +
> +do_deploy() {
> + # Copy the images to deploy directory
> + cp -rf ${D}/firmware/* ${DEPLOYDIR}/
> +}
> +addtask deploy after do_install
> --
> 2.26.2
>
>
^ permalink raw reply [flat|nested] 12+ messages in thread
end of thread, other threads:[~2020-07-30 19:55 UTC | newest]
Thread overview: 12+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2020-07-29 10:11 [PATCH 1/9] arm/scp-firmware: merge bb/inc Ross Burton
2020-07-29 10:11 ` [PATCH 2/9] arm/scp-firmware: oe_runmake already passes EXTRA_OEMAKE Ross Burton
2020-07-29 10:11 ` [PATCH 3/9] arm/scp-firmware: always compile verbosely Ross Burton
2020-07-29 10:11 ` [PATCH 4/9] arm/scp-firmware: use gitsm fetcher Ross Burton
2020-07-30 8:37 ` Ross Burton
2020-07-29 10:11 ` [PATCH 5/9] arm-bsp/scp-firmware: remove cmsis SRCREV Ross Burton
2020-07-29 10:11 ` [PATCH 6/9] arm-bsp/scp-firmware: use wildcard bbappend Ross Burton
2020-07-29 10:11 ` [PATCH 7/9] arm/scp-firmware: move to 2.6.0 release tag Ross Burton
2020-07-30 19:54 ` [meta-arm] " Jon Mason
2020-07-29 10:11 ` [PATCH 8/9] arm-bsp/scp-firmware: use full version number 2.6.0, not 2.6 Ross Burton
2020-07-29 10:11 ` [PATCH 9/9] arm-bsp/scp-firmware: bump TC0 SRCREV and fix PV Ross Burton
2020-07-30 19:55 ` [meta-arm] [PATCH 1/9] arm/scp-firmware: merge bb/inc Jon Mason
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.