* [morty 1/4] ti-cgt-arm: Include recipes for 16.9.1
@ 2017-04-19 10:30 Karthik Ramanan
2017-04-19 10:30 ` [morty 2/4] Remove CCS dependencies for all components Karthik Ramanan
` (3 more replies)
0 siblings, 4 replies; 8+ messages in thread
From: Karthik Ramanan @ 2017-04-19 10:30 UTC (permalink / raw)
To: meta-ti
From: Ivan Pang <i-pang@ti.com>
Signed-off-by: Ivan Pang <i-pang@ti.com>
Signed-off-by: Karthik Ramanan <a0393906@ti.com>
---
classes/component_meta.bbclass | 29 +++++++++++++++++++++++++++++
recipes-ti/devtools/ti-cgt-arm-linux.bb | 26 ++++++++++++++++++++++++++
recipes-ti/devtools/ti-cgt-arm.bb | 26 ++++++++++++++++++++++++++
recipes-ti/devtools/ti-cgt-arm.inc | 19 +++++++++++++++++++
4 files changed, 100 insertions(+)
create mode 100644 classes/component_meta.bbclass
create mode 100644 recipes-ti/devtools/ti-cgt-arm-linux.bb
create mode 100644 recipes-ti/devtools/ti-cgt-arm.bb
create mode 100644 recipes-ti/devtools/ti-cgt-arm.inc
diff --git a/classes/component_meta.bbclass b/classes/component_meta.bbclass
new file mode 100644
index 0000000..f2dc754
--- /dev/null
+++ b/classes/component_meta.bbclass
@@ -0,0 +1,29 @@
+CM_NAME ?= ""
+CM_VERSION ?= ""
+CM_ROOT_DIR ?= ""
+CM_BINARY ?= ""
+CM_DESCRIPTION ?= ""
+
+do_component_meta() {
+ if [ ! -d "${DEPLOY_DIR_IMAGE}" ]
+ then
+ mkdir -p ${DEPLOY_DIR_IMAGE}
+ fi
+
+ if [ ! -e "${DEPLOY_DIR_IMAGE}/.components_meta" ]
+ then
+ touch ${DEPLOY_DIR_IMAGE}/.components_meta
+ fi
+
+ # Check if component is already documented in .components_meta
+ if ! grep -q "${CM_ROOT_DIR}" ${DEPLOY_DIR_IMAGE}/.components_meta
+ then
+ # Add component meta information
+ echo "${CM_NAME}|${CM_VERSION}|${CM_ROOT_DIR}|${CM_BINARY}|${CM_DESCRIPTION}" >> \
+ ${DEPLOY_DIR_IMAGE}/.components_meta
+ fi
+}
+
+do_component_meta[lockfiles] = "${DEPLOY_DIR_IMAGE}/component_meta.lock"
+
+addtask do_component_meta after do_install before do_package
diff --git a/recipes-ti/devtools/ti-cgt-arm-linux.bb b/recipes-ti/devtools/ti-cgt-arm-linux.bb
new file mode 100644
index 0000000..dbb143c
--- /dev/null
+++ b/recipes-ti/devtools/ti-cgt-arm-linux.bb
@@ -0,0 +1,26 @@
+include ti-cgt-arm.inc
+
+BINFILE = "ti_cgt_tms470_${PV}.LTS_linux_installer_x86.bin"
+BINFILE_MD5 = "aa65a078eeddbf10e8e132a4cf1d58f0"
+BINFILE_SHA256 = "a372fd6f7b2608e11326b5c7438311aa37c7fbca0728b158cb9064a0666a8a05"
+
+do_install() {
+ cp ${S}/../${BINFILE} ${S}/${BINFILE_NAME}
+}
+
+inherit component_meta
+CM_NAME = "TI CGT ARM"
+CM_VERSION = "${PV}"
+CM_ROOT_DIR = "ti-cgt-arm_${PV}"
+CM_DESCRIPTION = "TI ARM code generation tools, including C/C++ compiler, linker, and run-time-support libraries"
+CM_BINARY = "${BINFILE_NAME}"
+
+deltask do_create_srcipk
+addtask create_srcipk after do_install before do_populate_sysroot
+
+CREATE_SRCIPK = "1"
+SRCIPK_INSTALL_DIR = "${CM_ROOT_DIR}"
+SRCIPK_SRC_DIR = "${S}"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
diff --git a/recipes-ti/devtools/ti-cgt-arm.bb b/recipes-ti/devtools/ti-cgt-arm.bb
new file mode 100644
index 0000000..464374d
--- /dev/null
+++ b/recipes-ti/devtools/ti-cgt-arm.bb
@@ -0,0 +1,26 @@
+include ti-cgt-arm.inc
+
+S = "${WORKDIR}/ti-cgt-arm-${PV}"
+
+require recipes-ti/includes/ti-unpack.inc
+require recipes-ti/includes/ti-staging.inc
+require recipes-ti/includes/ti-paths.inc
+
+TI_BIN_UNPK_ARGS = "--prefix ${S}"
+TI_BIN_UNPK_CMDS = ""
+
+BINFILE = "ti_cgt_tms470_${PV}.LTS_linux_installer_x86.bin"
+BINFILE_MD5 = "aa65a078eeddbf10e8e132a4cf1d58f0"
+BINFILE_SHA256 = "a372fd6f7b2608e11326b5c7438311aa37c7fbca0728b158cb9064a0666a8a05"
+
+do_install() {
+ install -d ${D}${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}
+ cp -r ${S}/ti-cgt-arm*/. ${D}${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}
+}
+
+FILES_${PN} += "${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}"
+
+BBCLASSEXTEND = "native nativesdk"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
diff --git a/recipes-ti/devtools/ti-cgt-arm.inc b/recipes-ti/devtools/ti-cgt-arm.inc
new file mode 100644
index 0000000..195d59e
--- /dev/null
+++ b/recipes-ti/devtools/ti-cgt-arm.inc
@@ -0,0 +1,19 @@
+DESCRIPTION = "TI ARM Code Generation Tools"
+HOMEPAGE = "https://www-a.ti.com/downloads/sds_support/TICodegenerationTools/download.htm"
+LICENSE = "(TI-TSPA & Thai-Open-Source-Software-Center) & BSD-3-Clause & BSL-1.0 & Hewlett-Packard & AFL-3.0 & MIT & BSD-2-Clause & PD & BSD-4-Clause"
+
+LIC_FILES_CHKSUM = "file://../${BINFILE};md5=${BINFILE_MD5}"
+
+PV = "16.9.1"
+PE = "0"
+
+BINFILE_NAME = "cgt_arm_installer"
+
+SRC_URI = "http://software-dl.ti.com/codegen/esd/cgt_public_sw/TMS470/${PV}.LTS/${BINFILE};name=${BINFILE_NAME}"
+
+SRC_URI[cgt_arm_installer.md5sum] = "${BINFILE_MD5}"
+SRC_URI[cgt_arm_installer.sha256sum] = "${BINFILE_SHA256}"
+
+FILES_${PN} += "${S}/*"
+
+INSANE_SKIP_${PN} += "arch staticdev"
--
1.9.1
^ permalink raw reply related [flat|nested] 8+ messages in thread
* [morty 2/4] Remove CCS dependencies for all components
2017-04-19 10:30 [morty 1/4] ti-cgt-arm: Include recipes for 16.9.1 Karthik Ramanan
@ 2017-04-19 10:30 ` Karthik Ramanan
2017-04-19 19:45 ` Denys Dmytriyenko
2017-04-19 10:30 ` [morty 3/4] ti-ccsv6: Remove the recipe Karthik Ramanan
` (2 subsequent siblings)
3 siblings, 1 reply; 8+ messages in thread
From: Karthik Ramanan @ 2017-04-19 10:30 UTC (permalink / raw)
To: meta-ti
Signed-off-by: Karthik Ramanan <a0393906@ti.com>
---
classes/ti-pdk.bbclass | 2 +-
recipes-bsp/edma3-lld/edma3-lld-rtos_git.bb | 2 +-
recipes-bsp/ipumm-fw/ipumm-fw_git.bb | 2 +-
recipes-ti/includes/ti-paths.inc | 1 -
recipes-ti/ipc/ti-ipc-rtos.inc | 2 +-
5 files changed, 4 insertions(+), 5 deletions(-)
diff --git a/classes/ti-pdk.bbclass b/classes/ti-pdk.bbclass
index fd7c3e7..eca3652 100644
--- a/classes/ti-pdk.bbclass
+++ b/classes/ti-pdk.bbclass
@@ -5,7 +5,7 @@ inherit perlnative
DEPENDS = "ti-xdctools ti-cg-xml-native ti-sysbios common-csl-ip-rtos libxml-simple-perl-native gcc-arm-none-eabi-native ti-cgt6x-native ti-pdk-build-rtos"
-DEPENDS_append_omap-a15 = " ti-ccsv6-native"
+DEPENDS_append_omap-a15 = " ti-cgt-arm-native"
DEPENDS_remove_ti33x = "ti-cgt6x-native"
DEPENDS_remove_ti43x = "ti-cgt6x-native"
diff --git a/recipes-bsp/edma3-lld/edma3-lld-rtos_git.bb b/recipes-bsp/edma3-lld/edma3-lld-rtos_git.bb
index 6a01d0b..ce9ef85 100644
--- a/recipes-bsp/edma3-lld/edma3-lld-rtos_git.bb
+++ b/recipes-bsp/edma3-lld/edma3-lld-rtos_git.bb
@@ -4,7 +4,7 @@ require recipes-ti/includes/ti-staging.inc
PR = "${INC_PR}.0"
-DEPENDS = "ti-sysbios ti-xdctools gcc-arm-none-eabi-native ti-ccsv6-native ti-cgt6x-native"
+DEPENDS = "ti-sysbios ti-xdctools gcc-arm-none-eabi-native ti-cgt-arm-native ti-cgt6x-native"
COMPATIBLE_MACHINE = "ti33x|ti43x|omap-a15|keystone"
PACKAGE_ARCH = "${MACHINE_ARCH}"
diff --git a/recipes-bsp/ipumm-fw/ipumm-fw_git.bb b/recipes-bsp/ipumm-fw/ipumm-fw_git.bb
index 1a5d285..1291e69 100644
--- a/recipes-bsp/ipumm-fw/ipumm-fw_git.bb
+++ b/recipes-bsp/ipumm-fw/ipumm-fw_git.bb
@@ -29,7 +29,7 @@ require recipes-ti/includes/ti-staging.inc
inherit update-alternatives
-DEPENDS = "ti-xdctools ti-sysbios ti-codec-engine ti-framework-components ti-xdais ti-ccsv6-native ti-ipc-rtos"
+DEPENDS = "ti-xdctools ti-sysbios ti-codec-engine ti-framework-components ti-xdais ti-cgt-arm-native ti-ipc-rtos"
export HWVERSION="ES10"
export BIOSTOOLSROOT="${STAGING_DIR_TARGET}/usr/share/ti"
diff --git a/recipes-ti/includes/ti-paths.inc b/recipes-ti/includes/ti-paths.inc
index e7d3e82..c5e25c9 100644
--- a/recipes-ti/includes/ti-paths.inc
+++ b/recipes-ti/includes/ti-paths.inc
@@ -46,7 +46,6 @@ export XDC_INSTALL_DIR_RECIPE = "${installdir}/ti-xdctools-tree"
export PDK_INSTALL_DIR_RECIPE = "${installdir}/ti-pdk-tree"
export OSAL_INSTALL_DIR_RECIPE = "${installdir}/ti-osal-tree"
export M4_TOOLCHAIN_INSTALL_DIR_RECIPE = "${installdir}/ti-cgt-arm"
-export CCSV6_INSTALL_DIR_RECIPE = "${installdir}/ccsv6"
export GCC_ARM_NONE_TOOLCHAIN_RECIPE = "${installdir}/gcc-arm-none-eabi"
export TI_CGT_PRU_INSTALL_DIR_RECIPE = "${installdir}/cgt-pru"
export DSPLIB_C66_INSTALL_DIR_RECIPE = "${installdir}/ti-dsplib-c66x-tree"
diff --git a/recipes-ti/ipc/ti-ipc-rtos.inc b/recipes-ti/ipc/ti-ipc-rtos.inc
index b29e984..696a897 100644
--- a/recipes-ti/ipc/ti-ipc-rtos.inc
+++ b/recipes-ti/ipc/ti-ipc-rtos.inc
@@ -43,7 +43,7 @@ DEPENDS_append_keystone = " ti-cgt6x-native \
gcc-arm-none-eabi-native \
"
DEPENDS_append_omap-a15 = " ti-cgt6x-native \
- ti-ccsv6-native \
+ ti-cgt-arm-native \
gcc-arm-none-eabi-native \
"
IPC_TARGETS = ""
--
1.9.1
^ permalink raw reply related [flat|nested] 8+ messages in thread
* Re: [morty 2/4] Remove CCS dependencies for all components
2017-04-19 10:30 ` [morty 2/4] Remove CCS dependencies for all components Karthik Ramanan
@ 2017-04-19 19:45 ` Denys Dmytriyenko
0 siblings, 0 replies; 8+ messages in thread
From: Denys Dmytriyenko @ 2017-04-19 19:45 UTC (permalink / raw)
To: Karthik Ramanan; +Cc: meta-ti
On Wed, Apr 19, 2017 at 04:00:02PM +0530, Karthik Ramanan wrote:
> Signed-off-by: Karthik Ramanan <a0393906@ti.com>
> ---
> classes/ti-pdk.bbclass | 2 +-
> recipes-bsp/edma3-lld/edma3-lld-rtos_git.bb | 2 +-
> recipes-bsp/ipumm-fw/ipumm-fw_git.bb | 2 +-
> recipes-ti/includes/ti-paths.inc | 1 -
> recipes-ti/ipc/ti-ipc-rtos.inc | 2 +-
> 5 files changed, 4 insertions(+), 5 deletions(-)
>
> diff --git a/classes/ti-pdk.bbclass b/classes/ti-pdk.bbclass
> index fd7c3e7..eca3652 100644
> --- a/classes/ti-pdk.bbclass
> +++ b/classes/ti-pdk.bbclass
> @@ -5,7 +5,7 @@ inherit perlnative
>
> DEPENDS = "ti-xdctools ti-cg-xml-native ti-sysbios common-csl-ip-rtos libxml-simple-perl-native gcc-arm-none-eabi-native ti-cgt6x-native ti-pdk-build-rtos"
>
> -DEPENDS_append_omap-a15 = " ti-ccsv6-native"
> +DEPENDS_append_omap-a15 = " ti-cgt-arm-native"
> DEPENDS_remove_ti33x = "ti-cgt6x-native"
> DEPENDS_remove_ti43x = "ti-cgt6x-native"
>
> diff --git a/recipes-bsp/edma3-lld/edma3-lld-rtos_git.bb b/recipes-bsp/edma3-lld/edma3-lld-rtos_git.bb
> index 6a01d0b..ce9ef85 100644
> --- a/recipes-bsp/edma3-lld/edma3-lld-rtos_git.bb
> +++ b/recipes-bsp/edma3-lld/edma3-lld-rtos_git.bb
> @@ -4,7 +4,7 @@ require recipes-ti/includes/ti-staging.inc
>
> PR = "${INC_PR}.0"
>
> -DEPENDS = "ti-sysbios ti-xdctools gcc-arm-none-eabi-native ti-ccsv6-native ti-cgt6x-native"
> +DEPENDS = "ti-sysbios ti-xdctools gcc-arm-none-eabi-native ti-cgt-arm-native ti-cgt6x-native"
>
> COMPATIBLE_MACHINE = "ti33x|ti43x|omap-a15|keystone"
> PACKAGE_ARCH = "${MACHINE_ARCH}"
> diff --git a/recipes-bsp/ipumm-fw/ipumm-fw_git.bb b/recipes-bsp/ipumm-fw/ipumm-fw_git.bb
> index 1a5d285..1291e69 100644
> --- a/recipes-bsp/ipumm-fw/ipumm-fw_git.bb
> +++ b/recipes-bsp/ipumm-fw/ipumm-fw_git.bb
> @@ -29,7 +29,7 @@ require recipes-ti/includes/ti-staging.inc
>
> inherit update-alternatives
>
> -DEPENDS = "ti-xdctools ti-sysbios ti-codec-engine ti-framework-components ti-xdais ti-ccsv6-native ti-ipc-rtos"
> +DEPENDS = "ti-xdctools ti-sysbios ti-codec-engine ti-framework-components ti-xdais ti-cgt-arm-native ti-ipc-rtos"
>
> export HWVERSION="ES10"
> export BIOSTOOLSROOT="${STAGING_DIR_TARGET}/usr/share/ti"
> diff --git a/recipes-ti/includes/ti-paths.inc b/recipes-ti/includes/ti-paths.inc
> index e7d3e82..c5e25c9 100644
> --- a/recipes-ti/includes/ti-paths.inc
> +++ b/recipes-ti/includes/ti-paths.inc
> @@ -46,7 +46,6 @@ export XDC_INSTALL_DIR_RECIPE = "${installdir}/ti-xdctools-tree"
> export PDK_INSTALL_DIR_RECIPE = "${installdir}/ti-pdk-tree"
> export OSAL_INSTALL_DIR_RECIPE = "${installdir}/ti-osal-tree"
> export M4_TOOLCHAIN_INSTALL_DIR_RECIPE = "${installdir}/ti-cgt-arm"
> -export CCSV6_INSTALL_DIR_RECIPE = "${installdir}/ccsv6"
I'd suggest removing this variable in patch #3, along with removing CCS
recipe.
> export GCC_ARM_NONE_TOOLCHAIN_RECIPE = "${installdir}/gcc-arm-none-eabi"
> export TI_CGT_PRU_INSTALL_DIR_RECIPE = "${installdir}/cgt-pru"
> export DSPLIB_C66_INSTALL_DIR_RECIPE = "${installdir}/ti-dsplib-c66x-tree"
> diff --git a/recipes-ti/ipc/ti-ipc-rtos.inc b/recipes-ti/ipc/ti-ipc-rtos.inc
> index b29e984..696a897 100644
> --- a/recipes-ti/ipc/ti-ipc-rtos.inc
> +++ b/recipes-ti/ipc/ti-ipc-rtos.inc
> @@ -43,7 +43,7 @@ DEPENDS_append_keystone = " ti-cgt6x-native \
> gcc-arm-none-eabi-native \
> "
> DEPENDS_append_omap-a15 = " ti-cgt6x-native \
> - ti-ccsv6-native \
> + ti-cgt-arm-native \
> gcc-arm-none-eabi-native \
> "
> IPC_TARGETS = ""
> --
> 1.9.1
>
> --
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti
^ permalink raw reply [flat|nested] 8+ messages in thread
* [morty 3/4] ti-ccsv6: Remove the recipe
2017-04-19 10:30 [morty 1/4] ti-cgt-arm: Include recipes for 16.9.1 Karthik Ramanan
2017-04-19 10:30 ` [morty 2/4] Remove CCS dependencies for all components Karthik Ramanan
@ 2017-04-19 10:30 ` Karthik Ramanan
2017-04-19 10:30 ` [morty 4/4] ti-cgt-arm: Update to version 16.9.2 Karthik Ramanan
2017-04-19 19:43 ` [morty 1/4] ti-cgt-arm: Include recipes for 16.9.1 Denys Dmytriyenko
3 siblings, 0 replies; 8+ messages in thread
From: Karthik Ramanan @ 2017-04-19 10:30 UTC (permalink / raw)
To: meta-ti
Signed-off-by: Karthik Ramanan <a0393906@ti.com>
---
recipes-ti/devtools/ti-ccsv6-native_6.1.3.00034.bb | 45 ----------------------
1 file changed, 45 deletions(-)
delete mode 100644 recipes-ti/devtools/ti-ccsv6-native_6.1.3.00034.bb
diff --git a/recipes-ti/devtools/ti-ccsv6-native_6.1.3.00034.bb b/recipes-ti/devtools/ti-ccsv6-native_6.1.3.00034.bb
deleted file mode 100644
index 334c7df..0000000
--- a/recipes-ti/devtools/ti-ccsv6-native_6.1.3.00034.bb
+++ /dev/null
@@ -1,45 +0,0 @@
-DESCRIPTION = "TI DSP Code Generation Tools"
-HOMEPAGE = "http://processors.wiki.ti.com/index.php/Download_CCS#Code_Composer_Studio_Version_6_Downloads"
-LICENSE = "(TI-TSPA & Thai-Open-Source-Software-Center) & BSD-3-Clause & BSL-1.0 & Hewlett-Packard & AFL-3.0 & MIT & BSD-2-Clause & PD"
-
-LIC_FILES_CHKSUM = "file://${WORKDIR}/ccsv6/doc/EULA/EULA.doc;md5=24fb8a52ac52d3938b5888362edb295a"
-
-inherit native
-
-require recipes-ti/includes/ti-unpack.inc
-require recipes-ti/includes/ti-staging.inc
-require recipes-ti/includes/ti-paths.inc
-
-TI_CGT_ARM_VERSION = "15.12.1.LTS"
-
-SRC_URI = "http://install.source.dir.local/CCS${PV}_linux.tar.gz;name=ccsv6"
-
-S = "${WORKDIR}/CCS${PV}_linux"
-
-BINFILE = "CCS${PV}_linux/ccs_setup_${PV}.bin"
-TI_BIN_UNPK_ARGS = "--mode unattended --prefix ${WORKDIR}"
-TI_BIN_UNPK_CMDS = ""
-
-SRC_URI[ccsv6.md5sum] = "ceaa5023c1a4b51bc637d3de1a15786b"
-SRC_URI[ccsv6.sha256sum] = "fb3205a21942da09684c871371513707c841c4fd8d88a62f6a7865b0a86cc492"
-
-do_install() {
- install -d ${D}${CCSV6_INSTALL_DIR_RECIPE}
- cp -r ${WORKDIR}/ccsv6/. ${D}${CCSV6_INSTALL_DIR_RECIPE}
-
- install -d ${D}${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}
- cp -r ${WORKDIR}/ccsv6/tools/compiler/ti-cgt-arm_${TI_CGT_ARM_VERSION}/. \
- ${D}${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}
-}
-
-FILES_${PN} += "\
- ${CCSV6_INSTALL_DIR_RECIPE} \
- ${M4_TOOLCHAIN_INSTALL_DIR_RECIPE} \
-"
-
-INHIBIT_PACKAGE_STRIP = "1"
-INHIBIT_SYSROOT_STRIP = "1"
-INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
-INSANE_SKIP_${PN} = "arch libdir ldflags staticdev textrel dev-so"
-
-EXCLUDE_FROM_SHLIBS = "1"
--
1.9.1
^ permalink raw reply related [flat|nested] 8+ messages in thread
* [morty 4/4] ti-cgt-arm: Update to version 16.9.2
2017-04-19 10:30 [morty 1/4] ti-cgt-arm: Include recipes for 16.9.1 Karthik Ramanan
2017-04-19 10:30 ` [morty 2/4] Remove CCS dependencies for all components Karthik Ramanan
2017-04-19 10:30 ` [morty 3/4] ti-ccsv6: Remove the recipe Karthik Ramanan
@ 2017-04-19 10:30 ` Karthik Ramanan
2017-04-19 19:47 ` Denys Dmytriyenko
2017-04-19 19:43 ` [morty 1/4] ti-cgt-arm: Include recipes for 16.9.1 Denys Dmytriyenko
3 siblings, 1 reply; 8+ messages in thread
From: Karthik Ramanan @ 2017-04-19 10:30 UTC (permalink / raw)
To: meta-ti
Signed-off-by: Karthik Ramanan <a0393906@ti.com>
---
recipes-ti/devtools/ti-cgt-arm.bb | 4 ++--
recipes-ti/devtools/ti-cgt-arm.inc | 2 +-
2 files changed, 3 insertions(+), 3 deletions(-)
diff --git a/recipes-ti/devtools/ti-cgt-arm.bb b/recipes-ti/devtools/ti-cgt-arm.bb
index 464374d..dbe61d4 100644
--- a/recipes-ti/devtools/ti-cgt-arm.bb
+++ b/recipes-ti/devtools/ti-cgt-arm.bb
@@ -10,8 +10,8 @@ TI_BIN_UNPK_ARGS = "--prefix ${S}"
TI_BIN_UNPK_CMDS = ""
BINFILE = "ti_cgt_tms470_${PV}.LTS_linux_installer_x86.bin"
-BINFILE_MD5 = "aa65a078eeddbf10e8e132a4cf1d58f0"
-BINFILE_SHA256 = "a372fd6f7b2608e11326b5c7438311aa37c7fbca0728b158cb9064a0666a8a05"
+BINFILE_MD5 = "7b73e51e9548a4a0bf3923a336b1a974"
+BINFILE_SHA256 = "d1a5c255319088be7d75b3fce1b16a2e3d60c75023db7dad16cab6d4d3425d06"
do_install() {
install -d ${D}${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}
diff --git a/recipes-ti/devtools/ti-cgt-arm.inc b/recipes-ti/devtools/ti-cgt-arm.inc
index 195d59e..c14580c 100644
--- a/recipes-ti/devtools/ti-cgt-arm.inc
+++ b/recipes-ti/devtools/ti-cgt-arm.inc
@@ -4,7 +4,7 @@ LICENSE = "(TI-TSPA & Thai-Open-Source-Software-Center) & BSD-3-Clause & BSL-1.0
LIC_FILES_CHKSUM = "file://../${BINFILE};md5=${BINFILE_MD5}"
-PV = "16.9.1"
+PV = "16.9.2"
PE = "0"
BINFILE_NAME = "cgt_arm_installer"
--
1.9.1
^ permalink raw reply related [flat|nested] 8+ messages in thread
* Re: [morty 4/4] ti-cgt-arm: Update to version 16.9.2
2017-04-19 10:30 ` [morty 4/4] ti-cgt-arm: Update to version 16.9.2 Karthik Ramanan
@ 2017-04-19 19:47 ` Denys Dmytriyenko
0 siblings, 0 replies; 8+ messages in thread
From: Denys Dmytriyenko @ 2017-04-19 19:47 UTC (permalink / raw)
To: Karthik Ramanan; +Cc: meta-ti
Since you'd need to completely re-do patch #1, I suggest you squash this
change as well.
On Wed, Apr 19, 2017 at 04:00:04PM +0530, Karthik Ramanan wrote:
> Signed-off-by: Karthik Ramanan <a0393906@ti.com>
> ---
> recipes-ti/devtools/ti-cgt-arm.bb | 4 ++--
> recipes-ti/devtools/ti-cgt-arm.inc | 2 +-
> 2 files changed, 3 insertions(+), 3 deletions(-)
>
> diff --git a/recipes-ti/devtools/ti-cgt-arm.bb b/recipes-ti/devtools/ti-cgt-arm.bb
> index 464374d..dbe61d4 100644
> --- a/recipes-ti/devtools/ti-cgt-arm.bb
> +++ b/recipes-ti/devtools/ti-cgt-arm.bb
> @@ -10,8 +10,8 @@ TI_BIN_UNPK_ARGS = "--prefix ${S}"
> TI_BIN_UNPK_CMDS = ""
>
> BINFILE = "ti_cgt_tms470_${PV}.LTS_linux_installer_x86.bin"
> -BINFILE_MD5 = "aa65a078eeddbf10e8e132a4cf1d58f0"
> -BINFILE_SHA256 = "a372fd6f7b2608e11326b5c7438311aa37c7fbca0728b158cb9064a0666a8a05"
> +BINFILE_MD5 = "7b73e51e9548a4a0bf3923a336b1a974"
> +BINFILE_SHA256 = "d1a5c255319088be7d75b3fce1b16a2e3d60c75023db7dad16cab6d4d3425d06"
>
> do_install() {
> install -d ${D}${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}
> diff --git a/recipes-ti/devtools/ti-cgt-arm.inc b/recipes-ti/devtools/ti-cgt-arm.inc
> index 195d59e..c14580c 100644
> --- a/recipes-ti/devtools/ti-cgt-arm.inc
> +++ b/recipes-ti/devtools/ti-cgt-arm.inc
> @@ -4,7 +4,7 @@ LICENSE = "(TI-TSPA & Thai-Open-Source-Software-Center) & BSD-3-Clause & BSL-1.0
>
> LIC_FILES_CHKSUM = "file://../${BINFILE};md5=${BINFILE_MD5}"
>
> -PV = "16.9.1"
> +PV = "16.9.2"
> PE = "0"
>
> BINFILE_NAME = "cgt_arm_installer"
> --
> 1.9.1
>
> --
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti
^ permalink raw reply [flat|nested] 8+ messages in thread
* Re: [morty 1/4] ti-cgt-arm: Include recipes for 16.9.1
2017-04-19 10:30 [morty 1/4] ti-cgt-arm: Include recipes for 16.9.1 Karthik Ramanan
` (2 preceding siblings ...)
2017-04-19 10:30 ` [morty 4/4] ti-cgt-arm: Update to version 16.9.2 Karthik Ramanan
@ 2017-04-19 19:43 ` Denys Dmytriyenko
2017-04-21 14:17 ` Karthik Ramanan
3 siblings, 1 reply; 8+ messages in thread
From: Denys Dmytriyenko @ 2017-04-19 19:43 UTC (permalink / raw)
To: Karthik Ramanan; +Cc: meta-ti
Please see inline.
On Wed, Apr 19, 2017 at 04:00:01PM +0530, Karthik Ramanan wrote:
> From: Ivan Pang <i-pang@ti.com>
>
> Signed-off-by: Ivan Pang <i-pang@ti.com>
> Signed-off-by: Karthik Ramanan <a0393906@ti.com>
> ---
> classes/component_meta.bbclass | 29 +++++++++++++++++++++++++++++
> recipes-ti/devtools/ti-cgt-arm-linux.bb | 26 ++++++++++++++++++++++++++
> recipes-ti/devtools/ti-cgt-arm.bb | 26 ++++++++++++++++++++++++++
> recipes-ti/devtools/ti-cgt-arm.inc | 19 +++++++++++++++++++
> 4 files changed, 100 insertions(+)
> create mode 100644 classes/component_meta.bbclass
> create mode 100644 recipes-ti/devtools/ti-cgt-arm-linux.bb
> create mode 100644 recipes-ti/devtools/ti-cgt-arm.bb
> create mode 100644 recipes-ti/devtools/ti-cgt-arm.inc
>
> diff --git a/classes/component_meta.bbclass b/classes/component_meta.bbclass
> new file mode 100644
> index 0000000..f2dc754
> --- /dev/null
> +++ b/classes/component_meta.bbclass
> @@ -0,0 +1,29 @@
> +CM_NAME ?= ""
> +CM_VERSION ?= ""
> +CM_ROOT_DIR ?= ""
> +CM_BINARY ?= ""
> +CM_DESCRIPTION ?= ""
I'm not sure what's the purpose of this class and why you are including it
here...
I'd suggest you drop it completely.
> +do_component_meta() {
> + if [ ! -d "${DEPLOY_DIR_IMAGE}" ]
> + then
> + mkdir -p ${DEPLOY_DIR_IMAGE}
> + fi
> +
> + if [ ! -e "${DEPLOY_DIR_IMAGE}/.components_meta" ]
> + then
> + touch ${DEPLOY_DIR_IMAGE}/.components_meta
> + fi
> +
> + # Check if component is already documented in .components_meta
> + if ! grep -q "${CM_ROOT_DIR}" ${DEPLOY_DIR_IMAGE}/.components_meta
> + then
> + # Add component meta information
> + echo "${CM_NAME}|${CM_VERSION}|${CM_ROOT_DIR}|${CM_BINARY}|${CM_DESCRIPTION}" >> \
> + ${DEPLOY_DIR_IMAGE}/.components_meta
> + fi
> +}
> +
> +do_component_meta[lockfiles] = "${DEPLOY_DIR_IMAGE}/component_meta.lock"
> +
> +addtask do_component_meta after do_install before do_package
> diff --git a/recipes-ti/devtools/ti-cgt-arm-linux.bb b/recipes-ti/devtools/ti-cgt-arm-linux.bb
> new file mode 100644
> index 0000000..dbb143c
> --- /dev/null
> +++ b/recipes-ti/devtools/ti-cgt-arm-linux.bb
> @@ -0,0 +1,26 @@
> +include ti-cgt-arm.inc
> +
> +BINFILE = "ti_cgt_tms470_${PV}.LTS_linux_installer_x86.bin"
> +BINFILE_MD5 = "aa65a078eeddbf10e8e132a4cf1d58f0"
> +BINFILE_SHA256 = "a372fd6f7b2608e11326b5c7438311aa37c7fbca0728b158cb9064a0666a8a05"
> +
> +do_install() {
> + cp ${S}/../${BINFILE} ${S}/${BINFILE_NAME}
Why do you need this step?
In general, what's the difference between ti-cgt-arm-linux.bb and ti-cgt-arm.bb?
Anyway, this ti-cgt-arm-linux recipe looks superflous to me...
> +}
> +
> +inherit component_meta
> +CM_NAME = "TI CGT ARM"
> +CM_VERSION = "${PV}"
> +CM_ROOT_DIR = "ti-cgt-arm_${PV}"
> +CM_DESCRIPTION = "TI ARM code generation tools, including C/C++ compiler, linker, and run-time-support libraries"
> +CM_BINARY = "${BINFILE_NAME}"
> +
> +deltask do_create_srcipk
> +addtask create_srcipk after do_install before do_populate_sysroot
> +
> +CREATE_SRCIPK = "1"
> +SRCIPK_INSTALL_DIR = "${CM_ROOT_DIR}"
> +SRCIPK_SRC_DIR = "${S}"
This should not be here! This has nothing to do with meta-ti!
> +INHIBIT_PACKAGE_STRIP = "1"
> +INHIBIT_SYSROOT_STRIP = "1"
> diff --git a/recipes-ti/devtools/ti-cgt-arm.bb b/recipes-ti/devtools/ti-cgt-arm.bb
> new file mode 100644
> index 0000000..464374d
> --- /dev/null
> +++ b/recipes-ti/devtools/ti-cgt-arm.bb
> @@ -0,0 +1,26 @@
> +include ti-cgt-arm.inc
> +
> +S = "${WORKDIR}/ti-cgt-arm-${PV}"
May need to be set in .inc file...
> +require recipes-ti/includes/ti-unpack.inc
> +require recipes-ti/includes/ti-staging.inc
> +require recipes-ti/includes/ti-paths.inc
> +
> +TI_BIN_UNPK_ARGS = "--prefix ${S}"
> +TI_BIN_UNPK_CMDS = ""
> +
> +BINFILE = "ti_cgt_tms470_${PV}.LTS_linux_installer_x86.bin"
> +BINFILE_MD5 = "aa65a078eeddbf10e8e132a4cf1d58f0"
> +BINFILE_SHA256 = "a372fd6f7b2608e11326b5c7438311aa37c7fbca0728b158cb9064a0666a8a05"
> +
> +do_install() {
> + install -d ${D}${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}
> + cp -r ${S}/ti-cgt-arm*/. ${D}${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}
> +}
> +
> +FILES_${PN} += "${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}"
> +
> +BBCLASSEXTEND = "native nativesdk"
> +
> +INHIBIT_PACKAGE_STRIP = "1"
> +INHIBIT_SYSROOT_STRIP = "1"
> diff --git a/recipes-ti/devtools/ti-cgt-arm.inc b/recipes-ti/devtools/ti-cgt-arm.inc
> new file mode 100644
> index 0000000..195d59e
> --- /dev/null
> +++ b/recipes-ti/devtools/ti-cgt-arm.inc
> @@ -0,0 +1,19 @@
> +DESCRIPTION = "TI ARM Code Generation Tools"
Use SUMMARY
> +HOMEPAGE = "https://www-a.ti.com/downloads/sds_support/TICodegenerationTools/download.htm"
> +LICENSE = "(TI-TSPA & Thai-Open-Source-Software-Center) & BSD-3-Clause & BSL-1.0 & Hewlett-Packard & AFL-3.0 & MIT & BSD-2-Clause & PD & BSD-4-Clause"
Is this the correct license?
> +LIC_FILES_CHKSUM = "file://../${BINFILE};md5=${BINFILE_MD5}"
This is very incorrect! Please point to the real license file.
> +PV = "16.9.1"
> +PE = "0"
Drop this - 0 is the default.
> +BINFILE_NAME = "cgt_arm_installer"
> +
> +SRC_URI = "http://software-dl.ti.com/codegen/esd/cgt_public_sw/TMS470/${PV}.LTS/${BINFILE};name=${BINFILE_NAME}"
> +
> +SRC_URI[cgt_arm_installer.md5sum] = "${BINFILE_MD5}"
> +SRC_URI[cgt_arm_installer.sha256sum] = "${BINFILE_SHA256}"
> +
> +FILES_${PN} += "${S}/*"
??? What's this?
> +INSANE_SKIP_${PN} += "arch staticdev"
> --
> 1.9.1
>
> --
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti
^ permalink raw reply [flat|nested] 8+ messages in thread
* Re: [morty 1/4] ti-cgt-arm: Include recipes for 16.9.1
2017-04-19 19:43 ` [morty 1/4] ti-cgt-arm: Include recipes for 16.9.1 Denys Dmytriyenko
@ 2017-04-21 14:17 ` Karthik Ramanan
0 siblings, 0 replies; 8+ messages in thread
From: Karthik Ramanan @ 2017-04-21 14:17 UTC (permalink / raw)
To: Denys Dmytriyenko; +Cc: meta-ti
Hi Denys,
I have reworked the patches to address all your comments.
Regarding the license, I looked into the ti-cgt-arm folder after
extraction, it has mention of all these licenses that are captured in
the recipe.
The v2 of the patch set has been validated with the latest morty/morty-next.
Regards
Karthik
On 20-Apr-17 1:13 AM, Denys Dmytriyenko wrote:
> Please see inline.
>
>
> On Wed, Apr 19, 2017 at 04:00:01PM +0530, Karthik Ramanan wrote:
>> From: Ivan Pang <i-pang@ti.com>
>>
>> Signed-off-by: Ivan Pang <i-pang@ti.com>
>> Signed-off-by: Karthik Ramanan <a0393906@ti.com>
>> ---
>> classes/component_meta.bbclass | 29 +++++++++++++++++++++++++++++
>> recipes-ti/devtools/ti-cgt-arm-linux.bb | 26 ++++++++++++++++++++++++++
>> recipes-ti/devtools/ti-cgt-arm.bb | 26 ++++++++++++++++++++++++++
>> recipes-ti/devtools/ti-cgt-arm.inc | 19 +++++++++++++++++++
>> 4 files changed, 100 insertions(+)
>> create mode 100644 classes/component_meta.bbclass
>> create mode 100644 recipes-ti/devtools/ti-cgt-arm-linux.bb
>> create mode 100644 recipes-ti/devtools/ti-cgt-arm.bb
>> create mode 100644 recipes-ti/devtools/ti-cgt-arm.inc
>>
>> diff --git a/classes/component_meta.bbclass b/classes/component_meta.bbclass
>> new file mode 100644
>> index 0000000..f2dc754
>> --- /dev/null
>> +++ b/classes/component_meta.bbclass
>> @@ -0,0 +1,29 @@
>> +CM_NAME ?= ""
>> +CM_VERSION ?= ""
>> +CM_ROOT_DIR ?= ""
>> +CM_BINARY ?= ""
>> +CM_DESCRIPTION ?= ""
> I'm not sure what's the purpose of this class and why you are including it
> here...
> I'd suggest you drop it completely.
>
>
>> +do_component_meta() {
>> + if [ ! -d "${DEPLOY_DIR_IMAGE}" ]
>> + then
>> + mkdir -p ${DEPLOY_DIR_IMAGE}
>> + fi
>> +
>> + if [ ! -e "${DEPLOY_DIR_IMAGE}/.components_meta" ]
>> + then
>> + touch ${DEPLOY_DIR_IMAGE}/.components_meta
>> + fi
>> +
>> + # Check if component is already documented in .components_meta
>> + if ! grep -q "${CM_ROOT_DIR}" ${DEPLOY_DIR_IMAGE}/.components_meta
>> + then
>> + # Add component meta information
>> + echo "${CM_NAME}|${CM_VERSION}|${CM_ROOT_DIR}|${CM_BINARY}|${CM_DESCRIPTION}" >> \
>> + ${DEPLOY_DIR_IMAGE}/.components_meta
>> + fi
>> +}
>> +
>> +do_component_meta[lockfiles] = "${DEPLOY_DIR_IMAGE}/component_meta.lock"
>> +
>> +addtask do_component_meta after do_install before do_package
>> diff --git a/recipes-ti/devtools/ti-cgt-arm-linux.bb b/recipes-ti/devtools/ti-cgt-arm-linux.bb
>> new file mode 100644
>> index 0000000..dbb143c
>> --- /dev/null
>> +++ b/recipes-ti/devtools/ti-cgt-arm-linux.bb
>> @@ -0,0 +1,26 @@
>> +include ti-cgt-arm.inc
>> +
>> +BINFILE = "ti_cgt_tms470_${PV}.LTS_linux_installer_x86.bin"
>> +BINFILE_MD5 = "aa65a078eeddbf10e8e132a4cf1d58f0"
>> +BINFILE_SHA256 = "a372fd6f7b2608e11326b5c7438311aa37c7fbca0728b158cb9064a0666a8a05"
>> +
>> +do_install() {
>> + cp ${S}/../${BINFILE} ${S}/${BINFILE_NAME}
> Why do you need this step?
>
> In general, what's the difference between ti-cgt-arm-linux.bb and ti-cgt-arm.bb?
>
> Anyway, this ti-cgt-arm-linux recipe looks superflous to me...
>
>
>> +}
>> +
>> +inherit component_meta
>> +CM_NAME = "TI CGT ARM"
>> +CM_VERSION = "${PV}"
>> +CM_ROOT_DIR = "ti-cgt-arm_${PV}"
>> +CM_DESCRIPTION = "TI ARM code generation tools, including C/C++ compiler, linker, and run-time-support libraries"
>> +CM_BINARY = "${BINFILE_NAME}"
>> +
>> +deltask do_create_srcipk
>> +addtask create_srcipk after do_install before do_populate_sysroot
>> +
>> +CREATE_SRCIPK = "1"
>> +SRCIPK_INSTALL_DIR = "${CM_ROOT_DIR}"
>> +SRCIPK_SRC_DIR = "${S}"
> This should not be here! This has nothing to do with meta-ti!
>
>
>> +INHIBIT_PACKAGE_STRIP = "1"
>> +INHIBIT_SYSROOT_STRIP = "1"
>> diff --git a/recipes-ti/devtools/ti-cgt-arm.bb b/recipes-ti/devtools/ti-cgt-arm.bb
>> new file mode 100644
>> index 0000000..464374d
>> --- /dev/null
>> +++ b/recipes-ti/devtools/ti-cgt-arm.bb
>> @@ -0,0 +1,26 @@
>> +include ti-cgt-arm.inc
>> +
>> +S = "${WORKDIR}/ti-cgt-arm-${PV}"
> May need to be set in .inc file...
>
>
>> +require recipes-ti/includes/ti-unpack.inc
>> +require recipes-ti/includes/ti-staging.inc
>> +require recipes-ti/includes/ti-paths.inc
>> +
>> +TI_BIN_UNPK_ARGS = "--prefix ${S}"
>> +TI_BIN_UNPK_CMDS = ""
>> +
>> +BINFILE = "ti_cgt_tms470_${PV}.LTS_linux_installer_x86.bin"
>> +BINFILE_MD5 = "aa65a078eeddbf10e8e132a4cf1d58f0"
>> +BINFILE_SHA256 = "a372fd6f7b2608e11326b5c7438311aa37c7fbca0728b158cb9064a0666a8a05"
>> +
>> +do_install() {
>> + install -d ${D}${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}
>> + cp -r ${S}/ti-cgt-arm*/. ${D}${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}
>> +}
>> +
>> +FILES_${PN} += "${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}"
>> +
>> +BBCLASSEXTEND = "native nativesdk"
>> +
>> +INHIBIT_PACKAGE_STRIP = "1"
>> +INHIBIT_SYSROOT_STRIP = "1"
>> diff --git a/recipes-ti/devtools/ti-cgt-arm.inc b/recipes-ti/devtools/ti-cgt-arm.inc
>> new file mode 100644
>> index 0000000..195d59e
>> --- /dev/null
>> +++ b/recipes-ti/devtools/ti-cgt-arm.inc
>> @@ -0,0 +1,19 @@
>> +DESCRIPTION = "TI ARM Code Generation Tools"
> Use SUMMARY
>
>
>> +HOMEPAGE = "https://www-a.ti.com/downloads/sds_support/TICodegenerationTools/download.htm"
>> +LICENSE = "(TI-TSPA & Thai-Open-Source-Software-Center) & BSD-3-Clause & BSL-1.0 & Hewlett-Packard & AFL-3.0 & MIT & BSD-2-Clause & PD & BSD-4-Clause"
> Is this the correct license?
>
>
>> +LIC_FILES_CHKSUM = "file://../${BINFILE};md5=${BINFILE_MD5}"
> This is very incorrect! Please point to the real license file.
>
>
>> +PV = "16.9.1"
>> +PE = "0"
> Drop this - 0 is the default.
>
>
>> +BINFILE_NAME = "cgt_arm_installer"
>> +
>> +SRC_URI = "http://software-dl.ti.com/codegen/esd/cgt_public_sw/TMS470/${PV}.LTS/${BINFILE};name=${BINFILE_NAME}"
>> +
>> +SRC_URI[cgt_arm_installer.md5sum] = "${BINFILE_MD5}"
>> +SRC_URI[cgt_arm_installer.sha256sum] = "${BINFILE_SHA256}"
>> +
>> +FILES_${PN} += "${S}/*"
> ??? What's this?
>
>
>> +INSANE_SKIP_${PN} += "arch staticdev"
>> --
>> 1.9.1
>>
>> --
>> _______________________________________________
>> meta-ti mailing list
>> meta-ti@yoctoproject.org
>> https://lists.yoctoproject.org/listinfo/meta-ti
^ permalink raw reply [flat|nested] 8+ messages in thread
end of thread, other threads:[~2017-04-21 14:17 UTC | newest]
Thread overview: 8+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2017-04-19 10:30 [morty 1/4] ti-cgt-arm: Include recipes for 16.9.1 Karthik Ramanan
2017-04-19 10:30 ` [morty 2/4] Remove CCS dependencies for all components Karthik Ramanan
2017-04-19 19:45 ` Denys Dmytriyenko
2017-04-19 10:30 ` [morty 3/4] ti-ccsv6: Remove the recipe Karthik Ramanan
2017-04-19 10:30 ` [morty 4/4] ti-cgt-arm: Update to version 16.9.2 Karthik Ramanan
2017-04-19 19:47 ` Denys Dmytriyenko
2017-04-19 19:43 ` [morty 1/4] ti-cgt-arm: Include recipes for 16.9.1 Denys Dmytriyenko
2017-04-21 14:17 ` Karthik Ramanan
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.