[meta-mingw][PATCH 0/9][master][jethro] Current set of patches that enable mingw support

[meta-mingw][PATCH 0/9][master][jethro] Current set of patches that enable mingw support

[Mark Hatle]

This is my current set of patches to enable working meta-mingw support.

It includes both master and jethro contents.

See git://git.yoctoproject.org/poky-contrib

mgh/meta-mingw-jethro -- for Jethro specific branch
mgh/meta-mingw -- for Master specific branch

Mark Hatle (9):
  nativesdk-gcc: Add mingw32 named libraries to files list
  meta-environment: Update environment files to batch files
  toolchain-scripts-mingw32: Use short paths (8.3)
  toolchain-scripts-mingw32.bbclass: Update to match YP 2.0 release
  binutils-cross-canadian: Fix LTO failure
  gettext,gmp: Resync to oe-core versions
  *-mingw32.conf: Update the SDKMACHINE to include additional
    PREFERRED_PROVIDER
  binutils/gdb: Sync with latest oe-core master version
  gdb-cross-canadian: Disable readline support on mingw

 classes/toolchain-scripts-mingw32.bbclass          | 94 ++++++++++++++++++++++
 conf/machine-sdk/i686-mingw32.conf                 |  1 +
 conf/machine-sdk/x86_64-mingw32.conf               |  1 +
 recipes-core/gettext/gettext_0.19.%.bbappend       |  2 +
 recipes-core/gettext/gettext_0.19.4.bbappend       |  2 -
 recipes-core/meta/meta-environment.bbappend        |  4 +
 .../binutils/binutils-cross-canadian_2.2%.bbappend |  5 ++
 .../binutils-cross-canadian_2.25%.bbappend         |  5 --
 recipes-devtools/gcc/gcc_%.bbappend                |  6 ++
 .../gdb/gdb-cross-canadian_7.%.bbappend            |  6 ++
 .../gdb/gdb-cross-canadian_7.9.1.bbappend          |  5 --
 recipes-support/gmp/gmp_6.0.0.bbappend             |  3 -
 recipes-support/gmp/gmp_6.1.0.bbappend             |  3 +
 13 files changed, 122 insertions(+), 15 deletions(-)
 create mode 100644 classes/toolchain-scripts-mingw32.bbclass
 create mode 100644 recipes-core/gettext/gettext_0.19.%.bbappend
 delete mode 100644 recipes-core/gettext/gettext_0.19.4.bbappend
 create mode 100644 recipes-core/meta/meta-environment.bbappend
 create mode 100644 recipes-devtools/binutils/binutils-cross-canadian_2.2%.bbappend
 delete mode 100644 recipes-devtools/binutils/binutils-cross-canadian_2.25%.bbappend
 create mode 100644 recipes-devtools/gcc/gcc_%.bbappend
 create mode 100644 recipes-devtools/gdb/gdb-cross-canadian_7.%.bbappend
 delete mode 100644 recipes-devtools/gdb/gdb-cross-canadian_7.9.1.bbappend
 delete mode 100644 recipes-support/gmp/gmp_6.0.0.bbappend
 create mode 100644 recipes-support/gmp/gmp_6.1.0.bbappend

-- 
2.5.0

[meta-mingw][PATCH 1/9][master][jethro] nativesdk-gcc: Add mingw32 named libraries to files list

[Mark Hatle]

Also we skip the staticdev sanity check, as the '.a' file should be packaged
as listed.

Signed-off-by: Mark Hatle <mark.hatle@windriver.com>
---
 recipes-devtools/gcc/gcc_%.bbappend | 6 ++++++
 1 file changed, 6 insertions(+)
 create mode 100644 recipes-devtools/gcc/gcc_%.bbappend

diff --git a/recipes-devtools/gcc/gcc_%.bbappend b/recipes-devtools/gcc/gcc_%.bbappend
new file mode 100644
index 0000000..a779bb9
--- /dev/null
+++ b/recipes-devtools/gcc/gcc_%.bbappend
@@ -0,0 +1,6 @@
+FILES_${PN}_append_mingw32 = "\
+   ${libexecdir}/gcc/${TARGET_SYS}/${BINV}/liblto_plugin-0.dll \
+   ${libexecdir}/gcc/${TARGET_SYS}/${BINV}/liblto_plugin.dll.a \
+"
+
+INSANE_SKIP_append_mingw32 = " staticdev"
-- 
2.5.0

[meta-mingw][PATCH 2/9][master][jethro] meta-environment: Update environment files to batch files

[Mark Hatle]

Since the environment .sh files can't be used on a normal windows machine,
change to providing .bat files instead.  The same mechanisms normally used
can be used on the Windows command line. i.e.

Unix way:
$ source environment-setup-armv5te-wrs-linux-gnueabi.sh
$ $CC hello.c

Win32 way:
C:\Users\mhatle\win-sdk>environment-setup-armv5te-wrs-linux-gnueabi.bat

C:\Users\mhatle\win-sdk>%CC% hello.c

Signed-off-by: Mark Hatle <mark.hatle@windriver.com>
---
 classes/toolchain-scripts-mingw32.bbclass   | 87 +++++++++++++++++++++++++++++
 recipes-core/meta/meta-environment.bbappend |  4 ++
 2 files changed, 91 insertions(+)
 create mode 100644 classes/toolchain-scripts-mingw32.bbclass
 create mode 100644 recipes-core/meta/meta-environment.bbappend

diff --git a/classes/toolchain-scripts-mingw32.bbclass b/classes/toolchain-scripts-mingw32.bbclass
new file mode 100644
index 0000000..5ac69a1
--- /dev/null
+++ b/classes/toolchain-scripts-mingw32.bbclass
@@ -0,0 +1,87 @@
+# Based off of the oe-core meta/classes/toolchain-scripts.bbclass version
+toolchain_create_sdk_env_script_sdkmingw32 () {
+	# Create environment setup script
+	libdir=${4:-${libdir}}
+	sysroot=${3:-${SDKTARGETSYSROOT}}
+	sysroot=${sysroot##${SDKPATH}}
+	pathnative=${SDKPATHNATIVE}
+	pathnative=${pathnative##${SDKPATH}}
+	multimach_target_sys=${2:-${REAL_MULTIMACH_TARGET_SYS}}
+	script=${1:-${SDK_OUTPUT}/${SDKPATH}/environment-setup-$multimach_target_sys}.bat
+	rm -f $script
+	touch $script
+	echo 'set SDKROOT=%~dp0%' >> $script
+	echo 'set SDKTARGETSYSROOT=%SDKROOT%'"$sysroot" >> $script
+	EXTRAPATH=""
+	for i in ${CANADIANEXTRAOS}; do
+		EXTRAPATH="$EXTRAPATH;%~\$PATH:0%$pathnative${bindir_nativesdk}/${TARGET_ARCH}${TARGET_VENDOR}-$i"
+	done
+	echo 'set PATH=%SDKROOT%'"$pathnative"'${bindir_nativesdk};%SDKROOT%'"$pathnative"'${bindir_nativesdk}/${TARGET_SYS}'"$EXTRAPATH"';%PATH%' >> $script
+	echo 'set PKG_CONFIG_SYSROOT_DIR=%SDKTARGETSYSROOT%' >> $script
+	echo 'set PKG_CONFIG_PATH=%SDKTARGETSYSROOT%'"$libdir"'/pkgconfig' >> $script
+	echo 'set CONFIG_SITE=%SDKROOT%/site-config-'"${multimach_target_sys}" >> $script
+	echo 'set OECORE_NATIVE_SYSROOT=%SDKROOT%'"$pathnative" >> $script
+	echo 'set OECORE_TARGET_SYSROOT=%SDKTARGETSYSROOT%' >> $script
+	echo 'set OECORE_ACLOCAL_OPTS=-I %SDKROOT%'"$pathnative"'/usr/share/aclocal' >> $script
+	echo 'set PYTHONHOME=%SDKROOT%'"$pathnative"'${prefix_nativesdk}' >> $script
+
+	toolchain_shared_env_script
+
+	# Change unix '/' to Win32 '\'
+	sed -e 's,/,\\,g' -i $script
+
+	# Make the file windows friendly...
+	awk 'sub("$", "\r")' $script > $script.new
+	mv $script.new $script
+}
+
+toolchain_shared_env_script_sdkmingw32 () {
+	echo 'set CC=${TARGET_PREFIX}gcc ${TARGET_CC_ARCH} --sysroot=%SDKTARGETSYSROOT%' >> $script
+	echo 'set CXX=${TARGET_PREFIX}g++ ${TARGET_CC_ARCH} --sysroot=%SDKTARGETSYSROOT%' >> $script
+	echo 'set CPP=${TARGET_PREFIX}gcc -E ${TARGET_CC_ARCH} --sysroot=%SDKTARGETSYSROOT%' >> $script
+	echo 'set AS=${TARGET_PREFIX}as ${TARGET_AS_ARCH}' >> $script
+	echo 'set LD=${TARGET_PREFIX}ld ${TARGET_LD_ARCH} --sysroot=%SDKTARGETSYSROOT%' >> $script
+	echo 'set GDB=${TARGET_PREFIX}gdb' >> $script
+	echo 'set STRIP=${TARGET_PREFIX}strip' >> $script
+	echo 'set RANLIB=${TARGET_PREFIX}ranlib' >> $script
+	echo 'set OBJCOPY=${TARGET_PREFIX}objcopy' >> $script
+	echo 'set OBJDUMP=${TARGET_PREFIX}objdump' >> $script
+	echo 'set AR=${TARGET_PREFIX}ar' >> $script
+	echo 'set NM=${TARGET_PREFIX}nm' >> $script
+	echo 'set M4=m4' >> $script
+	echo 'set TARGET_PREFIX=${TARGET_PREFIX}' >> $script
+	echo 'set CONFIGURE_FLAGS=--target=${TARGET_SYS} --host=${TARGET_SYS} --build=${SDK_ARCH}-linux --with-libtool-sysroot=%SDKTARGETSYSROOT%' >> $script
+	echo 'set CFLAGS=${TARGET_CFLAGS}' >> $script
+	echo 'set CXXFLAGS=${TARGET_CXXFLAGS}' >> $script
+	echo 'set LDFLAGS=${TARGET_LDFLAGS}' >> $script
+	echo 'set CPPFLAGS=${TARGET_CPPFLAGS}' >> $script
+	echo 'set OECORE_DISTRO_VERSION=${DISTRO_VERSION}' >> $script
+	echo 'set OECORE_SDK_VERSION=${SDK_VERSION}' >> $script
+	echo 'set ARCH=${ARCH}' >> $script
+	echo 'set CROSS_COMPILE=${TARGET_PREFIX}' >> $script
+
+	cat >> $script <<EOF
+
+@REM Append environment subscripts
+
+@IF EXIST %OECORE_TARGET_SYSROOT%\\environment-setup.d (
+   FOR %%x IN (%OECORE_TARGET_SYSROOT%\\environment-setup.d\\*.bat) DO call "%%x"
+)
+
+@IF EXIST %OECORE_NATIVE_SYSROOT%\\environment-setup.d (
+   FOR %%x IN (%OECORE_NATIVE_SYSROOT%\\environment-setup.d\\*.bat) DO call "%%x"
+)
+EOF
+}
+
+toolchain_create_sdk_siteconfig_append_sdkmingw32 () {
+        # Make the file windows friendly...
+        awk 'sub("$", "\r")' $siteconfig > $siteconfig.new
+        mv $siteconfig.new $siteconfig
+}
+
+toolchain_create_sdk_version_append_sdkmingw32 () {
+        # Make the file windows friendly...
+        awk 'sub("$", "\r")' $versionfile > $versionfile.new
+        mv $versionfile.new $versionfile
+}
diff --git a/recipes-core/meta/meta-environment.bbappend b/recipes-core/meta/meta-environment.bbappend
new file mode 100644
index 0000000..0846042
--- /dev/null
+++ b/recipes-core/meta/meta-environment.bbappend
@@ -0,0 +1,4 @@
+TCSCRIPTS ?= ""
+TCSCRIPTS_sdkmingw32 = "toolchain-scripts-mingw32"
+
+inherit ${TCSCRIPTS}
-- 
2.5.0

[meta-mingw][PATCH 3/9][master][jethro] toolchain-scripts-mingw32: Use short paths (8.3)

[Mark Hatle]

When using standard paths, the user may end up exceeding the path length to
some toolchain helper libraries (DLLs) and binaries.

By switching to using the "short path", we can avoid this in many more cases.

If the user does exceed the path length, their only option will be to move
the SDK lower in their directory tree.

Signed-off-by: Mark Hatle <mark.hatle@windriver.com>
---
 classes/toolchain-scripts-mingw32.bbclass | 3 ++-
 1 file changed, 2 insertions(+), 1 deletion(-)

diff --git a/classes/toolchain-scripts-mingw32.bbclass b/classes/toolchain-scripts-mingw32.bbclass
index 5ac69a1..0353875 100644
--- a/classes/toolchain-scripts-mingw32.bbclass
+++ b/classes/toolchain-scripts-mingw32.bbclass
@@ -10,7 +10,8 @@ toolchain_create_sdk_env_script_sdkmingw32 () {
 	script=${1:-${SDK_OUTPUT}/${SDKPATH}/environment-setup-$multimach_target_sys}.bat
 	rm -f $script
 	touch $script
-	echo 'set SDKROOT=%~dp0%' >> $script
+	# Be sure to use the 'short' path, so we can have deeper directories.
+	echo 'set SDKROOT=%~sdp0%' >> $script
 	echo 'set SDKTARGETSYSROOT=%SDKROOT%'"$sysroot" >> $script
 	EXTRAPATH=""
 	for i in ${CANADIANEXTRAOS}; do
-- 
2.5.0

[meta-mingw][PATCH 4/9][master][jethro] toolchain-scripts-mingw32.bbclass: Update to match YP 2.0 release

[Mark Hatle]

The environment script generatation is updated to match YP 2.0 version.

In addition, there was an error in the way the EXTRAPATH component was being
generated.

Signed-off-by: Mark Hatle <mark.hatle@windriver.com>
---
 classes/toolchain-scripts-mingw32.bbclass | 24 +++++++++++++++---------
 1 file changed, 15 insertions(+), 9 deletions(-)

diff --git a/classes/toolchain-scripts-mingw32.bbclass b/classes/toolchain-scripts-mingw32.bbclass
index 0353875..b996a3e 100644
--- a/classes/toolchain-scripts-mingw32.bbclass
+++ b/classes/toolchain-scripts-mingw32.bbclass
@@ -1,30 +1,35 @@
 # Based off of the oe-core meta/classes/toolchain-scripts.bbclass version
 toolchain_create_sdk_env_script_sdkmingw32 () {
 	# Create environment setup script
+	sdkpathnative=${7:-${SDKPATHNATIVE}}
+	prefix=${6:-${prefix_nativesdk}}
+	bindir=${5:-${bindir_nativesdk}}
 	libdir=${4:-${libdir}}
 	sysroot=${3:-${SDKTARGETSYSROOT}}
-	sysroot=${sysroot##${SDKPATH}}
-	pathnative=${SDKPATHNATIVE}
-	pathnative=${pathnative##${SDKPATH}}
 	multimach_target_sys=${2:-${REAL_MULTIMACH_TARGET_SYS}}
 	script=${1:-${SDK_OUTPUT}/${SDKPATH}/environment-setup-$multimach_target_sys}.bat
 	rm -f $script
 	touch $script
 	# Be sure to use the 'short' path, so we can have deeper directories.
 	echo 'set SDKROOT=%~sdp0%' >> $script
-	echo 'set SDKTARGETSYSROOT=%SDKROOT%'"$sysroot" >> $script
+
+	# Convert to mingw32 subpaths
+	sysroot='%SDKROOT%'${sysroot##${SDKPATH}}
+	sdkpathnative='%SDKROOT%'${sdkpathnative##${SDKPATH}}
+
+	echo 'set SDKTARGETSYSROOT='"$sysroot" >> $script
 	EXTRAPATH=""
 	for i in ${CANADIANEXTRAOS}; do
-		EXTRAPATH="$EXTRAPATH;%~\$PATH:0%$pathnative${bindir_nativesdk}/${TARGET_ARCH}${TARGET_VENDOR}-$i"
+		EXTRAPATH="$EXTRAPATH;$sdkpathnative$bindir/${TARGET_ARCH}${TARGET_VENDOR}-$i"
 	done
-	echo 'set PATH=%SDKROOT%'"$pathnative"'${bindir_nativesdk};%SDKROOT%'"$pathnative"'${bindir_nativesdk}/${TARGET_SYS}'"$EXTRAPATH"';%PATH%' >> $script
+	echo "set PATH=$sdkpathnative$bindir;$sdkpathnative$bindir/../${HOST_SYS}/bin;$sdkpathnative$bindir/${TARGET_SYS}"$EXTRAPATH';%PATH%' >> $script
 	echo 'set PKG_CONFIG_SYSROOT_DIR=%SDKTARGETSYSROOT%' >> $script
 	echo 'set PKG_CONFIG_PATH=%SDKTARGETSYSROOT%'"$libdir"'/pkgconfig' >> $script
 	echo 'set CONFIG_SITE=%SDKROOT%/site-config-'"${multimach_target_sys}" >> $script
-	echo 'set OECORE_NATIVE_SYSROOT=%SDKROOT%'"$pathnative" >> $script
+	echo "set OECORE_NATIVE_SYSROOT=$sdkpathnative" >> $script
 	echo 'set OECORE_TARGET_SYSROOT=%SDKTARGETSYSROOT%' >> $script
-	echo 'set OECORE_ACLOCAL_OPTS=-I %SDKROOT%'"$pathnative"'/usr/share/aclocal' >> $script
-	echo 'set PYTHONHOME=%SDKROOT%'"$pathnative"'${prefix_nativesdk}' >> $script
+	echo "set OECORE_ACLOCAL_OPTS=-I $sdkpathnative/usr/share/aclocal" >> $script
+	echo "set PYTHONHOME=$sdkpathnative$prefix" >> $script
 
 	toolchain_shared_env_script
 
@@ -56,6 +61,7 @@ toolchain_shared_env_script_sdkmingw32 () {
 	echo 'set CXXFLAGS=${TARGET_CXXFLAGS}' >> $script
 	echo 'set LDFLAGS=${TARGET_LDFLAGS}' >> $script
 	echo 'set CPPFLAGS=${TARGET_CPPFLAGS}' >> $script
+	echo 'set KCFLAGS=--sysroot=%SDKTARGETSYSROOT%' >> $script
 	echo 'set OECORE_DISTRO_VERSION=${DISTRO_VERSION}' >> $script
 	echo 'set OECORE_SDK_VERSION=${SDK_VERSION}' >> $script
 	echo 'set ARCH=${ARCH}' >> $script
-- 
2.5.0

[meta-mingw][PATCH 5/9][master][jethro] binutils-cross-canadian: Fix LTO failure

[Mark Hatle]

GCC was failing with a message similar to:

e:/windri~1/lx8.sdk/qemux8~1.800/sysroots/i686-w~1/usr/bin/i586-w~3/../../libexec/i586-wrs-linux/gcc/i586-wrs-linux/5.2.0/real-ld.exe: unrecognized option '-plugin'

The issue was that by default plugin support was disabled in binutils.  By
enabling the plugin support, the LTO support should also now work properly.

Signed-off-by: Mark Hatle <mark.hatle@windriver.com>
---
 recipes-devtools/binutils/binutils-cross-canadian_2.25%.bbappend | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/recipes-devtools/binutils/binutils-cross-canadian_2.25%.bbappend b/recipes-devtools/binutils/binutils-cross-canadian_2.25%.bbappend
index 026c932..5845fe0 100644
--- a/recipes-devtools/binutils/binutils-cross-canadian_2.25%.bbappend
+++ b/recipes-devtools/binutils/binutils-cross-canadian_2.25%.bbappend
@@ -1,4 +1,4 @@
-EXTRA_OECONF_append_sdkmingw32 = " --disable-plugins --disable-nls"
+EXTRA_OECONF_append_sdkmingw32 = " --disable-nls"
 LDFLAGS_append_sdkmingw32 = " -Wl,-static"
 
 DEPENDS_remove_sdkmingw32 = "nativesdk-gettext"
-- 
2.5.0

[meta-mingw][PATCH 6/9][master] gettext, gmp: Resync to oe-core versions

[Mark Hatle]

Use a wild card for gettext 0.19 version.  It's unlikely this setting will
change during the gettext 0.19.* lifecycle.

Signed-off-by: Mark Hatle <mark.hatle@windriver.com>
---
 recipes-core/gettext/gettext_0.19.%.bbappend | 2 ++
 recipes-core/gettext/gettext_0.19.4.bbappend | 2 --
 recipes-support/gmp/gmp_6.0.0.bbappend       | 3 ---
 recipes-support/gmp/gmp_6.1.0.bbappend       | 3 +++
 4 files changed, 5 insertions(+), 5 deletions(-)
 create mode 100644 recipes-core/gettext/gettext_0.19.%.bbappend
 delete mode 100644 recipes-core/gettext/gettext_0.19.4.bbappend
 delete mode 100644 recipes-support/gmp/gmp_6.0.0.bbappend
 create mode 100644 recipes-support/gmp/gmp_6.1.0.bbappend

diff --git a/recipes-core/gettext/gettext_0.19.%.bbappend b/recipes-core/gettext/gettext_0.19.%.bbappend
new file mode 100644
index 0000000..ac76feb
--- /dev/null
+++ b/recipes-core/gettext/gettext_0.19.%.bbappend
@@ -0,0 +1,2 @@
+DEPENDS_append_mingw32 = " pthreads-win32"
+LDFLAGS_prepend_mingw32 = " -lpthread "
diff --git a/recipes-core/gettext/gettext_0.19.4.bbappend b/recipes-core/gettext/gettext_0.19.4.bbappend
deleted file mode 100644
index ac76feb..0000000
--- a/recipes-core/gettext/gettext_0.19.4.bbappend
+++ /dev/null
@@ -1,2 +0,0 @@
-DEPENDS_append_mingw32 = " pthreads-win32"
-LDFLAGS_prepend_mingw32 = " -lpthread "
diff --git a/recipes-support/gmp/gmp_6.0.0.bbappend b/recipes-support/gmp/gmp_6.0.0.bbappend
deleted file mode 100644
index 7f25fe2..0000000
--- a/recipes-support/gmp/gmp_6.0.0.bbappend
+++ /dev/null
@@ -1,3 +0,0 @@
-do_install_append_mingw32 () {
-	ln -s libgmp.lib ${D}${libdir}/gmp.lib 
-}
\ No newline at end of file
diff --git a/recipes-support/gmp/gmp_6.1.0.bbappend b/recipes-support/gmp/gmp_6.1.0.bbappend
new file mode 100644
index 0000000..7f25fe2
--- /dev/null
+++ b/recipes-support/gmp/gmp_6.1.0.bbappend
@@ -0,0 +1,3 @@
+do_install_append_mingw32 () {
+	ln -s libgmp.lib ${D}${libdir}/gmp.lib 
+}
\ No newline at end of file
-- 
2.5.0

[meta-mingw][PATCH 7/9][master] *-mingw32.conf: Update the SDKMACHINE to include additional PREFERRED_PROVIDER

[Mark Hatle]

nativesdk-${SDK_PREFIX}libc-initial is also needed to override some
glibc settings.

Signed-off-by: Mark Hatle <mark.hatle@windriver.com>
---
 conf/machine-sdk/i686-mingw32.conf   | 1 +
 conf/machine-sdk/x86_64-mingw32.conf | 1 +
 2 files changed, 2 insertions(+)

diff --git a/conf/machine-sdk/i686-mingw32.conf b/conf/machine-sdk/i686-mingw32.conf
index 0bdedaa..db08d84 100644
--- a/conf/machine-sdk/i686-mingw32.conf
+++ b/conf/machine-sdk/i686-mingw32.conf
@@ -4,6 +4,7 @@ SDK_OS = "mingw32"
 GCCTHREADS_mingw32 = "win32"
 
 PREFERRED_PROVIDER_virtual/nativesdk-${SDK_PREFIX}libc-for-gcc = "nativesdk-mingw-w64-runtime"
+PREFERRED_PROVIDER_virtual/nativesdk-${SDK_PREFIX}libc-initial = "nativesdk-mingw-w64-runtime"
 PREFERRED_PROVIDER_virtual/nativesdk-libc = "nativesdk-mingw-w64-runtime"
 PREFERRED_PROVIDER_virtual/nativesdk-libintl = "nativesdk-mingw-w64-runtime"
 PREFERRED_PROVIDER_virtual/nativesdk-libiconv = "nativesdk-libiconv"
diff --git a/conf/machine-sdk/x86_64-mingw32.conf b/conf/machine-sdk/x86_64-mingw32.conf
index 5e80dfa..2cb1b1f 100644
--- a/conf/machine-sdk/x86_64-mingw32.conf
+++ b/conf/machine-sdk/x86_64-mingw32.conf
@@ -4,6 +4,7 @@ SDK_OS = "mingw32"
 GCCTHREADS_mingw32 = "win32"
 
 PREFERRED_PROVIDER_virtual/nativesdk-${SDK_PREFIX}libc-for-gcc = "nativesdk-mingw-w64-runtime"
+PREFERRED_PROVIDER_virtual/nativesdk-${SDK_PREFIX}libc-initial = "nativesdk-mingw-w64-runtime"
 PREFERRED_PROVIDER_virtual/nativesdk-libc = "nativesdk-mingw-w64-runtime"
 PREFERRED_PROVIDER_virtual/nativesdk-libintl = "nativesdk-mingw-w64-runtime"
 PREFERRED_PROVIDER_virtual/nativesdk-libiconv = "nativesdk-libiconv"
-- 
2.5.0

[meta-mingw][PATCH 8/9][master] binutils/gdb: Sync with latest oe-core master version

[Mark Hatle]

Signed-off-by: Mark Hatle <mark.hatle@windriver.com>
---
 recipes-devtools/binutils/binutils-cross-canadian_2.2%.bbappend  | 5 +++++
 recipes-devtools/binutils/binutils-cross-canadian_2.25%.bbappend | 5 -----
 recipes-devtools/gdb/gdb-cross-canadian_7.%.bbappend             | 5 +++++
 recipes-devtools/gdb/gdb-cross-canadian_7.9.1.bbappend           | 5 -----
 4 files changed, 10 insertions(+), 10 deletions(-)
 create mode 100644 recipes-devtools/binutils/binutils-cross-canadian_2.2%.bbappend
 delete mode 100644 recipes-devtools/binutils/binutils-cross-canadian_2.25%.bbappend
 create mode 100644 recipes-devtools/gdb/gdb-cross-canadian_7.%.bbappend
 delete mode 100644 recipes-devtools/gdb/gdb-cross-canadian_7.9.1.bbappend

diff --git a/recipes-devtools/binutils/binutils-cross-canadian_2.2%.bbappend b/recipes-devtools/binutils/binutils-cross-canadian_2.2%.bbappend
new file mode 100644
index 0000000..5845fe0
--- /dev/null
+++ b/recipes-devtools/binutils/binutils-cross-canadian_2.2%.bbappend
@@ -0,0 +1,5 @@
+EXTRA_OECONF_append_sdkmingw32 = " --disable-nls"
+LDFLAGS_append_sdkmingw32 = " -Wl,-static"
+
+DEPENDS_remove_sdkmingw32 = "nativesdk-gettext"
+DEPENDS_remove_sdkmingw32 = "nativesdk-flex"
diff --git a/recipes-devtools/binutils/binutils-cross-canadian_2.25%.bbappend b/recipes-devtools/binutils/binutils-cross-canadian_2.25%.bbappend
deleted file mode 100644
index 5845fe0..0000000
--- a/recipes-devtools/binutils/binutils-cross-canadian_2.25%.bbappend
+++ /dev/null
@@ -1,5 +0,0 @@
-EXTRA_OECONF_append_sdkmingw32 = " --disable-nls"
-LDFLAGS_append_sdkmingw32 = " -Wl,-static"
-
-DEPENDS_remove_sdkmingw32 = "nativesdk-gettext"
-DEPENDS_remove_sdkmingw32 = "nativesdk-flex"
diff --git a/recipes-devtools/gdb/gdb-cross-canadian_7.%.bbappend b/recipes-devtools/gdb/gdb-cross-canadian_7.%.bbappend
new file mode 100644
index 0000000..bf4bd75
--- /dev/null
+++ b/recipes-devtools/gdb/gdb-cross-canadian_7.%.bbappend
@@ -0,0 +1,5 @@
+LDFLAGS_append_sdkmingw32 = " -Wl,-static"
+EXEEXT_sdkmingw32 = ".exe"
+DEPENDS_remove_sdkmingw32 = "nativesdk-ncurses nativesdk-readline nativesdk-python"
+RDEPENDS_${PN}_remove_sdkmingw32 = "nativesdk-python-core nativesdk-python-lang nativesdk-python-re nativesdk-python-codecs nativesdk-python-netclient"
+EXTRA_OECONF_append_sdkmingw32 = "--without-curses --without-system-readline --with-python=no"
diff --git a/recipes-devtools/gdb/gdb-cross-canadian_7.9.1.bbappend b/recipes-devtools/gdb/gdb-cross-canadian_7.9.1.bbappend
deleted file mode 100644
index bf4bd75..0000000
--- a/recipes-devtools/gdb/gdb-cross-canadian_7.9.1.bbappend
+++ /dev/null
@@ -1,5 +0,0 @@
-LDFLAGS_append_sdkmingw32 = " -Wl,-static"
-EXEEXT_sdkmingw32 = ".exe"
-DEPENDS_remove_sdkmingw32 = "nativesdk-ncurses nativesdk-readline nativesdk-python"
-RDEPENDS_${PN}_remove_sdkmingw32 = "nativesdk-python-core nativesdk-python-lang nativesdk-python-re nativesdk-python-codecs nativesdk-python-netclient"
-EXTRA_OECONF_append_sdkmingw32 = "--without-curses --without-system-readline --with-python=no"
-- 
2.5.0

[meta-mingw][PATCH 9/9][master] gdb-cross-canadian: Disable readline support on mingw

[Mark Hatle]

Signed-off-by: Mark Hatle <mark.hatle@windriver.com>
---
 recipes-devtools/gdb/gdb-cross-canadian_7.%.bbappend | 1 +
 1 file changed, 1 insertion(+)

diff --git a/recipes-devtools/gdb/gdb-cross-canadian_7.%.bbappend b/recipes-devtools/gdb/gdb-cross-canadian_7.%.bbappend
index bf4bd75..b9610cb 100644
--- a/recipes-devtools/gdb/gdb-cross-canadian_7.%.bbappend
+++ b/recipes-devtools/gdb/gdb-cross-canadian_7.%.bbappend
@@ -3,3 +3,4 @@ EXEEXT_sdkmingw32 = ".exe"
 DEPENDS_remove_sdkmingw32 = "nativesdk-ncurses nativesdk-readline nativesdk-python"
 RDEPENDS_${PN}_remove_sdkmingw32 = "nativesdk-python-core nativesdk-python-lang nativesdk-python-re nativesdk-python-codecs nativesdk-python-netclient"
 EXTRA_OECONF_append_sdkmingw32 = "--without-curses --without-system-readline --with-python=no"
+PACKAGECONFIG_remove_sdkmingw32 = "readline"
-- 
2.5.0