[meta-fsl-arm][PATCH v4 00/13] Upgrade i.MX multimedia to jethro_4.1.15-1.0.0_ga release

[meta-fsl-arm][PATCH v4 00/13] Upgrade i.MX multimedia to jethro_4.1.15-1.0.0_ga release

[Yuqing Zhu]

--Upgrade libfslcodec to v4.0.9( Rename to imx-codec)
--Upgrade libfslparser to v4.0.9( Rename to imx-parser)
--Upgrade gst1.0-fsl-plugin to v4.0.9( Rename to imx-gst1.0-plugin)
--Upgrade libfslvpuwrap to v1.0.65( Rename to imx-vpuwrap)
--Upgrade fsl-alsa-plugins to v1.0.26( Rename to imx-alsa-plugins)

Yuqing Zhu (13):
  libfslvpuwrap: Upgrade to v1.0.65
  fsl-alsa-plugins: Upgrade to v1.0.26
  libfslparser: Upgrade to v4.0.9
  libfslcodec: Upgrade to v4.0.9
  gst1.0-fsl-plugin: Upgrade to v4.0.9
  gstreamer1.0-plugins-imx: Update PACKAGECONFIG
  imx-base: Update MACHINE_EXTRA_RRECOMMENDS and MACHINE_SOCARCH_FILTER
  chromium-imx: Update dependency name of vpuwrap
  libfslvpuwrap: Remove the old recipe
  libfslparser: Remove the old recipe
  fsl-alsa-plugins: Remove the old recipe
  gst1.0-fsl-plugin: Remove the old recipe
  libfslcodec: Remove the old recipe

 .../recipes-browser/chromium/chromium-imx.inc      |  4 +-
 conf/machine/include/imx-base.inc                  |  4 +-
 .../0001-asrc_pair-update-output-buffer-size.patch | 47 ----------------------
 ...lugins_1.0.25.bb => imx-alsa-plugins_1.0.26.bb} | 15 +++----
 .../gstreamer/gstreamer1.0-plugins-imx_0.12.1.bb   |  4 +-
 ...-plugin_4.0.8.bb => imx-gst1.0-plugin_4.0.9.bb} | 31 ++++++++------
 .../libfslcodec.inc => imx-codec/imx-codec.inc}    | 27 +++++++++----
 recipes-multimedia/imx-codec/imx-codec_4.0.9.bb    |  9 +++++
 .../libfslparser.inc => imx-parser/imx-parser.inc} |  9 ++++-
 recipes-multimedia/imx-parser/imx-parser_4.0.9.bb  |  9 +++++
 .../imx-vpuwrap_1.0.65.bb}                         | 13 ++++--
 .../libfslcodec/libfslcodec_4.0.8.bb               |  9 -----
 .../libfslparser/libfslparser_4.0.8.bb             |  9 -----
 13 files changed, 85 insertions(+), 105 deletions(-)
 delete mode 100644 recipes-multimedia/alsa/fsl-alsa-plugins/0001-asrc_pair-update-output-buffer-size.patch
 rename recipes-multimedia/alsa/{fsl-alsa-plugins_1.0.25.bb => imx-alsa-plugins_1.0.26.bb} (68%)
 rename recipes-multimedia/gstreamer/{gst1.0-fsl-plugin_4.0.8.bb => imx-gst1.0-plugin_4.0.9.bb} (73%)
 rename recipes-multimedia/{libfslcodec/libfslcodec.inc => imx-codec/imx-codec.inc} (76%)
 create mode 100644 recipes-multimedia/imx-codec/imx-codec_4.0.9.bb
 rename recipes-multimedia/{libfslparser/libfslparser.inc => imx-parser/imx-parser.inc} (82%)
 create mode 100644 recipes-multimedia/imx-parser/imx-parser_4.0.9.bb
 rename recipes-multimedia/{libfslvpuwrap/libfslvpuwrap_1.0.62.bb => imx-vpuwrap/imx-vpuwrap_1.0.65.bb} (54%)
 delete mode 100644 recipes-multimedia/libfslcodec/libfslcodec_4.0.8.bb
 delete mode 100644 recipes-multimedia/libfslparser/libfslparser_4.0.8.bb

-- 
1.9.1

[meta-fsl-arm][PATCH v4 01/13] libfslvpuwrap: Upgrade to v1.0.65

[Yuqing Zhu]

--Change the recipe name from "libfslvpuwrap" to "imx-vpuwrap".

--Add RREPLACE/RPROVIDES/RCONFLICTS for backwards compatibility.

--Update 'nLastFrameEndPosPhy' in seqinit stage to avoid feed
  the same SPS to vpu repeatedly.

Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
---
 .../imx-vpuwrap/imx-vpuwrap_1.0.65.bb              | 28 ++++++++++++++++++++++
 1 file changed, 28 insertions(+)
 create mode 100644 recipes-multimedia/imx-vpuwrap/imx-vpuwrap_1.0.65.bb

diff --git a/recipes-multimedia/imx-vpuwrap/imx-vpuwrap_1.0.65.bb b/recipes-multimedia/imx-vpuwrap/imx-vpuwrap_1.0.65.bb
new file mode 100644
index 0000000..ecf7d5a
--- /dev/null
+++ b/recipes-multimedia/imx-vpuwrap/imx-vpuwrap_1.0.65.bb
@@ -0,0 +1,28 @@
+# Copyright (C) 2013-2016 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+DESCRIPTION = "Freescale Multimedia VPU wrapper"
+DEPENDS = "imx-vpu"
+LICENSE = "Proprietary"
+SECTION = "multimedia"
+LIC_FILES_CHKSUM = "file://COPYING;md5=8cf95184c220e247b9917e7244124c5a"
+
+# For backwards compatibility
+RREPLACES_${PN} = "libfslvpuwrap"
+RPROVIDES_${PN} = "libfslvpuwrap"
+RCONFLICTS_${PN} = "libfslvpuwrap"
+
+SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
+S = "${WORKDIR}/${PN}-${PV}"
+
+SRC_URI[md5sum] = "0bbcd6b9c9906fb85f98160eba94827b"
+SRC_URI[sha256sum] = "ddeacb7d9cb26c8864374df6d3f090aad47cd2ae409c2b9c817b773447252d61"
+
+inherit fsl-eula-unpack autotools pkgconfig
+
+do_install_append() {
+    # FIXME: Drop examples for now
+    rm -r ${D}${datadir}
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "(mx6q|mx6dl)"
-- 
1.9.1

[meta-fsl-arm][PATCH v4 02/13] fsl-alsa-plugins: Upgrade to v1.0.26

[Yuqing Zhu]

--Change the recipe name from "fsl-alsa-plugins" to "imx-alsa-plugins"

--Add RREPLACE/RPROVIDES/RCONFLICTS for backwards compatibility.

--Remove 0001-asrc_pair-update-output-buffer-size.patch as it has been
  integrated into the package.

Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
---
 recipes-multimedia/alsa/imx-alsa-plugins_1.0.26.bb | 38 ++++++++++++++++++++++
 1 file changed, 38 insertions(+)
 create mode 100644 recipes-multimedia/alsa/imx-alsa-plugins_1.0.26.bb

diff --git a/recipes-multimedia/alsa/imx-alsa-plugins_1.0.26.bb b/recipes-multimedia/alsa/imx-alsa-plugins_1.0.26.bb
new file mode 100644
index 0000000..5ed1fb5
--- /dev/null
+++ b/recipes-multimedia/alsa/imx-alsa-plugins_1.0.26.bb
@@ -0,0 +1,38 @@
+# Copyright (C) 2013-2016 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "Freescale alsa-lib plugins"
+LICENSE = "GPLv2"
+SECTION = "multimedia"
+DEPENDS = "alsa-lib virtual/kernel"
+
+# For backwards compatibility
+RREPLACES_${PN} = "fsl-alsa-plugins"
+RPROVIDES_${PN} = "fsl-alsa-plugins"
+RCONFLICTS_${PN} = "fsl-alsa-plugins"
+
+# Make sure kernel sources are available
+do_configure[depends] += "virtual/kernel:do_shared_workdir"
+
+LIC_FILES_CHKSUM = "file://COPYING.GPL;md5=94d55d512a9ba36caa9b7df079bae19f"
+
+inherit autotools pkgconfig
+
+SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.tar.gz"
+SRC_URI[md5sum] = "8fe4bcfddeca82dd01a9c4c6ce9471df"
+SRC_URI[sha256sum] = "0a7e8d90fdde2f6780605ecfee674e6e13523915a7bcd64078bc507ac1a8deb8"
+
+INCLUDE_DIR = "-I${STAGING_KERNEL_DIR}/include/uapi -I${STAGING_KERNEL_DIR}/include"
+
+EXTRA_OECONF = "CFLAGS="${INCLUDE_DIR}""
+
+INSANE_SKIP_${PN} = "dev-so"
+
+FILES_${PN} += "${libdir}/alsa-lib/libasound_*.so"
+FILES_${PN}-dbg += "${libdir}/alsa-lib/.debug"
+FILES_${PN}-dev += "${libdir}/alsa-lib/*.la"
+
+COMPATIBLE_MACHINE = "(mx6|mx6ul|mx7)"
+PACKAGE_ARCH_mx6 = "${MACHINE_SOCARCH}"
+PACKAGE_ARCH_mx6ul = "${MACHINE_SOCARCH}"
+PACKAGE_ARCH_mx7 = "${MACHINE_SOCARCH}"
-- 
1.9.1

[meta-fsl-arm][PATCH v4 03/13] libfslparser: Upgrade to v4.0.9

[Yuqing Zhu]

--Change the recipe name from "libfslparser" to "imx-parser"

--Add RREPLACE/RPROVIDES/RCONFLICTS for backwards compatibility.

--Add aac latm parser in parser_libs, support aac latm in mpeg2 parser

Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
---
 recipes-multimedia/imx-parser/imx-parser.inc      | 38 +++++++++++++++++++++++
 recipes-multimedia/imx-parser/imx-parser_4.0.9.bb |  9 ++++++
 2 files changed, 47 insertions(+)
 create mode 100644 recipes-multimedia/imx-parser/imx-parser.inc
 create mode 100644 recipes-multimedia/imx-parser/imx-parser_4.0.9.bb

diff --git a/recipes-multimedia/imx-parser/imx-parser.inc b/recipes-multimedia/imx-parser/imx-parser.inc
new file mode 100644
index 0000000..6fb34de
--- /dev/null
+++ b/recipes-multimedia/imx-parser/imx-parser.inc
@@ -0,0 +1,38 @@
+# Copyright (C) 2012-2014 O.S. Systems Software LTDA.
+# Copyright (C) 2012-2016 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+DESCRIPTION = "Freescale Multimedia parser libs"
+LICENSE = "Proprietary"
+SECTION = "multimedia"
+LIC_FILES_CHKSUM = "file://COPYING;md5=8cf95184c220e247b9917e7244124c5a"
+
+# For backwards compatibility
+RREPLACES_${PN} = "libfslparser"
+RPROVIDES_${PN} = "libfslparser"
+RCONFLICTS_${PN} = "libfslparser"
+
+inherit fsl-eula-unpack autotools pkgconfig
+
+SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
+
+# Choose between Soft Float-Point and Hard Float-Point
+EXTRA_OECONF = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', '--enable-fhw', '--enable-fsw', d)}"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+
+python __set_insane_skip() {
+    # FIXME: All binaries lack GNU_HASH in elf binary but as we don't have
+    # the source we cannot fix it. Disable the insane check for now.
+    # FIXME: gst-fsl-plugin looks for the .so files so we need to deploy those
+    for p in d.getVar('PACKAGES', True).split():
+        d.setVar("INSANE_SKIP_%s" % p, "ldflags dev-so textrel")
+}
+
+do_package_qa[prefuncs] += "__set_insane_skip"
+
+# FIXME: gst-fsl-plugin looks for the .so files so we need to deploy those
+FILES_${PN} += "${libdir}/imx-mm/*/*${SOLIBS} ${libdir}/imx-mm/*/*${SOLIBSDEV}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
diff --git a/recipes-multimedia/imx-parser/imx-parser_4.0.9.bb b/recipes-multimedia/imx-parser/imx-parser_4.0.9.bb
new file mode 100644
index 0000000..1650172
--- /dev/null
+++ b/recipes-multimedia/imx-parser/imx-parser_4.0.9.bb
@@ -0,0 +1,9 @@
+# Copyright (C) 2013-2015 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+require imx-parser.inc
+
+SRC_URI[md5sum] = "184687baede96fe3919196c3f91d907c"
+SRC_URI[sha256sum] = "1bec0101843db2e95d61e3dbe9e35172d874e54be19cc5d8bf72a735d5e3236f"
+
+COMPATIBLE_MACHINE = "(mx6|mx6ul|mx7)"
-- 
1.9.1

[meta-fsl-arm][PATCH v4 04/13] libfslcodec: Upgrade to v4.0.9

[Yuqing Zhu]

--Change the recipe name from "libfslcodec" to "imx-codec"

--Add RREPLACE/RPROVIDES/RCONFLICTS for backwards compatibility.

--[aac_dec] refine the code for pure c build
  aac decoder c build need float point support, which use some
  float point function.

Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
---
 recipes-multimedia/imx-codec/imx-codec.inc      | 109 ++++++++++++++++++++++++
 recipes-multimedia/imx-codec/imx-codec_4.0.9.bb |   9 ++
 2 files changed, 118 insertions(+)
 create mode 100644 recipes-multimedia/imx-codec/imx-codec.inc
 create mode 100644 recipes-multimedia/imx-codec/imx-codec_4.0.9.bb

diff --git a/recipes-multimedia/imx-codec/imx-codec.inc b/recipes-multimedia/imx-codec/imx-codec.inc
new file mode 100644
index 0000000..e6fd9c6
--- /dev/null
+++ b/recipes-multimedia/imx-codec/imx-codec.inc
@@ -0,0 +1,109 @@
+# Copyright (C) 2012-2016 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+DESCRIPTION = "Freescale Multimedia codec libs"
+LICENSE = "Proprietary"
+SECTION = "multimedia"
+LIC_FILES_CHKSUM = "file://COPYING;md5=8cf95184c220e247b9917e7244124c5a"
+
+inherit fsl-eula-unpack autotools pkgconfig
+
+SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
+
+# Choose between Soft Float-Point and Hard Float-Point
+EXTRA_OECONF = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', '--enable-fhw', '', d)}"
+
+PACKAGECONFIG ?= ""
+PACKAGECONFIG_mx6q = "vpu"
+PACKAGECONFIG_mx6dl = "vpu"
+
+PACKAGECONFIG[vpu] = "--enable-vpu,--disable-vpu,imx-vpu"
+
+do_install_append() {
+    # FIXME: This link points to nowhere
+    rm ${D}${libdir}/imx-mm/audio-codec/lib_src_ppp_arm11_elinux.so
+
+    # LTIB move the files around or gst-fsl-plugin won't find them
+    for p in $(find ${D}${libdir}/imx-mm -mindepth 2 -maxdepth 2 -not -type d); do
+            mv $p ${D}${libdir}
+    done
+    rmdir ${D}${libdir}/imx-mm/video-codec
+
+}
+
+python __set_insane_skip() {
+    # Ensure we have PACKAGES expanded
+    bb.build.exec_func("read_subpackage_metadata", d)
+
+    for p in d.getVar('PACKAGES', True).split():
+        # Even though we are packaging libraries those are plugins so we
+        # shouldn't rename the packages to follow its sonames.
+        d.setVar("DEBIAN_NOAUTONAME_%s" % p, "1")
+
+        # FIXME: All binaries lack GNU_HASH in elf binary but as we don't have
+        # the source we cannot fix it. Disable the insane check for now.
+        if p == 'imx-codec-test-bin':
+            # FIXME: includes the DUT .so files so we need to deploy those
+            d.setVar("INSANE_SKIP_%s" % p, "ldflags textrel libdir")
+        else:
+            d.setVar("INSANE_SKIP_%s" % p, "ldflags textrel")
+}
+
+do_package_qa[prefuncs] += "__set_insane_skip"
+
+python __split_libfslcodec_plugins() {
+    codecdir = bb.data.expand('${libdir}', d)
+    do_split_packages(d, codecdir, '^lib_([^_]*).*_arm.*_elinux\.so\..*',
+                      aux_files_pattern='${libdir}/imx-mm/audio-codec/wrap/lib_%sd_wrap_arm*_elinux.so.*',
+                      output_pattern='imx-codec-%s',
+                      description='Freescale i.MX Codec (%s)',
+                      extra_depends='')
+    pkgs = d.getVar('PACKAGES', True).split()
+    for pkg in pkgs:
+        meta = pkg[10:]
+        if meta != '':
+            d.setVar('RREPLACES_%s' % pkg, ' libfslcodec-%s' % meta)
+            d.setVar('RPROVIDES_%s' % pkg, ' libfslcodec-%s' % meta)
+            d.setVar('RCONFLICTS_%s' % pkg, ' libfslcodec-%s' % meta)
+        else :
+            d.setVar('RREPLACES_%s' % pkg, ' libfslcodec')
+            d.setVar('RPROVIDES_%s' % pkg, ' libfslcodec')
+            d.setVar('RCONFLICTS_%s' % pkg, ' libfslcodec')
+}
+
+python __set_metapkg_rdepends() {
+    # Allow addition of all codecs in a image; useful specially for
+    # debugging.
+    codec_pkgs = oe.utils.packages_filter_out_system(d)
+    codec_pkgs = filter(lambda x: x not in ['imx-codec-test-bin', 'imx-codec-test-source'],
+                        codec_pkgs)
+    d.appendVar('RDEPENDS_imx-codec-meta', ' ' + ' '.join(codec_pkgs))
+}
+
+PACKAGESPLITFUNCS =+ "__split_libfslcodec_plugins __set_metapkg_rdepends"
+
+PACKAGES_DYNAMIC = "${PN}-*"
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+
+PACKAGES += "${PN}-meta ${PN}-test-bin ${PN}-test-source"
+
+ALLOW_EMPTY_${PN} = "1"
+ALLOW_EMPTY_${PN}-meta = "1"
+
+# Ensure we get warnings if we miss something
+FILES_${PN} = ""
+
+FILES_${PN}-dev += "${libdir}/imx-mm/*/*${SOLIBSDEV} \
+                    ${libdir}/imx-mm/*/*/*${SOLIBSDEV} \
+                    ${libdir}/pkgconfig/*.pc ${includedir}/imx-mm/*"
+
+FILES_${PN}-test-bin += "${datadir}/imx-mm/*/examples/*/bin"
+
+FILES_${PN}-test-source += "${datadir}/imx-mm/*"
+
+# FIXME: The wrap and lib names does not match
+FILES_${PN}-oggvorbis += "${libdir}/imx-mm/audio-codec/wrap/lib_vorbisd_wrap_arm*_elinux.so.*"
+FILES_${PN}-nb += "${libdir}/imx-mm/audio-codec/wrap/lib_nbamrd_wrap_arm*_elinux.so.*"
+FILES_${PN}-wb += "${libdir}/imx-mm/audio-codec/wrap/lib_wbamrd_wrap_arm*_elinux.so.*"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
diff --git a/recipes-multimedia/imx-codec/imx-codec_4.0.9.bb b/recipes-multimedia/imx-codec/imx-codec_4.0.9.bb
new file mode 100644
index 0000000..3fb9802
--- /dev/null
+++ b/recipes-multimedia/imx-codec/imx-codec_4.0.9.bb
@@ -0,0 +1,9 @@
+# Copyright (C) 2013-2016 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+require imx-codec.inc
+
+SRC_URI[md5sum] = "bcf54698af6f52958b36e34dcbd9fcd1"
+SRC_URI[sha256sum] = "62bda182143cde9743cba0eb2a1c315a53cb434294605742f9fc364219958888"
+
+COMPATIBLE_MACHINE = "(mx6|mx6ul|mx7)"
-- 
1.9.1

[meta-fsl-arm][PATCH v4 05/13] gst1.0-fsl-plugin: Upgrade to v4.0.9

[Yuqing Zhu]

--Change the recipe name from "gst1.0-fsl-plugin" to "imx-gst1.0-plugin"

--Add RREPLACE/RPROVIDES/RCONFLICTS for backwards compatibility.

--Remove dependency on gstreamer1.0-plugins-bad
  There is a patch in gstreamer1.0-plugins-bad which intall the header file of
  gstaggregator and gstvideoaggregator.
  so we can use them outside of gstreamer-plugins-bad package.

Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
---
 .../gstreamer/imx-gst1.0-plugin_4.0.9.bb           | 85 ++++++++++++++++++++++
 1 file changed, 85 insertions(+)
 create mode 100644 recipes-multimedia/gstreamer/imx-gst1.0-plugin_4.0.9.bb

diff --git a/recipes-multimedia/gstreamer/imx-gst1.0-plugin_4.0.9.bb b/recipes-multimedia/gstreamer/imx-gst1.0-plugin_4.0.9.bb
new file mode 100644
index 0000000..c32ccb3
--- /dev/null
+++ b/recipes-multimedia/gstreamer/imx-gst1.0-plugin_4.0.9.bb
@@ -0,0 +1,85 @@
+# Copyright (C) 2014,2016 Freescale Semiconductor
+# Copyright (C) 2012-2015 O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "Gstreamer freescale plugins"
+LICENSE = "GPLv2 & LGPLv2 & LGPLv2.1"
+SECTION = "multimedia"
+
+DEPENDS = "imx-codec imx-parser virtual/kernel gstreamer1.0 gstreamer1.0-plugins-base"
+DEPENDS_append_mx6q = " imx-lib imx-vpu imx-vpuwrap"
+DEPENDS_append_mx6dl = " imx-lib imx-vpu imx-vpuwrap"
+DEPENDS_append_mx6sl = " imx-lib"
+DEPENDS_append_mx6sx = " imx-lib"
+DEPENDS_append_mx6ul = " imx-lib"
+DEPENDS_append_mx7 = " imx-lib"
+
+# For backwards compatibility
+RREPLACES_${PN} = "gst1.0-fsl-plugin"
+RPROVIDES_${PN} = "gst1.0-fsl-plugin"
+RCONFLICTS_${PN} = "gst1.0-fsl-plugin"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \
+                    file://COPYING-LGPL-2;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
+                    file://COPYING-LGPL-2.1;md5=fbc093901857fcd118f065f900982c24"
+
+SRC_URI = " \
+    ${FSL_MIRROR}/imx-gst1.0-plugin-${PV}.tar.gz \
+"
+
+SRC_URI[md5sum] = "56fc7d4fcbad0ba14739b668793fcf2c"
+SRC_URI[sha256sum] = "4ab74e3660a56c5a79c714b820bb1ce8dd1db5d66c92529b5378bb211cf25896"
+
+S = "${WORKDIR}/imx-gst1.0-plugin-${PV}"
+
+inherit autotools pkgconfig
+
+# Make sure kernel sources are available
+do_configure[depends] += "virtual/kernel:do_shared_workdir"
+
+PLATFORM_mx6 = "MX6"
+PLATFORM_mx6sl = "MX6SL"
+PLATFORM_mx6sx = "MX6SX"
+PLATFORM_mx6ul = "MX6UL"
+PLATFORM_mx7= "MX7D"
+
+# Todo add a mechanism to map possible build targets
+EXTRA_OECONF = "PLATFORM=${PLATFORM} \
+                CPPFLAGS="-I${STAGING_KERNEL_BUILDDIR}/include/generated/uapi -I${STAGING_KERNEL_DIR}/include/uapi -I${STAGING_KERNEL_DIR}/include" \
+                CROSS_ROOT=${PKG_CONFIG_SYSROOT_DIR} \
+                ${@base_contains('DISTRO_FEATURES', 'wayland', base_contains('DISTRO_FEATURES', 'x11', '--disable-x11', '', d), '', d)}"
+
+PACKAGES =+ "${PN}-gplay ${PN}-libgplaycore ${PN}-libgstfsl ${PN}-grecorder ${PN}-librecorder-engine ${PN}-libplayengine"
+
+# Add codec list that the beep plugin run-time depended
+BEEP_RDEPENDS = "imx-codec-aac imx-codec-mp3 imx-codec-oggvorbis"
+RDEPENDS_${PN} += "imx-parser ${BEEP_RDEPENDS} gstreamer1.0-plugins-good-id3demux "
+
+PACKAGECONFIG ?= ""
+PACKAGECONFIG_mx6 = "overlaysink"
+
+
+# FIXME: Add all features
+# feature from excluded mm packages
+PACKAGECONFIG[ac3] += ",,imx-ac3codec,imx-ac3codec"
+# feature from special mm packages
+PACKAGECONFIG[aacp] += ",,imx-aacpcodec,imx-aacpcodec"
+MSDEPENDS = "imx-msparser imx-mscodec"
+PACKAGECONFIG[wma10dec] += ",,${MSDEPENDS},${MSDEPENDS}"
+PACKAGECONFIG[wma8enc] += "--enable-wma8enc,--disable-wma8enc,${MSDEPENDS},${MSDEPENDS}"
+OVDEPENDS = "virtual/libg2d"
+PACKAGECONFIG[overlaysink] += "--enable-overlaysink,--disable-overlaysink, ${OVDEPENDS}"
+
+FILES_${PN} = "${libdir}/gstreamer-1.0/*.so ${datadir}"
+
+FILES_${PN}-dbg += "${libdir}/gstreamer-1.0/.debug"
+FILES_${PN}-dev += "${libdir}/gstreamer-1.0/*.la ${libdir}/pkgconfig/*.pc"
+FILES_${PN}-staticdev += "${libdir}/gstreamer-1.0/*.a"
+FILES_${PN}-gplay = "${bindir}/gplay-1.0"
+FILES_${PN}-libgplaycore = "${libdir}/libgplaycore-1.0${SOLIBS}"
+FILES_${PN}-libgstfsl = "${libdir}/libgstfsl-1.0${SOLIBS}"
+FILES_${PN}-grecorder = "${bindir}/grecorder-1.0"
+FILES_${PN}-librecorder-engine = "${libdir}/librecorder_engine-1.0${SOLIBS}"
+FILES_${PN}-libplayengine = "${libdir}/libplayengine-1.0${SOLIBS}"
+
+COMPATIBLE_MACHINE = "(mx6|mx6ul|mx7)"
-- 
1.9.1

[meta-fsl-arm][PATCH v4 06/13] gstreamer1.0-plugins-imx: Update PACKAGECONFIG

[Yuqing Zhu]

libfslcodec has been renamed as imx-codec, need to update the PACKAGECONFIG.

Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
---
 recipes-multimedia/gstreamer/gstreamer1.0-plugins-imx_0.12.1.bb | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/recipes-multimedia/gstreamer/gstreamer1.0-plugins-imx_0.12.1.bb b/recipes-multimedia/gstreamer/gstreamer1.0-plugins-imx_0.12.1.bb
index f968dbc..c20b942 100644
--- a/recipes-multimedia/gstreamer/gstreamer1.0-plugins-imx_0.12.1.bb
+++ b/recipes-multimedia/gstreamer/gstreamer1.0-plugins-imx_0.12.1.bb
@@ -53,8 +53,8 @@ PACKAGECONFIG[ipu] = ",--disable-ipu,"
 PACKAGECONFIG[vpu] = ",--disable-vpu,libimxvpuapi"
 PACKAGECONFIG[eglvivsink] = "${EGL_PLATFORM_CONF},--disable-eglvivsink,${EGLVIVSINK_DEPENDS}"
 PACKAGECONFIG[v4l2src] = ",--disable-v4l2src,"
-PACKAGECONFIG[uniaudiodec] = ",--disable-uniaudiodec,libfslcodec"
-PACKAGECONFIG[mp3encoder] = ",--disable-mp3encoder,libfslcodec"
+PACKAGECONFIG[uniaudiodec] = ",--disable-uniaudiodec,imx-codec"
+PACKAGECONFIG[mp3encoder] = ",--disable-mp3encoder,imx-codec"
 
 # LIBV is used by gst-plugins-package.inc to specify the GStreamer version (0.10 vs 1.0)
 LIBV = "1.0"
-- 
1.9.1

[meta-fsl-arm][PATCH v4 07/13] imx-base: Update MACHINE_EXTRA_RRECOMMENDS and MACHINE_SOCARCH_FILTER

[Yuqing Zhu]

libfslcodec/ libfslvpuwrap/ libfslparser/ fsl-alsa-plugins have been
renamed as imx-codec/ imx-vpuwrap/ imx-parser/ imx-alsa-plugins, need to
do update.

Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
---
 conf/machine/include/imx-base.inc | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/conf/machine/include/imx-base.inc b/conf/machine/include/imx-base.inc
index 1aacc71..65ff04d 100644
--- a/conf/machine/include/imx-base.inc
+++ b/conf/machine/include/imx-base.inc
@@ -63,7 +63,7 @@ MACHINE_SOCARCH_SUFFIX_vf50 = "-vf50"
 MACHINE_SOCARCH_SUFFIX_mx6ul = "-mx6ul"
 
 MACHINE_ARCH_FILTER = "virtual/kernel imx-vpu"
-MACHINE_SOCARCH_FILTER_append_mx6 = " libfslcodec libfslvpuwrap libfslparser"
+MACHINE_SOCARCH_FILTER_append_mx6 = " imx-codec imx-vpuwrap imx-parser"
 MACHINE_SOCARCH_FILTER_append_mx6 = " virtual/libopenvg virtual/libgles1 virtual/libgles2 virtual/egl virtual/mesa virtual/libgl virtual/libg2d"
 
 INHERIT += "fsl-dynamic-packagearch"
@@ -85,7 +85,7 @@ MACHINE_EXTRA_RRECOMMENDS += "${MACHINE_FIRMWARE}"
 
 # Extra audio support
 # FIXME: Add support for ALL SoC families
-MACHINE_EXTRA_RRECOMMENDS_append_mx6 = " ${@base_contains('DISTRO_FEATURES', 'alsa', 'fsl-alsa-plugins', '', d)}"
+MACHINE_EXTRA_RRECOMMENDS_append_mx6 = " ${@base_contains('DISTRO_FEATURES', 'alsa', 'imx-alsa-plugins', '', d)}"
 
 # Extra udev rules
 MACHINE_EXTRA_RRECOMMENDS += "udev-rules-imx"
-- 
1.9.1

[meta-fsl-arm][PATCH v4 08/13] chromium-imx: Update dependency name of vpuwrap

[Yuqing Zhu]

libfslvpuwrap has been renamed to imx-vpuwrap, need to
do update.

Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
---
 browser-layer/recipes-browser/chromium/chromium-imx.inc | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/browser-layer/recipes-browser/chromium/chromium-imx.inc b/browser-layer/recipes-browser/chromium/chromium-imx.inc
index f63807d..db9580a 100644
--- a/browser-layer/recipes-browser/chromium/chromium-imx.inc
+++ b/browser-layer/recipes-browser/chromium/chromium-imx.inc
@@ -1,5 +1,5 @@
-DEPENDS_append_mx6q = " libfslvpuwrap"
-DEPENDS_append_mx6dl = " libfslvpuwrap"
+DEPENDS_append_mx6q = " imx-vpuwrap"
+DEPENDS_append_mx6dl = " imx-vpuwrap"
 
 # Additional imx code and patches are included in the chromium-imx git repository.
 # The code below fetches this repository, copies the extra source over to the main
-- 
1.9.1

[meta-fsl-arm][PATCH v4 09/13] libfslvpuwrap: Remove the old recipe

[Yuqing Zhu]

Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
---
 .../libfslvpuwrap/libfslvpuwrap_1.0.62.bb          | 23 ----------------------
 1 file changed, 23 deletions(-)
 delete mode 100644 recipes-multimedia/libfslvpuwrap/libfslvpuwrap_1.0.62.bb

diff --git a/recipes-multimedia/libfslvpuwrap/libfslvpuwrap_1.0.62.bb b/recipes-multimedia/libfslvpuwrap/libfslvpuwrap_1.0.62.bb
deleted file mode 100644
index 363184b..0000000
--- a/recipes-multimedia/libfslvpuwrap/libfslvpuwrap_1.0.62.bb
+++ /dev/null
@@ -1,23 +0,0 @@
-# Copyright (C) 2013-2015 Freescale Semiconductor
-# Released under the MIT license (see COPYING.MIT for the terms)
-DESCRIPTION = "Freescale Multimedia VPU wrapper"
-DEPENDS = "imx-vpu"
-LICENSE = "Proprietary"
-SECTION = "multimedia"
-LIC_FILES_CHKSUM = "file://COPYING;md5=3880bb9c943b135a30fad5e8aabd3ee9"
-
-SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
-S = "${WORKDIR}/${PN}-${PV}"
-
-SRC_URI[md5sum] = "6497758e27f72992a86ac918ce12db56"
-SRC_URI[sha256sum] = "0717faccb5413dc95ce9ad919400095ecf722320478c924366793a6cc450ae16"
-
-inherit fsl-eula-unpack autotools pkgconfig
-
-do_install_append() {
-    # FIXME: Drop examples for now
-    rm -r ${D}${datadir}
-}
-
-PACKAGE_ARCH = "${MACHINE_ARCH}"
-COMPATIBLE_MACHINE = "(mx6q|mx6dl)"
-- 
1.9.1

[meta-fsl-arm][PATCH v4 10/13] libfslparser: Remove the old recipe

[Yuqing Zhu]

Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
---
 recipes-multimedia/libfslparser/libfslparser.inc   | 33 ----------------------
 .../libfslparser/libfslparser_4.0.8.bb             |  9 ------
 2 files changed, 42 deletions(-)
 delete mode 100644 recipes-multimedia/libfslparser/libfslparser.inc
 delete mode 100644 recipes-multimedia/libfslparser/libfslparser_4.0.8.bb

diff --git a/recipes-multimedia/libfslparser/libfslparser.inc b/recipes-multimedia/libfslparser/libfslparser.inc
deleted file mode 100644
index b63aad8..0000000
--- a/recipes-multimedia/libfslparser/libfslparser.inc
+++ /dev/null
@@ -1,33 +0,0 @@
-# Copyright (C) 2012-2014 O.S. Systems Software LTDA.
-# Copyright (C) 2012-2013 Freescale Semiconductor
-# Released under the MIT license (see COPYING.MIT for the terms)
-DESCRIPTION = "Freescale Multimedia parser libs"
-LICENSE = "Proprietary"
-SECTION = "multimedia"
-LIC_FILES_CHKSUM = "file://COPYING;md5=3880bb9c943b135a30fad5e8aabd3ee9"
-
-inherit fsl-eula-unpack autotools pkgconfig
-
-SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
-
-# Choose between Soft Float-Point and Hard Float-Point
-EXTRA_OECONF = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', '--enable-fhw', '--enable-fsw', d)}"
-
-INHIBIT_PACKAGE_STRIP = "1"
-INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
-
-python __set_insane_skip() {
-    # FIXME: All binaries lack GNU_HASH in elf binary but as we don't have
-    # the source we cannot fix it. Disable the insane check for now.
-    # FIXME: gst-fsl-plugin looks for the .so files so we need to deploy those
-    for p in d.getVar('PACKAGES', True).split():
-        d.setVar("INSANE_SKIP_%s" % p, "ldflags dev-so textrel")
-}
-
-do_package_qa[prefuncs] += "__set_insane_skip"
-
-# FIXME: gst-fsl-plugin looks for the .so files so we need to deploy those
-FILES_${PN} += "${libdir}/imx-mm/*/*${SOLIBS} ${libdir}/imx-mm/*/*${SOLIBSDEV}"
-
-PACKAGE_ARCH = "${MACHINE_ARCH}"
-
diff --git a/recipes-multimedia/libfslparser/libfslparser_4.0.8.bb b/recipes-multimedia/libfslparser/libfslparser_4.0.8.bb
deleted file mode 100644
index 06657fd..0000000
--- a/recipes-multimedia/libfslparser/libfslparser_4.0.8.bb
+++ /dev/null
@@ -1,9 +0,0 @@
-# Copyright (C) 2013-2015 Freescale Semiconductor
-# Released under the MIT license (see COPYING.MIT for the terms)
-
-require libfslparser.inc
-
-SRC_URI[md5sum] = "9538df4dc416e12ff13fdf12ddbf3684"
-SRC_URI[sha256sum] = "a04621783c84a9776216caff9563c7f840fddd584b0b2d27738d6ca6d2c77f32"
-
-COMPATIBLE_MACHINE = "(mx6|mx6ul|mx7)"
-- 
1.9.1

[meta-fsl-arm][PATCH v4 11/13] fsl-alsa-plugins: Remove the old recipe

[Yuqing Zhu]

Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
---
 .../0001-asrc_pair-update-output-buffer-size.patch | 47 ----------------------
 recipes-multimedia/alsa/fsl-alsa-plugins_1.0.25.bb | 37 -----------------
 2 files changed, 84 deletions(-)
 delete mode 100644 recipes-multimedia/alsa/fsl-alsa-plugins/0001-asrc_pair-update-output-buffer-size.patch
 delete mode 100644 recipes-multimedia/alsa/fsl-alsa-plugins_1.0.25.bb

diff --git a/recipes-multimedia/alsa/fsl-alsa-plugins/0001-asrc_pair-update-output-buffer-size.patch b/recipes-multimedia/alsa/fsl-alsa-plugins/0001-asrc_pair-update-output-buffer-size.patch
deleted file mode 100644
index d76c74d..0000000
--- a/recipes-multimedia/alsa/fsl-alsa-plugins/0001-asrc_pair-update-output-buffer-size.patch
+++ /dev/null
@@ -1,47 +0,0 @@
-From 9acab46fe307ec71d4a4dbe447e356f90b6a4a09 Mon Sep 17 00:00:00 2001
-From: Shengjiu Wang <shengjiu.wang@freescale.com>
-Date: Fri, 12 Dec 2014 14:58:06 +0800
-Subject: [PATCH] [asrc_pair] update output buffer size
-
-When input size larger than DMA_MAX_BYTES the output size should be updated.
-Otherwise the asrc have will not have enough data, then it will be timeout.
-
-Upstream Status: Inappropriate [platform specific]
-
-Signed-off-by: Shengjiu Wang <shengjiu.wang@freescale.com>
----
- asrc/asrc_pair.c | 11 ++++++++---
- 1 file changed, 8 insertions(+), 3 deletions(-)
-
-diff --git a/asrc/asrc_pair.c b/asrc/asrc_pair.c
-index e3df027..e74e8b1 100644
---- a/asrc/asrc_pair.c
-+++ b/asrc/asrc_pair.c
-@@ -139,7 +139,7 @@ asrc_pair *asrc_pair_create(unsigned int channels, ssize_t in_period_frames,
-     config.dma_buffer_size = dma_buffer_size;
-     config.input_sample_rate = in_rate;
-     config.output_sample_rate = out_rate;
--    config.buffer_num = 1;
-+    config.buffer_num = buf_num;
-     config.input_word_width = ASRC_WIDTH_16_BIT;
-     config.output_word_width = ASRC_WIDTH_16_BIT;
-     config.inclk = INCLK_NONE;
-@@ -303,8 +303,13 @@ void asrc_pair_convert_s16(asrc_pair *pair, const int16_t *src, unsigned int src
-
-     while (src_left > 0)
-     {
--        in_len = src_left > pair->buf_size ? pair->buf_size : src_left;
--        out_len = dst_left;
-+	if (src_left > pair->buf_size) {
-+		in_len = pair->buf_size;
-+		out_len = dst_left * in_len/src_left;
-+	} else {
-+		in_len = src_left;
-+		out_len = dst_left;
-+	}
-
-         buf_info.input_buffer_vaddr = s;
-         buf_info.input_buffer_length = in_len;
---
-1.9.1
-
diff --git a/recipes-multimedia/alsa/fsl-alsa-plugins_1.0.25.bb b/recipes-multimedia/alsa/fsl-alsa-plugins_1.0.25.bb
deleted file mode 100644
index 2959c7a..0000000
--- a/recipes-multimedia/alsa/fsl-alsa-plugins_1.0.25.bb
+++ /dev/null
@@ -1,37 +0,0 @@
-# Copyright (C) 2013 Freescale Semiconductor
-# Released under the MIT license (see COPYING.MIT for the terms)
-
-DESCRIPTION = "Freescale alsa-lib plugins"
-LICENSE = "GPLv2"
-SECTION = "multimedia"
-DEPENDS = "alsa-lib virtual/kernel"
-
-# Make sure kernel sources are available
-do_configure[depends] += "virtual/kernel:do_shared_workdir"
-
-LIC_FILES_CHKSUM = "file://COPYING.GPL;md5=94d55d512a9ba36caa9b7df079bae19f"
-
-inherit autotools pkgconfig
-
-SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.tar.gz"
-SRC_URI[md5sum] = "b1ca7a250a8cd5da07062081b30b4118"
-SRC_URI[sha256sum] = "902df92255d755e8eb08b3c3db0c7b9d70d26d9659b219373bee425ffdc34245"
-
-SRC_URI_append_mx6 = " file://0001-asrc_pair-update-output-buffer-size.patch"
-SRC_URI_append_mx6ul = " file://0001-asrc_pair-update-output-buffer-size.patch"
-SRC_URI_append_mx7 = " file://0001-asrc_pair-update-output-buffer-size.patch"
-
-INCLUDE_DIR = "-I${STAGING_KERNEL_DIR}/include/uapi -I${STAGING_KERNEL_DIR}/include"
-
-EXTRA_OECONF = "CFLAGS="${INCLUDE_DIR}""
-
-INSANE_SKIP_${PN} = "dev-so"
-
-FILES_${PN} += "${libdir}/alsa-lib/libasound_*.so"
-FILES_${PN}-dbg += "${libdir}/alsa-lib/.debug"
-FILES_${PN}-dev += "${libdir}/alsa-lib/*.la"
-
-COMPATIBLE_MACHINE = "(mx6|mx6ul|mx7)"
-PACKAGE_ARCH_mx6 = "${MACHINE_SOCARCH}"
-PACKAGE_ARCH_mx6ul = "${MACHINE_SOCARCH}"
-PACKAGE_ARCH_mx7 = "${MACHINE_SOCARCH}"
-- 
1.9.1

[meta-fsl-arm][PATCH v4 12/13] gst1.0-fsl-plugin: Remove the old recipe

[Yuqing Zhu]

Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
---
 .../gstreamer/gst1.0-fsl-plugin_4.0.8.bb           | 80 ----------------------
 1 file changed, 80 deletions(-)
 delete mode 100644 recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.8.bb

diff --git a/recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.8.bb b/recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.8.bb
deleted file mode 100644
index 8de4889..0000000
--- a/recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.8.bb
+++ /dev/null
@@ -1,80 +0,0 @@
-# Copyright (C) 2014,2015 Freescale Semiconductor
-# Copyright (C) 2012-2015 O.S. Systems Software LTDA.
-# Released under the MIT license (see COPYING.MIT for the terms)
-
-DESCRIPTION = "Gstreamer freescale plugins"
-LICENSE = "GPLv2 & LGPLv2 & LGPLv2.1"
-SECTION = "multimedia"
-
-DEPENDS = "libfslcodec libfslparser virtual/kernel gstreamer1.0 gstreamer1.0-plugins-base gstreamer1.0-plugins-bad"
-DEPENDS_append_mx6q = " imx-lib imx-vpu libfslvpuwrap"
-DEPENDS_append_mx6dl = " imx-lib imx-vpu libfslvpuwrap"
-DEPENDS_append_mx6sl = " imx-lib"
-DEPENDS_append_mx6sx = " imx-lib"
-DEPENDS_append_mx6ul = " imx-lib"
-DEPENDS_append_mx7 = " imx-lib"
-
-LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \
-                    file://COPYING-LGPL-2;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
-                    file://COPYING-LGPL-2.1;md5=fbc093901857fcd118f065f900982c24"
-
-SRC_URI = " \
-    ${FSL_MIRROR}/gst1.0-fsl-plugins-${PV}.tar.gz \
-"
-
-SRC_URI[md5sum] = "0669eeea4e37203e2e654a00ded35ba2"
-SRC_URI[sha256sum] = "43c86f88d3c7b1da8d38815eaec297a9b8652e1fb770ff89c26d617f63ea068b"
-
-S = "${WORKDIR}/gst1.0-fsl-plugins-${PV}"
-
-inherit autotools pkgconfig
-
-# Make sure kernel sources are available
-do_configure[depends] += "virtual/kernel:do_shared_workdir"
-
-PLATFORM_mx6 = "MX6"
-PLATFORM_mx6sl = "MX6SL"
-PLATFORM_mx6sx = "MX6SX"
-PLATFORM_mx6ul = "MX6UL"
-PLATFORM_mx7= "MX7D"
-
-# Todo add a mechanism to map possible build targets
-EXTRA_OECONF = "PLATFORM=${PLATFORM} \
-                CPPFLAGS="-I${STAGING_KERNEL_BUILDDIR}/include/generated/uapi -I${STAGING_KERNEL_DIR}/include/uapi -I${STAGING_KERNEL_DIR}/include" \
-                CROSS_ROOT=${PKG_CONFIG_SYSROOT_DIR} \
-                ${@base_contains('DISTRO_FEATURES', 'wayland', base_contains('DISTRO_FEATURES', 'x11', '--disable-x11', '', d), '', d)}"
-
-PACKAGES =+ "${PN}-gplay ${PN}-libgplaycore ${PN}-libgstfsl ${PN}-grecorder ${PN}-librecorder-engine ${PN}-libplayengine"
-
-# Add codec list that the beep plugin run-time depended
-BEEP_RDEPENDS = "libfslcodec-aac libfslcodec-mp3 libfslcodec-oggvorbis"
-RDEPENDS_${PN} += "libfslparser ${BEEP_RDEPENDS} gstreamer1.0-plugins-good-id3demux "
-
-PACKAGECONFIG ?= ""
-PACKAGECONFIG_mx6 = "overlaysink"
-
-
-# FIXME: Add all features
-# feature from excluded mm packages
-PACKAGECONFIG[ac3] += ",,libfslac3codec,libfslac3codec"
-# feature from special mm packages
-PACKAGECONFIG[aacp] += ",,libfslaacpcodec,libfslaacpcodec"
-MSDEPENDS = "libfslmsparser libfslmscodec"
-PACKAGECONFIG[wma10dec] += ",,${MSDEPENDS},${MSDEPENDS}"
-PACKAGECONFIG[wma8enc] += "--enable-wma8enc,--disable-wma8enc,${MSDEPENDS},${MSDEPENDS}"
-OVDEPENDS = "virtual/libg2d"
-PACKAGECONFIG[overlaysink] += "--enable-overlaysink,--disable-overlaysink, ${OVDEPENDS}"
-
-FILES_${PN} = "${libdir}/gstreamer-1.0/*.so ${datadir}"
-
-FILES_${PN}-dbg += "${libdir}/gstreamer-1.0/.debug"
-FILES_${PN}-dev += "${libdir}/gstreamer-1.0/*.la ${libdir}/pkgconfig/*.pc"
-FILES_${PN}-staticdev += "${libdir}/gstreamer-1.0/*.a"
-FILES_${PN}-gplay = "${bindir}/gplay-1.0"
-FILES_${PN}-libgplaycore = "${libdir}/libgplaycore-1.0${SOLIBS}"
-FILES_${PN}-libgstfsl = "${libdir}/libgstfsl-1.0${SOLIBS}"
-FILES_${PN}-grecorder = "${bindir}/grecorder-1.0"
-FILES_${PN}-librecorder-engine = "${libdir}/librecorder_engine-1.0${SOLIBS}"
-FILES_${PN}-libplayengine = "${libdir}/libplayengine-1.0${SOLIBS}"
-
-COMPATIBLE_MACHINE = "(mx6|mx6ul|mx7)"
-- 
1.9.1

[meta-fsl-arm][PATCH v4 13/13] libfslcodec: Remove the old recipe

[Yuqing Zhu]

Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
---
 recipes-multimedia/libfslcodec/libfslcodec.inc     | 98 ----------------------
 .../libfslcodec/libfslcodec_4.0.8.bb               |  9 --
 2 files changed, 107 deletions(-)
 delete mode 100644 recipes-multimedia/libfslcodec/libfslcodec.inc
 delete mode 100644 recipes-multimedia/libfslcodec/libfslcodec_4.0.8.bb

diff --git a/recipes-multimedia/libfslcodec/libfslcodec.inc b/recipes-multimedia/libfslcodec/libfslcodec.inc
deleted file mode 100644
index 2f0bc44..0000000
--- a/recipes-multimedia/libfslcodec/libfslcodec.inc
+++ /dev/null
@@ -1,98 +0,0 @@
-# Copyright (C) 2012-2014 Freescale Semiconductor
-# Released under the MIT license (see COPYING.MIT for the terms)
-DESCRIPTION = "Freescale Multimedia codec libs"
-LICENSE = "Proprietary"
-SECTION = "multimedia"
-LIC_FILES_CHKSUM = "file://COPYING;md5=3880bb9c943b135a30fad5e8aabd3ee9"
-
-inherit fsl-eula-unpack autotools pkgconfig
-
-SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
-
-# Choose between Soft Float-Point and Hard Float-Point
-EXTRA_OECONF = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', '--enable-fhw', '', d)}"
-
-PACKAGECONFIG ?= ""
-PACKAGECONFIG_mx6q = "vpu"
-PACKAGECONFIG_mx6dl = "vpu"
-
-PACKAGECONFIG[vpu] = "--enable-vpu,--disable-vpu,imx-vpu"
-
-do_install_append() {
-	# FIXME: This link points to nowhere
-	rm ${D}${libdir}/imx-mm/audio-codec/lib_src_ppp_arm11_elinux.so
-
-    # LTIB move the files around or gst-fsl-plugin won't find them
-    for p in $(find ${D}${libdir}/imx-mm -mindepth 2 -maxdepth 2 -not -type d); do
-            mv $p ${D}${libdir}
-    done
-    rmdir ${D}${libdir}/imx-mm/video-codec
-
-}
-
-python __set_insane_skip() {
-    # Ensure we have PACKAGES expanded
-    bb.build.exec_func("read_subpackage_metadata", d)
-
-    for p in d.getVar('PACKAGES', True).split():
-        # Even though we are packaging libraries those are plugins so we
-        # shouldn't rename the packages to follow its sonames.
-        d.setVar("DEBIAN_NOAUTONAME_%s" % p, "1")
-
-        # FIXME: All binaries lack GNU_HASH in elf binary but as we don't have
-        # the source we cannot fix it. Disable the insane check for now.
-        if p == 'libfslcodec-test-bin':
-            # FIXME: includes the DUT .so files so we need to deploy those
-            d.setVar("INSANE_SKIP_%s" % p, "ldflags textrel libdir")
-        else:
-            d.setVar("INSANE_SKIP_%s" % p, "ldflags textrel")
-}
-
-do_package_qa[prefuncs] += "__set_insane_skip"
-
-python __split_libfslcodec_plugins() {
-    codecdir = bb.data.expand('${libdir}', d)
-    do_split_packages(d, codecdir, '^lib_([^_]*).*_arm.*_elinux\.so\..*',
-                      aux_files_pattern='${libdir}/imx-mm/audio-codec/wrap/lib_%sd_wrap_arm*_elinux.so.*',
-                      output_pattern='libfslcodec-%s',
-                      description='Freescale i.MX Codec (%s)',
-                      extra_depends='')
-}
-
-python __set_metapkg_rdepends() {
-    # Allow addition of all codecs in a image; useful specially for
-    # debugging.
-    codec_pkgs = oe.utils.packages_filter_out_system(d)
-    codec_pkgs = filter(lambda x: x not in ['libfslcodec-test-bin', 'libfslcodec-test-source'],
-                        codec_pkgs)
-    d.appendVar('RDEPENDS_libfslcodec-meta', ' ' + ' '.join(codec_pkgs))
-}
-
-PACKAGESPLITFUNCS =+ "__split_libfslcodec_plugins __set_metapkg_rdepends"
-
-PACKAGES_DYNAMIC = "${PN}-*"
-INHIBIT_PACKAGE_STRIP = "1"
-INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
-
-PACKAGES += "${PN}-meta ${PN}-test-bin ${PN}-test-source"
-
-ALLOW_EMPTY_${PN} = "1"
-ALLOW_EMPTY_${PN}-meta = "1"
-
-# Ensure we get warnings if we miss something
-FILES_${PN} = ""
-
-FILES_${PN}-dev += "${libdir}/imx-mm/*/*${SOLIBSDEV} \
-                    ${libdir}/imx-mm/*/*/*${SOLIBSDEV} \
-                    ${libdir}/pkgconfig/*.pc ${includedir}/imx-mm/*"
-
-FILES_${PN}-test-bin += "${datadir}/imx-mm/*/examples/*/bin"
-
-FILES_${PN}-test-source += "${datadir}/imx-mm/*"
-
-# FIXME: The wrap and lib names does not match
-FILES_${PN}-oggvorbis += "${libdir}/imx-mm/audio-codec/wrap/lib_vorbisd_wrap_arm*_elinux.so.*"
-FILES_${PN}-nb += "${libdir}/imx-mm/audio-codec/wrap/lib_nbamrd_wrap_arm*_elinux.so.*"
-FILES_${PN}-wb += "${libdir}/imx-mm/audio-codec/wrap/lib_wbamrd_wrap_arm*_elinux.so.*"
-
-PACKAGE_ARCH = "${MACHINE_ARCH}"
diff --git a/recipes-multimedia/libfslcodec/libfslcodec_4.0.8.bb b/recipes-multimedia/libfslcodec/libfslcodec_4.0.8.bb
deleted file mode 100644
index 1b32f90..0000000
--- a/recipes-multimedia/libfslcodec/libfslcodec_4.0.8.bb
+++ /dev/null
@@ -1,9 +0,0 @@
-# Copyright (C) 2013-2015 Freescale Semiconductor
-# Released under the MIT license (see COPYING.MIT for the terms)
-
-require libfslcodec.inc
-
-SRC_URI[md5sum] = "462fb27b20cd7df56a49b9e7d6b7c8b4"
-SRC_URI[sha256sum] = "544ffc5989bce18ca50c7a826cc03370b1cf8455335e4291ef0c0779b4c33de0"
-
-COMPATIBLE_MACHINE = "(mx6|mx6ul|mx7)"
-- 
1.9.1