* [meta-oe][PATCH 1/7] libebml: add 1.2.2
@ 2013-01-27 15:41 Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 2/7] libmatroska: add 1.3.0 Koen Kooi
` (6 more replies)
0 siblings, 7 replies; 11+ messages in thread
From: Koen Kooi @ 2013-01-27 15:41 UTC (permalink / raw)
To: openembedded-devel; +Cc: Koen Kooi
Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
---
.../recipes-mkv/libebml/libebml_1.2.2.bb | 31 ++++++++++++++++++++++
1 file changed, 31 insertions(+)
create mode 100644 meta-multimedia/recipes-mkv/libebml/libebml_1.2.2.bb
diff --git a/meta-multimedia/recipes-mkv/libebml/libebml_1.2.2.bb b/meta-multimedia/recipes-mkv/libebml/libebml_1.2.2.bb
new file mode 100644
index 0000000..210a409
--- /dev/null
+++ b/meta-multimedia/recipes-mkv/libebml/libebml_1.2.2.bb
@@ -0,0 +1,31 @@
+SUMMARY = "libebml is a C++ libary to parse EBML files."
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://LICENSE.LGPL;md5=f14599a2f089f6ff8c97e2baa4e3d575"
+
+SRC_URI = "http://dl.matroska.org/downloads/libebml/libebml-${PV}.tar.bz2"
+SRC_URI[md5sum] = "726cc2bd1a525929ff35ff9854c0ebab"
+SRC_URI[sha256sum] = "476b08c6436a96c024a53e788e7c945ce9b41cd8654165763444aa7e5245b7a5"
+
+do_compile() {
+ cd ${S}/make/linux
+ oe_runmake CROSS="${TARGET_PREFIX}"
+}
+
+do_install() {
+ cd ${S}/make/linux
+
+ install -d ${D}${libdir}
+ install -m 0644 libebml.a ${D}${libdir}
+ install -m 0755 libebml.so.* ${D}${libdir}
+ cp -a libebml.so ${D}${libdir}
+
+ install -d ${D}${includedir}/ebml
+ for i in ../../ebml/*.h; do
+ install -m 0644 $i ${D}${includedir}/ebml
+ done
+
+ install -d ${D}${includedir}/ebml/c
+ for i in ../../ebml/c/*.h; do
+ install -m 0644 $i ${D}${includedir}/ebml/c
+ done
+}
--
1.8.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [meta-oe][PATCH 2/7] libmatroska: add 1.3.0
2013-01-27 15:41 [meta-oe][PATCH 1/7] libebml: add 1.2.2 Koen Kooi
@ 2013-01-27 15:41 ` Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 3/7] mkvtoolnix: add 5.9.0 Koen Kooi
` (5 subsequent siblings)
6 siblings, 0 replies; 11+ messages in thread
From: Koen Kooi @ 2013-01-27 15:41 UTC (permalink / raw)
To: openembedded-devel; +Cc: Koen Kooi
Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
---
.../recipes-mkv/libmatroska/libmatroska_1.3.0.bb | 33 ++++++++++++++++++++++
1 file changed, 33 insertions(+)
create mode 100644 meta-multimedia/recipes-mkv/libmatroska/libmatroska_1.3.0.bb
diff --git a/meta-multimedia/recipes-mkv/libmatroska/libmatroska_1.3.0.bb b/meta-multimedia/recipes-mkv/libmatroska/libmatroska_1.3.0.bb
new file mode 100644
index 0000000..3a3dd0e
--- /dev/null
+++ b/meta-multimedia/recipes-mkv/libmatroska/libmatroska_1.3.0.bb
@@ -0,0 +1,33 @@
+SUMMARY = "libmatroska is a C++ libary to parse Matroska files (.mkv and .mka)"
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://LICENSE.LGPL;md5=f14599a2f089f6ff8c97e2baa4e3d575"
+
+DEPENDS = "libebml"
+
+SRC_URI = "http://dl.matroska.org/downloads/${BPN}/${BPN}-${PV}.tar.bz2"
+SRC_URI[md5sum] = "f4a8c411f09d39c754eb726efd616043"
+SRC_URI[sha256sum] = "5231ec958571365e719a6fd3c220227af6cf0f14e0bd1bcf766ddbc068d18e69"
+
+do_compile() {
+ cd ${S}/make/linux
+ oe_runmake CROSS="${TARGET_PREFIX}"
+}
+
+do_install() {
+ cd ${S}/make/linux
+
+ install -d ${D}${libdir}
+ install -m 0644 libmatroska.a ${D}${libdir}
+ install -m 0755 libmatroska.so.* ${D}${libdir}
+ cp -a libmatroska.so ${D}${libdir}
+
+ install -d ${D}${includedir}/matroska
+ for i in ../../matroska/*.h; do
+ install -m 0644 $i ${D}${includedir}/matroska
+ done
+
+ install -d ${D}${includedir}/matroska/c
+ for i in ../../matroska/c/*.h; do
+ install -m 0644 $i ${D}${includedir}/matroska/c
+ done
+}
--
1.8.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [meta-oe][PATCH 3/7] mkvtoolnix: add 5.9.0
2013-01-27 15:41 [meta-oe][PATCH 1/7] libebml: add 1.2.2 Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 2/7] libmatroska: add 1.3.0 Koen Kooi
@ 2013-01-27 15:41 ` Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 4/7] x264: add git version Koen Kooi
` (4 subsequent siblings)
6 siblings, 0 replies; 11+ messages in thread
From: Koen Kooi @ 2013-01-27 15:41 UTC (permalink / raw)
To: openembedded-devel; +Cc: Koen Kooi
Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
---
.../recipes-mkv/mkvtoolnix/mkvtoolnix_5.9.0.bb | 30 ++++++++++++++++++++++
1 file changed, 30 insertions(+)
create mode 100644 meta-multimedia/recipes-mkv/mkvtoolnix/mkvtoolnix_5.9.0.bb
diff --git a/meta-multimedia/recipes-mkv/mkvtoolnix/mkvtoolnix_5.9.0.bb b/meta-multimedia/recipes-mkv/mkvtoolnix/mkvtoolnix_5.9.0.bb
new file mode 100644
index 0000000..e7f93d2
--- /dev/null
+++ b/meta-multimedia/recipes-mkv/mkvtoolnix/mkvtoolnix_5.9.0.bb
@@ -0,0 +1,30 @@
+SUMMARY = "MKVToolNix -- Cross-platform tools for Matroska"
+HOMEPAGE = "http://www.bunkus.org/videotools/mkvtoolnix/source.html"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+DEPENDS = "curl boost expat zlib libebml libmatroska libogg libvorbis bzip2 lzo file ruby-native"
+
+SRC_URI = "http://www.bunkus.org/videotools/mkvtoolnix/sources/mkvtoolnix-${PV}.tar.bz2"
+SRC_URI[md5sum] = "033621461ef8eb922fc1366e0a9a6f16"
+SRC_URI[sha256sum] = "d913f531331c3332d2fb334c872ea19bfea7293dfedc4bf33ae7162e4efcbde1"
+
+inherit autotools
+
+EXTRA_OECONF = " --with-boost-libdir=${STAGING_LIBDIR} \
+ "
+
+# remove some hardcoded searchpaths
+do_configure_prepend() {
+ sed -i -e s:/usr/local/lib:${STAGING_LIBDIR}:g -e s:/usr/local/include:${STAGING_INCDIR}:g ac/ebml.m4
+}
+
+# Yeah, no makefile
+do_compile() {
+ ./drake
+}
+
+do_install() {
+ ./drake install DESTDIR=${D}
+}
--
1.8.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [meta-oe][PATCH 4/7] x264: add git version
2013-01-27 15:41 [meta-oe][PATCH 1/7] libebml: add 1.2.2 Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 2/7] libmatroska: add 1.3.0 Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 3/7] mkvtoolnix: add 5.9.0 Koen Kooi
@ 2013-01-27 15:41 ` Koen Kooi
2013-01-27 19:19 ` Martin Jansa
2013-01-27 15:41 ` [meta-oe][PATCH 5/7] libav: enable x264 encoder support Koen Kooi
` (3 subsequent siblings)
6 siblings, 1 reply; 11+ messages in thread
From: Koen Kooi @ 2013-01-27 15:41 UTC (permalink / raw)
To: openembedded-devel; +Cc: Koen Kooi
Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
---
meta-oe/recipes-multimedia/x264/x264_git.bb | 43 +++++++++++++++++++++++++++++
1 file changed, 43 insertions(+)
create mode 100644 meta-oe/recipes-multimedia/x264/x264_git.bb
diff --git a/meta-oe/recipes-multimedia/x264/x264_git.bb b/meta-oe/recipes-multimedia/x264/x264_git.bb
new file mode 100644
index 0000000..ba8e979
--- /dev/null
+++ b/meta-oe/recipes-multimedia/x264/x264_git.bb
@@ -0,0 +1,43 @@
+SUMMARY = "x264 is a free software library and application for encoding video streams into the H.264/MPEG-4 AVC format"
+HOMEPAGE = "http://www.videolan.org/developers/x264.html"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
+
+DEPENDS = "yasm-native"
+
+SRC_URI = "git://git.videolan.org/x264.git"
+SRCREV = "1cffe9f406cc54f4759fc9eeb85598fb8cae66c7"
+
+PV = "r2230+git"
+
+S = "${WORKDIR}/git"
+
+inherit lib_package pkgconfig
+
+X264_DISABLE_ASM = ""
+X264_DISABLE_ASM_armv4 = "--disable-asm"
+X264_DISABLE_ASM_armv4t = "--disable-asm"
+X264_DISABLE_ASM_armv5te = "--disable-asm"
+
+EXTRA_OECONF = '--prefix=${prefix} \
+ --host=${HOST_SYS} \
+ --cross-prefix=${TARGET_PREFIX} \
+ --sysroot=${STAGING_DIR_TARGET} \
+ --enable-shared \
+ --enable-static \
+ --disable-lavf \
+ ${X264_DISABLE_ASM} \
+ '
+
+do_configure() {
+ ./configure ${EXTRA_OECONF}
+}
+
+# Get rid of -e
+EXTRA_OEMAKE = ""
+AS = "${TARGET_PREFIX}gcc"
+
+do_install() {
+ oe_runmake install DESTDIR=${D}
+}
--
1.8.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [meta-oe][PATCH 5/7] libav: enable x264 encoder support
2013-01-27 15:41 [meta-oe][PATCH 1/7] libebml: add 1.2.2 Koen Kooi
` (2 preceding siblings ...)
2013-01-27 15:41 ` [meta-oe][PATCH 4/7] x264: add git version Koen Kooi
@ 2013-01-27 15:41 ` Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 6/7] apcupsd: fix QA error and SUMMARY Koen Kooi
` (2 subsequent siblings)
6 siblings, 0 replies; 11+ messages in thread
From: Koen Kooi @ 2013-01-27 15:41 UTC (permalink / raw)
To: openembedded-devel; +Cc: Koen Kooi
Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
---
meta-oe/recipes-multimedia/libav/libav.inc | 5 +++--
1 file changed, 3 insertions(+), 2 deletions(-)
diff --git a/meta-oe/recipes-multimedia/libav/libav.inc b/meta-oe/recipes-multimedia/libav/libav.inc
index e85ae29..388a567 100644
--- a/meta-oe/recipes-multimedia/libav/libav.inc
+++ b/meta-oe/recipes-multimedia/libav/libav.inc
@@ -9,9 +9,9 @@ PROVIDES = "ffmpeg"
ARM_INSTRUCTION_SET = "arm"
# faac faad2 lame schroedinger libgsm
-DEPENDS = "virtual/libsdl zlib libogg libvorbis libvpx libtheora ${@base_conditional('ENTERPRISE_DISTRO', '1', '', 'liba52', d)}"
+DEPENDS = "x264 virtual/libsdl zlib libogg libvorbis libvpx libtheora ${@base_conditional('ENTERPRISE_DISTRO', '1', '', 'liba52', d)}"
-INC_PR = "r6"
+INC_PR = "r7"
inherit autotools pkgconfig
@@ -42,6 +42,7 @@ EXTRA_OECONF = " \
--enable-x11grab \
--enable-libtheora \
--enable-libvorbis \
+ --enable-libx264 \
--arch=${TARGET_ARCH} \
--target-os="linux" \
--enable-cross-compile \
--
1.8.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [meta-oe][PATCH 6/7] apcupsd: fix QA error and SUMMARY
2013-01-27 15:41 [meta-oe][PATCH 1/7] libebml: add 1.2.2 Koen Kooi
` (3 preceding siblings ...)
2013-01-27 15:41 ` [meta-oe][PATCH 5/7] libav: enable x264 encoder support Koen Kooi
@ 2013-01-27 15:41 ` Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 7/7] python-smbus: add 3.0.3 Koen Kooi
2013-01-28 10:43 ` [meta-oe][PATCH 1/7] libebml: add 1.2.2 Martin Jansa
6 siblings, 0 replies; 11+ messages in thread
From: Koen Kooi @ 2013-01-27 15:41 UTC (permalink / raw)
To: openembedded-devel; +Cc: Koen Kooi
Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
---
meta-oe/recipes-support/apcupsd/apcupsd_3.14.10.bb | 6 +++++-
1 file changed, 5 insertions(+), 1 deletion(-)
diff --git a/meta-oe/recipes-support/apcupsd/apcupsd_3.14.10.bb b/meta-oe/recipes-support/apcupsd/apcupsd_3.14.10.bb
index e50d03f..bd11f0d 100644
--- a/meta-oe/recipes-support/apcupsd/apcupsd_3.14.10.bb
+++ b/meta-oe/recipes-support/apcupsd/apcupsd_3.14.10.bb
@@ -1,4 +1,4 @@
-SUMMARY = "foo"
+SUMMARY = "Apcupsd a daemon for controlling APC UPSes"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=c12853cc7fdf20d17b4fddefd26b7802"
@@ -32,4 +32,8 @@ do_configure() {
oe_runconf
}
+do_install_append() {
+ rm ${D}${datadir}/hal -rf
+}
+
--
1.8.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [meta-oe][PATCH 7/7] python-smbus: add 3.0.3
2013-01-27 15:41 [meta-oe][PATCH 1/7] libebml: add 1.2.2 Koen Kooi
` (4 preceding siblings ...)
2013-01-27 15:41 ` [meta-oe][PATCH 6/7] apcupsd: fix QA error and SUMMARY Koen Kooi
@ 2013-01-27 15:41 ` Koen Kooi
2013-01-28 10:43 ` [meta-oe][PATCH 1/7] libebml: add 1.2.2 Martin Jansa
6 siblings, 0 replies; 11+ messages in thread
From: Koen Kooi @ 2013-01-27 15:41 UTC (permalink / raw)
To: openembedded-devel; +Cc: Koen Kooi
Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
---
.../recipes-devtools/python/python-smbus_3.0.3.bb | 20 ++++++++++++++++++++
1 file changed, 20 insertions(+)
create mode 100644 meta-oe/recipes-devtools/python/python-smbus_3.0.3.bb
diff --git a/meta-oe/recipes-devtools/python/python-smbus_3.0.3.bb b/meta-oe/recipes-devtools/python/python-smbus_3.0.3.bb
new file mode 100644
index 0000000..5ba24c6
--- /dev/null
+++ b/meta-oe/recipes-devtools/python/python-smbus_3.0.3.bb
@@ -0,0 +1,20 @@
+DESCRIPTION = "Set of i2c tools for linux - Python module"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://smbusmodule.c;startline=1;endline=17;md5=fa24df321a520ff8e10f203425ab9fa8"
+
+SRC_URI = "http://dl.lm-sensors.org/i2c-tools/releases/i2c-tools-${PV}.tar.bz2 \
+ "
+SRC_URI[md5sum] = "511376eed04455cdb277ef19c5f73bb4"
+SRC_URI[sha256sum] = "23b28e474741834e3f1b35b0686528769a13adc92d2ff5603cbda1d6bd5e5629"
+
+DEPENDS = "i2c-tools"
+
+inherit distutils
+
+S = "${WORKDIR}/i2c-tools-${PV}/py-smbus/"
+
+do_configure_prepend() {
+ # Adjust for OE header rename
+ sed -i s:linux/i2c-dev.h:linux/i2c-dev-user.h: Module.mk
+ sed -i s:linux/i2c-dev.h:linux/i2c-dev-user.h: smbusmodule.c
+}
--
1.8.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* Re: [meta-oe][PATCH 4/7] x264: add git version
2013-01-27 15:41 ` [meta-oe][PATCH 4/7] x264: add git version Koen Kooi
@ 2013-01-27 19:19 ` Martin Jansa
2013-01-27 20:38 ` Koen Kooi
0 siblings, 1 reply; 11+ messages in thread
From: Martin Jansa @ 2013-01-27 19:19 UTC (permalink / raw)
To: openembedded-devel; +Cc: Koen Kooi
[-- Attachment #1: Type: text/plain, Size: 2649 bytes --]
On Sun, Jan 27, 2013 at 04:41:19PM +0100, Koen Kooi wrote:
> Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
> ---
> meta-oe/recipes-multimedia/x264/x264_git.bb | 43 +++++++++++++++++++++++++++++
> 1 file changed, 43 insertions(+)
> create mode 100644 meta-oe/recipes-multimedia/x264/x264_git.bb
>
> diff --git a/meta-oe/recipes-multimedia/x264/x264_git.bb b/meta-oe/recipes-multimedia/x264/x264_git.bb
> new file mode 100644
> index 0000000..ba8e979
> --- /dev/null
> +++ b/meta-oe/recipes-multimedia/x264/x264_git.bb
> @@ -0,0 +1,43 @@
> +SUMMARY = "x264 is a free software library and application for encoding video streams into the H.264/MPEG-4 AVC format"
> +HOMEPAGE = "http://www.videolan.org/developers/x264.html"
> +
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
> +
> +DEPENDS = "yasm-native"
> +
> +SRC_URI = "git://git.videolan.org/x264.git"
> +SRCREV = "1cffe9f406cc54f4759fc9eeb85598fb8cae66c7"
> +
> +PV = "r2230+git"
> +
> +S = "${WORKDIR}/git"
> +
> +inherit lib_package pkgconfig
> +
> +X264_DISABLE_ASM = ""
> +X264_DISABLE_ASM_armv4 = "--disable-asm"
> +X264_DISABLE_ASM_armv4t = "--disable-asm"
> +X264_DISABLE_ASM_armv5te = "--disable-asm"
Can we use more generic overrides?
meta/conf/machine/include/arm/arch-armv5.inc:MACHINEOVERRIDES .= "${@bb.utils.contains("TUNE_FEATURES", "armv5", ":armv5", "" ,d)}"
meta/conf/machine/include/arm/arch-armv4.inc:MACHINEOVERRIDES .= "${@bb.utils.contains("TUNE_FEATURES", "armv4", ":armv4", "" ,d)}"
I'll update it in jansa/in-test, but send me your ack.
PKG_ARCH is not in default OVERRIDES IIRC and with different distro
settings for default tune it could be also xscalete or arm926ejste etc.
Cheers,
> +
> +EXTRA_OECONF = '--prefix=${prefix} \
> + --host=${HOST_SYS} \
> + --cross-prefix=${TARGET_PREFIX} \
> + --sysroot=${STAGING_DIR_TARGET} \
> + --enable-shared \
> + --enable-static \
> + --disable-lavf \
> + ${X264_DISABLE_ASM} \
> + '
> +
> +do_configure() {
> + ./configure ${EXTRA_OECONF}
> +}
> +
> +# Get rid of -e
> +EXTRA_OEMAKE = ""
> +AS = "${TARGET_PREFIX}gcc"
> +
> +do_install() {
> + oe_runmake install DESTDIR=${D}
> +}
> --
> 1.8.1
>
>
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-devel
--
Martin 'JaMa' Jansa jabber: Martin.Jansa@gmail.com
[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]
^ permalink raw reply [flat|nested] 11+ messages in thread
* Re: [meta-oe][PATCH 4/7] x264: add git version
2013-01-27 19:19 ` Martin Jansa
@ 2013-01-27 20:38 ` Koen Kooi
0 siblings, 0 replies; 11+ messages in thread
From: Koen Kooi @ 2013-01-27 20:38 UTC (permalink / raw)
To: Martin Jansa; +Cc: openembedded-devel
Op 27 jan. 2013, om 20:19 heeft Martin Jansa <martin.jansa@gmail.com> het volgende geschreven:
> On Sun, Jan 27, 2013 at 04:41:19PM +0100, Koen Kooi wrote:
>> Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
>> ---
>> meta-oe/recipes-multimedia/x264/x264_git.bb | 43 +++++++++++++++++++++++++++++
>> 1 file changed, 43 insertions(+)
>> create mode 100644 meta-oe/recipes-multimedia/x264/x264_git.bb
>>
>> diff --git a/meta-oe/recipes-multimedia/x264/x264_git.bb b/meta-oe/recipes-multimedia/x264/x264_git.bb
>> new file mode 100644
>> index 0000000..ba8e979
>> --- /dev/null
>> +++ b/meta-oe/recipes-multimedia/x264/x264_git.bb
>> @@ -0,0 +1,43 @@
>> +SUMMARY = "x264 is a free software library and application for encoding video streams into the H.264/MPEG-4 AVC format"
>> +HOMEPAGE = "http://www.videolan.org/developers/x264.html"
>> +
>> +LICENSE = "GPLv2"
>> +LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
>> +
>> +DEPENDS = "yasm-native"
>> +
>> +SRC_URI = "git://git.videolan.org/x264.git"
>> +SRCREV = "1cffe9f406cc54f4759fc9eeb85598fb8cae66c7"
>> +
>> +PV = "r2230+git"
>> +
>> +S = "${WORKDIR}/git"
>> +
>> +inherit lib_package pkgconfig
>> +
>> +X264_DISABLE_ASM = ""
>> +X264_DISABLE_ASM_armv4 = "--disable-asm"
>> +X264_DISABLE_ASM_armv4t = "--disable-asm"
>> +X264_DISABLE_ASM_armv5te = "--disable-asm"
>
> Can we use more generic overrides?
> meta/conf/machine/include/arm/arch-armv5.inc:MACHINEOVERRIDES .= "${@bb.utils.contains("TUNE_FEATURES", "armv5", ":armv5", "" ,d)}"
> meta/conf/machine/include/arm/arch-armv4.inc:MACHINEOVERRIDES .= "${@bb.utils.contains("TUNE_FEATURES", "armv4", ":armv4", "" ,d)}"
>
> I'll update it in jansa/in-test, but send me your ack.
Thanks!
Acked-by: Koen Kooi <koen@dominion.thruhere.net>
>
> PKG_ARCH is not in default OVERRIDES IIRC and with different distro
> settings for default tune it could be also xscalete or arm926ejste etc.
I hadn't thought about that, thanks for noticing!
>
> Cheers,
>
>> +
>> +EXTRA_OECONF = '--prefix=${prefix} \
>> + --host=${HOST_SYS} \
>> + --cross-prefix=${TARGET_PREFIX} \
>> + --sysroot=${STAGING_DIR_TARGET} \
>> + --enable-shared \
>> + --enable-static \
>> + --disable-lavf \
>> + ${X264_DISABLE_ASM} \
>> + '
>> +
>> +do_configure() {
>> + ./configure ${EXTRA_OECONF}
>> +}
>> +
>> +# Get rid of -e
>> +EXTRA_OEMAKE = ""
>> +AS = "${TARGET_PREFIX}gcc"
>> +
>> +do_install() {
>> + oe_runmake install DESTDIR=${D}
>> +}
>> --
>> 1.8.1
>>
>>
>> _______________________________________________
>> Openembedded-devel mailing list
>> Openembedded-devel@lists.openembedded.org
>> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-devel
>
> --
> Martin 'JaMa' Jansa jabber: Martin.Jansa@gmail.com
^ permalink raw reply [flat|nested] 11+ messages in thread
* Re: [meta-oe][PATCH 1/7] libebml: add 1.2.2
2013-01-27 15:41 [meta-oe][PATCH 1/7] libebml: add 1.2.2 Koen Kooi
` (5 preceding siblings ...)
2013-01-27 15:41 ` [meta-oe][PATCH 7/7] python-smbus: add 3.0.3 Koen Kooi
@ 2013-01-28 10:43 ` Martin Jansa
2013-01-28 11:30 ` Koen Kooi
6 siblings, 1 reply; 11+ messages in thread
From: Martin Jansa @ 2013-01-28 10:43 UTC (permalink / raw)
To: openembedded-devel; +Cc: Koen Kooi
[-- Attachment #1: Type: text/plain, Size: 2044 bytes --]
On Sun, Jan 27, 2013 at 04:41:16PM +0100, Koen Kooi wrote:
> Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
All applied, Thanks.
Now I have only:
3424ca7 wscan: add 20121111
5c7cfdd xbmc: first try at making it build for non-GLES platforms
pending from you :).
> ---
> .../recipes-mkv/libebml/libebml_1.2.2.bb | 31 ++++++++++++++++++++++
> 1 file changed, 31 insertions(+)
> create mode 100644 meta-multimedia/recipes-mkv/libebml/libebml_1.2.2.bb
>
> diff --git a/meta-multimedia/recipes-mkv/libebml/libebml_1.2.2.bb b/meta-multimedia/recipes-mkv/libebml/libebml_1.2.2.bb
> new file mode 100644
> index 0000000..210a409
> --- /dev/null
> +++ b/meta-multimedia/recipes-mkv/libebml/libebml_1.2.2.bb
> @@ -0,0 +1,31 @@
> +SUMMARY = "libebml is a C++ libary to parse EBML files."
> +LICENSE = "LGPLv2.1"
> +LIC_FILES_CHKSUM = "file://LICENSE.LGPL;md5=f14599a2f089f6ff8c97e2baa4e3d575"
> +
> +SRC_URI = "http://dl.matroska.org/downloads/libebml/libebml-${PV}.tar.bz2"
> +SRC_URI[md5sum] = "726cc2bd1a525929ff35ff9854c0ebab"
> +SRC_URI[sha256sum] = "476b08c6436a96c024a53e788e7c945ce9b41cd8654165763444aa7e5245b7a5"
> +
> +do_compile() {
> + cd ${S}/make/linux
> + oe_runmake CROSS="${TARGET_PREFIX}"
> +}
> +
> +do_install() {
> + cd ${S}/make/linux
> +
> + install -d ${D}${libdir}
> + install -m 0644 libebml.a ${D}${libdir}
> + install -m 0755 libebml.so.* ${D}${libdir}
> + cp -a libebml.so ${D}${libdir}
> +
> + install -d ${D}${includedir}/ebml
> + for i in ../../ebml/*.h; do
> + install -m 0644 $i ${D}${includedir}/ebml
> + done
> +
> + install -d ${D}${includedir}/ebml/c
> + for i in ../../ebml/c/*.h; do
> + install -m 0644 $i ${D}${includedir}/ebml/c
> + done
> +}
> --
> 1.8.1
>
>
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-devel
--
Martin 'JaMa' Jansa jabber: Martin.Jansa@gmail.com
[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]
^ permalink raw reply [flat|nested] 11+ messages in thread
* Re: [meta-oe][PATCH 1/7] libebml: add 1.2.2
2013-01-28 10:43 ` [meta-oe][PATCH 1/7] libebml: add 1.2.2 Martin Jansa
@ 2013-01-28 11:30 ` Koen Kooi
0 siblings, 0 replies; 11+ messages in thread
From: Koen Kooi @ 2013-01-28 11:30 UTC (permalink / raw)
To: Martin Jansa; +Cc: openembedded-devel
Op 28 jan. 2013, om 11:43 heeft Martin Jansa <martin.jansa@gmail.com> het volgende geschreven:
> On Sun, Jan 27, 2013 at 04:41:16PM +0100, Koen Kooi wrote:
>> Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
>
> All applied, Thanks.
>
> Now I have only:
> 3424ca7 wscan: add 20121111
> 5c7cfdd xbmc: first try at making it build for non-GLES platforms
> pending from you :).
Still haven't had the time to look at fixing wscan and xbmc is a *$(*$(#*$(@ mess when trying to make it build against EMGD libs
^ permalink raw reply [flat|nested] 11+ messages in thread
end of thread, other threads:[~2013-01-28 11:46 UTC | newest]
Thread overview: 11+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2013-01-27 15:41 [meta-oe][PATCH 1/7] libebml: add 1.2.2 Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 2/7] libmatroska: add 1.3.0 Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 3/7] mkvtoolnix: add 5.9.0 Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 4/7] x264: add git version Koen Kooi
2013-01-27 19:19 ` Martin Jansa
2013-01-27 20:38 ` Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 5/7] libav: enable x264 encoder support Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 6/7] apcupsd: fix QA error and SUMMARY Koen Kooi
2013-01-27 15:41 ` [meta-oe][PATCH 7/7] python-smbus: add 3.0.3 Koen Kooi
2013-01-28 10:43 ` [meta-oe][PATCH 1/7] libebml: add 1.2.2 Martin Jansa
2013-01-28 11:30 ` Koen Kooi
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.