[meta-fsl-arm][PATCH v3 1/7] imx-gpu-viv: Add a new DISTRO check to support XWayland

[meta-fsl-arm][PATCH v3 1/7] imx-gpu-viv: Add a new DISTRO check to support XWayland

[Tom Hochstein]

From: Neena Busireddy <neena.busireddy@freescale.com>

When X11 and Wayland DISTRO_FEATURES are available, install wayland
related libraries as we will be using X11 on top of Wayland(XWayland).

Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 recipes-graphics/imx-gpu-viv/imx-gpu-viv.inc | 35 +++++++++++++---------------
 1 file changed, 16 insertions(+), 19 deletions(-)

diff --git a/recipes-graphics/imx-gpu-viv/imx-gpu-viv.inc b/recipes-graphics/imx-gpu-viv/imx-gpu-viv.inc
index 2c62711..bb366c6 100644
--- a/recipes-graphics/imx-gpu-viv/imx-gpu-viv.inc
+++ b/recipes-graphics/imx-gpu-viv/imx-gpu-viv.inc
@@ -120,25 +120,11 @@ do_install () {
 
     install -d ${D}${libdir}/pkgconfig
 
-    # The preference order, based in DISTRO_FEATURES, is x11, wayland and fb
-    if [ "${USE_X11}" = "yes" ]; then
-        cp -r ${S}/gpu-core/usr/lib/dri ${D}${libdir}
-        cp -r ${S}/apitrace/x11/usr/lib/* ${D}${libdir}
-        cp -r ${S}/apitrace/x11/usr/bin/* ${D}${bindir}
-
-        backend=x11
-
-        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/egl_x11.pc ${D}${libdir}/pkgconfig/egl.pc
-        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/glesv1_cm_x11.pc ${D}${libdir}/pkgconfig/glesv1_cm.pc
-        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/glesv2_x11.pc ${D}${libdir}/pkgconfig/glesv2.pc
-        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/vg_x11.pc ${D}${libdir}/pkgconfig/vg.pc
-        #FIXME: WL & X11 is not currently functional
-        #if [ "${USE_WL}" = "yes" ]; then
-        #    install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/gc_wayland_protocol.pc ${D}${libdir}/pkgconfig/gc_wayland_protocol.pc
-        #    install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/wayland-egl.pc ${D}${libdir}/pkgconfig/wayland-egl.pc
-        #    install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/wayland-viv.pc ${D}${libdir}/pkgconfig/wayland-viv.pc
-        #fi
-    elif [ "${USE_WL}" = "yes" ]; then
+    # The preference order, based in DISTRO_FEATURES, is Wayland (with or without X11), X11 and fb
+    if [ "${USE_WL}" = "yes" ]; then
+        if [ "${USE_X11}" = "yes" ]; then
+            cp -r ${S}/gpu-core/usr/lib/dri ${D}${libdir}
+        fi
         cp -r ${S}/apitrace/non-x11/usr/lib/* ${D}${libdir}
         cp -r ${S}/apitrace/non-x11/usr/bin/* ${D}${bindir}
 
@@ -151,6 +137,17 @@ do_install () {
         install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/gc_wayland_protocol.pc ${D}${libdir}/pkgconfig/gc_wayland_protocol.pc
         install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/wayland-egl.pc ${D}${libdir}/pkgconfig/wayland-egl.pc
         install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/wayland-viv.pc ${D}${libdir}/pkgconfig/wayland-viv.pc
+    elif [ "${USE_X11}" = "yes" ]; then
+        cp -r ${S}/gpu-core/usr/lib/dri ${D}${libdir}
+        cp -r ${S}/apitrace/x11/usr/lib/* ${D}${libdir}
+        cp -r ${S}/apitrace/x11/usr/bin/* ${D}${bindir}
+
+        backend=x11
+
+        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/egl_x11.pc ${D}${libdir}/pkgconfig/egl.pc
+        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/glesv1_cm_x11.pc ${D}${libdir}/pkgconfig/glesv1_cm.pc
+        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/glesv2_x11.pc ${D}${libdir}/pkgconfig/glesv2.pc
+        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/vg_x11.pc ${D}${libdir}/pkgconfig/vg.pc
     else
         # Regular framebuffer
         install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/glesv1_cm.pc ${D}${libdir}/pkgconfig/glesv1_cm.pc
-- 
2.1.4

[meta-fsl-arm][PATCH v3 2/7] weston: Add xwayland changes

[Tom Hochstein]

From: Neena Busireddy <neena.busireddy@freescale.com>

Configure weston to support XWayland backend.

Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 recipes-graphics/wayland/weston_%.bbappend | 2 ++
 1 file changed, 2 insertions(+)

diff --git a/recipes-graphics/wayland/weston_%.bbappend b/recipes-graphics/wayland/weston_%.bbappend
index a7496da..6c62447 100644
--- a/recipes-graphics/wayland/weston_%.bbappend
+++ b/recipes-graphics/wayland/weston_%.bbappend
@@ -7,6 +7,8 @@ PACKAGECONFIG_append_mx6dl = " cairo-glesv2"
 PACKAGECONFIG_append_mx6sx = " cairo-glesv2"
 PACKAGECONFIG_remove_mx6sl = "egl"
 
+PACKAGECONFIG_mx6 += "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'xwayland', '', d)}"
+
 EXTRA_OECONF_append_mx6 = " \
     --disable-libunwind \
     --disable-xwayland-test \
-- 
2.1.4

[meta-fsl-arm][PATCH v3 3/7] glmark2: Use wayland backend whenever it is availiable

[Tom Hochstein]

From: Neena Busireddy <neena.busireddy@freescale.com>

If Wayland exists in DISTRO features, wayland egl build configuration will be enabled.
It is not mandatory for a GPU driver to support multiple backends (X11, wayland) at the same time.

Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 openembedded-layer/recipes-benchmark/glmark2/glmark2_%.bbappend | 5 +++--
 1 file changed, 3 insertions(+), 2 deletions(-)

diff --git a/openembedded-layer/recipes-benchmark/glmark2/glmark2_%.bbappend b/openembedded-layer/recipes-benchmark/glmark2/glmark2_%.bbappend
index 0e04a65..83f8d15 100644
--- a/openembedded-layer/recipes-benchmark/glmark2/glmark2_%.bbappend
+++ b/openembedded-layer/recipes-benchmark/glmark2/glmark2_%.bbappend
@@ -1,3 +1,4 @@
-PACKAGECONFIG_mx6 = "${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'x11-gl x11-gles2', \
-                         bb.utils.contains('DISTRO_FEATURES', 'wayland opengl', 'wayland-gles2', '', d), d)}"
+PACKAGECONFIG_mx6  = "${@bb.utils.contains('DISTRO_FEATURES', 'opengl wayland', 'wayland-gles2', \
+                          bb.utils.contains('DISTRO_FEATURES', 'opengl x11', 'x11-gl x11-gles2', '', d), d)}"
+
 PACKAGECONFIG_remove_mx6sl = "x11-gles2"
-- 
2.1.4

[meta-fsl-arm][PATCH v3 4/7] mesa-demos: Use wayland backend whenever it is availiable

[Tom Hochstein]

From: Neena Busireddy <neena.busireddy@freescale.com>

If Wayland exists in DISTRO features, wayland egl build configuration will be enabled
It is not mandatory for a GPU driver to support multiple backends (X11, wayland) at the same time.

Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 recipes-graphics/mesa/mesa-demos_%.bbappend | 10 +++-------
 1 file changed, 3 insertions(+), 7 deletions(-)

diff --git a/recipes-graphics/mesa/mesa-demos_%.bbappend b/recipes-graphics/mesa/mesa-demos_%.bbappend
index 1f070a4..a8aaf11 100644
--- a/recipes-graphics/mesa/mesa-demos_%.bbappend
+++ b/recipes-graphics/mesa/mesa-demos_%.bbappend
@@ -4,13 +4,9 @@ SRC_URI_append_mx6 = " file://Replace-glWindowPos2iARB-calls-with-glWindowPos2i.
                     file://fix-clear-build-break.patch \
                     file://Additional-eglSwapBuffer-calling-makes-wrong-throttl.patch \
                     file://Add-OpenVG-demos-to-support-wayland.patch"
+PACKAGECONFIG_remove_mx6 = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}"
+PACKAGECONFIG_remove_mx6 = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'glu', '', d)}"
 
-PACKAGECONFIG_remove_mx6 = " \
-    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', \
-         bb.utils.contains('DISTRO_FEATURES', 'wayland', 'glu', '', d), d)}"
 PACKAGECONFIG_remove_mx6sl = "gles1 gles2"
 
-PACKAGECONFIG_append = "\
-    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', \
-       bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland vg', '', d), d)} \
-"
+PACKAGECONFIG_append_mx6 = " ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland vg', '', d)}"
-- 
2.1.4

[meta-fsl-arm][PATCH v3 5/7] chromium: Use Wayland backend whenever it is available

[Tom Hochstein]

From: Neena Busireddy <neena.busireddy@freescale.com>

Do not enable X11 when chromium is running through wayland.
When both X11 and wayland DISTRO_FEATURES are availiable, chromium uses wayland.
Wayland backend is preferred as we are using X11 on top of Wayland (XWayland).

Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 .../recipes-browser/chromium/chromium_40.0.2214.91.bbappend         | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/browser-layer/recipes-browser/chromium/chromium_40.0.2214.91.bbappend b/browser-layer/recipes-browser/chromium/chromium_40.0.2214.91.bbappend
index d9c5d15..5d3186e 100644
--- a/browser-layer/recipes-browser/chromium/chromium_40.0.2214.91.bbappend
+++ b/browser-layer/recipes-browser/chromium/chromium_40.0.2214.91.bbappend
@@ -10,3 +10,9 @@ CHROMIUM_IMX_VPU_PATCHES_mx6q += "${VPU_PATCHES}"
 CHROMIUM_IMX_VPU_PATCHES_mx6dl += "${VPU_PATCHES}"
 
 CHROMIUM_IMX_WAYLAND_PATCHES += "file://${PATCH_BASE_DIR}/wayland/0001-Modify-eglwayland-versions-for-Vivante-GPUs.patch"
+
+# Don't use X if it's running through Wayland
+ENABLE_X11 = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', '0', \
+                 bb.utils.contains('DISTRO_FEATURES', 'x11', '1', \
+                 '0', d), d)}"
+ENABLE_WAYLAND = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', '1', '0', d)}"
-- 
2.1.4

[meta-fsl-arm][PATCH v3 6/7] gstreamer: Add XWayland change

[Tom Hochstein]

Configure gstreamer build for XWayland backend.

Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.7.bb | 12 ++++++++----
 1 file changed, 8 insertions(+), 4 deletions(-)

diff --git a/recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.7.bb b/recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.7.bb
index 62b38c7..a84372b 100644
--- a/recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.7.bb
+++ b/recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.7.bb
@@ -49,11 +49,14 @@ PACKAGES =+ "${PN}-gplay ${PN}-libgplaycore ${PN}-libgstfsl ${PN}-grecorder ${PN
 BEEP_RDEPENDS = "libfslcodec-aac libfslcodec-mp3 libfslcodec-oggvorbis"
 RDEPENDS_${PN} += "libfslparser ${BEEP_RDEPENDS} gstreamer1.0-plugins-good-id3demux "
 
+IMX_PACKAGECONFIG = "overlaysink \
+                     ${@bb.utils.contains('DISTRO_FEATURES', 'x11 wayland', 'xwayland', '', d)} \
+                     "
 PACKAGECONFIG ?= ""
-PACKAGECONFIG_mx6q = "overlaysink"
-PACKAGECONFIG_mx6dl = "overlaysink"
-PACKAGECONFIG_mx6sx = "overlaysink"
-PACKAGECONFIG_mx6sl = "overlaysink"
+PACKAGECONFIG_mx6q = "${IMX_PACKAGECONFIG}"
+PACKAGECONFIG_mx6dl = "${IMX_PACKAGECONFIG}"
+PACKAGECONFIG_mx6sx = "${IMX_PACKAGECONFIG}"
+PACKAGECONFIG_mx6sl = "${IMX_PACKAGECONFIG}"
 
 # FIXME: Add all features
 # feature from excluded mm packages
@@ -65,6 +68,7 @@ PACKAGECONFIG[wma10dec] += ",,${MSDEPENDS},${MSDEPENDS}"
 PACKAGECONFIG[wma8enc] += "--enable-wma8enc,--disable-wma8enc,${MSDEPENDS},${MSDEPENDS}"
 OVDEPENDS = "virtual/libg2d"
 PACKAGECONFIG[overlaysink] += "--enable-overlaysink,--disable-overlaysink, ${OVDEPENDS}"
+PACKAGECONFIG[xwayland] += "--disable-x11"
 
 FILES_${PN} = "${libdir}/gstreamer-1.0/*.so ${datadir}"
 
-- 
2.1.4

[meta-fsl-arm][PATCH v3 7/7] imx-base.inc: Remove X11 display server packages for XWayland

[Tom Hochstein]

From: Neena Busireddy <neena.busireddy@freescale.com>

Do not install X11 display server packages when both X11 and Wayland DISTRO_FEATURES are
selected (XWayland).

Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 conf/machine/include/imx-base.inc | 6 +++---
 1 file changed, 3 insertions(+), 3 deletions(-)

diff --git a/conf/machine/include/imx-base.inc b/conf/machine/include/imx-base.inc
index bd64bc5..37affbc 100644
--- a/conf/machine/include/imx-base.inc
+++ b/conf/machine/include/imx-base.inc
@@ -28,10 +28,10 @@ UBOOT_ENTRYPOINT_vf = "0x80008000"
 
 PREFERRED_PROVIDER_virtual/xserver = "xserver-xorg"
 XSERVER_DRIVER = "xf86-video-fbdev"
-XSERVER_DRIVER_mx6 = "xf86-video-imxfb-vivante"
-XSERVER_DRIVER_mx6ul = "xf86-video-fbdev"
+XSERVER_DRIVER_mx6 = "${@bb.utils.contains('DISTRO_FEATURES', 'x11 wayland', '', 'xf86-video-imxfb-vivante', d)}"
+XSERVER_DRIVER_mx6ul = "${@bb.utils.contains('DISTRO_FEATURES', 'x11 wayland', '', 'xf86-video-fbdev', d)}"
 XSERVER = "xserver-xorg \
-           xf86-input-evdev \
+           ${@bb.utils.contains('DISTRO_FEATURES', 'x11 wayland', '', 'xf86-input-evdev', d)} \
            ${XSERVER_DRIVER}"
 
 # Ship kernel modules
-- 
2.1.4

Re: [meta-fsl-arm][PATCH v3 2/7] weston: Add xwayland changes

[Otavio Salvador]

Hello Tom,

On Wed, Nov 25, 2015 at 8:07 PM, Tom Hochstein
<tom.hochstein@freescale.com> wrote:
> From: Neena Busireddy <neena.busireddy@freescale.com>
>
> Configure weston to support XWayland backend.
>
> Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
> Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>

This addition should be add on the SoC specific append. For example:

PACKAGECONFIG_append_mx6q = " cairo-glesv2"

becomes:

PACKAGECONFIG_append_mx6q = " cairo-glesv2 \

${@bb.utils.contains('DISTRO_FEATURES', 'x11 wayland', 'xwayland', '',
d)}"

Also your patch where not checking if BOTH distro features were
present (x11 and wayland).

-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750

Re: [meta-fsl-arm][PATCH v3 4/7] mesa-demos: Use wayland backend whenever it is availiable

[Otavio Salvador]

On Wed, Nov 25, 2015 at 8:07 PM, Tom Hochstein
<tom.hochstein@freescale.com> wrote:
> From: Neena Busireddy <neena.busireddy@freescale.com>
>
> If Wayland exists in DISTRO features, wayland egl build configuration will be enabled
> It is not mandatory for a GPU driver to support multiple backends (X11, wayland) at the same time.
>
> Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
> Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
> ---
>  recipes-graphics/mesa/mesa-demos_%.bbappend | 10 +++-------
>  1 file changed, 3 insertions(+), 7 deletions(-)
>
> diff --git a/recipes-graphics/mesa/mesa-demos_%.bbappend b/recipes-graphics/mesa/mesa-demos_%.bbappend
> index 1f070a4..a8aaf11 100644
> --- a/recipes-graphics/mesa/mesa-demos_%.bbappend
> +++ b/recipes-graphics/mesa/mesa-demos_%.bbappend
> @@ -4,13 +4,9 @@ SRC_URI_append_mx6 = " file://Replace-glWindowPos2iARB-calls-with-glWindowPos2i.
>                      file://fix-clear-build-break.patch \
>                      file://Additional-eglSwapBuffer-calling-makes-wrong-throttl.patch \
>                      file://Add-OpenVG-demos-to-support-wayland.patch"
> +PACKAGECONFIG_remove_mx6 = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}"
> +PACKAGECONFIG_remove_mx6 = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'glu', '', d)}"

Use a single remove here.

> -PACKAGECONFIG_remove_mx6 = " \
> -    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', \
> -         bb.utils.contains('DISTRO_FEATURES', 'wayland', 'glu', '', d), d)}"
>  PACKAGECONFIG_remove_mx6sl = "gles1 gles2"
>
> -PACKAGECONFIG_append = "\
> -    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', \
> -       bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland vg', '', d), d)} \
> -"
> +PACKAGECONFIG_append_mx6 = " ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland vg', '', d)}"

This part seems fine.

-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750

Re: [meta-fsl-arm][PATCH v3 5/7] chromium: Use Wayland backend whenever it is available

[Otavio Salvador]

On Wed, Nov 25, 2015 at 8:07 PM, Tom Hochstein
<tom.hochstein@freescale.com> wrote:
> From: Neena Busireddy <neena.busireddy@freescale.com>
>
> Do not enable X11 when chromium is running through wayland.
> When both X11 and wayland DISTRO_FEATURES are availiable, chromium uses wayland.
> Wayland backend is preferred as we are using X11 on top of Wayland (XWayland).
>
> Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
> Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>

Carlos, can you review this?

-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750