[PATCH 0/2] distcc,avahi - add users offline

[PATCH 0/2] distcc,avahi - add users offline

[Laurentiu Palcu]

Hi,

This is part of "run all postinstalls at do_rootfs time" effort.

Thanks,
Laurentiu

Laurentiu Palcu (2):
  avahi: use useradd.bbclass to add avahi-autoipd user
  distcc: use useradd.bbclass to add the distcc user

 meta/recipes-connectivity/avahi/avahi.inc     |   19 ++++++++-----------
 meta/recipes-devtools/distcc/distcc_2.18.3.bb |   19 +++++++++++--------
 2 files changed, 19 insertions(+), 19 deletions(-)

-- 
1.7.9.5

[PATCH 1/2] avahi: use useradd.bbclass to add avahi-autoipd user

[Laurentiu Palcu]

This is needed for the postinstalls to be run at do_rootfs time.

[YOCTO #3605]

Signed-off-by: Laurentiu Palcu <laurentiu.palcu@intel.com>
---
 meta/recipes-connectivity/avahi/avahi.inc |   19 ++++++++-----------
 1 file changed, 8 insertions(+), 11 deletions(-)

diff --git a/meta/recipes-connectivity/avahi/avahi.inc b/meta/recipes-connectivity/avahi/avahi.inc
index a0a1681..d529b37 100644
--- a/meta/recipes-connectivity/avahi/avahi.inc
+++ b/meta/recipes-connectivity/avahi/avahi.inc
@@ -14,7 +14,7 @@ SECTION = "network"
 # python scripts are under GPLv2+
 LICENSE = "GPLv2+ & LGPLv2.1+"
 
-INC_PR = "r5"
+INC_PR = "r6"
 
 DEPENDS = "expat libcap libdaemon dbus glib-2.0"
 
@@ -26,11 +26,17 @@ SRC_URI = "http://avahi.org/download/avahi-${PV}.tar.gz \
           file://fix_for_automake_1.12.x.patch \
           "
 
-USERADD_PACKAGES = "avahi-daemon"
+USERADD_PACKAGES = "avahi-daemon avahi-autoipd"
 USERADD_PARAM_avahi-daemon = "--system --home /var/run/avahi-daemon \
                               --no-create-home --shell /bin/false \
                               --user-group avahi"
 
+USERADD_PARAM_avahi-autoipd = "--system --home /var/run/avahi-autoipd \
+                              --no-create-home --shell /bin/false \
+                              --user-group \
+                              -c \"Avahi autoip daemon\" \
+                              avahi-autoipd"
+
 inherit autotools pkgconfig update-rc.d gettext useradd
 
 EXTRA_OECONF = "--with-distro=debian \
@@ -137,15 +143,6 @@ if [ -z "$D" ]; then
 fi
 }
 
-pkg_postinst_avahi-autoipd () {
-	# can't do this offline
-	if [ "x$D" != "x" ]; then
-		exit 1
-	fi
-	grep "^avahi-autoipd:" /etc/group > /dev/null || addgroup avahi-autoipd
-	grep "^avahi-autoipd:" /etc/passwd > /dev/null || adduser --disabled-password --system --home /var/lib/avahi-autoipd --no-create-home avahi-autoipd --ingroup avahi-autoipd -g "Avahi autoip daemon"
-}
-
 pkg_postrm_avahi-daemon () {
 	deluser avahi || true
 	delgroup avahi || true
-- 
1.7.9.5

[PATCH 2/2] distcc: use useradd.bbclass to add the distcc user

[Laurentiu Palcu]

This is needed for the postinstalls to run at do_rootfs time.

[YOCTO #3601]

Signed-off-by: Laurentiu Palcu <laurentiu.palcu@intel.com>
---
 meta/recipes-devtools/distcc/distcc_2.18.3.bb |   19 +++++++++++--------
 1 file changed, 11 insertions(+), 8 deletions(-)

diff --git a/meta/recipes-devtools/distcc/distcc_2.18.3.bb b/meta/recipes-devtools/distcc/distcc_2.18.3.bb
index de181e5..bd2af4a 100644
--- a/meta/recipes-devtools/distcc/distcc_2.18.3.bb
+++ b/meta/recipes-devtools/distcc/distcc_2.18.3.bb
@@ -4,7 +4,7 @@ compilation of C/C++/ObjC code across machines on a network."
 SECTION = "devel"
 LICENSE = "GPLv2"
 LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
-PR = "r8"
+PR = "r9"
 
 DEPENDS = "avahi"
 
@@ -28,7 +28,14 @@ SRC_URI = "http://distcc.googlecode.com/files/${BPN}-${PV}.tar.bz2 \
 SRC_URI[md5sum] = "0d6b80a1efc3a3d816c4f4175f63eaa2"
 SRC_URI[sha256sum] = "6500f1bc2a30b1f044ebed79c6ce15457d1712263e65f0db7d6046af262ba434"
 
-inherit autotools pkgconfig update-rc.d
+inherit autotools pkgconfig update-rc.d useradd
+
+USERADD_PACKAGES = "${PN}"
+USERADD_PARAM_${PN} = "--system \
+                       --home /dev/null \
+                       --no-create-home \
+                       --gid nogroup \
+                       distcc"
 
 INITSCRIPT_NAME = "distcc"
 
@@ -53,10 +60,6 @@ FILES_${PN} = " ${sysconfdir} \
 FILES_distcc-distmon-gnome = "  ${bindir}/distccmon-gnome \
 				${datadir}/distcc"
 
-pkg_postinst_${PN} () {
-	if test "x$D" != "x"; then
-		exit 1
-	else
-		grep distcc /etc/passwd || adduser --system --home /dev/null --no-create-home --empty-password --ingroup nogroup distcc
-	fi
+pkg_postrm_${PN} () {
+	deluser distcc || true
 }
-- 
1.7.9.5