[meta-qt4][PATCH 1/3] qwt: Add recipe.

[meta-qt4][PATCH 1/3] qwt: Add recipe.

[Philip Balister]

 * Copied from meta-openembedded/jethro.
 * Used by GNU Radio.

Signed-off-by: Philip Balister <philip@balister.org>
---
 .../qwt-6.0.1/qwt6-fix-linking-with-ld-gold.patch  | 34 +++++++++
 recipes-qt4/recipes-libs/qwt-6.0.1/qwt6.patch      | 86 ++++++++++++++++++++++
 recipes-qt4/recipes-libs/qwt.inc                   | 40 ++++++++++
 recipes-qt4/recipes-libs/qwt_6.0.1.bb              | 10 +++
 4 files changed, 170 insertions(+)
 create mode 100644 recipes-qt4/recipes-libs/qwt-6.0.1/qwt6-fix-linking-with-ld-gold.patch
 create mode 100644 recipes-qt4/recipes-libs/qwt-6.0.1/qwt6.patch
 create mode 100644 recipes-qt4/recipes-libs/qwt.inc
 create mode 100644 recipes-qt4/recipes-libs/qwt_6.0.1.bb

diff --git a/recipes-qt4/recipes-libs/qwt-6.0.1/qwt6-fix-linking-with-ld-gold.patch b/recipes-qt4/recipes-libs/qwt-6.0.1/qwt6-fix-linking-with-ld-gold.patch
new file mode 100644
index 0000000..1fdd9cf
--- /dev/null
+++ b/recipes-qt4/recipes-libs/qwt-6.0.1/qwt6-fix-linking-with-ld-gold.patch
@@ -0,0 +1,34 @@
+Upstream-Status: Pending
+
+diff -urpN qwt-6.0.1_orig/qwtbuild.pri qwt-6.0.1/qwtbuild.pri
+--- qwt-6.0.1_orig/qwtbuild.pri	2011-08-02 00:33:53.000000000 +1000
++++ qwt-6.0.1/qwtbuild.pri	2012-08-21 10:27:30.721990849 +1000
+@@ -67,3 +67,13 @@ unix {
+         error( "local build will conflict with $${QMAKE_LIBDIR_QT}/libqwt.*" )
+     }
+ }
++
++######################################################################
++# libs for building qwt
++######################################################################
++
++unix {
++    # Some linkers require explicit linking with librt (eg ld.gold)
++    LIBS += -lrt
++}
++
+diff -urpN qwt-6.0.1_orig/qwt.prf qwt-6.0.1/qwt.prf
+--- qwt-6.0.1_orig/qwt.prf	2011-08-02 00:33:51.000000000 +1000
++++ qwt-6.0.1/qwt.prf	2012-08-21 11:19:49.435240439 +1000
+@@ -9,6 +9,11 @@
+ 
+ include ( ./qwtconfig.pri )
+ 
++unix {
++
++	LIBS += -lrt
++}
++
+ contains(QWT_CONFIG, QwtDll) {
+ 
+     DEFINES *= QWT_DLL
diff --git a/recipes-qt4/recipes-libs/qwt-6.0.1/qwt6.patch b/recipes-qt4/recipes-libs/qwt-6.0.1/qwt6.patch
new file mode 100644
index 0000000..4fb1a9b
--- /dev/null
+++ b/recipes-qt4/recipes-libs/qwt-6.0.1/qwt6.patch
@@ -0,0 +1,86 @@
+- add support for SUFFIX_STR
+---
+diff --git a/examples/examples.pri b/examples/examples.pri
+index a6911c8..854ce89 100644
+--- a/examples/examples.pri
++++ b/examples/examples.pri
+@@ -13,9 +13,17 @@ include( $${QWT_ROOT}/qwtbuild.pri )
+ 
+ TEMPLATE     = app
+ 
++SUFFIX_STR =
++CONFIG(debug, debug|release) {
++    SUFFIX_STR = $${DEBUG_SUFFIX}
++}
++else {
++    SUFFIX_STR = $${RELEASE_SUFFIX}
++}
++
+ INCLUDEPATH += $${QWT_ROOT}/src
+ DEPENDPATH  += $${QWT_ROOT}/src
+-DESTDIR      = $${QWT_ROOT}/examples/bin
++DESTDIR      = $${QWT_ROOT}/examples/bin$${SUFFIX_STR}
+ 
+ QMAKE_RPATHDIR *= $${QWT_ROOT}/lib
+ 
+diff --git a/qwtconfig.pri b/qwtconfig.pri
+index b0d2110..be119b7 100644
+--- a/qwtconfig.pri
++++ b/qwtconfig.pri
+@@ -30,6 +30,13 @@ QWT_INSTALL_DOCS      = $${QWT_INSTALL_PREFIX}/doc
+ QWT_INSTALL_HEADERS   = $${QWT_INSTALL_PREFIX}/include
+ QWT_INSTALL_LIBS      = $${QWT_INSTALL_PREFIX}/lib
+ 
++DEBUG_SUFFIX        = 
++RELEASE_SUFFIX      = 
++
++win32 {
++    DEBUG_SUFFIX      = d
++}
++
+ ######################################################################
+ # Designer plugin
+ ######################################################################
+diff --git a/src/src.pro b/src/src.pro
+index beb7125..ebf8ea6 100644
+--- a/src/src.pro
++++ b/src/src.pro
+@@ -13,8 +13,16 @@ QWT_ROOT = $${PWD}/..
+ include( $${QWT_ROOT}/qwtconfig.pri )
+ include( $${QWT_ROOT}/qwtbuild.pri )
+ 
++SUFFIX_STR =
++CONFIG(debug, debug|release) {
++    SUFFIX_STR = $${DEBUG_SUFFIX}
++}
++else {
++    SUFFIX_STR = $${RELEASE_SUFFIX}
++}
++
+ TEMPLATE          = lib
+-TARGET            = $$qtLibraryTarget(qwt)
++TARGET            = $$qtLibraryTarget(qwt)$${SUFFIX_STR}
+ 
+ DESTDIR           = $${QWT_ROOT}/lib
+ 
+diff --git a/textengines/mathml/mathml.pro b/textengines/mathml/mathml.pro
+index b0ed9f9..403828b 100644
+--- a/textengines/mathml/mathml.pro
++++ b/textengines/mathml/mathml.pro
+@@ -12,7 +12,15 @@ message(Beside the Qwt license you also have to take care of its license. )
+ 
+ include( $${PWD}/../textengines.pri )
+ 
+-TARGET    = $$qtLibraryTarget(qwtmathml)
++SUFFIX_STR =
++CONFIG(debug, debug|release) {
++    SUFFIX_STR = $${DEBUG_SUFFIX}
++}
++else {
++    SUFFIX_STR = $${RELEASE_SUFFIX}
++}
++
++TARGET    = $$qtLibraryTarget(qwtmathml$${SUFFIX_STR})
+ QT       += xml
+ 
+ HEADERS = \
diff --git a/recipes-qt4/recipes-libs/qwt.inc b/recipes-qt4/recipes-libs/qwt.inc
new file mode 100644
index 0000000..60f73a6
--- /dev/null
+++ b/recipes-qt4/recipes-libs/qwt.inc
@@ -0,0 +1,40 @@
+DESCRIPTION = "Qt Widget Extension for Technical Applications"
+SECTION = "libs"
+
+# LGPLv2.1 + some exceptions
+LICENSE = "QWTv1.0"
+LIC_FILES_CHKSUM = "file://COPYING;md5=dac2743472b0462ff3cfb4af42051c88"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/qwt/qwt-${PV}.tar.bz2;name=qwt \
+           file://qwt6.patch \
+           file://qwt6-fix-linking-with-ld-gold.patch"
+
+S = "${WORKDIR}/qwt-${PV}"
+
+do_configure_prepend() {
+    sed -i -e 's:RELEASE_SUFFIX      = :RELEASE_SUFFIX      = ${QT_LIBINFIX}:' *.pri
+    sed -i -e 's:qtAddLibrary(qwt:qtAddLibrary(qwt)${QT_LIBINFIX}:g' *.prf
+    sed -e 's/# QWT_CONFIG     += QwtExamples/QWT_CONFIG     += QwtExamples/g' -i qwtconfig.pri
+    sed -i -e 's:/usr/local/qwt-$$QWT_VERSION:${D}${prefix}:g' ${S}/*.pri
+}
+
+do_install() {
+    oe_runmake -e install
+    install -d ${D}${datadir}/doc/${PN}
+    mv ${D}${prefix}/doc/* ${D}${datadir}/doc/${PN}/
+    rmdir ${D}${prefix}/doc
+    cd ${S}/examples
+    install -d ${D}/${bindir}
+    cd bin${QT_LIBINFIX}/
+    for i in * ; do
+        cp -pPR ${i} ${D}/${bindir}/${i}${QT_LIBINFIX}
+    done
+    install -d ${D}${libdir}/${QT_DIR_NAME}
+    mv ${D}${prefix}/plugins ${D}${libdir}/${QT_DIR_NAME}
+}
+
+PACKAGES_prepend = "${PN}-examples ${PN}-features ${PN}-plugins "
+FILES_${PN}-examples = "${bindir}/*"
+FILES_${PN}-features = "${prefix}/features"
+FILES_${PN}-plugins = "${libdir}/${QT_DIR_NAME}/plugins/designer/*.so"
+FILES_${PN}-dbg += "${libdir}/${QT_DIR_NAME}/plugins/designer/.debug"
diff --git a/recipes-qt4/recipes-libs/qwt_6.0.1.bb b/recipes-qt4/recipes-libs/qwt_6.0.1.bb
new file mode 100644
index 0000000..f38816a
--- /dev/null
+++ b/recipes-qt4/recipes-libs/qwt_6.0.1.bb
@@ -0,0 +1,10 @@
+inherit qt4x11
+
+require qwt.inc
+
+PR = "r1"
+
+SRC_URI[qwt.md5sum] = "ace68558eab873e2da7e641179c4ef0c"
+SRC_URI[qwt.sha256sum] = "3fe19dd5962d705632fc2ef616b009299de6cf1e702538296924dbfdc8003cb2"
+
+RPROVIDES_${PN}-dev = "libqwt-dev"
-- 
2.5.0

[meta-qt4][PATCH 2/3] sip: Add recipe.

[Philip Balister]

 * Recipe copied from meta-openembedded/jethro.
 * Used by GNU Radio.

Signed-off-by: Philip Balister <philip@balister.org>
---
 recipes-qt4/recipes-python/sip_4.16.4.bb | 54 ++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 recipes-qt4/recipes-python/sip_4.16.4.bb

diff --git a/recipes-qt4/recipes-python/sip_4.16.4.bb b/recipes-qt4/recipes-python/sip_4.16.4.bb
new file mode 100644
index 0000000..032d125
--- /dev/null
+++ b/recipes-qt4/recipes-python/sip_4.16.4.bb
@@ -0,0 +1,54 @@
+SUMMARY = "SIP is a C++/Python Wrapper Generator"
+AUTHOR = "Phil Thompson"
+HOMEPAGE = "http://www.riverbankcomputing.co.uk/sip"
+SECTION = "devel"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://LICENSE-GPL2;md5=e91355d8a6f8bd8f7c699d62863c7303"
+DEPENDS_class-target = "qt4-x11-free python"
+
+# riverbankcomputing is upstream, but keeps only latest version, sf usually have few older
+#SRC_URI = "http://www.riverbankcomputing.com/static/Downloads/sip4/sip-${PV}.tar.gz"
+SRC_URI = "${SOURCEFORGE_MIRROR}/project/pyqt/sip/sip-${PV}/sip-${PV}.tar.gz"
+SRC_URI[md5sum] = "a9840670a064dbf8f63a8f653776fec9"
+SRC_URI[sha256sum] = "ceda443fc5e129e67a067e2cd7b73ff037f8b10b50e407baa2b1d9f2199d57f5"
+
+BBCLASSEXTEND = "native"
+
+PACKAGES += "python-sip"
+
+inherit qmake2 python-dir pythonnative distro_features_check
+# depends on qt4-x11-free
+REQUIRED_DISTRO_FEATURES = "x11"
+
+EXTRA_QMAKEVARS_POST += "CONFIG=console"
+
+export BUILD_SYS
+export HOST_SYS
+export STAGING_LIBDIR
+export STAGING_INCDIR
+
+do_configure_prepend_class-target() {
+    echo "py_platform = linux" > sip.cfg
+    echo "py_inc_dir = %(sysroot)/${includedir}/python%(py_major).%(py_minor)" >> sip.cfg
+    echo "sip_bin_dir = ${D}/${bindir}" >> sip.cfg
+    echo "sip_inc_dir = ${D}/${includedir}" >> sip.cfg
+    echo "sip_module_dir = ${D}/${libdir}/python%(py_major).%(py_minor)/site-packages" >> sip.cfg
+    echo "sip_sip_dir = ${D}/${datadir}/sip" >> sip.cfg
+    python configure.py --use-qmake --configuration sip.cfg --sysroot ${STAGING_DIR_HOST}
+}
+do_configure_prepend_class-native() {
+    echo "py_platform = linux" > sip.cfg
+    echo "py_inc_dir = ${includedir}/python%(py_major).%(py_minor)" >> sip.cfg
+    echo "sip_bin_dir = ${D}/${bindir}" >> sip.cfg
+    echo "sip_inc_dir = ${D}/${includedir}" >> sip.cfg
+    echo "sip_module_dir = ${D}/${libdir}/python%(py_major).%(py_minor)/site-packages" >> sip.cfg
+    echo "sip_sip_dir = ${D}/${datadir}/sip" >> sip.cfg
+    python configure.py --use-qmake --configuration sip.cfg --sysroot ${STAGING_DIR_NATIVE}
+}
+do_install() {
+    oe_runmake install
+}
+
+FILES_python-${BPN} = "${libdir}/${PYTHON_DIR}/site-packages/"
+FILES_${PN}-dbg += "${libdir}/${PYTHON_DIR}/site-packages/.debug"
+
-- 
2.5.0

[meta-qt4][PATCH 3/3] python-pyqt: Add recipe.

[Philip Balister]

 * Recipe copied from meta-openembedded/jethro.
 * Used by GNU Radio.

Signed-off-by: Philip Balister <philip@balister.org>
---
 recipes-qt4/recipes-python/python-pyqt_4.11.3.bb | 59 ++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 recipes-qt4/recipes-python/python-pyqt_4.11.3.bb

diff --git a/recipes-qt4/recipes-python/python-pyqt_4.11.3.bb b/recipes-qt4/recipes-python/python-pyqt_4.11.3.bb
new file mode 100644
index 0000000..cfddee8
--- /dev/null
+++ b/recipes-qt4/recipes-python/python-pyqt_4.11.3.bb
@@ -0,0 +1,59 @@
+SUMMARY = "Python Qt4 Bindings"
+AUTHOR = "Phil Thomson @ riverbank.co.uk"
+HOMEPAGE = "http://riverbankcomputing.co.uk"
+SECTION = "devel/python"
+LICENSE = "GPLv2 & GPLv3 & GPL_EXCEPTION"
+LIC_FILES_CHKSUM = "\
+    file://GPL_EXCEPTION.TXT;md5=b73b0be471db679533dc94781c14af58 \
+    file://GPL_EXCEPTION_ADDENDUM.TXT;md5=c1e04ec2aa0911061005a801abf81e40 \
+    file://OPENSOURCE-NOTICE.TXT;md5=6ad9123620cc04a22c394753ad4767d7 \
+    file://LICENSE.GPL2;md5=577ff65f6653562af318bfc3944b1f20 \
+    file://LICENSE.GPL3;md5=feee51612c3c1191a1d5f41156fa2c75 \
+"
+DEPENDS = "sip sip-native qt4-x11-free python"
+
+SRC_URI = "\
+    ${SOURCEFORGE_MIRROR}/pyqt/PyQt-x11-gpl-${PV}.tar.gz \
+"
+SRC_URI[md5sum] = "997c3e443165a89a559e0d96b061bf70"
+SRC_URI[sha256sum] = "853780dcdbe2e6ba785d703d059b096e1fc49369d3e8d41a060be874b8745686"
+
+S = "${WORKDIR}/PyQt-x11-gpl-${PV}"
+
+PARALLEL_MAKE = ""
+
+inherit qmake2 pythonnative python-dir distro_features_check
+# depends on qt4-x11-free
+REQUIRED_DISTRO_FEATURES = "x11"
+
+DISABLED_FEATURES = "PyQt_Desktop_OpenGL PyQt_Accessibility PyQt_SessionManager"
+
+DISABLED_FEATURES_append_arm = " PyQt_qreal_double"
+
+PYQT_MODULES = "QtCore QtGui QtDeclarative QtNetwork QtSvg QtWebKit"
+PYQT_MODULES_aarch64 = "QtCore QtGui QtDeclarative QtNetwork QtSvg"
+
+do_configure() {
+    echo "py_platform = linux" > pyqt.cfg
+    echo "py_inc_dir = %(sysroot)/$includedir/python%(py_major).%(py_minor)" >> pyqt.cfg
+    echo "py_pylib_dir = %(sysroot)/${libdir}/python%(py_major).%(py_minor)" >> pyqt.cfg
+    echo "py_pylib_lib = python%(py_major).%(py_minor)mu" >> pyqt.cfg
+    echo "pyqt_module_dir = ${D}/${libdir}/python%(py_major).%(py_minor)/site-packages" >> pyqt.cfg
+    echo "pyqt_bin_dir = ${D}/${bindir}" >> pyqt.cfg
+    echo "pyqt_sip_dir = ${D}/${datadir}/sip/PyQt4" >> pyqt.cfg
+    echo "pyuic_interpreter = ${D}/${bindir}/python%(py_major).%(py_minor)" >> pyqt.cfg
+    echo "pyqt_disabled_features = ${DISABLED_FEATURES}" >> pyqt.cfg
+    echo "qt_shared = True" >> pyqt.cfg
+    echo "[Qt 4.8]" >> pyqt.cfg
+    echo "pyqt_modules = ${PYQT_MODULES}" >> pyqt.cfg
+    echo yes | python configure-ng.py --verbose --qmake  ${STAGING_BINDIR_NATIVE}/qmake2 --configuration pyqt.cfg --sysroot ${STAGING_DIR_HOST}
+}
+do_install() {
+     oe_runmake install
+}
+
+RDEPENDS_${PN} = "python-core python-sip"
+
+FILES_${PN} += "${libdir}/${PYTHON_DIR}/site-packages ${datadir}/sip/PyQt4/"
+FILES_${PN}-dbg += "${libdir}/${PYTHON_DIR}/site-packages/*/.debug/"
+
-- 
2.5.0

Re: [meta-qt4][PATCH 3/3] python-pyqt: Add recipe.

[Alexander Kanavin]

On 01/19/2016 07:24 PM, Philip Balister wrote:
>   * Recipe copied from meta-openembedded/jethro.
>   * Used by GNU Radio.
>
> Signed-off-by: Philip Balister <philip@balister.org>

Thanks, all three pushed to meta-qt4.

Alex

Re: [meta-qt4][PATCH 1/3] qwt: Add recipe.

[Alexander Kanavin]

On 01/19/2016 07:24 PM, Philip Balister wrote:
>   * Copied from meta-openembedded/jethro.
>   * Used by GNU Radio.

ERROR: QA Issue: File '/usr/lib/libqwtmathml.so.6.0.1' from qwt was 
already stripped, this will prevent future debugging! [already-stripped]
ERROR: QA Issue: File '/usr/lib/libqwt.so.6.0.1' from qwt was already 
stripped, this will prevent future debugging! [already-stripped]
ERROR: QA Issue: File 
'/usr/lib/qt4/plugins/designer/libqwt_designer_plugin.so' from qwt was 
already stripped, this will prevent future debugging! [already-stripped]
ERROR: Fatal QA errors found, failing task.
ERROR: Function failed: do_package


Can you fix this please?

Aelx