[PATCH] sbl-boot-rtos: Added recipe for sbl-boot

[PATCH] sbl-boot-rtos: Added recipe for sbl-boot

[Mahesh Radhakrishnan]

Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
---
 recipes-bsp/sbl-boot/sbl-boot-rtos_git.bb | 116 ++++++++++++++++++++++++++++++
 1 file changed, 116 insertions(+)
 create mode 100644 recipes-bsp/sbl-boot/sbl-boot-rtos_git.bb

diff --git a/recipes-bsp/sbl-boot/sbl-boot-rtos_git.bb b/recipes-bsp/sbl-boot/sbl-boot-rtos_git.bb
new file mode 100644
index 0000000..247cddb
--- /dev/null
+++ b/recipes-bsp/sbl-boot/sbl-boot-rtos_git.bb
@@ -0,0 +1,116 @@
+require recipes-ti/includes/ti-paths.inc
+require recipes-ti/includes/ti-staging.inc
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://src/qspi/sbl_qspi.h;beginline=1;endline=40;md5=db47887841d8a8cd6c41e72dd13b6d20"
+
+COMPATIBLE_MACHINE = "omap-a15|keystone|omapl1"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+SBL_BOOT_GIT_URI = "git://git.ti.com/keystone-rtos/sbl.git"
+SBL_BOOT_GIT_PROTOCOL = "git"
+SBL_BOOT_GIT_BRANCH = "master"
+
+# Below commit ID corresponds to "DEV.SBL.01.00.06.00B"
+SBL_BOOT_SRCREV = "b05f51145fad910c4a830eb8c98afba552b86c9d"
+
+BRANCH = "${SBL_BOOT_GIT_BRANCH}"
+SRC_URI = "${SBL_BOOT_GIT_URI};protocol=${SBL_BOOT_GIT_PROTOCOL};branch=${BRANCH}"
+
+SRCREV = "${SBL_BOOT_SRCREV}"
+PV = "01.00.06.00B"
+PR = "r0"
+
+S = "${WORKDIR}/git"
+
+DEPENDS = " ti-cgt-arm-native \
+            uart-lld-rtos \
+            spi-lld-rtos \
+            i2c-lld-rtos \
+            board-rtos \
+            common-csl-ip-rtos\
+"
+
+DEPENDS_append_omap-a15= " mmcsd-lld-rtos \
+            fatfs-rtos \
+            pm-lld-rtos \
+"
+
+DEPENDS_append_k2g = " mmcsd-lld-rtos \
+            fatfs-rtos \
+"
+
+DEPENDS_append_k2g-hs-evm = " \
+            secdev \
+"
+
+DEPENDS_append_omapl1= " mmcsd-lld-rtos \
+            fatfs-rtos \
+"
+
+CLEANBROKEN = "1"
+
+PARTNO = ""
+PARTNO_am57xx-evm = "am57xx"
+PARTNO_k2g = "k2g"
+PARTNO_k2hk-evm = "k2hk"
+PARTNO_k2e-evm = "k2e"
+PARTNO_k2l-evm = "k2l"
+PARTNO_omapl137-evm = "omapl137"
+
+export TOOLCHAIN_PATH_A15 = "${GCC_ARM_NONE_TOOLCHAIN}"
+export TOOLCHAIN_PATH_M4 = "${M4_TOOLCHAIN_INSTALL_DIR}"
+export TOOLCHAIN_PATH_ARM9 = "${M4_TOOLCHAIN_INSTALL_DIR}"
+export C6X_GEN_INSTALL_PATH="${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
+export CROSS_TOOL_PRFX = "arm-none-eabi-"
+export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
+LDFLAGS = ""
+CFLAGS = ""
+
+export SBL_SRC_DIR = "${S}"
+export SPI_WRTR_SRC_DIR = "${S}"
+export QSPI_WRTR_SRC_DIR = "${S}"
+
+# Environment variables for K2G HS
+export SECBIN = "${SECDEV_INSTALL_DIR}/scripts/secimagecreate.sh"
+export KEYPATH = "${SECDEV_INSTALL_DIR}/sec/ks2keys/dev"
+export BM_DIR = "${SECDEV_INSTALL_DIR}/boot-monitor"
+export SK_DIR = "${SECDEV_INSTALL_DIR}/ram_secure_kernel"
+
+do_compile() {
+    cd build
+    ./sbl_${PARTNO}.sh
+}
+
+do_compile_k2g-hs-evm() {
+    make clean BOARD=evmK2G
+    make flashwriter_clean BOARD=evmK2G
+    make clean BOARD=iceK2G
+    make flashwriter_clean BOARD=iceK2G
+    make all BOARD=evmK2G SOC=K2G BOOTMODE=mmcsd SECUREMODE=yes
+    make all BOARD=evmK2G SOC=K2G BOOTMODE=qspi  SECUREMODE=yes
+    make flashwriter BOARD=evmK2G SOC=K2G SECUREMODE=yes
+    make all BOARD=iceK2G SOC=K2G BOOTMODE=mmcsd
+    make all BOARD=iceK2G SOC=K2G BOOTMODE=qspi
+    make flashwriter BOARD=iceK2G SOC=K2G
+    rm -rf binary/evmK2G/mmcsd/obj/
+    rm -rf binary/evmK2G/qspi/obj/
+    rm -rf binary/iceK2G/mmcsd/obj/
+    rm -rf binary/iceK2G/qspi/obj/
+    tar -cf sbl.tar --exclude='*.tar' --exclude='*.git*' ./*
+}
+
+do_compile_omapl138-lcdk() {
+    cd build
+    ./sbl_omapl138.sh
+    ./sbl_c6748.sh
+}
+
+do_install() {
+  install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/sbl
+  find -name "*.tar" -exec tar xf {} --no-same-owner -C ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/sbl \;
+}
+
+FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
+
+INSANE_SKIP_${PN} = "arch"
-- 
1.9.1