* [PATCH] classes: add gsettings.bbclass
@ 2012-08-14 16:10 Ross Burton
2012-08-15 13:46 ` Richard Purdie
0 siblings, 1 reply; 2+ messages in thread
From: Ross Burton @ 2012-08-14 16:10 UTC (permalink / raw)
To: openembedded-core
This class registers postinst/postrm hooks to compile the GSetting schemas, and
adds the relevant dependencies. If possible the postinst happens on the host to
avoid running it on the target.
[ YOCTO #2798 ]
---
meta/classes/gsettings.bbclass | 37 +++++++++++++++++++++++++++++++++++++
1 file changed, 37 insertions(+)
create mode 100644 meta/classes/gsettings.bbclass
diff --git a/meta/classes/gsettings.bbclass b/meta/classes/gsettings.bbclass
new file mode 100644
index 0000000..1e3f7a1
--- /dev/null
+++ b/meta/classes/gsettings.bbclass
@@ -0,0 +1,37 @@
+# A bbclass to handle installed GSettings (glib) schemas, updated the compiled
+# form on package install and remove.
+#
+# The compiled schemas are platform-agnostic, so we can depend on
+# glib-2.0-native for the native tool and run the postinst script when the
+# rootfs builds to save a little time on first boot.
+
+# TODO use a trigger so that this runs once per package operation run
+
+DEPENDS += "glib-2.0-native"
+
+RDEPENDS_${PN} += "glib-2.0-utils"
+
+FILES_${PN} += "${datadir}/glib-2.0/schemas"
+
+gsettings_postinstrm () {
+ glib-compile-schemas $D${datadir}/glib-2.0/schemas
+}
+
+python populate_packages_append () {
+ pkg = d.getVar('PN', True)
+ bb.note("adding gsettings postinst scripts to %s" % pkg)
+
+ postinst = d.getVar('pkg_postinst_%s' % pkg, True) or d.getVar('pkg_postinst', True)
+ if not postinst:
+ postinst = '#!/bin/sh\n'
+ postinst += d.getVar('gsettings_postinstrm', True)
+ d.setVar('pkg_postinst_%s' % pkg, postinst)
+
+ bb.note("adding gsettings postrm scripts to %s" % pkg)
+
+ postrm = d.getVar('pkg_postrm_%s' % pkg, True) or d.getVar('pkg_postrm', True)
+ if not postrm:
+ postrm = '#!/bin/sh\n'
+ postrm += d.getVar('gsettings_postinstrm', True)
+ d.setVar('pkg_postrm_%s' % pkg, postrm)
+}
--
1.7.10.4
^ permalink raw reply related [flat|nested] 2+ messages in thread
* Re: [PATCH] classes: add gsettings.bbclass
2012-08-14 16:10 [PATCH] classes: add gsettings.bbclass Ross Burton
@ 2012-08-15 13:46 ` Richard Purdie
0 siblings, 0 replies; 2+ messages in thread
From: Richard Purdie @ 2012-08-15 13:46 UTC (permalink / raw)
To: Patches and discussions about the oe-core layer
On Tue, 2012-08-14 at 17:10 +0100, Ross Burton wrote:
> This class registers postinst/postrm hooks to compile the GSetting schemas, and
> adds the relevant dependencies. If possible the postinst happens on the host to
> avoid running it on the target.
>
> [ YOCTO #2798 ]
> ---
> meta/classes/gsettings.bbclass | 37 +++++++++++++++++++++++++++++++++++++
> 1 file changed, 37 insertions(+)
> create mode 100644 meta/classes/gsettings.bbclass
Merged to master, thanks.
Richard
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2012-08-15 13:58 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2012-08-14 16:10 [PATCH] classes: add gsettings.bbclass Ross Burton
2012-08-15 13:46 ` Richard Purdie
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.