[PATCH 0/5] BlueZ 5 experimental recipes

[PATCH 0/5] BlueZ 5 experimental recipes

[Cristian Iorga]

This sets of patches adds bluez5 recipes as experimental packages.
BlueZ 5.X is not an upgrade for Bluez 4.x, as such, no upgrade is
provided/possible.
The two versions of the BT stack also conflicts each other.

Alexandru DAMIAN (1):
  bluez5: add readline dependency

Cristian Iorga (3):
  bluez5: new package for v5.3
  bluez4: conflicts with/replaces bluez5
  bluez5: upgrade to v5.7

Richard Purdie (1):
  bluez5: Set udev variables using pkg-config

 meta/recipes-connectivity/bluez/bluez4_4.101.bb    |    5 ++-
 .../bluez5/bluez5-5.7/bluetooth.conf               |   16 +++++++
 .../bluez5/bluez5-5.7/fix-udev-paths.patch         |   35 +++++++++++++++
 meta/recipes-connectivity/bluez5/bluez5.inc        |   45 ++++++++++++++++++++
 meta/recipes-connectivity/bluez5/bluez5_5.7.bb     |   38 +++++++++++++++++
 5 files changed, 138 insertions(+), 1 deletion(-)
 create mode 100644 meta/recipes-connectivity/bluez5/bluez5-5.7/bluetooth.conf
 create mode 100644 meta/recipes-connectivity/bluez5/bluez5-5.7/fix-udev-paths.patch
 create mode 100644 meta/recipes-connectivity/bluez5/bluez5.inc
 create mode 100644 meta/recipes-connectivity/bluez5/bluez5_5.7.bb

-- 
1.7.10.4

[PATCH 1/5] bluez5: new package for v5.3

[Cristian Iorga]

- bluez5 does not replace bluez4
- bluez5 is integrated with systemd
- RCONFLICTS/RREPLACES bluez4

Signed-off-by: Cristian Iorga <cristian.iorga@intel.com>
---
 .../bluez5/bluez5-5.4/bluetooth.conf               |   16 +++++++
 .../bluez5/bluez5-5.4/fix-udev-paths.patch         |   35 +++++++++++++++
 meta/recipes-connectivity/bluez5/bluez5.inc        |   45 ++++++++++++++++++++
 meta/recipes-connectivity/bluez5/bluez5_5.4.bb     |   38 +++++++++++++++++
 4 files changed, 134 insertions(+)
 create mode 100644 meta/recipes-connectivity/bluez5/bluez5-5.4/bluetooth.conf
 create mode 100644 meta/recipes-connectivity/bluez5/bluez5-5.4/fix-udev-paths.patch
 create mode 100644 meta/recipes-connectivity/bluez5/bluez5.inc
 create mode 100644 meta/recipes-connectivity/bluez5/bluez5_5.4.bb

diff --git a/meta/recipes-connectivity/bluez5/bluez5-5.4/bluetooth.conf b/meta/recipes-connectivity/bluez5/bluez5-5.4/bluetooth.conf
new file mode 100644
index 0000000..ca5e9e4
--- /dev/null
+++ b/meta/recipes-connectivity/bluez5/bluez5-5.4/bluetooth.conf
@@ -0,0 +1,16 @@
+<!-- This configuration file specifies the required security policies
+     for Bluetooth core daemon to work. -->
+
+<!DOCTYPE busconfig PUBLIC "-//freedesktop//DTD D-BUS Bus Configuration 1.0//EN"
+ "http://www.freedesktop.org/standards/dbus/1.0/busconfig.dtd">
+<busconfig>
+
+  <!-- ../system.conf have denied everything, so we just punch some holes -->
+
+  <policy context="default">
+    <allow own="org.bluez"/>
+    <allow send_destination="org.bluez"/>
+    <allow send_interface="org.bluez.Agent"/>
+  </policy>
+
+</busconfig>
diff --git a/meta/recipes-connectivity/bluez5/bluez5-5.4/fix-udev-paths.patch b/meta/recipes-connectivity/bluez5/bluez5-5.4/fix-udev-paths.patch
new file mode 100644
index 0000000..37362f5
--- /dev/null
+++ b/meta/recipes-connectivity/bluez5/bluez5-5.4/fix-udev-paths.patch
@@ -0,0 +1,35 @@
+Add udevdir/udevrulesdir options
+
+Upstream-Status: Inappropriate [configuration]
+Signed-off-by: Constantin Musca <constantinx.musca@intel.com>
+Signed-off-by: Cristian Iorga <cristian.iorga@intel.com>
+
+Index: bluez-5.0/Makefile.am
+===================================================================
+--- bluez-5.0.orig/Makefile.am	2012-12-24 19:46:54.000000000 +0200
++++ bluez-5.0/Makefile.am	2013-01-30 14:33:15.760615474 +0200
+@@ -175,7 +175,7 @@
+ include Makefile.obexd
+ 
+ if HID2HCI
+-rulesdir = @UDEV_DIR@/rules.d
++rulesdir = @UDEV_RULES_DIR@
+ 
+ rules_DATA = tools/97-hid2hci.rules
+ 
+Index: bluez-5.0/configure.ac
+===================================================================
+--- bluez-5.0.orig/configure.ac	2012-12-24 19:46:54.000000000 +0200
++++ bluez-5.0/configure.ac	2013-01-30 14:34:59.068613895 +0200
+@@ -160,6 +160,11 @@
+ 	AC_SUBST(UDEV_DIR, [${path_udevdir}])
+ fi
+ 
++AC_ARG_WITH([udevrulesdir],
++    AS_HELP_STRING([--with-udevrulesdir=DIR], [udev rules directory]),
++    [], [with_udevrulesdir=/lib/udev/rules.d])
++AC_SUBST([UDEV_RULES_DIR], [$with_udevrulesdir])
++
+ AM_CONDITIONAL(HID2HCI, test "${enable_tools}" != "no" &&
+ 		test "${enable_udev}" != "no" && test "${enable_usb}" != "no")
+ 
diff --git a/meta/recipes-connectivity/bluez5/bluez5.inc b/meta/recipes-connectivity/bluez5/bluez5.inc
new file mode 100644
index 0000000..db9c766
--- /dev/null
+++ b/meta/recipes-connectivity/bluez5/bluez5.inc
@@ -0,0 +1,45 @@
+SUMMARY = "Linux Bluetooth Stack Userland V5"
+DESCRIPTION = "Linux Bluetooth stack V5 userland components.  These include a system configurations, daemons, tools and system libraries."
+HOMEPAGE = "http://www.bluez.org"
+SECTION = "libs"
+LICENSE = "GPLv2+ & LGPLv2.1+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e \
+                    file://COPYING.LIB;md5=fb504b67c50331fc78734fed90fb0e09 \
+                    file://src/main.c;beginline=1;endline=24;md5=9bc54b93cd7e17bf03f52513f39f926e"
+DEPENDS = "udev libusb dbus-glib glib-2.0 libcheck libical"
+
+PACKAGECONFIG ??= "\
+    ${@base_contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)}\
+    ${@base_contains('DISTRO_FEATURES', 'pie', 'pie', '', d)}\
+"
+PACKAGECONFIG[alsa] = "--enable-alsa,--disable-alsa,alsa-lib"
+PACKAGECONFIG[pie] = "--enable-pie,--disable-pie,"
+
+ASNEEDED = ""
+
+SRC_URI = "\
+  ${KERNELORG_MIRROR}/linux/bluetooth/bluez-${PV}.tar.gz \
+"
+S = "${WORKDIR}/bluez-${PV}"
+
+inherit autotools pkgconfig systemd
+
+EXTRA_OECONF = "\
+  --disable-gstreamer \
+  --enable-usb \
+  --enable-tools \
+  --enable-bccmd \
+  --enable-hid2hci \
+  --enable-dfutool \
+  --disable-hidd \
+  --disable-pand \
+  --disable-dund \
+  --disable-cups \
+  --enable-test \
+  --enable-datafiles \
+  --with-udevdir=${base_libdir}/udev \
+  --with-udevrulesdir=${nonarch_base_libdir}/udev/rules.d \
+  ${@base_contains('DISTRO_FEATURES', 'systemd', '--with-systemdunitdir=${systemd_unitdir}/system/', '--disable-systemd', d)} \
+"
+
+SYSTEMD_SERVICE_${PN} = "bluetooth.service"
diff --git a/meta/recipes-connectivity/bluez5/bluez5_5.4.bb b/meta/recipes-connectivity/bluez5/bluez5_5.4.bb
new file mode 100644
index 0000000..4379de6
--- /dev/null
+++ b/meta/recipes-connectivity/bluez5/bluez5_5.4.bb
@@ -0,0 +1,38 @@
+require bluez5.inc
+
+SRC_URI += "file://bluetooth.conf \
+            file://fix-udev-paths.patch"
+
+SRC_URI[md5sum] = "e4a7d8bab9c28053a53f00bc940382a8"
+SRC_URI[sha256sum] = "65b2d0d7eead2b3c49216b9f94ea71c3d15da92fb3fd49fce1ee6e91af1b4430"
+
+RCONFLICTS_${PN} = "bluez4"
+RREPLACES_${PN} = "bluez4"
+
+do_install_append() {
+	install -d ${D}${sysconfdir}/bluetooth/
+	install -m 0644 ${S}/profiles/audio/audio.conf ${D}/${sysconfdir}/bluetooth/
+	install -m 0644 ${S}/profiles/network/network.conf ${D}/${sysconfdir}/bluetooth/
+	install -m 0644 ${S}/profiles/input/input.conf ${D}/${sysconfdir}/bluetooth/
+	# at_console doesn't really work with the current state of OE, so punch some more holes so people can actually use BT
+	install -m 0644 ${WORKDIR}/bluetooth.conf ${D}/${sysconfdir}/dbus-1/system.d/
+}
+
+ALLOW_EMPTY_libasound-module-bluez = "1"
+PACKAGES =+ "libasound-module-bluez ${PN}-test"
+
+FILES_libasound-module-bluez = "${libdir}/alsa-lib/lib*.so ${datadir}/alsa"
+FILES_${PN} += "${libdir}/bluetooth/plugins ${libdir}/bluetooth/plugins/*.so ${base_libdir}/udev/ ${nonarch_base_libdir}/udev/ ${systemd_unitdir}/ ${datadir}/dbus-1"
+FILES_${PN}-dev += "\
+  ${libdir}/bluetooth/plugins/*.la \
+  ${libdir}/alsa-lib/*.la \
+"
+
+FILES_${PN}-test = "${libdir}/bluez/test/*"
+
+FILES_${PN}-dbg += "\
+  ${libdir}/${PN}/bluetooth/.debug \
+  ${libdir}/bluetooth/plugins/.debug \
+  ${libdir}/*/.debug \
+  ${base_libdir}/udev/.debug \
+  "
-- 
1.7.10.4

[PATCH 2/5] bluez4: conflicts with/replaces bluez5

[Cristian Iorga]

- RCONFLICTS/RREPLACES bluez5

Signed-off-by: Cristian Iorga <cristian.iorga@intel.com>
---
 meta/recipes-connectivity/bluez/bluez4_4.101.bb |    5 ++++-
 1 file changed, 4 insertions(+), 1 deletion(-)

diff --git a/meta/recipes-connectivity/bluez/bluez4_4.101.bb b/meta/recipes-connectivity/bluez/bluez4_4.101.bb
index f48adfd..91ebc63 100644
--- a/meta/recipes-connectivity/bluez/bluez4_4.101.bb
+++ b/meta/recipes-connectivity/bluez/bluez4_4.101.bb
@@ -1,6 +1,6 @@
 require bluez4.inc
 
-PR = "r5"
+PR = "r6"
 
 SRC_URI += "file://bluetooth.conf \
             file://sbc_mmx.patch \
@@ -11,6 +11,9 @@ SRC_URI += "file://bluetooth.conf \
 SRC_URI[md5sum] = "fb42cb7038c380eb0e2fa208987c96ad"
 SRC_URI[sha256sum] = "59738410ade9f0e61a13c0f77d9aaffaafe49ba9418107e4ad75fe52846f7487"
 
+RCONFLICTS_${PN} = "bluez5"
+RREPLACES_${PN} = "bluez5"
+
 do_install_append() {
 	install -m 0644 ${S}/audio/audio.conf ${D}/${sysconfdir}/bluetooth/
 	install -m 0644 ${S}/network/network.conf ${D}/${sysconfdir}/bluetooth/
-- 
1.7.10.4

[PATCH 3/5] bluez5: upgrade to v5.7

[Cristian Iorga]

Signed-off-by: Cristian Iorga <cristian.iorga@intel.com>
---
 .../bluez5/{bluez5-5.4 => bluez5-5.7}/bluetooth.conf               |    0
 .../bluez5/{bluez5-5.4 => bluez5-5.7}/fix-udev-paths.patch         |    0
 meta/recipes-connectivity/bluez5/{bluez5_5.4.bb => bluez5_5.7.bb}  |    4 ++--
 3 files changed, 2 insertions(+), 2 deletions(-)
 rename meta/recipes-connectivity/bluez5/{bluez5-5.4 => bluez5-5.7}/bluetooth.conf (100%)
 rename meta/recipes-connectivity/bluez5/{bluez5-5.4 => bluez5-5.7}/fix-udev-paths.patch (100%)
 rename meta/recipes-connectivity/bluez5/{bluez5_5.4.bb => bluez5_5.7.bb} (90%)

diff --git a/meta/recipes-connectivity/bluez5/bluez5-5.4/bluetooth.conf b/meta/recipes-connectivity/bluez5/bluez5-5.7/bluetooth.conf
similarity index 100%
rename from meta/recipes-connectivity/bluez5/bluez5-5.4/bluetooth.conf
rename to meta/recipes-connectivity/bluez5/bluez5-5.7/bluetooth.conf
diff --git a/meta/recipes-connectivity/bluez5/bluez5-5.4/fix-udev-paths.patch b/meta/recipes-connectivity/bluez5/bluez5-5.7/fix-udev-paths.patch
similarity index 100%
rename from meta/recipes-connectivity/bluez5/bluez5-5.4/fix-udev-paths.patch
rename to meta/recipes-connectivity/bluez5/bluez5-5.7/fix-udev-paths.patch
diff --git a/meta/recipes-connectivity/bluez5/bluez5_5.4.bb b/meta/recipes-connectivity/bluez5/bluez5_5.7.bb
similarity index 90%
rename from meta/recipes-connectivity/bluez5/bluez5_5.4.bb
rename to meta/recipes-connectivity/bluez5/bluez5_5.7.bb
index 4379de6..824800b 100644
--- a/meta/recipes-connectivity/bluez5/bluez5_5.4.bb
+++ b/meta/recipes-connectivity/bluez5/bluez5_5.7.bb
@@ -3,8 +3,8 @@ require bluez5.inc
 SRC_URI += "file://bluetooth.conf \
             file://fix-udev-paths.patch"
 
-SRC_URI[md5sum] = "e4a7d8bab9c28053a53f00bc940382a8"
-SRC_URI[sha256sum] = "65b2d0d7eead2b3c49216b9f94ea71c3d15da92fb3fd49fce1ee6e91af1b4430"
+SRC_URI[md5sum] = "ce0ef43938e8bfc230f3f06d6ad02d7e"
+SRC_URI[sha256sum] = "902299204b7139c913765603c7054a604570aea9e9fddb30454bd1b5e5997860"
 
 RCONFLICTS_${PN} = "bluez4"
 RREPLACES_${PN} = "bluez4"
-- 
1.7.10.4

[PATCH 4/5] bluez5: add readline dependency

[Cristian Iorga]

From: Alexandru DAMIAN <alexandru.damian@intel.com>

    bluez5 uses readline to be build, but the dependency is not listed
    This is listed in the configuration log.
    So we add it.

Signed-off-by: Cristian Iorga <cristian.iorga@intel.com>
---
 meta/recipes-connectivity/bluez5/bluez5.inc |    2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta/recipes-connectivity/bluez5/bluez5.inc b/meta/recipes-connectivity/bluez5/bluez5.inc
index db9c766..86a9bbe 100644
--- a/meta/recipes-connectivity/bluez5/bluez5.inc
+++ b/meta/recipes-connectivity/bluez5/bluez5.inc
@@ -6,7 +6,7 @@ LICENSE = "GPLv2+ & LGPLv2.1+"
 LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e \
                     file://COPYING.LIB;md5=fb504b67c50331fc78734fed90fb0e09 \
                     file://src/main.c;beginline=1;endline=24;md5=9bc54b93cd7e17bf03f52513f39f926e"
-DEPENDS = "udev libusb dbus-glib glib-2.0 libcheck libical"
+DEPENDS = "udev libusb dbus-glib glib-2.0 libcheck libical readline"
 
 PACKAGECONFIG ??= "\
     ${@base_contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)}\
-- 
1.7.10.4

[PATCH 5/5] bluez5: Set udev variables using pkg-config

[Cristian Iorga]

From: Richard Purdie <richard.purdie@linuxfoundation.org>

Signed-off-by: Cristian Iorga <cristian.iorga@intel.com>
---
 meta/recipes-connectivity/bluez5/bluez5.inc    |    4 ++--
 meta/recipes-connectivity/bluez5/bluez5_5.7.bb |    2 +-
 2 files changed, 3 insertions(+), 3 deletions(-)

diff --git a/meta/recipes-connectivity/bluez5/bluez5.inc b/meta/recipes-connectivity/bluez5/bluez5.inc
index 86a9bbe..240e13d 100644
--- a/meta/recipes-connectivity/bluez5/bluez5.inc
+++ b/meta/recipes-connectivity/bluez5/bluez5.inc
@@ -37,8 +37,8 @@ EXTRA_OECONF = "\
   --disable-cups \
   --enable-test \
   --enable-datafiles \
-  --with-udevdir=${base_libdir}/udev \
-  --with-udevrulesdir=${nonarch_base_libdir}/udev/rules.d \
+  --with-udevdir=`pkg-config --variable=udevdir udev` \
+  --with-udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d \
   ${@base_contains('DISTRO_FEATURES', 'systemd', '--with-systemdunitdir=${systemd_unitdir}/system/', '--disable-systemd', d)} \
 "
 
diff --git a/meta/recipes-connectivity/bluez5/bluez5_5.7.bb b/meta/recipes-connectivity/bluez5/bluez5_5.7.bb
index 824800b..0160f61 100644
--- a/meta/recipes-connectivity/bluez5/bluez5_5.7.bb
+++ b/meta/recipes-connectivity/bluez5/bluez5_5.7.bb
@@ -34,5 +34,5 @@ FILES_${PN}-dbg += "\
   ${libdir}/${PN}/bluetooth/.debug \
   ${libdir}/bluetooth/plugins/.debug \
   ${libdir}/*/.debug \
-  ${base_libdir}/udev/.debug \
+  */udev/.debug \
   "
-- 
1.7.10.4

Re: [PATCH 4/5] bluez5: add readline dependency

[Burton, Ross]

On 12 July 2013 15:06, Cristian Iorga <cristian.iorga@intel.com> wrote:
> From: Alexandru DAMIAN <alexandru.damian@intel.com>
>
>     bluez5 uses readline to be build, but the dependency is not listed
>     This is listed in the configuration log.
>     So we add it.
>
> Signed-off-by: Cristian Iorga <cristian.iorga@intel.com>

Squash this too.

Ross

Re: [PATCH 5/5] bluez5: Set udev variables using pkg-config

[Burton, Ross]

On 12 July 2013 15:06, Cristian Iorga <cristian.iorga@intel.com> wrote:
> +  --with-udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d \

Again this commit should be squashed, but if we're doing this line in
particular then we're negating the point of fix-udev-paths.patch
introduced in 1/5.  Drop the patch and this argument.

Ross

[PATCH 4/5] bluez5: add readline dependency

[Cristian Iorga]

From: Alexandru DAMIAN <alexandru.damian@intel.com>

    bluez5 uses readline to be build, but the dependency is not listed
    This is listed in the configuration log.
    So we add it.

Signed-off-by: Cristian Iorga <cristian.iorga@intel.com>
---
 meta/recipes-connectivity/bluez5/bluez5.inc |    2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta/recipes-connectivity/bluez5/bluez5.inc b/meta/recipes-connectivity/bluez5/bluez5.inc
index db9c766..86a9bbe 100644
--- a/meta/recipes-connectivity/bluez5/bluez5.inc
+++ b/meta/recipes-connectivity/bluez5/bluez5.inc
@@ -6,7 +6,7 @@ LICENSE = "GPLv2+ & LGPLv2.1+"
 LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e \
                     file://COPYING.LIB;md5=fb504b67c50331fc78734fed90fb0e09 \
                     file://src/main.c;beginline=1;endline=24;md5=9bc54b93cd7e17bf03f52513f39f926e"
-DEPENDS = "udev libusb dbus-glib glib-2.0 libcheck libical"
+DEPENDS = "udev libusb dbus-glib glib-2.0 libcheck libical readline"
 
 PACKAGECONFIG ??= "\
     ${@base_contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)}\
-- 
1.7.10.4