[PATCH 0/5] Add WiLink8 WiFi and Bluetooth firmware and tools

[PATCH 0/5] Add WiLink8 WiFi and Bluetooth firmware and tools

[Denys Dmytriyenko]

From: Denys Dmytriyenko <denys@ti.com>

Moved and cleaned up from meta-arago-extras

Denys Dmytriyenko (5):
  wl18xx-fw: add version 8.7.1 (R8.7_SP1)
  bt-fw: add version 8.7.1 (R8.7_SP1)
  wlconf: add version 8.7.1 (R8.7_SP1)
  wl18xx-target-scripts: add version 8.7.1 (R8.7_SP1)
  wl18xx-calibrator: add version 8.7.1 (R8.7_SP1)

 recipes-bsp/bt-fw/bt-fw_git.bb                     | 24 +++++++++++++
 ...01-Add-Makefile-to-install-firmware-files.patch | 29 ++++++++++++++++
 recipes-bsp/wl18xx-fw/wl18xx-fw_8.7.1.bb           | 26 +++++++++++++++
 .../wl18xx-calibrator/wl18xx-calibrator_8.7.1.bb   | 24 +++++++++++++
 .../wl18xx-target-scripts_8.7.1.bb                 | 22 ++++++++++++
 recipes-connectivity/wlconf/wlconf_8.7.1.bb        | 39 ++++++++++++++++++++++
 6 files changed, 164 insertions(+)
 create mode 100644 recipes-bsp/bt-fw/bt-fw_git.bb
 create mode 100644 recipes-bsp/wl18xx-fw/wl18xx-fw/0001-Add-Makefile-to-install-firmware-files.patch
 create mode 100644 recipes-bsp/wl18xx-fw/wl18xx-fw_8.7.1.bb
 create mode 100644 recipes-connectivity/wl18xx-calibrator/wl18xx-calibrator_8.7.1.bb
 create mode 100644 recipes-connectivity/wl18xx-target-scripts/wl18xx-target-scripts_8.7.1.bb
 create mode 100644 recipes-connectivity/wlconf/wlconf_8.7.1.bb

-- 
2.7.4

[PATCH 1/5] wl18xx-fw: add version 8.7.1 (R8.7_SP1)

[Denys Dmytriyenko]

From: Denys Dmytriyenko <denys@ti.com>

Previous versions were provided by meta-arago-extras, moving to meta-ti now.

Signed-off-by: Denys Dmytriyenko <denys@ti.com>
---
 ...01-Add-Makefile-to-install-firmware-files.patch | 29 ++++++++++++++++++++++
 recipes-bsp/wl18xx-fw/wl18xx-fw_8.7.1.bb           | 26 +++++++++++++++++++
 2 files changed, 55 insertions(+)
 create mode 100644 recipes-bsp/wl18xx-fw/wl18xx-fw/0001-Add-Makefile-to-install-firmware-files.patch
 create mode 100644 recipes-bsp/wl18xx-fw/wl18xx-fw_8.7.1.bb

diff --git a/recipes-bsp/wl18xx-fw/wl18xx-fw/0001-Add-Makefile-to-install-firmware-files.patch b/recipes-bsp/wl18xx-fw/wl18xx-fw/0001-Add-Makefile-to-install-firmware-files.patch
new file mode 100644
index 0000000..a8db077
--- /dev/null
+++ b/recipes-bsp/wl18xx-fw/wl18xx-fw/0001-Add-Makefile-to-install-firmware-files.patch
@@ -0,0 +1,29 @@
+From 3a8fc3ccf00796254d6cef4b6d4cd70dc37012e1 Mon Sep 17 00:00:00 2001
+From: Denys Dmytriyenko <denys@ti.com>
+Date: Fri, 10 Mar 2017 13:28:29 -0500
+Subject: [PATCH] Add Makefile to install firmware files
+
+Signed-off-by: Denys Dmytriyenko <denys@ti.com>
+---
+ Makefile | 9 +++++++++
+ 1 file changed, 9 insertions(+)
+ create mode 100644 Makefile
+
+diff --git a/Makefile b/Makefile
+new file mode 100644
+index 0000000..1cf38e3
+--- /dev/null
++++ b/Makefile
+@@ -0,0 +1,9 @@
++# Installs the the ti-connectivity wlan firmware files into the root file system
++
++install:
++	@if [ ! -d $(DESTDIR) ] ; then \
++		echo "Target filesystem directory doesn't exist."; \
++		exit 1; \
++	fi
++	install -d  $(DEST_DIR)/lib/firmware/ti-connectivity
++	cp *.bin $(DEST_DIR)/lib/firmware/ti-connectivity/
+-- 
+2.7.4
+
diff --git a/recipes-bsp/wl18xx-fw/wl18xx-fw_8.7.1.bb b/recipes-bsp/wl18xx-fw/wl18xx-fw_8.7.1.bb
new file mode 100644
index 0000000..ec360fe
--- /dev/null
+++ b/recipes-bsp/wl18xx-fw/wl18xx-fw_8.7.1.bb
@@ -0,0 +1,26 @@
+DESCRIPTION = "Firmware files for use with TI wl18xx"
+LICENSE = "TI-TSPA"
+LIC_FILES_CHKSUM = "file://LICENCE;md5=4977a0fe767ee17765ae63c435a32a9e"
+
+SRC_URI = " \
+	git://git.ti.com/wilink8-wlan/wl18xx_fw.git;protocol=git;branch=${BRANCH} \
+	file://0001-Add-Makefile-to-install-firmware-files.patch \
+"
+
+# Tag: R8.7-SP1 (8.7.1)
+SRCREV = "fe3909e93d15a4b17e43699dde2bba0e9a3c0abc"
+BRANCH = "master"
+
+S = "${WORKDIR}/git"
+
+CLEANBROKEN = "1"
+
+do_compile() {
+    :
+}
+
+do_install() {
+    oe_runmake 'DEST_DIR=${D}' install
+}
+
+FILES_${PN} = "/lib/firmware/ti-connectivity/*"
-- 
2.7.4

[PATCH 2/5] bt-fw: add version 8.7.1 (R8.7_SP1)

[Denys Dmytriyenko]

From: Denys Dmytriyenko <denys@ti.com>

Previous versions were provided by meta-arago-extras, moving to meta-ti now.

Signed-off-by: Denys Dmytriyenko <denys@ti.com>
---
 recipes-bsp/bt-fw/bt-fw_git.bb | 24 ++++++++++++++++++++++++
 1 file changed, 24 insertions(+)
 create mode 100644 recipes-bsp/bt-fw/bt-fw_git.bb

diff --git a/recipes-bsp/bt-fw/bt-fw_git.bb b/recipes-bsp/bt-fw/bt-fw_git.bb
new file mode 100644
index 0000000..f3d740b
--- /dev/null
+++ b/recipes-bsp/bt-fw/bt-fw_git.bb
@@ -0,0 +1,24 @@
+DESCRIPTION = "Firmware files for Bluetooth"
+LICENSE = "TI-TSPA"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=f39eac9f4573be5b012e8313831e72a9"
+
+PV = "8.7.1+git${SRCPV}"
+
+CLEANBROKEN = "1"
+
+SRCREV = "0ee619b598d023fffc77679f099bc2a4815510e4"
+BRANCH = "master"
+SRC_URI = "git://git.ti.com/ti-bt/service-packs.git;branch=${BRANCH}"
+
+S = "${WORKDIR}/git"
+
+do_compile() {
+    :
+}
+
+do_install() {
+    install -d ${D}${base_libdir}/firmware/ti-connectivity
+    oe_runmake "DEST_DIR=${D}" "BASE_LIB_DIR=${base_libdir}" install
+}
+
+FILES_${PN} += "${base_libdir}/firmware/ti-connectivity/*"
-- 
2.7.4

[PATCH 3/5] wlconf: add version 8.7.1 (R8.7_SP1)

[Denys Dmytriyenko]

From: Denys Dmytriyenko <denys@ti.com>

Previous versions were provided by meta-arago-extras, moving to meta-ti now.

Signed-off-by: Denys Dmytriyenko <denys@ti.com>
---
 recipes-connectivity/wlconf/wlconf_8.7.1.bb | 39 +++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)
 create mode 100644 recipes-connectivity/wlconf/wlconf_8.7.1.bb

diff --git a/recipes-connectivity/wlconf/wlconf_8.7.1.bb b/recipes-connectivity/wlconf/wlconf_8.7.1.bb
new file mode 100644
index 0000000..fdff614
--- /dev/null
+++ b/recipes-connectivity/wlconf/wlconf_8.7.1.bb
@@ -0,0 +1,39 @@
+DESCRIPTION = "Configuration utility for TI wireless drivers"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://README;beginline=1;endline=21;md5=adc05a1903d3f107f85c90328e3a9438"
+
+# Tag: R8.7_SP1 (8.7.1) +fix
+SRCREV = "ee653d2845b0029c14f49ca83a2f6c02037ec239"
+SRC_URI = "git://git.ti.com/wilink8-wlan/18xx-ti-utils.git"
+
+S = "${WORKDIR}/git/wlconf"
+
+EXTRA_OEMAKE = "CC="${CC}""
+
+do_install() {
+	install -d ${D}${bindir}
+	install -d ${D}${bindir}/wlconf/
+	install -d ${D}${bindir}/wlconf/official_inis
+	install -d ${D}/lib/firmware/ti-connectivity
+
+	install -m 0755 wlconf ${D}${bindir}/wlconf/
+	install -m 0755 dictionary.txt ${D}${bindir}/wlconf/
+	install -m 0755 struct.bin ${D}${bindir}/wlconf/
+	install -m 0755 default.conf ${D}${bindir}/wlconf/
+	install -m 0755 wl18xx-conf-default.bin ${D}${bindir}/wlconf/
+	install -m 0755 wl18xx-conf-default.bin ${D}/lib/firmware/ti-connectivity/wl18xx-conf.bin
+	install -m 0755 README ${D}${bindir}/wlconf/
+	install -m 0755 example.conf ${D}${bindir}/wlconf/
+	install -m 0755 example.ini ${D}${bindir}/wlconf/
+	install -m 0755 configure-device.sh ${D}${bindir}/wlconf/
+	install -m 0755 ${S}/official_inis/* \
+			${D}${bindir}/wlconf/official_inis/
+}
+
+FILES_${PN} += " \
+	${bindir}/wlconf \
+	${bindir}/wlconf/official_inis \
+	/lib/firmware/ti-connectivity/wl18xx-conf.bin \
+"
+
+FILES_${PN}-dbg += "${bindir}/wlconf/.debug"
-- 
2.7.4

[PATCH 4/5] wl18xx-target-scripts: add version 8.7.1 (R8.7_SP1)

[Denys Dmytriyenko]

From: Denys Dmytriyenko <denys@ti.com>

Previous versions were provided by meta-arago-extras, moving to meta-ti now.

Signed-off-by: Denys Dmytriyenko <denys@ti.com>
---
 .../wl18xx-target-scripts_8.7.1.bb                 | 22 ++++++++++++++++++++++
 1 file changed, 22 insertions(+)
 create mode 100644 recipes-connectivity/wl18xx-target-scripts/wl18xx-target-scripts_8.7.1.bb

diff --git a/recipes-connectivity/wl18xx-target-scripts/wl18xx-target-scripts_8.7.1.bb b/recipes-connectivity/wl18xx-target-scripts/wl18xx-target-scripts_8.7.1.bb
new file mode 100644
index 0000000..07a164b
--- /dev/null
+++ b/recipes-connectivity/wl18xx-target-scripts/wl18xx-target-scripts_8.7.1.bb
@@ -0,0 +1,22 @@
+DESCRIPTION = "Scripts and configuration files for TI wireless drivers"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://README;beginline=1;endline=21;md5=b8d6a0865f50159bf5c0d175d1f4a705"
+
+# Tag: R8.7_SP1 (8.7.1)
+SRCREV = "a07b6e711d2a70608101d3d6cdc5749c4d8a96d5"
+BRANCH = "sitara-scripts"
+SRC_URI = "git://git.ti.com/wilink8-wlan/wl18xx-target-scripts.git;protocol=git;branch=${BRANCH}"
+
+S = "${WORKDIR}/git"
+
+FILES_${PN} += "${datadir}/wl18xx/"
+
+do_install() {
+	install -d ${D}${datadir}/wl18xx/
+
+	scripts=`find ./ -type f -name "*.*"`
+	for s in $scripts
+	do
+		install -m 0755 $s ${D}${datadir}/wl18xx/
+	done
+}
-- 
2.7.4

[PATCH 5/5] wl18xx-calibrator: add version 8.7.1 (R8.7_SP1)

[Denys Dmytriyenko]

From: Denys Dmytriyenko <denys@ti.com>

Previous versions were provided by meta-arago-extras as ti-wifi-utils, moving to meta-ti now.

Signed-off-by: Denys Dmytriyenko <denys@ti.com>
---
 .../wl18xx-calibrator/wl18xx-calibrator_8.7.1.bb   | 24 ++++++++++++++++++++++
 1 file changed, 24 insertions(+)
 create mode 100644 recipes-connectivity/wl18xx-calibrator/wl18xx-calibrator_8.7.1.bb

diff --git a/recipes-connectivity/wl18xx-calibrator/wl18xx-calibrator_8.7.1.bb b/recipes-connectivity/wl18xx-calibrator/wl18xx-calibrator_8.7.1.bb
new file mode 100644
index 0000000..e3b2e7f
--- /dev/null
+++ b/recipes-connectivity/wl18xx-calibrator/wl18xx-calibrator_8.7.1.bb
@@ -0,0 +1,24 @@
+DESCRIPTION = "The calibrator utility for TI wireless solution based on wl18xx driver"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4725015cb0be7be389cf06deeae3683d"
+
+DEPENDS = "libnl"
+RDEPENDS_${PN} = "wl18xx-fw"
+
+#Tag: R8.7_SP1 (8.7.1)
+SRCREV = "39542357111d1f24e866c2857d561a348c04cce4"
+SRC_URI = "git://git.ti.com/wilink8-wlan/18xx-ti-utils.git"
+
+S = "${WORKDIR}/git"
+
+export CROSS_COMPILE = "${TARGET_PREFIX}"
+
+EXTRA_OEMAKE = "CFLAGS="${CFLAGS} -I${STAGING_INCDIR}/libnl3/ -DCONFIG_LIBNL32 " \
+		LDFLAGS="${LDFLAGS} -L${STAGING_LIBDIR}" \
+		CC="${CC}" \
+		NLVER=3"
+
+do_install() {
+    install -d ${D}${bindir}
+    install -m 0755 calibrator ${D}${bindir}/
+}
-- 
2.7.4