[PATCH 01/20] fsl-tlu: add recipe

[PATCH 01/20] fsl-tlu: add recipe

[Zhenhua Luo]

The fsl-tlu package includes the TLU(Table Lookup Unit) test scripts and
and configuration files.

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 recipes-bsp/fsl-tlu/fsl-tlu_1.0.0.bb | 18 ++++++++++++++++++
 1 file changed, 18 insertions(+)
 create mode 100644 recipes-bsp/fsl-tlu/fsl-tlu_1.0.0.bb

diff --git a/recipes-bsp/fsl-tlu/fsl-tlu_1.0.0.bb b/recipes-bsp/fsl-tlu/fsl-tlu_1.0.0.bb
new file mode 100644
index 0000000..213e74a
--- /dev/null
+++ b/recipes-bsp/fsl-tlu/fsl-tlu_1.0.0.bb
@@ -0,0 +1,18 @@
+SUMMARY = "Freescale TLU(Table Lookup Unit) test package"
+DESCRIPTION = "This package includes the TLU(Table Lookup Unit) test scripts \
+and configuration files."
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=8a71d0475d08eee76d8b6d0c6dbec543"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/fsl-tlu.git;branch=master"
+SRCREV = "8837cce3c86b30c0931c319e9e1a8ca622ae5354"
+
+S = "${WORKDIR}/git"
+
+do_install() {
+    install -d ${D}${sbindir}/fsl_tlu
+    find . -type f -exec cp {} ${D}${sbindir}/fsl_tlu/ \;
+}
+
+COMPATIBLE_MACHINE = "(e500mc)"
-- 
2.4.3

[PATCH 02/20] qoriq-ppc.inc: disable virtual terminal support for QorIQ PPC

[Zhenhua Luo]

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 conf/machine/include/qoriq-ppc.inc | 2 ++
 1 file changed, 2 insertions(+)

diff --git a/conf/machine/include/qoriq-ppc.inc b/conf/machine/include/qoriq-ppc.inc
index c60da4a..3d39780 100644
--- a/conf/machine/include/qoriq-ppc.inc
+++ b/conf/machine/include/qoriq-ppc.inc
@@ -8,4 +8,6 @@ UBINIZE_ARGS ??= "-m 512 -p 16KiB -s 512"
 SERIAL_CONSOLES ?= "115200;ttyS0 115200;ttyS1 115200;ttyEHV0"
 SERIAL_CONSOLES_CHECK ?= "${SERIAL_CONSOLES}"
 
+USE_VT ?= "0"
+
 MACHINEOVERRIDES .= ":qoriq-ppc"
-- 
2.4.3

[PATCH 03/20] rename scatter-gather to kernel-module-scatter-gather and move bb to kernel-modules subdir

[Zhenhua Luo]

* rename scatter-gather to kernel-module-scatter-gather
* move bb file to the common kernel-modules subdirectory

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 .../kernel-module-scatter-gather_git.bb}                                  | 0
 1 file changed, 0 insertions(+), 0 deletions(-)
 rename recipes-kernel/{scatter-gather/scatter-gather_git.bb => kernel-modules/kernel-module-scatter-gather_git.bb} (100%)

diff --git a/recipes-kernel/scatter-gather/scatter-gather_git.bb b/recipes-kernel/kernel-modules/kernel-module-scatter-gather_git.bb
similarity index 100%
rename from recipes-kernel/scatter-gather/scatter-gather_git.bb
rename to recipes-kernel/kernel-modules/kernel-module-scatter-gather_git.bb
-- 
2.4.3

[PATCH 04/20] kernel-module-scatter-gather: update COMPATIBLE_MACHINE from ls1021atwr to ls1021a

[Zhenhua Luo]

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 recipes-kernel/kernel-modules/kernel-module-scatter-gather_git.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/recipes-kernel/kernel-modules/kernel-module-scatter-gather_git.bb b/recipes-kernel/kernel-modules/kernel-module-scatter-gather_git.bb
index 0fb6c65..1caec3e 100644
--- a/recipes-kernel/kernel-modules/kernel-module-scatter-gather_git.bb
+++ b/recipes-kernel/kernel-modules/kernel-module-scatter-gather_git.bb
@@ -9,4 +9,4 @@ SRCREV = "97db173d08a70abe2b9a6fa928299a117f3febc2"
 
 S = "${WORKDIR}/git"
 
-COMPATIBLE_MACHINE = "(ls1021atwr)"
+COMPATIBLE_MACHINE = "(ls1021a)"
-- 
2.4.3

[PATCH 05/20] kernel-module-ls-debug: move to kernel-modules subdir

[Zhenhua Luo]

Move the kernel module bb file to kernel-modules subdirectory which
manages recipes of kernel module.

Signee-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 .../kernel-module-ls-debug_git.bb                                         | 0
 1 file changed, 0 insertions(+), 0 deletions(-)
 rename recipes-kernel/{kernel-module-ls-debug => kernel-modules}/kernel-module-ls-debug_git.bb (100%)

diff --git a/recipes-kernel/kernel-module-ls-debug/kernel-module-ls-debug_git.bb b/recipes-kernel/kernel-modules/kernel-module-ls-debug_git.bb
similarity index 100%
rename from recipes-kernel/kernel-module-ls-debug/kernel-module-ls-debug_git.bb
rename to recipes-kernel/kernel-modules/kernel-module-ls-debug_git.bb
-- 
2.4.3

[PATCH 06/20] rename qoriq-debug to kernel-module-qoriq-debug and move bb to kernel-modules subdir

[Zhenhua Luo]

* rename qoriq-debug to kernel-module-qoriq-debug
* move bb file to the common kernel-modules subdirectory

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 .../kernel-module-qoriq-debug_git.bb}                                     | 0
 1 file changed, 0 insertions(+), 0 deletions(-)
 rename recipes-kernel/{qoriq-debug/qoriq-debug_git.bb => kernel-modules/kernel-module-qoriq-debug_git.bb} (100%)

diff --git a/recipes-kernel/qoriq-debug/qoriq-debug_git.bb b/recipes-kernel/kernel-modules/kernel-module-qoriq-debug_git.bb
similarity index 100%
rename from recipes-kernel/qoriq-debug/qoriq-debug_git.bb
rename to recipes-kernel/kernel-modules/kernel-module-qoriq-debug_git.bb
-- 
2.4.3

[PATCH 07/20] rename pkc-host to kernel-module-pkc-host and move bb to kernel-modules subdir

[Zhenhua Luo]

* rename pkc-host to kernel-module-pkc-host
* move bb file to the common kernel-modules subdirectory

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 .../pkc-host_git.bb => kernel-modules/kernel-module-pkc-host_git.bb}      | 0
 1 file changed, 0 insertions(+), 0 deletions(-)
 rename recipes-kernel/{pkc-host/pkc-host_git.bb => kernel-modules/kernel-module-pkc-host_git.bb} (100%)

diff --git a/recipes-kernel/pkc-host/pkc-host_git.bb b/recipes-kernel/kernel-modules/kernel-module-pkc-host_git.bb
similarity index 100%
rename from recipes-kernel/pkc-host/pkc-host_git.bb
rename to recipes-kernel/kernel-modules/kernel-module-pkc-host_git.bb
-- 
2.4.3

[PATCH 08/20] rename skmm-host to kernel-module-skmm-host and move bb to kernel-modules subdir

[Zhenhua Luo]

* rename skmm-host to kernel-module-skmm-host
* move bb file to the common kernel-modules subdirectory

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 .../skmm-host_git.bb => kernel-modules/kernel-module-skmm-host_git.bb}    | 0
 1 file changed, 0 insertions(+), 0 deletions(-)
 rename recipes-kernel/{skmm-host/skmm-host_git.bb => kernel-modules/kernel-module-skmm-host_git.bb} (100%)

diff --git a/recipes-kernel/skmm-host/skmm-host_git.bb b/recipes-kernel/kernel-modules/kernel-module-skmm-host_git.bb
similarity index 100%
rename from recipes-kernel/skmm-host/skmm-host_git.bb
rename to recipes-kernel/kernel-modules/kernel-module-skmm-host_git.bb
-- 
2.4.3

[PATCH 09/20] Add kernel-module prefix for ipc kernel module bb and move bb to kernel-modules subdir

[Zhenhua Luo]

* rename ipc-modules-multi to kernel-module-ipc-multi
* rename ipc-modules-single to kernel-module-ipc-single
* rename ipc-modules to kernel-module-ipc
* move kernel module recipes to the kernel-modules subdirectory

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 .../kernel-module-ipc-multi_git.bb}                                     | 2 +-
 .../kernel-module-ipc-single_git.bb}                                    | 2 +-
 .../ipc-modules.inc => kernel-modules/kernel-module-ipc.inc}            | 0
 3 files changed, 2 insertions(+), 2 deletions(-)
 rename recipes-kernel/{ipc-modules/ipc-modules-multi_git.bb => kernel-modules/kernel-module-ipc-multi_git.bb} (91%)
 rename recipes-kernel/{ipc-modules/ipc-modules-single_git.bb => kernel-modules/kernel-module-ipc-single_git.bb} (90%)
 rename recipes-kernel/{ipc-modules/ipc-modules.inc => kernel-modules/kernel-module-ipc.inc} (100%)

diff --git a/recipes-kernel/ipc-modules/ipc-modules-multi_git.bb b/recipes-kernel/kernel-modules/kernel-module-ipc-multi_git.bb
similarity index 91%
rename from recipes-kernel/ipc-modules/ipc-modules-multi_git.bb
rename to recipes-kernel/kernel-modules/kernel-module-ipc-multi_git.bb
index e5dc115..4570e78 100644
--- a/recipes-kernel/ipc-modules/ipc-modules-multi_git.bb
+++ b/recipes-kernel/kernel-modules/kernel-module-ipc-multi_git.bb
@@ -1,4 +1,4 @@
-require ipc-modules.inc
+require kernel-module-ipc.inc
 
 EXTRA_OEMAKE ="KERNEL_DIR=${STAGING_KERNEL_DIR} ${SOC}=1 CONFIG_MULTI_RAT=1"
 
diff --git a/recipes-kernel/ipc-modules/ipc-modules-single_git.bb b/recipes-kernel/kernel-modules/kernel-module-ipc-single_git.bb
similarity index 90%
rename from recipes-kernel/ipc-modules/ipc-modules-single_git.bb
rename to recipes-kernel/kernel-modules/kernel-module-ipc-single_git.bb
index 03817e0..5c81d34 100644
--- a/recipes-kernel/ipc-modules/ipc-modules-single_git.bb
+++ b/recipes-kernel/kernel-modules/kernel-module-ipc-single_git.bb
@@ -1,4 +1,4 @@
-require ipc-modules.inc
+require kernel-module-ipc.inc
 
 EXTRA_OEMAKE ="KERNEL_DIR=${STAGING_KERNEL_DIR} ${SOC}=1"
 
diff --git a/recipes-kernel/ipc-modules/ipc-modules.inc b/recipes-kernel/kernel-modules/kernel-module-ipc.inc
similarity index 100%
rename from recipes-kernel/ipc-modules/ipc-modules.inc
rename to recipes-kernel/kernel-modules/kernel-module-ipc.inc
-- 
2.4.3

[PATCH 10/20] rename ar to kernel-module-ar and move bb to kernel-modules subdir

[Zhenhua Luo]

* rename ar to kernel-module-ar
* move bb file to the common kernel-modules subdirectory

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 .../{auto-resp/ar_git.bb => kernel-modules/kernel-module-ar_git.bb}       | 0
 1 file changed, 0 insertions(+), 0 deletions(-)
 rename recipes-kernel/{auto-resp/ar_git.bb => kernel-modules/kernel-module-ar_git.bb} (100%)

diff --git a/recipes-kernel/auto-resp/ar_git.bb b/recipes-kernel/kernel-modules/kernel-module-ar_git.bb
similarity index 100%
rename from recipes-kernel/auto-resp/ar_git.bb
rename to recipes-kernel/kernel-modules/kernel-module-ar_git.bb
-- 
2.4.3

[PATCH 11/20] rename uio-seville to kernel-module-uio-seville and move bb to kernel-modules subdir

[Zhenhua Luo]

* rename uio-seville to kernel-module-uio-seville
* move bb file to the common kernel-modules subdirectory

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 .../kernel-module-uio-seville_0.1.bb}                                     | 0
 1 file changed, 0 insertions(+), 0 deletions(-)
 rename recipes-kernel/{uio-seville/uio-seville_0.1.bb => kernel-modules/kernel-module-uio-seville_0.1.bb} (100%)
 mode change 100755 => 100644

diff --git a/recipes-kernel/uio-seville/uio-seville_0.1.bb b/recipes-kernel/kernel-modules/kernel-module-uio-seville_0.1.bb
old mode 100755
new mode 100644
similarity index 100%
rename from recipes-kernel/uio-seville/uio-seville_0.1.bb
rename to recipes-kernel/kernel-modules/kernel-module-uio-seville_0.1.bb
-- 
2.4.3

[PATCH 12/20] rename ceetm to kernel-module-ceetm and move bb to kernel-modules subdir

[Zhenhua Luo]

* rename ceetm to kernel-module-ceetm
* move bb file to the common kernel-modules subdirectory

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 .../{ceetm/ceetm_git.bb => kernel-modules/kernel-module-ceetm_git.bb}     | 0
 1 file changed, 0 insertions(+), 0 deletions(-)
 rename recipes-kernel/{ceetm/ceetm_git.bb => kernel-modules/kernel-module-ceetm_git.bb} (100%)

diff --git a/recipes-kernel/ceetm/ceetm_git.bb b/recipes-kernel/kernel-modules/kernel-module-ceetm_git.bb
similarity index 100%
rename from recipes-kernel/ceetm/ceetm_git.bb
rename to recipes-kernel/kernel-modules/kernel-module-ceetm_git.bb
-- 
2.4.3

[PATCH 13/20] rename asf to kernel-module-asf and move bb to kernel-modules subdir

[Zhenhua Luo]

* rename asf to kernel-module-asf
* move bb file to the common kernel-modules subdirectory

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 .../{asf/asf_git.bb => kernel-modules/kernel-module-asf_git.bb}           | 0
 1 file changed, 0 insertions(+), 0 deletions(-)
 rename recipes-kernel/{asf/asf_git.bb => kernel-modules/kernel-module-asf_git.bb} (100%)

diff --git a/recipes-kernel/asf/asf_git.bb b/recipes-kernel/kernel-modules/kernel-module-asf_git.bb
similarity index 100%
rename from recipes-kernel/asf/asf_git.bb
rename to recipes-kernel/kernel-modules/kernel-module-asf_git.bb
-- 
2.4.3

[PATCH 14/20] openssl-qoriq should provide the same output packages as poky openssl

[Zhenhua Luo]

The same output packages of poky openssl should be provided by openssl-qoriq,
otherwise the following build error will appear when multiple output packages
of openssl are depended, some are provided by openssl-qoriq, the others are
provided by poky openssl.

  ERROR: Multiple .bb files are due to be built which each provide openssl
  (.../meta-freescale/recipes-connectivity/openssl/openssl-qoriq_1.0.1i.bb
  /poky/meta/recipes-connectivity/openssl/openssl_1.0.2d.bb). This usually
  means one provides something the other doesn't and should.

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 recipes-connectivity/openssl/openssl-qoriq.inc | 30 ++++++++++++++++++++++----
 1 file changed, 26 insertions(+), 4 deletions(-)

diff --git a/recipes-connectivity/openssl/openssl-qoriq.inc b/recipes-connectivity/openssl/openssl-qoriq.inc
index ee02fb7..b792c01 100644
--- a/recipes-connectivity/openssl/openssl-qoriq.inc
+++ b/recipes-connectivity/openssl/openssl-qoriq.inc
@@ -32,13 +32,35 @@ export AS = "${CC} -c"
 
 inherit pkgconfig siteinfo multilib_header
 
-PACKAGES =+ "libcrypto libssl ${PN}-misc openssl-conf"
+PACKAGES = "openssl-engines openssl-engines-dbg libcrypto libssl openssl-misc \
+    openssl-conf openssl-ptest openssl-dbg openssl-staticdev openssl-dev \
+    openssl-doc openssl-locale openssl"
+FILES_openssl-engines = "${libdir}/ssl/engines/*.so ${libdir}/engines"
+FILES_openssl-engines-dbg = "${libdir}/ssl/engines/.debug"
 FILES_libcrypto = "${base_libdir}/libcrypto${SOLIBS}"
 FILES_libssl = "${libdir}/libssl.so.*"
-FILES_${PN} =+ " ${libdir}/ssl/*"
-FILES_${PN}-misc = "${libdir}/ssl/misc ${bindir}/c_rehash"
+FILES_openssl-misc = "${libdir}/ssl/misc ${bindir}/c_rehash"
+FILES_openssl-ptest = "${libdir}/openssl/ptest"
+FILES_openssl-dbg = "${bindir}/.debug ${sbindir}/.debug ${libdir}/openssl/.debug \
+    ${libdir}/.debug ${base_bindir}/.debug ${sbindir}/.debug \
+    ${base_libdir}/.debug ${libdir}/openssl/.debug ${libdir}/matchbox-panel/.debug \
+    ${libdir}/openssl/openssl/.debug /usr/src/debug"
+FILES_openssl-staticdev = "${libdir}/*.a ${base_libdir}/*.a ${libdir}/openssl/*.a"
+FILES_openssl-dev = "${includedir} ${base_libdir}/lib*.so ${libdir}/lib*.so \
+    ${libdir}/*.la ${libdir}/*.o ${libdir}/pkgconfig ${datadir}/pkgconfig \
+    ${datadir}/aclocal ${base_libdir}/*.o ${libdir}/openssl/*.la ${base_libdir}/*.la \
+    ${base_libdir}/libcrypto.so"
+FILES_openssl-doc = "${datadir}/doc ${datadir}/man ${datadir}/info ${datadir}/gtk-doc \
+    ${datadir}/gnome/help"
+FILES_openssl-locale = "${datadir}/locale"
+FILES_openssl = "${libdir}/ssl/* ${bindir}/* ${sbindir}/* ${libdir}/openssl/* \
+    ${libdir}/lib*.so.* ${sysconfdir} ${sharedstatedir} ${localstatedir} ${base_bindir}/* \
+    ${base_sbindir}/* ${base_libdir}/*.so.* ${base_libdir}/udev/rules.d \
+    ${libdir}/udev/rules.d ${datadir}/openssl ${libdir}/openssl/* ${datadir}/pixmaps \
+    ${datadir}/applications ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
+    ${libdir}/bonobo/servers"
+
 RDEPENDS_${PN}-misc = "${@base_contains('PACKAGECONFIG', 'perl', 'perl', '', d)}"
-FILES_${PN}-dev += "${base_libdir}/libcrypto${SOLIBSDEV}"
 
 # Add the openssl.cnf file to the openssl-conf package.  Make the libcrypto
 # package RRECOMMENDS on this package.  This will enable the configuration
-- 
2.4.3

[PATCH 15/20] u-boot-qpriq: add quote mark to avoid build error when multiple u-boot configs are built

[Zhenhua Luo]

The the following build error:
    ./poky/p4080ds/tmp/work/p4080ds-poky-linux/u-boot-qoriq/2015.01+fslgit-r0/temp/run.do_deploy.16948: line 172: P4080DS_config: command not found
    UBOOT_MACHINES= P4080DS_config P4080DS_SECURE_BOOT_config P4080DS_SDCARD_config P4080DS_SPIFLASH_config

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 recipes-bsp/u-boot/u-boot-qoriq_2015.01.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/recipes-bsp/u-boot/u-boot-qoriq_2015.01.bb b/recipes-bsp/u-boot/u-boot-qoriq_2015.01.bb
index f5b258d..2ab2e13 100644
--- a/recipes-bsp/u-boot/u-boot-qoriq_2015.01.bb
+++ b/recipes-bsp/u-boot/u-boot-qoriq_2015.01.bb
@@ -154,7 +154,7 @@ do_install_append_qoriq-ppc() {
 
 do_deploy_append_qoriq-ppc() {
     if [ "x${UBOOT_MACHINES}" = "x" ]; then
-        UBOOT_MACHINES=${UBOOT_MACHINE}
+        UBOOT_MACHINES="${UBOOT_MACHINE}"
     fi
 
     for board in ${UBOOT_MACHINES}; do
-- 
2.4.3

[PATCH 16/20] apptrk: replace += with append to ensure CFLAGS is appended correctly

[Zhenhua Luo]

Fix the following build error:
Source/Linux_PA/linux_ppc_targimpl.c:19:24: fatal error: trk_prefix.h: No such file or directory

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 recipes-bsp/apptrk/apptrk_git.bb | 8 ++++----
 1 file changed, 4 insertions(+), 4 deletions(-)

diff --git a/recipes-bsp/apptrk/apptrk_git.bb b/recipes-bsp/apptrk/apptrk_git.bb
index cef1292..6cb8cfc 100644
--- a/recipes-bsp/apptrk/apptrk_git.bb
+++ b/recipes-bsp/apptrk/apptrk_git.bb
@@ -17,10 +17,10 @@ S = "${WORKDIR}/git"
 
 EXTRA_OEMAKE_qoriq-arm = "ARCH=arm"
 
-CFLAGS += "-I${STAGING_INCDIR} -ISource/Linux -ISource/Portable"
-CFLAGS_qoriq-arm += "-ISource/Linux_ARM -ISource/ARM"
-CFLAGS_qoriq-ppc += "-ISource/Linux_PA -ISource/PA -DPPC"
-CFLAGS_powerpc64 += "-DENABLE_64BIT_SUPPORT"
+CFLAGS_append = " -I${STAGING_INCDIR} -ISource/Linux -ISource/Portable"
+CFLAGS_append_qoriq-arm = "-ISource/Linux_ARM -ISource/ARM"
+CFLAGS_append_qoriq-ppc += "-ISource/Linux_PA -ISource/PA -DPPC"
+CFLAGS_append_powerpc64 += "-DENABLE_64BIT_SUPPORT"
 
 do_install() {
         oe_runmake install DESTDIR=${D}
-- 
2.4.3

[PATCH 18/20] valgrind: add bbappend for multilib support and override memcpy/memset

[Zhenhua Luo]

* Add bbappend for qoriq(except e500v2) to create a symbolic link as the
  user expects to see a /usr/bin/valgrind on 64-bit MACHINE's, ensure that
  the link created, points to the *64-bit* valgrind. Assume that the presence
  of the patterns: "\-64b" in ${MACHINE} and "64" in ${TARGET_ARCH}, indicate
  the 64-bit flavour and that their absence indicates 32-bit flavour respectively.
  Now, when both 32-bit and 64-bit flavours are available to choose from; it
  does happen that even though ${MACHINE} is chosen to indicate the choice of
  the 32-bit case, the 64-bit tools are built too. So, ensure that on 32-bit,
  the link points to the 32-bit valgrind, and of-course, that on 64-bit, the
  link points to the 64-bit valgrind.
* Override the 32-bit implementations of memcpy(), memset() from glibc.
  On 64-bit platforms, for 32-bit mode, the Freescale optimized implementations
  of the glibc functions memcpy(), memset() use POWER ISA Category:64-bit
  instructions. By design, these are not implementatble in Valgrind in 32-bit
  mode. Therefore, we override the library versions with plain classic POWER
  32-bit alternate versions (emitted at -O0 by GCC).
  Add COMPATIBLE_MACHINE

Signed-off-by: Ting Liu <b28495@freescale.com>
Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 .../override-32-bit-glibc-memcpy-memset.patch      | 159 +++++++++++++++++++++
 recipes-devtools/valgrind/valgrind_3.10.1.bbappend |  19 +++
 2 files changed, 178 insertions(+)
 create mode 100644 recipes-devtools/valgrind/valgrind/override-32-bit-glibc-memcpy-memset.patch
 create mode 100644 recipes-devtools/valgrind/valgrind_3.10.1.bbappend

diff --git a/recipes-devtools/valgrind/valgrind/override-32-bit-glibc-memcpy-memset.patch b/recipes-devtools/valgrind/valgrind/override-32-bit-glibc-memcpy-memset.patch
new file mode 100644
index 0000000..56da7d2
--- /dev/null
+++ b/recipes-devtools/valgrind/valgrind/override-32-bit-glibc-memcpy-memset.patch
@@ -0,0 +1,159 @@
+Upstream-Status: Pending
+
+ Override the 32-bit implementations of memcpy(), memset() from glibc.
+
+ On 64-bit platforms, for 32-bit mode, the Freescale optimized implementations
+ of the glibc functions memcpy(), memset() use POWER ISA Category:64-bit
+ instructions. By design, these are not implementatble in Valgrind in 32-bit
+ mode. Therefore, we override the library versions with plain classic POWER
+ 32-bit alternate versions (emitted at -O0 by GCC).
+
+ Note that this does not affect in any way, the user's ability to debug their
+ code with Valgrind.
+
+Signed-off-by: Anmol Paralkar <Anmol@freescale.com>
+
+Index: coregrind/pub_core_trampoline.h
+===================================================================
+--- a/coregrind/pub_core_trampoline.h	(revision 14779)
++++ b/coregrind/pub_core_trampoline.h	(working copy)
+@@ -79,6 +79,8 @@
+ extern UInt  VG_(ppc32_linux_REDIR_FOR_strlen)( void* );
+ extern UInt  VG_(ppc32_linux_REDIR_FOR_strcmp)( void*, void* );
+ extern void* VG_(ppc32_linux_REDIR_FOR_strchr)( void*, Int );
++extern void *VG_(ppc32_linux_fsl_REDIR_FOR_memcpy)(void *dest, const void *src, Int n);
++extern void *VG_(ppc32_linux_fsl_REDIR_FOR_memset)(void *s, Int c, Int n);
+ #endif
+ 
+ #if defined(VGP_ppc64be_linux) || defined(VGP_ppc64le_linux)
+Index: coregrind/m_trampoline.S
+===================================================================
+--- a/coregrind/m_trampoline.S	(revision 14779)
++++ b/coregrind/m_trampoline.S	(working copy)
+@@ -307,6 +307,105 @@
+ .global VG_(trampoline_stuff_start)
+ VG_(trampoline_stuff_start):
+ 
++/* To obtain the assembly below, do: gcc -S -m32 on:
++#define VG_(x) x
++
++void *VG_(ppc32_linux_fsl_REDIR_FOR_memcpy)(char *dst, const char *src, int n)
++{
++  const char *p;
++  char *q = dst;
++  p = src;
++  while ((p - src) < n)
++    *q++ = *p++;
++  return dst;
++}
++*/
++.align 2
++.globl VG_(ppc32_linux_fsl_REDIR_FOR_memcpy)
++.type   VG_(ppc32_linux_fsl_REDIR_FOR_memcpy), @function
++VG_(ppc32_linux_fsl_REDIR_FOR_memcpy):
++        stwu 1,-48(1)
++        stw 31,44(1)
++        mr 31,1
++        stw 3,24(31)
++        stw 4,28(31)
++        stw 5,32(31)
++        lwz 9,24(31)
++        stw 9,12(31)
++        lwz 9,28(31)
++        stw 9,8(31)
++        b .L2
++.L3:   
++        lwz 9,12(31)
++        addi 10,9,1
++        stw 10,12(31)
++        lwz 10,8(31)
++        addi 8,10,1
++        stw 8,8(31)
++        lbz 10,0(10)
++        rlwinm 10,10,0,0xff
++        stb 10,0(9)
++.L2:   
++        lwz 10,8(31)
++        lwz 9,28(31)
++        subf 10,9,10
++        lwz 9,32(31)
++        cmpw 7,10,9
++        blt 7,.L3
++        lwz 9,24(31)
++        mr 3,9
++        addi 11,31,48
++        lwz 31,-4(11)
++        mr 1,11
++        blr
++.size   VG_(ppc32_linux_fsl_REDIR_FOR_memcpy),.-VG_(ppc32_linux_fsl_REDIR_FOR_memcpy)
++
++/* To obtain the assembly below, do: gcc -S -m32 on:
++#define VG_(x) x
++void *VG_(ppc32_linux_fsl_REDIR_FOR_memset)(char *s, int c, int n)
++{
++  char *p;
++  p = s;
++  while ((p - s) < n)
++    *p++ = c;
++  return s;
++}
++ */
++.align 2
++.globl VG_(ppc32_linux_fsl_REDIR_FOR_memset)
++.type   VG_(ppc32_linux_fsl_REDIR_FOR_memset), @function
++VG_(ppc32_linux_fsl_REDIR_FOR_memset):
++        stwu 1,-48(1)
++        stw 31,44(1)
++        mr 31,1
++        stw 3,24(31)
++        stw 4,28(31)
++        stw 5,32(31)
++        lwz 9,24(31)
++        stw 9,8(31)
++        b .L6
++.L7:
++        lwz 9,8(31)
++        addi 10,9,1
++        stw 10,8(31)
++        lwz 10,28(31)
++        rlwinm 10,10,0,0xff
++        stb 10,0(9)
++.L6:   
++        lwz 10,8(31)
++        lwz 9,24(31)
++        subf 10,9,10
++        lwz 9,32(31)
++        cmpw 7,10,9
++        blt 7,.L7
++        lwz 9,24(31)
++        mr 3,9
++        addi 11,31,48
++        lwz 31,-4(11)
++        mr 1,11
++        blr
++.size   VG_(ppc32_linux_fsl_REDIR_FOR_memset),.-VG_(ppc32_linux_fsl_REDIR_FOR_memset)
++
+ .global VG_(ppc32_linux_SUBST_FOR_sigreturn)
+ VG_(ppc32_linux_SUBST_FOR_sigreturn):
+ 	li 0,__NR_sigreturn
+Index: coregrind/m_redir.c
+===================================================================
+--- a/coregrind/m_redir.c	(revision 14779)
++++ b/coregrind/m_redir.c	(working copy)
+@@ -1284,6 +1284,16 @@
+    }
+ 
+ #  elif defined(VGP_ppc32_linux)
++   add_hardwired_spec(
++      "ld.so.1", "memcpy",
++      (Addr)VG_(fnptr_to_fnentry)( &VG_(ppc32_linux_fsl_REDIR_FOR_memcpy) ),
++         complain_about_stripped_glibc_ldso
++   );
++   add_hardwired_spec(
++      "ld.so.1", "memset",
++      (Addr)VG_(fnptr_to_fnentry)( &VG_(ppc32_linux_fsl_REDIR_FOR_memset) ),
++         complain_about_stripped_glibc_ldso
++   );
+    /* If we're using memcheck, use these intercepts right from
+       the start, otherwise ld.so makes a lot of noise. */
+    if (0==VG_(strcmp)("Memcheck", VG_(details).name)) {
diff --git a/recipes-devtools/valgrind/valgrind_3.10.1.bbappend b/recipes-devtools/valgrind/valgrind_3.10.1.bbappend
new file mode 100644
index 0000000..5fefffc
--- /dev/null
+++ b/recipes-devtools/valgrind/valgrind_3.10.1.bbappend
@@ -0,0 +1,19 @@
+FILESEXTRAPATHS_prepend := "${THISDIR}/${BPN}:"
+
+SRC_URI_append_qoriq-ppc = " \
+    file://override-32-bit-glibc-memcpy-memset.patch \
+"
+
+do_install_append_qoriq-ppc() {
+    # Create a symbolic link as the user expects to see a /usr/bin/valgrind
+    # On 64-bit MACHINE's, ensure that the link created, points to the *64-bit*
+    # valgrind. Assume that the presence of the patterns: "\-64b" in ${MACHINE}
+    # and "64" in ${TARGET_ARCH}, indicate the 64-bit flavour and that their
+    # absence indicates 32-bit flavour respectively. Now, when both 32-bit and
+    # 64-bit flavours are available to choose from; it does happen that even
+    # though ${MACHINE} is chosen to indicate the choice of the 32-bit case, the
+    # 64-bit tools are built too. So, ensure that on 32-bit, the link points
+    # to the 32-bit valgrind, and of-course, that on 64-bit, the link points
+    # to the 64-bit valgrind.
+    ln -sf ${TARGET_ARCH}-valgrind valgrind
+}
-- 
2.4.3

[PATCH 19/20] ipc-ust: move MACHINE specific variable out of task

[Zhenhua Luo]

Move SOC definition out of task.

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 recipes-extended/ipc-ust/ipc-ust_git.bb | 10 ++++++----
 1 file changed, 6 insertions(+), 4 deletions(-)

diff --git a/recipes-extended/ipc-ust/ipc-ust_git.bb b/recipes-extended/ipc-ust/ipc-ust_git.bb
index 5ba3411..38d15b0 100644
--- a/recipes-extended/ipc-ust/ipc-ust_git.bb
+++ b/recipes-extended/ipc-ust/ipc-ust_git.bb
@@ -5,6 +5,12 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=fa38cd73d71527dc6efb546474f64d10"
 
 require ipc.inc
 
+SOC_bsc9131rdb = "B913x"
+SOC_bsc9132qds = "B913x"
+SOC_b4860qds = "B4860"
+SOC_b4420qds = "B4860"
+SOC_b4860qds-64b = "B4860"
+
 S = "${WORKDIR}/git"
 
 # workaround for issue of parallel build, required a actual fix in ipc source
@@ -13,10 +19,6 @@ PARALLEL_MAKE = ""
 EXTRA_OEMAKE = 'CROSS_COMPILE="${TARGET_PREFIX}" CC="${CC}" AR="${AR}"'
 
 do_compile () {
-    case ${MACHINE} in
-        bsc9132qds|bsc9131rdb) SOC=B913x;;
-        b4860qds|b4420qds|b4860qds-64b) SOC=B4860;;
-    esac
     oe_runmake ${SOC}=1
 }
 
-- 
2.4.3

[PATCH 20/20] hv-cfg: move MACHINE specific variable out of task

[Zhenhua Luo]

Move M definition out of task.

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---
 recipes-virtualization/hv-cfg/hv-cfg_git.bb | 9 +++------
 1 file changed, 3 insertions(+), 6 deletions(-)

diff --git a/recipes-virtualization/hv-cfg/hv-cfg_git.bb b/recipes-virtualization/hv-cfg/hv-cfg_git.bb
index e4f18e0..eea7734 100644
--- a/recipes-virtualization/hv-cfg/hv-cfg_git.bb
+++ b/recipes-virtualization/hv-cfg/hv-cfg_git.bb
@@ -23,22 +23,19 @@ SRCREV = "b9287b07390d17bfba936a806a72b91b89507c22"
 
 S = "${WORKDIR}/git"
 
+M_t1042d4rdb = "t1040rdb"
+M_t1040d4rdb = "t1040rdb"
+
 do_install () {
 	make install
 
 	M=`echo ${MACHINE} | sed s/-64b//g`
-	if [ "t1042d4rdb" = "${M}" ] || [ "t1040d4rdb" = "${M}" ];then
-		M=t1040rdb
-	fi
 	install -d ${D}/boot/hv-cfg
 	cp -r ${S}/${M}/${M}/* ${D}/boot/hv-cfg
 }
 
 do_deploy () {
 	M=`echo ${MACHINE} | sed s/-64b//g`
-	if [ "t1042d4rdb" = "${M}" ] || [ "t1040d4rdb" = "${M}" ];then
-		M=t1040rdb
-	fi
 	install -d ${DEPLOYDIR}/hv-cfg
 	cp -r ${S}/${M}/${M}/* ${DEPLOYDIR}/hv-cfg
 }
-- 
2.4.3

Re: [PATCH 14/20] openssl-qoriq should provide the same output packages as poky openssl

[Otavio Salvador]

On Fri, Aug 28, 2015 at 7:36 AM, Zhenhua Luo <zhenhua.luo@freescale.com> wrote:
> The same output packages of poky openssl should be provided by openssl-qoriq,
> otherwise the following build error will appear when multiple output packages
> of openssl are depended, some are provided by openssl-qoriq, the others are
> provided by poky openssl.
>
>   ERROR: Multiple .bb files are due to be built which each provide openssl
>   (.../meta-freescale/recipes-connectivity/openssl/openssl-qoriq_1.0.1i.bb
>   /poky/meta/recipes-connectivity/openssl/openssl_1.0.2d.bb). This usually
>   means one provides something the other doesn't and should.
>
> Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>

This is because the package arch is wrong. The right fix for this is
to adjust package arch accordingly.

-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750

Re: [PATCH 19/20] ipc-ust: move MACHINE specific variable out of task

[Otavio Salvador]

On Fri, Aug 28, 2015 at 7:36 AM, Zhenhua Luo <zhenhua.luo@freescale.com> wrote:
> Move SOC definition out of task.
>
> Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>

This should be set in the qoriq inc file, using SoC family as source.
I would do:

IPC_UST_SOC_b4860 = "B4860"

For example.

The recipe should check if IPC_UST_SOC is empty and skip the package,
as done in U-Boot for UBOOT_MACHINE.


-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750

Re: [PATCH 20/20] hv-cfg: move MACHINE specific variable out of task

[Otavio Salvador]

On Fri, Aug 28, 2015 at 7:36 AM, Zhenhua Luo <zhenhua.luo@freescale.com> wrote:
> Move M definition out of task.
>
> Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>

Same recommendation as ipc-ust.

-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750

Re: [PATCH 14/20] openssl-qoriq should provide the same output packages as poky openssl

[Luo Zhenhua]

> -----Original Message-----
> From: Otavio Salvador [mailto:otavio.salvador@ossystems.com.br]
> Sent: Tuesday, September 01, 2015 12:22 AM
> 
> On Fri, Aug 28, 2015 at 7:36 AM, Zhenhua Luo <zhenhua.luo@freescale.com>
> wrote:
> > The same output packages of poky openssl should be provided by
> > openssl-qoriq, otherwise the following build error will appear when
> > multiple output packages of openssl are depended, some are provided by
> > openssl-qoriq, the others are provided by poky openssl.
> >
> >   ERROR: Multiple .bb files are due to be built which each provide openssl
> >   (.../meta-freescale/recipes-connectivity/openssl/openssl-qoriq_1.0.1i.bb
> >   /poky/meta/recipes-connectivity/openssl/openssl_1.0.2d.bb). This usually
> >   means one provides something the other doesn't and should.
> >
> > Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
> 
> This is because the package arch is wrong. The right fix for this is to adjust
> package arch accordingly.
[Luo Zhenhua-B19537] I try to add PACKAGE_ARCH = "${MACHINE_ARCH}" in openssl-qoriq bb file, the issue persists, any comment? 
	According to the error message, the issue is caused by some packages are provided by poky openssl, which should be provided by openssl-qoriq. 


Best Regards,

Zhenhua

Re: [PATCH 14/20] openssl-qoriq should provide the same output packages as poky openssl

[Otavio Salvador]

On Tue, Sep 1, 2015 at 4:37 AM, Luo Zhenhua <zhenhua.luo@freescale.com> wrote:
>> -----Original Message-----
>> From: Otavio Salvador [mailto:otavio.salvador@ossystems.com.br]
>> Sent: Tuesday, September 01, 2015 12:22 AM
>>
>> On Fri, Aug 28, 2015 at 7:36 AM, Zhenhua Luo <zhenhua.luo@freescale.com>
>> wrote:
>> > The same output packages of poky openssl should be provided by
>> > openssl-qoriq, otherwise the following build error will appear when
>> > multiple output packages of openssl are depended, some are provided by
>> > openssl-qoriq, the others are provided by poky openssl.
>> >
>> >   ERROR: Multiple .bb files are due to be built which each provide openssl
>> >   (.../meta-freescale/recipes-connectivity/openssl/openssl-qoriq_1.0.1i.bb
>> >   /poky/meta/recipes-connectivity/openssl/openssl_1.0.2d.bb). This usually
>> >   means one provides something the other doesn't and should.
>> >
>> > Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
>>
>> This is because the package arch is wrong. The right fix for this is to adjust
>> package arch accordingly.
> [Luo Zhenhua-B19537] I try to add PACKAGE_ARCH = "${MACHINE_ARCH}" in openssl-qoriq bb file, the issue persists, any comment?
>         According to the error message, the issue is caused by some packages are provided by poky openssl, which should be provided by openssl-qoriq.

You seem to be lacking

RCONFLICTS
RREPLACES

and this can be done using an annonymous python.

-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750

Re: [PATCH 14/20] openssl-qoriq should provide the same output packages as poky openssl

[Luo Zhenhua]

> -----Original Message-----
> From: Otavio Salvador [mailto:otavio.salvador@ossystems.com.br]
> Sent: Tuesday, September 01, 2015 8:05 PM
> 
> On Tue, Sep 1, 2015 at 4:37 AM, Luo Zhenhua <zhenhua.luo@freescale.com>
> wrote:
> >> -----Original Message-----
> >> From: Otavio Salvador [mailto:otavio.salvador@ossystems.com.br]
> >> Sent: Tuesday, September 01, 2015 12:22 AM
> >>
> >> On Fri, Aug 28, 2015 at 7:36 AM, Zhenhua Luo
> >> <zhenhua.luo@freescale.com>
> >> wrote:
> >> > The same output packages of poky openssl should be provided by
> >> > openssl-qoriq, otherwise the following build error will appear when
> >> > multiple output packages of openssl are depended, some are provided
> >> > by openssl-qoriq, the others are provided by poky openssl.
> >> >
> >> >   ERROR: Multiple .bb files are due to be built which each provide openssl
> >> >   (.../meta-freescale/recipes-connectivity/openssl/openssl-
> qoriq_1.0.1i.bb
> >> >   /poky/meta/recipes-connectivity/openssl/openssl_1.0.2d.bb). This
> usually
> >> >   means one provides something the other doesn't and should.
> >> >
> >> > Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
> >>
> >> This is because the package arch is wrong. The right fix for this is
> >> to adjust package arch accordingly.
> > [Luo Zhenhua-B19537] I try to add PACKAGE_ARCH = "${MACHINE_ARCH}" in
> openssl-qoriq bb file, the issue persists, any comment?
> >         According to the error message, the issue is caused by some packages are
> provided by poky openssl, which should be provided by openssl-qoriq.
> 
> You seem to be lacking
> 
> RCONFLICTS
> RREPLACES
> 
> and this can be done using an annonymous python.
[Luo Zhenhua-B19537] Per my understanding, RCONFLICTS and RREPLACES are used when same output packages are provided by different packages. For openssl-qoriq build, some output packages are provided poky openssl, which should be provided by openssl-qoriq as well, can those two variables solve the problem? 

I add the following lines in openssl-qoriq bb file, the issue still exists. 
RCONFLICTS_${PN} = "openssl"
RREPLACES_${PN} = "openssl" 


Best Regards,

Zhenhua

Re: [PATCH 14/20] openssl-qoriq should provide the same output packages as poky openssl

[Otavio Salvador]

On Wed, Sep 2, 2015 at 6:02 AM, Luo Zhenhua <zhenhua.luo@freescale.com> wrote:
>> From: Otavio Salvador [mailto:otavio.salvador@ossystems.com.br]
>> You seem to be lacking
>>
>> RCONFLICTS
>> RREPLACES
>>
>> and this can be done using an annonymous python.
> [Luo Zhenhua-B19537] Per my understanding, RCONFLICTS and RREPLACES are used when same output packages are provided by different packages. For openssl-qoriq build, some output packages are provided poky openssl, which should be provided by openssl-qoriq as well, can those two variables solve the problem?
>
> I add the following lines in openssl-qoriq bb file, the issue still exists.
> RCONFLICTS_${PN} = "openssl"
> RREPLACES_${PN} = "openssl"

You need to set this using python for all packages and use the
counterpart of openssl one.

-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750

Re: [PATCH 14/20] openssl-qoriq should provide the same output packages as poky openssl

[Luo Zhenhua]

> -----Original Message-----
> From: Otavio Salvador [mailto:otavio.salvador@ossystems.com.br]
> Sent: Thursday, September 03, 2015 12:49 AM
>> On Wed, Sep 2, 2015 at 6:02 AM, Luo Zhenhua <zhenhua.luo@freescale.com>
>> wrote:
> >> From: Otavio Salvador [mailto:otavio.salvador@ossystems.com.br]
> >> You seem to be lacking
> >>
> >> RCONFLICTS
> >> RREPLACES
> >>
> >> and this can be done using an annonymous python.
> > [Luo Zhenhua-B19537] Per my understanding, RCONFLICTS and RREPLACES
> are used when same output packages are provided by different packages. For
> openssl-qoriq build, some output packages are provided poky openssl, which
> should be provided by openssl-qoriq as well, can those two variables solve the
> problem?
> >
> > I add the following lines in openssl-qoriq bb file, the issue still exists.
> > RCONFLICTS_${PN} = "openssl"
> > RREPLACES_${PN} = "openssl"
> 
> You need to set this using python for all packages and use the counterpart of
> openssl one.
[Luo Zhenhua-B19537] I try to use the following python function, the parse issue persists. If I define the variables in bb file. The parse issue goes away, any comment? 

The following python function doesn't work. 
python() {
    pkgs = ["engines", "engines-dbg", "misc", "dbg", "staticdev", "dev", "doc", "locale"]
    for pkg in pkgs:
         d.appendVar("RPROVIDES_${PN}_%s" % pkg, "openssl-%s" % pkg)
         d.appendVar("RREPLACES_${PN}_%s" % pkg, "openssl-%s" % pkg)
         d.appendVar("RCONFLICTS_${PN}_%s" % pkg, "openssl-%s" % pkg)
 
    d.appendVar("RPROVIDES_${PN}", "openssl")
    d.appendVar("RREPLACES_${PN}", "openssl")
    d.appendVar("RCONFLICTS_${PN}", "openssl")
}

Below definition work. 
RPROVIDES_${PN}-engines +=  "openssl-engines"
RCONFLICTS_${PN}-engines +=  "openssl-engines"
RREPLACES_${PN}-engines +=  "openssl-engines"

RPROVIDES_${PN}-engines-dbg += "openssl-engines-dbg"
RCONFLICTS_${PN}-engines-dbg += "openssl-engines-dbg"
RREPLACES_${PN}-engines-dbg += "openssl-engines-dbg"

RPROVIDES_${PN}-misc += "openssl-misc"
RCONFLICTS_${PN}-misc += "openssl-misc"
RREPLACES_${PN}-misc += "openssl-misc"

RPROVIDES_${PN}-dbg += "openssl-dbg"
RCONFLICTS_${PN}-dbg += "openssl-dbg"
RREPLACES_${PN}-dbg += "openssl-dbg"

RPROVIDES_${PN}-staticdev += "openssl-staticdev"
RCONFLICTS_${PN}-staticdev += "openssl-staticdev"
RREPLACES_${PN}-staticdev += "openssl-staticdev"

RPROVIDES_${PN}-dev += "openssl-dev"
RCONFLICTS_${PN}-dev += "openssl-dev"
RREPLACES_${PN}-dev += "openssl-dev"

RPROVIDES_${PN}-doc += "openssl-doc"
RCONFLICTS_${PN}-doc += "openssl-doc"
RREPLACES_${PN}-doc += "openssl-doc"

RPROVIDES_${PN}-locale += "openssl-locale"
RCONFLICTS_${PN}-locale += "openssl-locale"
RREPLACES_${PN}-locale += "openssl-locale"

RPROVIDES_${PN} += "openssl"
RCONFLICTS_${PN} += "openssl"
RREPLACES_${PN} += "openssl"


Best Regards,

Zhenhua