* [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld
@ 2017-08-30 22:42 Mahesh Radhakrishnan
2017-08-30 22:42 ` [PATCH v3 2/7] transport-rtos: Added transport recipes(bmet, nimu, nimu-icss) for rtos Mahesh Radhakrishnan
` (7 more replies)
0 siblings, 8 replies; 13+ messages in thread
From: Mahesh Radhakrishnan @ 2017-08-30 22:42 UTC (permalink / raw)
To: meta-ti
Upstreaming TI RTOS low level driver for Power Management module (PM)
Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
---
v3 - Removed the intermediate tar-untar for install
v2 - Added summary & merged in to a single recipe
recipes-bsp/pm-lld/pm-lld-rtos_git.bb | 89 +++++++++++++++++++++++++++++++++++
1 file changed, 89 insertions(+)
create mode 100644 recipes-bsp/pm-lld/pm-lld-rtos_git.bb
diff --git a/recipes-bsp/pm-lld/pm-lld-rtos_git.bb b/recipes-bsp/pm-lld/pm-lld-rtos_git.bb
new file mode 100644
index 0000000..72166b0
--- /dev/null
+++ b/recipes-bsp/pm-lld/pm-lld-rtos_git.bb
@@ -0,0 +1,89 @@
+SUMMARY = "TI RTOS driver for Power Management module (PM)"
+
+require recipes-ti/includes/ti-paths.inc
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://Power.h;beginline=1;endline=31;md5=527b91fdcd26cd19ac07a754f45dedbe"
+
+COMPATIBLE_MACHINE = "ti33x|ti43x|omap-a15|k2g"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+
+PM_LLD_GIT_URI = "git://git.ti.com/keystone-rtos/pm-lld.git"
+PM_LLD_GIT_PROTOCOL = "git"
+PM_LLD_GIT_BRANCH = "int_pm_am335x"
+PM_LLD_GIT_BRANCH_dra7xx-evm = "master"
+PM_LLD_GIT_DESTSUFFIX = "git/ti/drv/pm"
+
+# Below commit ID corresponds to "DEV.PM_LLD.01.04.00.01"
+PM_LLD_SRCREV = "c4908f94b3e655e6298aa9bfe9bbffbbc5d16111"
+
+# Below commit ID corresponds to "REL.PDK.TDA.01.07.00.06"
+PM_LLD_SRCREV_dra7xx-evm = "46ea13503d2991f636197edb206a9f62cea398d4"
+
+BRANCH = "${PM_LLD_GIT_BRANCH}"
+SRC_URI = "${PM_LLD_GIT_URI};destsuffix=${PM_LLD_GIT_DESTSUFFIX};protocol=${PM_LLD_GIT_PROTOCOL};branch=${BRANCH}"
+
+SRCREV = "${PM_LLD_SRCREV}"
+PV = "01.04.00.01"
+PR = "r0"
+
+S = "${WORKDIR}/${PM_LLD_GIT_DESTSUFFIX}"
+
+DEPENDS = " ti-sysbios \
+ gcc-arm-none-eabi-native \
+ osal-rtos \
+ ca-certificates-native \
+"
+DEPENDS_append_omap-a15 = " ti-cgt-arm-native \
+ ti-cgt6x-native \
+ common-csl-ip-rtos \
+"
+DEPENDS_append_ti33x = " starterware-rtos \
+"
+DEPENDS_append_ti43x = " starterware-rtos \
+"
+DEPENDS_append_k2g = " common-csl-ip-rtos \
+ ti-cgt6x-native \
+"
+
+# Fetch task cannot be completed until after ca-certificates-native populates sysroot with the SSL certificates
+do_fetch[depends] = "ca-certificates-native:do_populate_sysroot"
+
+export TOOLCHAIN_PATH_A15 = "${GCC_ARM_NONE_TOOLCHAIN}"
+export TOOLCHAIN_PATH_A8 = "${GCC_ARM_NONE_TOOLCHAIN}"
+export TOOLCHAIN_PATH_A9 = "${GCC_ARM_NONE_TOOLCHAIN}"
+export FPULIB_PATH = "${GCC_ARM_NONE_TOOLCHAIN}/lib/gcc/arm-none-eabi/4.9.3/fpu/"
+export TOOLCHAIN_PATH_M4 = "${M4_TOOLCHAIN_INSTALL_DIR}"
+export C6X_GEN_INSTALL_PATH = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
+export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
+export BIOS_INSTALL_PATH = "${SYSBIOS_INSTALL_DIR}"
+export XDC_INSTALL_PATH = "${XDC_INSTALL_DIR}"
+
+export PDK_PM_ROOT_PATH = "${WORKDIR}/git"
+
+# Used by DEST_ROOT to redirect binary and obj files away from sysroot PDK tree
+OBJ_DIR = "${WORKDIR}/git/ti/binary"
+
+do_compile() {
+ make clean lib xdc_meta doxygen LIMIT_SOCS="${TI_PDK_LIMIT_SOCS}" LIMIT_BOARDS="${TI_PDK_LIMIT_BOARDS}" DEST_ROOT=${OBJ_DIR}
+
+ # Remove unnecessary files from packaging
+ rm -rf patches/
+
+ # Cleanup docs
+ rm -rf docs/ReleaseNotes_PM_LLD.doc
+ rm -rf internal/
+
+ # Clean up .tar files from the package
+ find -name "*.tar" -exec rm -f {} \;
+}
+
+do_install() {
+ install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/drv/pm
+ cp -r ${S}/* ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/drv/pm
+}
+
+FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
+
+INSANE_SKIP_${PN} = "arch staticdev"
--
1.9.1
^ permalink raw reply related [flat|nested] 13+ messages in thread
* [PATCH v3 2/7] transport-rtos: Added transport recipes(bmet, nimu, nimu-icss) for rtos
2017-08-30 22:42 [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld Mahesh Radhakrishnan
@ 2017-08-30 22:42 ` Mahesh Radhakrishnan
2017-08-30 22:42 ` [PATCH v3 3/7] vps-lld-rtos: Added rtos recipe for vps-lld Mahesh Radhakrishnan
` (6 subsequent siblings)
7 siblings, 0 replies; 13+ messages in thread
From: Mahesh Radhakrishnan @ 2017-08-30 22:42 UTC (permalink / raw)
To: meta-ti
Upstreaming RTOS driver for Network Interface Management Unit
(NIMU),BMET Ethernet and NIMU ICSS
Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
---
v3 - Removed the redundant DEPENDS for dra7xx-evm
v2 - Added summary
recipes-bsp/transport-rtos/bmet-eth-rtos_git.bb | 21 +++++++++++++++
recipes-bsp/transport-rtos/nimu-icss-rtos_git.bb | 28 ++++++++++++++++++++
recipes-bsp/transport-rtos/nimu-rtos_git.bb | 33 ++++++++++++++++++++++++
recipes-bsp/transport-rtos/transport.inc | 17 ++++++++++++
4 files changed, 99 insertions(+)
create mode 100644 recipes-bsp/transport-rtos/bmet-eth-rtos_git.bb
create mode 100644 recipes-bsp/transport-rtos/nimu-icss-rtos_git.bb
create mode 100644 recipes-bsp/transport-rtos/nimu-rtos_git.bb
create mode 100644 recipes-bsp/transport-rtos/transport.inc
diff --git a/recipes-bsp/transport-rtos/bmet-eth-rtos_git.bb b/recipes-bsp/transport-rtos/bmet-eth-rtos_git.bb
new file mode 100644
index 0000000..775ef3d
--- /dev/null
+++ b/recipes-bsp/transport-rtos/bmet-eth-rtos_git.bb
@@ -0,0 +1,21 @@
+SUMMARY = "RTOS driver for BMET Ethernet"
+
+inherit ti-pdk
+require transport.inc
+
+PR = "${INC_PR}.0"
+
+LIC_FILES_CHKSUM = "file://bmet_transport.h;beginline=12;endline=40;md5=7c7fbe6af03d79b61025a67a8fc96f93"
+
+COMPATIBLE_MACHINE = "k2hk-evm|k2e-evm|k2l-evm"
+
+DEPENDS_append = " qmss-lld-rtos \
+ cppi-lld-rtos \
+"
+
+BMET_ETH_DESTSUFFIX = "git/bmet_eth"
+
+S = "${WORKDIR}/${BMET_ETH_DESTSUFFIX}"
+
+# HTML doc link params
+PDK_COMP_LINK_TEXT = "Baremetal Ethernet Transport"
diff --git a/recipes-bsp/transport-rtos/nimu-icss-rtos_git.bb b/recipes-bsp/transport-rtos/nimu-icss-rtos_git.bb
new file mode 100644
index 0000000..3ca196d
--- /dev/null
+++ b/recipes-bsp/transport-rtos/nimu-icss-rtos_git.bb
@@ -0,0 +1,28 @@
+SUMMARY = "RTOS driver for NIMU ICSS"
+
+inherit ti-pdk
+require transport.inc
+
+PR = "${INC_PR}.0"
+
+LIC_FILES_CHKSUM = "file://nimu_icssEth.h;beginline=1;endline=35;md5=fd897e67955a19ba88443d4bc2e7e18a"
+
+COMPATIBLE_MACHINE = "ti33x|ti43x|omap-a15|k2g|c66x|omapl1"
+
+DEPENDS_append = " ti-ndk \
+ pruss-lld-rtos \
+ icss-emac-lld-rtos \
+"
+
+NIMU_ICSS_DESTSUFFIX = "git/ndk/nimu_icss"
+
+# Build with make instead of XDC
+TI_PDK_XDCMAKE = "0"
+
+S = "${WORKDIR}/${NIMU_ICSS_DESTSUFFIX}"
+
+export PDK_NIMU_ICSS_ROOT_PATH ="${WORKDIR}/build"
+export DEST_ROOT="${S}"
+
+export NDK_INSTALL_PATH = "${NDK_INSTALL_DIR}"
+XDCPATH_append = ";${NDK_INSTALL_DIR}/packages"
diff --git a/recipes-bsp/transport-rtos/nimu-rtos_git.bb b/recipes-bsp/transport-rtos/nimu-rtos_git.bb
new file mode 100644
index 0000000..5366da7
--- /dev/null
+++ b/recipes-bsp/transport-rtos/nimu-rtos_git.bb
@@ -0,0 +1,33 @@
+SUMMARY = "RTOS driver for Network Interface Management Unit (NIMU)"
+
+inherit ti-pdk
+require transport.inc
+
+PR = "${INC_PR}.0"
+
+LIC_FILES_CHKSUM = "file://nimu_eth.h;beginline=1;endline=35;md5=52ba99291b03b91058e37115b66edb10"
+
+COMPATIBLE_MACHINE = "ti33x|ti43x|omap-a15|keystone|c66x|omapl1"
+
+NIMU_DESTSUFFIX = "git/ndk/nimu"
+
+S = "${WORKDIR}/${NIMU_DESTSUFFIX}"
+
+DEPENDS_append = " ti-ndk osal-rtos"
+DEPENDS_append_ti33x = " starterware-rtos emac-lld-rtos"
+DEPENDS_append_ti43x = " starterware-rtos emac-lld-rtos"
+DEPENDS_append_omap-a15 = " emac-lld-rtos"
+DEPENDS_append_keystone = " qmss-lld-rtos cppi-lld-rtos"
+DEPENDS_append_k2hk-evm = " pa-lld-rtos"
+DEPENDS_append_k2e-evm = " pa-lld-rtos"
+DEPENDS_append_k2l-evm = " pa-lld-rtos"
+DEPENDS_append_k2g = " emac-lld-rtos"
+
+# Build with make instead of XDC
+TI_PDK_XDCMAKE = "0"
+
+export PDK_NIMU_ROOT_PATH ="${WORKDIR}/build"
+export DEST_ROOT="${S}"
+
+export NDK_INSTALL_PATH = "${NDK_INSTALL_DIR}"
+XDCPATH_append = ";${NDK_INSTALL_DIR}/packages"
diff --git a/recipes-bsp/transport-rtos/transport.inc b/recipes-bsp/transport-rtos/transport.inc
new file mode 100644
index 0000000..82427fb
--- /dev/null
+++ b/recipes-bsp/transport-rtos/transport.inc
@@ -0,0 +1,17 @@
+LICENSE = "BSD-3-Clause"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+TRANSPORT_GIT_URI = "git://git.ti.com/keystone-rtos/transport.git"
+TRANSPORT_GIT_PROTOCOL = "git"
+TRANSPORT_GIT_BRANCH = "master"
+
+# Below commit ID corresponds to "DEV.TRANSPORT.01.00.00.07A"
+TRANSPORT_SRCREV = "099dbf371cea3b2d883f5c97a4b0e7ef40e84c6a"
+
+BRANCH = "${TRANSPORT_GIT_BRANCH}"
+SRC_URI = "${TRANSPORT_GIT_URI};protocol=${TRANSPORT_GIT_PROTOCOL};branch=${BRANCH}"
+
+SRCREV = "${TRANSPORT_SRCREV}"
+PV = "01.00.00.07A"
+INC_PR = "r0"
--
1.9.1
^ permalink raw reply related [flat|nested] 13+ messages in thread
* [PATCH v3 3/7] vps-lld-rtos: Added rtos recipe for vps-lld
2017-08-30 22:42 [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld Mahesh Radhakrishnan
2017-08-30 22:42 ` [PATCH v3 2/7] transport-rtos: Added transport recipes(bmet, nimu, nimu-icss) for rtos Mahesh Radhakrishnan
@ 2017-08-30 22:42 ` Mahesh Radhakrishnan
2017-08-30 22:42 ` [PATCH v3 4/7] cmb-addon-rtos: Adding CMB rtos recipe Mahesh Radhakrishnan
` (5 subsequent siblings)
7 siblings, 0 replies; 13+ messages in thread
From: Mahesh Radhakrishnan @ 2017-08-30 22:42 UTC (permalink / raw)
To: meta-ti
Upstreaming RTOS low level driver for Video processing subsystem.
Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
---
v3 - Removed intermediate tar-untar for do-install
v2 - Added summary
recipes-bsp/vps-lld/vps-lld-rtos_git.bb | 93 +++++++++++++++++++++++++++++++++
1 file changed, 93 insertions(+)
create mode 100644 recipes-bsp/vps-lld/vps-lld-rtos_git.bb
diff --git a/recipes-bsp/vps-lld/vps-lld-rtos_git.bb b/recipes-bsp/vps-lld/vps-lld-rtos_git.bb
new file mode 100644
index 0000000..3a968dd
--- /dev/null
+++ b/recipes-bsp/vps-lld/vps-lld-rtos_git.bb
@@ -0,0 +1,93 @@
+SUMMARY = "TI RTOS Low level driver for Video Processing Subsystem (VPS) "
+
+require recipes-ti/includes/ti-paths.inc
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://COPYING.txt;beginline=1;endline=32;md5=4303d306ea53eb66132983d6901c137d"
+
+COMPATIBLE_MACHINE = "omap-a15"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+VPS_LLD_GIT_URI = "git://git.ti.com/keystone-rtos/vps.git"
+VPS_LLD_GIT_PROTOCOL = "git"
+VPS_LLD_GIT_BRANCH = "master"
+VPS_LLD_GIT_DESTSUFFIX = "git"
+VPS_PACKAGE_BASE = "${S}/../vps_base"
+VPS_LLD_ROOTPATH = "${VPS_PACKAGE_BASE}/package/all/pdk_/packages/ti/drv/vps"
+
+# Below commit ID corresponds to "DEV.VPS_LLD.01.00.01.06B"
+VPS_LLD_SRCREV = "58729317b65bdb24d4343cbb1f7f6cb90ca2faf0"
+
+BRANCH = "${VPS_LLD_GIT_BRANCH}"
+SRC_URI = "${VPS_LLD_GIT_URI};destsuffix=${VPS_LLD_GIT_DESTSUFFIX};protocol=${VPS_LLD_GIT_PROTOCOL};branch=${BRANCH}"
+
+SRCREV = "${VPS_LLD_SRCREV}"
+PV = "01.00.01.06B"
+PR = "r0"
+
+S = "${WORKDIR}/${VPS_LLD_GIT_DESTSUFFIX}"
+
+DEPENDS = " ti-cgt6x-native \
+ ti-cgt-arm-native \
+ ti-sysbios \
+ common-csl-ip-rtos \
+ gcc-arm-none-eabi-native \
+ osal-rtos \
+ ca-certificates-native \
+ edma3-lld-rtos \
+ board-rtos \
+ uart-lld-rtos \
+ i2c-lld-rtos \
+ pm-lld-rtos \
+"
+
+# Fetch task cannot be completed until after ca-certificates-native populates sysroot with the SSL certificates
+do_fetch[depends] = "ca-certificates-native:do_populate_sysroot"
+
+export TOOLCHAIN_PATH_A15 = "${GCC_ARM_NONE_TOOLCHAIN}"
+export FPULIB_PATH = "${GCC_ARM_NONE_TOOLCHAIN}/lib/gcc/arm-none-eabi/4.9.3/fpu/"
+export TOOLCHAIN_PATH_M4 = "${M4_TOOLCHAIN_INSTALL_DIR}"
+export C6X_GEN_INSTALL_PATH = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
+export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
+export BIOS_INSTALL_PATH = "${SYSBIOS_INSTALL_DIR}"
+export XDC_INSTALL_PATH = "${XDC_INSTALL_DIR}"
+export EDMA3LLD_BIOS6_INSTALLDIR = "${EDMA3_LLD_INSTALL_DIR}"
+
+export PDK_VPS_ROOT_PATH = "${VPS_PACKAGE_BASE}/package/all/pdk_/packages"
+
+BOARD_PACKAGE = ""
+BOARD_PACKAGE_am57xx-evm = "evmAM572x"
+BOARD_PACKAGE_dra7xx-evm = "evmDRA75x"
+
+
+do_configure() {
+ rm -rf ${VPS_PACKAGE_BASE}
+ cd ${S}
+
+ # remove any previous package
+ rm -f ${VPS_PACKAGE_BASE}
+
+ # make the release package before building it
+ make package BOARD=${BOARD_PACKAGE} DEST_ROOT=${VPS_PACKAGE_BASE} PDK_VPS_COMP_PATH=${S}
+}
+
+do_compile() {
+ echo "vps lld root path is ${VPS_LLD_ROOTPATH}"
+ cd ${VPS_LLD_ROOTPATH}
+
+ # Build libraries
+ make clean lib xdc_meta doxygen LIMIT_SOCS="${TI_PDK_LIMIT_SOCS}" LIMIT_BOARDS="${TI_PDK_LIMIT_BOARDS}"
+
+ # Clean up .tar files from the package
+ find -name "*.tar" -exec rm -f {} \;
+}
+
+do_install() {
+ cd ${VPS_LLD_ROOTPATH}
+ install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/drv/vps
+ cp -r ./* ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/drv/vps
+}
+
+FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
+
+INSANE_SKIP_${PN} = "arch ldflags"
--
1.9.1
^ permalink raw reply related [flat|nested] 13+ messages in thread
* [PATCH v3 4/7] cmb-addon-rtos: Adding CMB rtos recipe
2017-08-30 22:42 [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld Mahesh Radhakrishnan
2017-08-30 22:42 ` [PATCH v3 2/7] transport-rtos: Added transport recipes(bmet, nimu, nimu-icss) for rtos Mahesh Radhakrishnan
2017-08-30 22:42 ` [PATCH v3 3/7] vps-lld-rtos: Added rtos recipe for vps-lld Mahesh Radhakrishnan
@ 2017-08-30 22:42 ` Mahesh Radhakrishnan
2017-08-31 13:27 ` [EXTERNAL] " Jacob Stiffler
2017-08-30 22:42 ` [PATCH v3 5/7] ti-ndk: Adding recipe for ti-ndk Mahesh Radhakrishnan
` (4 subsequent siblings)
7 siblings, 1 reply; 13+ messages in thread
From: Mahesh Radhakrishnan @ 2017-08-30 22:42 UTC (permalink / raw)
To: meta-ti
Upstreaming the recipe for Circular Microphone array board (CMB) RTOS
software
Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
---
v3 - Removed redundant code in do_compile & do_install
v2 - Added summary
recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb | 56 +++++++++++++++++++++++++++++
1 file changed, 56 insertions(+)
create mode 100644 recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb
diff --git a/recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb b/recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb
new file mode 100644
index 0000000..66d961b
--- /dev/null
+++ b/recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb
@@ -0,0 +1,56 @@
+SUMMARY = "TI RTOS software supporting circular microphone array board"
+require recipes-ti/includes/ti-paths.inc
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://cmbaddonver.h;beginline=8;endline=47;md5=d0cb159bf210cfafed63042da01c83e0"
+
+COMPATIBLE_MACHINE = "k2g|omapl137-evm"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+CMB_ADDON_GIT_URI = "git://git.ti.com/processor-sdk/circmicarray-addon.git"
+CMB_ADDON_GIT_PROTOCOL = "git"
+CMB_ADDON_GIT_BRANCH = "master"
+CMB_ADDON_GIT_DESTSUFFIX = "git/ti/addon"
+
+# Below commit ID corresponds to "DEV.CMB.01.01.00.00"
+CMB_ADDON_SRCREV = "29c05572b82251bac73cd685afcffdb8549eaaaf"
+
+SRCREV = "${CMB_ADDON_SRCREV}"
+PV = "01.01.00.00"
+PR = "r0"
+
+BRANCH = "${CMB_ADDON_GIT_BRANCH}"
+SRC_URI = "${CMB_ADDON_GIT_URI};destsuffix=${CMB_ADDON_GIT_DESTSUFFIX};protocol=${CMB_ADDON_GIT_PROTOCOL};branch=${BRANCH}"
+
+
+S = "${WORKDIR}/git/ti/addon/cmb"
+
+DEPENDS = " ti-cgt6x-native \
+ ti-sysbios \
+ ti-xdctools \
+ ti-pdk-build-rtos \
+ common-csl-ip-rtos \
+ gpio-lld-rtos \
+ i2c-lld-rtos \
+ mcasp-lld-rtos \
+ board-rtos \
+"
+
+export C6X_GEN_INSTALL_PATH = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
+export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
+export BIOS_INSTALL_PATH = "${SYSBIOS_INSTALL_DIR}"
+export XDC_INSTALL_PATH = "${XDC_INSTALL_DIR}"
+export XDCPATH = "${XDC_INSTALL_DIR}/packages;${SYSBIOS_INSTALL_DIR}/packages;${PDK_INSTALL_DIR}/packages"
+export PDK_CMB_ROOT_PATH = "${WORKDIR}/git"
+
+do_compile() {
+ make release LIMIT_SOCS="${TI_PDK_LIMIT_SOCS}" LIMIT_BOARDS="${TI_PDK_LIMIT_BOARDS}"
+}
+
+do_install() {
+ install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/addon/cmb
+ find -name "*.tar" -exec tar xf {} -C ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ \;
+}
+
+FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
--
1.9.1
^ permalink raw reply related [flat|nested] 13+ messages in thread
* [PATCH v3 5/7] ti-ndk: Adding recipe for ti-ndk
2017-08-30 22:42 [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld Mahesh Radhakrishnan
` (2 preceding siblings ...)
2017-08-30 22:42 ` [PATCH v3 4/7] cmb-addon-rtos: Adding CMB rtos recipe Mahesh Radhakrishnan
@ 2017-08-30 22:42 ` Mahesh Radhakrishnan
2017-08-31 13:28 ` [EXTERNAL] " Jacob Stiffler
2017-08-30 22:42 ` [PATCH v3 6/7] pruss-lld: Add rtos recipe & update the version to 1.0.0.7 Mahesh Radhakrishnan
` (3 subsequent siblings)
7 siblings, 1 reply; 13+ messages in thread
From: Mahesh Radhakrishnan @ 2017-08-30 22:42 UTC (permalink / raw)
To: meta-ti
Upstreaming recipe for TI RTOS Networking development kit
Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
---
v3 - Removed references to srcipk
v2 - Added summmary & merged in to a single recipe
recipes-ti/ndk/ti-ndk.inc | 21 +++++++++++++++++++++
recipes-ti/ndk/ti-ndk_2.25.01.11.bb | 13 +++++++++++++
2 files changed, 34 insertions(+)
create mode 100644 recipes-ti/ndk/ti-ndk.inc
create mode 100644 recipes-ti/ndk/ti-ndk_2.25.01.11.bb
diff --git a/recipes-ti/ndk/ti-ndk.inc b/recipes-ti/ndk/ti-ndk.inc
new file mode 100644
index 0000000..09d9ea0
--- /dev/null
+++ b/recipes-ti/ndk/ti-ndk.inc
@@ -0,0 +1,21 @@
+SUMMARY = "TI RTOS_Networking"
+HOMEPAGE = "http://software-dl.ti.com/dsps/dsps_public_sw/sdo_sb/targetcontent/ndk/index.html"
+SECTION = "devel"
+LICENSE = "BSD"
+
+require recipes-ti/includes/ti-paths.inc
+
+S = "${WORKDIR}/ndk_${PV}"
+
+SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/sdo_sb/targetcontent/ndk/${PV}/exports/ndk_${PV}.zip;name=ndkzip"
+
+do_install() {
+ CP_ARGS="-Prf --preserve=mode,timestamps --no-preserve=ownership"
+ install -d ${D}${NDK_INSTALL_DIR_RECIPE}
+ cp ${CP_ARGS} ${S}/* ${D}${NDK_INSTALL_DIR_RECIPE}
+}
+
+ALLOW_EMPTY_${PN} = "1"
+FILES_${PN}-dev += "${NDK_INSTALL_DIR_RECIPE}"
+
+INSANE_SKIP_${PN}-dev = "arch ldflags staticdev"
diff --git a/recipes-ti/ndk/ti-ndk_2.25.01.11.bb b/recipes-ti/ndk/ti-ndk_2.25.01.11.bb
new file mode 100644
index 0000000..d5d926b
--- /dev/null
+++ b/recipes-ti/ndk/ti-ndk_2.25.01.11.bb
@@ -0,0 +1,13 @@
+require ti-ndk.inc
+
+PV = "2_25_01_11"
+PR = "r0"
+
+LIC_FILES_CHKSUM = "file://ndk_${PV}_manifest.html;md5=80a8d9b76cf700929d3f5b6df09052d6"
+
+SRC_URI[ndkzip.md5sum] = "e42bfcc8c3a6d183d60f26ec01ccc79b"
+SRC_URI[ndkzip.sha256sum] = "a15bc9b570dc0628dd8b8c3665037a162610a6f86c5f17ebb6a329d3db60f071"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INHIBIT_SYSROOT_STRIP = "1"
--
1.9.1
^ permalink raw reply related [flat|nested] 13+ messages in thread
* [PATCH v3 6/7] pruss-lld: Add rtos recipe & update the version to 1.0.0.7
2017-08-30 22:42 [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld Mahesh Radhakrishnan
` (3 preceding siblings ...)
2017-08-30 22:42 ` [PATCH v3 5/7] ti-ndk: Adding recipe for ti-ndk Mahesh Radhakrishnan
@ 2017-08-30 22:42 ` Mahesh Radhakrishnan
2017-08-30 22:42 ` [PATCH v3 7/7] audk2g-addon-rtos: Adding rtos recipe for audio addons for k2g Mahesh Radhakrishnan
` (2 subsequent siblings)
7 siblings, 0 replies; 13+ messages in thread
From: Mahesh Radhakrishnan @ 2017-08-30 22:42 UTC (permalink / raw)
To: meta-ti
Upstreaming the RTOS low level driver of the PRUSS module & updating to
the latest version
Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
---
v3 - Added k2g SOC family in place of k2g-evm & k2g-hs-evm
v2 - Added summary
recipes-bsp/pruss-lld/pruss-lld-rtos_git.bb | 23 +++++++++++++++++++++++
recipes-bsp/pruss-lld/pruss-lld.inc | 8 ++++----
2 files changed, 27 insertions(+), 4 deletions(-)
create mode 100644 recipes-bsp/pruss-lld/pruss-lld-rtos_git.bb
diff --git a/recipes-bsp/pruss-lld/pruss-lld-rtos_git.bb b/recipes-bsp/pruss-lld/pruss-lld-rtos_git.bb
new file mode 100644
index 0000000..5068286
--- /dev/null
+++ b/recipes-bsp/pruss-lld/pruss-lld-rtos_git.bb
@@ -0,0 +1,23 @@
+SUMMARY = "TI RTOS low level driver library for PRUSS"
+
+inherit ti-pdk
+require recipes-bsp/pruss-lld/pruss-lld.inc
+
+PR = "${INC_PR}.0"
+
+S = "${WORKDIR}/${PRUSS_LLD_GIT_DESTSUFFIX}"
+
+DEPENDS_append = " osal-rtos"
+DEPENDS_append_ti33x = " starterware-rtos"
+DEPENDS_append_ti43x = " starterware-rtos"
+
+# Build with make instead of XDC
+TI_PDK_XDCMAKE = "0"
+
+export PDK_PRUSS_ROOT_PATH ="${WORKDIR}/build"
+export DEST_ROOT="${WORKDIR}/build"
+
+# HTML doc link params
+PDK_COMP_LINK_TEXT = "PRUSS LLD"
+
+INSANE_SKIP_${PN} = "arch"
diff --git a/recipes-bsp/pruss-lld/pruss-lld.inc b/recipes-bsp/pruss-lld/pruss-lld.inc
index 8620108..44d84b8 100644
--- a/recipes-bsp/pruss-lld/pruss-lld.inc
+++ b/recipes-bsp/pruss-lld/pruss-lld.inc
@@ -1,7 +1,7 @@
LICENSE = "BSD-3-Clause"
LIC_FILES_CHKSUM = "file://pruicss.h;beginline=1;endline=31;md5=315177aa03d58bcd124a6e799e2bd458"
-COMPATIBLE_MACHINE = "ti33x|ti43x|am57xx-evm|k2g-evm"
+COMPATIBLE_MACHINE = "ti33x|ti43x|am57xx-evm|k2g"
PACKAGE_ARCH = "${MACHINE_ARCH}"
PRUSS_LLD_GIT_URI = "git://git.ti.com/keystone-rtos/pruss-lld.git"
@@ -9,12 +9,12 @@ PRUSS_LLD_GIT_PROTOCOL = "git"
PRUSS_LLD_GIT_BRANCH = "master"
PRUSS_LLD_GIT_DESTSUFFIX = "git/ti/drv/pruss"
-# Below commit ID corresponds to "DEV.PRUSS_LLD.01.00.00.06A"
-PRUSS_LLD_SRCREV = "b98729cc1fc26c9ac32846146892646a23c28adb"
+# Below commit ID corresponds to "DEV.PRUSS_LLD.01.00.00.07"
+PRUSS_LLD_SRCREV = "636bb5645014723c54c08245cf8c2ee401eceb4f"
BRANCH = "${PRUSS_LLD_GIT_BRANCH}"
SRC_URI = "${PRUSS_LLD_GIT_URI};destsuffix=${PRUSS_LLD_GIT_DESTSUFFIX};protocol=${PRUSS_LLD_GIT_PROTOCOL};branch=${BRANCH}"
SRCREV = "${PRUSS_LLD_SRCREV}"
-PV = "01.00.00.06A"
+PV = "01.00.00.07"
INC_PR = "r0"
--
1.9.1
^ permalink raw reply related [flat|nested] 13+ messages in thread
* [PATCH v3 7/7] audk2g-addon-rtos: Adding rtos recipe for audio addons for k2g
2017-08-30 22:42 [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld Mahesh Radhakrishnan
` (4 preceding siblings ...)
2017-08-30 22:42 ` [PATCH v3 6/7] pruss-lld: Add rtos recipe & update the version to 1.0.0.7 Mahesh Radhakrishnan
@ 2017-08-30 22:42 ` Mahesh Radhakrishnan
2017-08-31 13:30 ` [EXTERNAL] " Jacob Stiffler
2017-08-31 13:23 ` [EXTERNAL] [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld Jacob Stiffler
2017-08-31 16:30 ` Denys Dmytriyenko
7 siblings, 1 reply; 13+ messages in thread
From: Mahesh Radhakrishnan @ 2017-08-30 22:42 UTC (permalink / raw)
To: meta-ti
Upstreaming RTOS audio addon software for K2G
Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
---
v3 - Removed redundant code in do-compile & do-install
v2 - Added summary
recipes-bsp/audk2g-addon/audk2g-addon-rtos_git.bb | 56 +++++++++++++++++++++++
1 file changed, 56 insertions(+)
create mode 100644 recipes-bsp/audk2g-addon/audk2g-addon-rtos_git.bb
diff --git a/recipes-bsp/audk2g-addon/audk2g-addon-rtos_git.bb b/recipes-bsp/audk2g-addon/audk2g-addon-rtos_git.bb
new file mode 100644
index 0000000..9e233e2
--- /dev/null
+++ b/recipes-bsp/audk2g-addon/audk2g-addon-rtos_git.bb
@@ -0,0 +1,56 @@
+SUMMARY = "TI RTOS Audio add-on software for k2g"
+
+require recipes-ti/includes/ti-paths.inc
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://audk2gaddonver.h;beginline=8;endline=47;md5=7a3996aaf1a3d3ca87358cf9b89bce3d"
+
+COMPATIBLE_MACHINE = "k2g"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+AUDK2G_ADDON_GIT_URI = "git://git.ti.com/processor-sdk/audk2g-addon.git"
+AUDK2G_ADDON_GIT_PROTOCOL = "git"
+AUDK2G_ADDON_GIT_BRANCH = "master"
+AUDK2G_ADDON_GIT_DESTSUFFIX = "git/ti/addon/audk2g"
+
+# Below commit ID corresponds to "DEV.AUDK2G.01.04.00.00"
+AUDK2G_ADDON_SRCREV = "815180b45ceb1fa3c110f9979106c7f5aa8b3ca2"
+
+BRANCH = "${AUDK2G_ADDON_GIT_BRANCH}"
+SRC_URI = "${AUDK2G_ADDON_GIT_URI};destsuffix=${AUDK2G_ADDON_GIT_DESTSUFFIX};protocol=${AUDK2G_ADDON_GIT_PROTOCOL};branch=${BRANCH}"
+
+SRCREV = "${AUDK2G_ADDON_SRCREV}"
+PV = "01.04.00.00"
+PR = "r0"
+
+S = "${WORKDIR}/git/ti/addon/audk2g"
+
+DEPENDS = " ti-cgt6x-native \
+ ti-sysbios \
+ ti-xdctools \
+ ti-pdk-build-rtos \
+ common-csl-ip-rtos \
+ gpio-lld-rtos \
+ i2c-lld-rtos \
+ board-rtos \
+"
+
+export C6X_GEN_INSTALL_PATH = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
+export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
+export BIOS_INSTALL_PATH = "${SYSBIOS_INSTALL_DIR}"
+export XDC_INSTALL_PATH = "${XDC_INSTALL_DIR}"
+
+export XDCPATH = "${XDC_INSTALL_DIR}/packages;${SYSBIOS_INSTALL_DIR}/packages;${PDK_INSTALL_DIR}/packages"
+
+export PDK_AUDK2G_ROOT_PATH = "${WORKDIR}/git"
+
+do_compile() {
+ make release LIMIT_SOCS="${TI_PDK_LIMIT_SOCS}" LIMIT_BOARDS="${TI_PDK_LIMIT_BOARDS}"
+}
+
+do_install() {
+ install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/addon/audk2g
+ find -name "*.tar" -exec tar xf {} -C ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ \;
+}
+
+FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
--
1.9.1
^ permalink raw reply related [flat|nested] 13+ messages in thread
* Re: [EXTERNAL] [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld
2017-08-30 22:42 [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld Mahesh Radhakrishnan
` (5 preceding siblings ...)
2017-08-30 22:42 ` [PATCH v3 7/7] audk2g-addon-rtos: Adding rtos recipe for audio addons for k2g Mahesh Radhakrishnan
@ 2017-08-31 13:23 ` Jacob Stiffler
2017-08-31 16:30 ` Denys Dmytriyenko
7 siblings, 0 replies; 13+ messages in thread
From: Jacob Stiffler @ 2017-08-31 13:23 UTC (permalink / raw)
To: Mahesh Radhakrishnan, meta-ti
On 8/30/2017 6:42 PM, Mahesh Radhakrishnan wrote:
> Upstreaming TI RTOS low level driver for Power Management module (PM)
> Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
> ---
>
> v3 - Removed the intermediate tar-untar for install
> v2 - Added summary & merged in to a single recipe
>
> recipes-bsp/pm-lld/pm-lld-rtos_git.bb | 89 +++++++++++++++++++++++++++++++++++
> 1 file changed, 89 insertions(+)
> create mode 100644 recipes-bsp/pm-lld/pm-lld-rtos_git.bb
>
> diff --git a/recipes-bsp/pm-lld/pm-lld-rtos_git.bb b/recipes-bsp/pm-lld/pm-lld-rtos_git.bb
> new file mode 100644
> index 0000000..72166b0
> --- /dev/null
> +++ b/recipes-bsp/pm-lld/pm-lld-rtos_git.bb
> @@ -0,0 +1,89 @@
> +SUMMARY = "TI RTOS driver for Power Management module (PM)"
> +
> +require recipes-ti/includes/ti-paths.inc
> +
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://Power.h;beginline=1;endline=31;md5=527b91fdcd26cd19ac07a754f45dedbe"
> +
> +COMPATIBLE_MACHINE = "ti33x|ti43x|omap-a15|k2g"
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +
> +PM_LLD_GIT_URI = "git://git.ti.com/keystone-rtos/pm-lld.git"
> +PM_LLD_GIT_PROTOCOL = "git"
> +PM_LLD_GIT_BRANCH = "int_pm_am335x"
> +PM_LLD_GIT_BRANCH_dra7xx-evm = "master"
> +PM_LLD_GIT_DESTSUFFIX = "git/ti/drv/pm"
> +
> +# Below commit ID corresponds to "DEV.PM_LLD.01.04.00.01"
> +PM_LLD_SRCREV = "c4908f94b3e655e6298aa9bfe9bbffbbc5d16111"
> +
> +# Below commit ID corresponds to "REL.PDK.TDA.01.07.00.06"
> +PM_LLD_SRCREV_dra7xx-evm = "46ea13503d2991f636197edb206a9f62cea398d4"
> +
> +BRANCH = "${PM_LLD_GIT_BRANCH}"
> +SRC_URI = "${PM_LLD_GIT_URI};destsuffix=${PM_LLD_GIT_DESTSUFFIX};protocol=${PM_LLD_GIT_PROTOCOL};branch=${BRANCH}"
> +
> +SRCREV = "${PM_LLD_SRCREV}"
> +PV = "01.04.00.01"
> +PR = "r0"
> +
> +S = "${WORKDIR}/${PM_LLD_GIT_DESTSUFFIX}"
> +
> +DEPENDS = " ti-sysbios \
> + gcc-arm-none-eabi-native \
> + osal-rtos \
> + ca-certificates-native \
> +"
> +DEPENDS_append_omap-a15 = " ti-cgt-arm-native \
> + ti-cgt6x-native \
> + common-csl-ip-rtos \
> +"
> +DEPENDS_append_ti33x = " starterware-rtos \
> +"
> +DEPENDS_append_ti43x = " starterware-rtos \
> +"
> +DEPENDS_append_k2g = " common-csl-ip-rtos \
> + ti-cgt6x-native \
> +"
> +
> +# Fetch task cannot be completed until after ca-certificates-native populates sysroot with the SSL certificates
> +do_fetch[depends] = "ca-certificates-native:do_populate_sysroot"
I dont think this is needed.
> +
> +export TOOLCHAIN_PATH_A15 = "${GCC_ARM_NONE_TOOLCHAIN}"
> +export TOOLCHAIN_PATH_A8 = "${GCC_ARM_NONE_TOOLCHAIN}"
> +export TOOLCHAIN_PATH_A9 = "${GCC_ARM_NONE_TOOLCHAIN}"
> +export FPULIB_PATH = "${GCC_ARM_NONE_TOOLCHAIN}/lib/gcc/arm-none-eabi/4.9.3/fpu/"
> +export TOOLCHAIN_PATH_M4 = "${M4_TOOLCHAIN_INSTALL_DIR}"
> +export C6X_GEN_INSTALL_PATH = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
> +export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
> +export BIOS_INSTALL_PATH = "${SYSBIOS_INSTALL_DIR}"
> +export XDC_INSTALL_PATH = "${XDC_INSTALL_DIR}"
> +
> +export PDK_PM_ROOT_PATH = "${WORKDIR}/git"
> +
> +# Used by DEST_ROOT to redirect binary and obj files away from sysroot PDK tree
> +OBJ_DIR = "${WORKDIR}/git/ti/binary"
> +
> +do_compile() {
> + make clean lib xdc_meta doxygen LIMIT_SOCS="${TI_PDK_LIMIT_SOCS}" LIMIT_BOARDS="${TI_PDK_LIMIT_BOARDS}" DEST_ROOT=${OBJ_DIR}
Could you use oe_runmake instead of directly calling make? And also pass
LIMIT_SOCS, LIMIT_BOARDS, and DEST_ROOT in EXTRA_OEMAKE.
Without this there could be an issue in the do_configure stage when
there is an attempt to clean the sources.
> +
> + # Remove unnecessary files from packaging
> + rm -rf patches/
> +
> + # Cleanup docs
> + rm -rf docs/ReleaseNotes_PM_LLD.doc
> + rm -rf internal/
> +
> + # Clean up .tar files from the package
> + find -name "*.tar" -exec rm -f {} \;
> +}
> +
> +do_install() {
> + install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/drv/pm
> + cp -r ${S}/* ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/drv/pm
> +}
> +
> +FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
> +
> +INSANE_SKIP_${PN} = "arch staticdev"
^ permalink raw reply [flat|nested] 13+ messages in thread
* Re: [EXTERNAL] [PATCH v3 4/7] cmb-addon-rtos: Adding CMB rtos recipe
2017-08-30 22:42 ` [PATCH v3 4/7] cmb-addon-rtos: Adding CMB rtos recipe Mahesh Radhakrishnan
@ 2017-08-31 13:27 ` Jacob Stiffler
0 siblings, 0 replies; 13+ messages in thread
From: Jacob Stiffler @ 2017-08-31 13:27 UTC (permalink / raw)
To: Mahesh Radhakrishnan, meta-ti
On 8/30/2017 6:42 PM, Mahesh Radhakrishnan wrote:
> Upstreaming the recipe for Circular Microphone array board (CMB) RTOS
> software
> Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
> ---
>
> v3 - Removed redundant code in do_compile & do_install
> v2 - Added summary
>
> recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb | 56 +++++++++++++++++++++++++++++
> 1 file changed, 56 insertions(+)
> create mode 100644 recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb
>
> diff --git a/recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb b/recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb
> new file mode 100644
> index 0000000..66d961b
> --- /dev/null
> +++ b/recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb
> @@ -0,0 +1,56 @@
> +SUMMARY = "TI RTOS software supporting circular microphone array board"
> +require recipes-ti/includes/ti-paths.inc
> +
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://cmbaddonver.h;beginline=8;endline=47;md5=d0cb159bf210cfafed63042da01c83e0"
> +
> +COMPATIBLE_MACHINE = "k2g|omapl137-evm"
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +CMB_ADDON_GIT_URI = "git://git.ti.com/processor-sdk/circmicarray-addon.git"
> +CMB_ADDON_GIT_PROTOCOL = "git"
> +CMB_ADDON_GIT_BRANCH = "master"
> +CMB_ADDON_GIT_DESTSUFFIX = "git/ti/addon"
> +
> +# Below commit ID corresponds to "DEV.CMB.01.01.00.00"
> +CMB_ADDON_SRCREV = "29c05572b82251bac73cd685afcffdb8549eaaaf"
> +
> +SRCREV = "${CMB_ADDON_SRCREV}"
> +PV = "01.01.00.00"
> +PR = "r0"
> +
> +BRANCH = "${CMB_ADDON_GIT_BRANCH}"
> +SRC_URI = "${CMB_ADDON_GIT_URI};destsuffix=${CMB_ADDON_GIT_DESTSUFFIX};protocol=${CMB_ADDON_GIT_PROTOCOL};branch=${BRANCH}"
> +
> +
> +S = "${WORKDIR}/git/ti/addon/cmb"
> +
> +DEPENDS = " ti-cgt6x-native \
> + ti-sysbios \
> + ti-xdctools \
> + ti-pdk-build-rtos \
> + common-csl-ip-rtos \
> + gpio-lld-rtos \
> + i2c-lld-rtos \
> + mcasp-lld-rtos \
> + board-rtos \
> +"
> +
> +export C6X_GEN_INSTALL_PATH = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
> +export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
> +export BIOS_INSTALL_PATH = "${SYSBIOS_INSTALL_DIR}"
> +export XDC_INSTALL_PATH = "${XDC_INSTALL_DIR}"
> +export XDCPATH = "${XDC_INSTALL_DIR}/packages;${SYSBIOS_INSTALL_DIR}/packages;${PDK_INSTALL_DIR}/packages"
> +export PDK_CMB_ROOT_PATH = "${WORKDIR}/git"
> +
> +do_compile() {
> + make release LIMIT_SOCS="${TI_PDK_LIMIT_SOCS}" LIMIT_BOARDS="${TI_PDK_LIMIT_BOARDS}"
Please use oe_runmake, passing LIMIT_SOCS and LIMIT_BOARDS in EXTRA_OEMAKE.
> +}
> +
> +do_install() {
> + install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/addon/cmb
> + find -name "*.tar" -exec tar xf {} -C ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ \;
> +}
> +
> +FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
^ permalink raw reply [flat|nested] 13+ messages in thread
* Re: [EXTERNAL] [PATCH v3 5/7] ti-ndk: Adding recipe for ti-ndk
2017-08-30 22:42 ` [PATCH v3 5/7] ti-ndk: Adding recipe for ti-ndk Mahesh Radhakrishnan
@ 2017-08-31 13:28 ` Jacob Stiffler
2017-09-26 18:43 ` Denys Dmytriyenko
0 siblings, 1 reply; 13+ messages in thread
From: Jacob Stiffler @ 2017-08-31 13:28 UTC (permalink / raw)
To: Mahesh Radhakrishnan, meta-ti
On 8/30/2017 6:42 PM, Mahesh Radhakrishnan wrote:
> Upstreaming recipe for TI RTOS Networking development kit
>
> Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
> ---
>
> v3 - Removed references to srcipk
> v2 - Added summmary & merged in to a single recipe
These files are not merged anymore.
>
> recipes-ti/ndk/ti-ndk.inc | 21 +++++++++++++++++++++
> recipes-ti/ndk/ti-ndk_2.25.01.11.bb | 13 +++++++++++++
> 2 files changed, 34 insertions(+)
> create mode 100644 recipes-ti/ndk/ti-ndk.inc
> create mode 100644 recipes-ti/ndk/ti-ndk_2.25.01.11.bb
>
> diff --git a/recipes-ti/ndk/ti-ndk.inc b/recipes-ti/ndk/ti-ndk.inc
> new file mode 100644
> index 0000000..09d9ea0
> --- /dev/null
> +++ b/recipes-ti/ndk/ti-ndk.inc
> @@ -0,0 +1,21 @@
> +SUMMARY = "TI RTOS_Networking"
> +HOMEPAGE = "http://software-dl.ti.com/dsps/dsps_public_sw/sdo_sb/targetcontent/ndk/index.html"
> +SECTION = "devel"
> +LICENSE = "BSD"
> +
> +require recipes-ti/includes/ti-paths.inc
> +
> +S = "${WORKDIR}/ndk_${PV}"
> +
> +SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/sdo_sb/targetcontent/ndk/${PV}/exports/ndk_${PV}.zip;name=ndkzip"
> +
> +do_install() {
> + CP_ARGS="-Prf --preserve=mode,timestamps --no-preserve=ownership"
> + install -d ${D}${NDK_INSTALL_DIR_RECIPE}
> + cp ${CP_ARGS} ${S}/* ${D}${NDK_INSTALL_DIR_RECIPE}
> +}
> +
> +ALLOW_EMPTY_${PN} = "1"
> +FILES_${PN}-dev += "${NDK_INSTALL_DIR_RECIPE}"
> +
> +INSANE_SKIP_${PN}-dev = "arch ldflags staticdev"
> diff --git a/recipes-ti/ndk/ti-ndk_2.25.01.11.bb b/recipes-ti/ndk/ti-ndk_2.25.01.11.bb
> new file mode 100644
> index 0000000..d5d926b
> --- /dev/null
> +++ b/recipes-ti/ndk/ti-ndk_2.25.01.11.bb
> @@ -0,0 +1,13 @@
> +require ti-ndk.inc
> +
> +PV = "2_25_01_11"
> +PR = "r0"
> +
> +LIC_FILES_CHKSUM = "file://ndk_${PV}_manifest.html;md5=80a8d9b76cf700929d3f5b6df09052d6"
> +
> +SRC_URI[ndkzip.md5sum] = "e42bfcc8c3a6d183d60f26ec01ccc79b"
> +SRC_URI[ndkzip.sha256sum] = "a15bc9b570dc0628dd8b8c3665037a162610a6f86c5f17ebb6a329d3db60f071"
> +
> +INHIBIT_PACKAGE_STRIP = "1"
> +INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
> +INHIBIT_SYSROOT_STRIP = "1"
^ permalink raw reply [flat|nested] 13+ messages in thread
* Re: [EXTERNAL] [PATCH v3 7/7] audk2g-addon-rtos: Adding rtos recipe for audio addons for k2g
2017-08-30 22:42 ` [PATCH v3 7/7] audk2g-addon-rtos: Adding rtos recipe for audio addons for k2g Mahesh Radhakrishnan
@ 2017-08-31 13:30 ` Jacob Stiffler
0 siblings, 0 replies; 13+ messages in thread
From: Jacob Stiffler @ 2017-08-31 13:30 UTC (permalink / raw)
To: Mahesh Radhakrishnan, meta-ti
On 8/30/2017 6:42 PM, Mahesh Radhakrishnan wrote:
> Upstreaming RTOS audio addon software for K2G
> Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
> ---
>
> v3 - Removed redundant code in do-compile & do-install
> v2 - Added summary
>
> recipes-bsp/audk2g-addon/audk2g-addon-rtos_git.bb | 56 +++++++++++++++++++++++
> 1 file changed, 56 insertions(+)
> create mode 100644 recipes-bsp/audk2g-addon/audk2g-addon-rtos_git.bb
>
> diff --git a/recipes-bsp/audk2g-addon/audk2g-addon-rtos_git.bb b/recipes-bsp/audk2g-addon/audk2g-addon-rtos_git.bb
> new file mode 100644
> index 0000000..9e233e2
> --- /dev/null
> +++ b/recipes-bsp/audk2g-addon/audk2g-addon-rtos_git.bb
> @@ -0,0 +1,56 @@
> +SUMMARY = "TI RTOS Audio add-on software for k2g"
> +
> +require recipes-ti/includes/ti-paths.inc
> +
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://audk2gaddonver.h;beginline=8;endline=47;md5=7a3996aaf1a3d3ca87358cf9b89bce3d"
> +
> +COMPATIBLE_MACHINE = "k2g"
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +AUDK2G_ADDON_GIT_URI = "git://git.ti.com/processor-sdk/audk2g-addon.git"
> +AUDK2G_ADDON_GIT_PROTOCOL = "git"
> +AUDK2G_ADDON_GIT_BRANCH = "master"
> +AUDK2G_ADDON_GIT_DESTSUFFIX = "git/ti/addon/audk2g"
> +
> +# Below commit ID corresponds to "DEV.AUDK2G.01.04.00.00"
> +AUDK2G_ADDON_SRCREV = "815180b45ceb1fa3c110f9979106c7f5aa8b3ca2"
> +
> +BRANCH = "${AUDK2G_ADDON_GIT_BRANCH}"
> +SRC_URI = "${AUDK2G_ADDON_GIT_URI};destsuffix=${AUDK2G_ADDON_GIT_DESTSUFFIX};protocol=${AUDK2G_ADDON_GIT_PROTOCOL};branch=${BRANCH}"
> +
> +SRCREV = "${AUDK2G_ADDON_SRCREV}"
> +PV = "01.04.00.00"
> +PR = "r0"
> +
> +S = "${WORKDIR}/git/ti/addon/audk2g"
> +
> +DEPENDS = " ti-cgt6x-native \
> + ti-sysbios \
> + ti-xdctools \
> + ti-pdk-build-rtos \
> + common-csl-ip-rtos \
> + gpio-lld-rtos \
> + i2c-lld-rtos \
> + board-rtos \
> +"
> +
> +export C6X_GEN_INSTALL_PATH = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
> +export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
> +export BIOS_INSTALL_PATH = "${SYSBIOS_INSTALL_DIR}"
> +export XDC_INSTALL_PATH = "${XDC_INSTALL_DIR}"
> +
> +export XDCPATH = "${XDC_INSTALL_DIR}/packages;${SYSBIOS_INSTALL_DIR}/packages;${PDK_INSTALL_DIR}/packages"
> +
> +export PDK_AUDK2G_ROOT_PATH = "${WORKDIR}/git"
> +
> +do_compile() {
> + make release LIMIT_SOCS="${TI_PDK_LIMIT_SOCS}" LIMIT_BOARDS="${TI_PDK_LIMIT_BOARDS}"
Same comment as 1/7 and 4/7. Please use oe_runmake
> +}
> +
> +do_install() {
> + install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/addon/audk2g
> + find -name "*.tar" -exec tar xf {} -C ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ \;
> +}
> +
> +FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
^ permalink raw reply [flat|nested] 13+ messages in thread
* Re: [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld
2017-08-30 22:42 [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld Mahesh Radhakrishnan
` (6 preceding siblings ...)
2017-08-31 13:23 ` [EXTERNAL] [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld Jacob Stiffler
@ 2017-08-31 16:30 ` Denys Dmytriyenko
7 siblings, 0 replies; 13+ messages in thread
From: Denys Dmytriyenko @ 2017-08-31 16:30 UTC (permalink / raw)
To: Mahesh Radhakrishnan; +Cc: meta-ti
Mahesh,
On Wed, Aug 30, 2017 at 06:42:10PM -0400, Mahesh Radhakrishnan wrote:
> Upstreaming TI RTOS low level driver for Power Management module (PM)
> Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
> ---
>
> v3 - Removed the intermediate tar-untar for install
There were many more questions/comments that you haven't addressed or
even answered:
https://lists.yoctoproject.org/pipermail/meta-ti/2017-August/010309.html
> v2 - Added summary & merged in to a single recipe
>
> recipes-bsp/pm-lld/pm-lld-rtos_git.bb | 89 +++++++++++++++++++++++++++++++++++
> 1 file changed, 89 insertions(+)
> create mode 100644 recipes-bsp/pm-lld/pm-lld-rtos_git.bb
>
> diff --git a/recipes-bsp/pm-lld/pm-lld-rtos_git.bb b/recipes-bsp/pm-lld/pm-lld-rtos_git.bb
> new file mode 100644
> index 0000000..72166b0
> --- /dev/null
> +++ b/recipes-bsp/pm-lld/pm-lld-rtos_git.bb
> @@ -0,0 +1,89 @@
> +SUMMARY = "TI RTOS driver for Power Management module (PM)"
> +
> +require recipes-ti/includes/ti-paths.inc
> +
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://Power.h;beginline=1;endline=31;md5=527b91fdcd26cd19ac07a754f45dedbe"
> +
> +COMPATIBLE_MACHINE = "ti33x|ti43x|omap-a15|k2g"
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +
> +PM_LLD_GIT_URI = "git://git.ti.com/keystone-rtos/pm-lld.git"
> +PM_LLD_GIT_PROTOCOL = "git"
> +PM_LLD_GIT_BRANCH = "int_pm_am335x"
> +PM_LLD_GIT_BRANCH_dra7xx-evm = "master"
> +PM_LLD_GIT_DESTSUFFIX = "git/ti/drv/pm"
> +
> +# Below commit ID corresponds to "DEV.PM_LLD.01.04.00.01"
> +PM_LLD_SRCREV = "c4908f94b3e655e6298aa9bfe9bbffbbc5d16111"
> +
> +# Below commit ID corresponds to "REL.PDK.TDA.01.07.00.06"
> +PM_LLD_SRCREV_dra7xx-evm = "46ea13503d2991f636197edb206a9f62cea398d4"
> +
> +BRANCH = "${PM_LLD_GIT_BRANCH}"
> +SRC_URI = "${PM_LLD_GIT_URI};destsuffix=${PM_LLD_GIT_DESTSUFFIX};protocol=${PM_LLD_GIT_PROTOCOL};branch=${BRANCH}"
> +
> +SRCREV = "${PM_LLD_SRCREV}"
> +PV = "01.04.00.01"
> +PR = "r0"
> +
> +S = "${WORKDIR}/${PM_LLD_GIT_DESTSUFFIX}"
> +
> +DEPENDS = " ti-sysbios \
> + gcc-arm-none-eabi-native \
> + osal-rtos \
> + ca-certificates-native \
> +"
> +DEPENDS_append_omap-a15 = " ti-cgt-arm-native \
> + ti-cgt6x-native \
> + common-csl-ip-rtos \
> +"
> +DEPENDS_append_ti33x = " starterware-rtos \
> +"
> +DEPENDS_append_ti43x = " starterware-rtos \
> +"
> +DEPENDS_append_k2g = " common-csl-ip-rtos \
> + ti-cgt6x-native \
> +"
> +
> +# Fetch task cannot be completed until after ca-certificates-native populates sysroot with the SSL certificates
> +do_fetch[depends] = "ca-certificates-native:do_populate_sysroot"
> +
> +export TOOLCHAIN_PATH_A15 = "${GCC_ARM_NONE_TOOLCHAIN}"
> +export TOOLCHAIN_PATH_A8 = "${GCC_ARM_NONE_TOOLCHAIN}"
> +export TOOLCHAIN_PATH_A9 = "${GCC_ARM_NONE_TOOLCHAIN}"
> +export FPULIB_PATH = "${GCC_ARM_NONE_TOOLCHAIN}/lib/gcc/arm-none-eabi/4.9.3/fpu/"
> +export TOOLCHAIN_PATH_M4 = "${M4_TOOLCHAIN_INSTALL_DIR}"
> +export C6X_GEN_INSTALL_PATH = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
> +export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
> +export BIOS_INSTALL_PATH = "${SYSBIOS_INSTALL_DIR}"
> +export XDC_INSTALL_PATH = "${XDC_INSTALL_DIR}"
> +
> +export PDK_PM_ROOT_PATH = "${WORKDIR}/git"
> +
> +# Used by DEST_ROOT to redirect binary and obj files away from sysroot PDK tree
> +OBJ_DIR = "${WORKDIR}/git/ti/binary"
> +
> +do_compile() {
> + make clean lib xdc_meta doxygen LIMIT_SOCS="${TI_PDK_LIMIT_SOCS}" LIMIT_BOARDS="${TI_PDK_LIMIT_BOARDS}" DEST_ROOT=${OBJ_DIR}
> +
> + # Remove unnecessary files from packaging
> + rm -rf patches/
> +
> + # Cleanup docs
> + rm -rf docs/ReleaseNotes_PM_LLD.doc
> + rm -rf internal/
> +
> + # Clean up .tar files from the package
> + find -name "*.tar" -exec rm -f {} \;
> +}
> +
> +do_install() {
> + install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/drv/pm
> + cp -r ${S}/* ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/drv/pm
> +}
> +
> +FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
> +
> +INSANE_SKIP_${PN} = "arch staticdev"
> --
> 1.9.1
>
> --
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti
^ permalink raw reply [flat|nested] 13+ messages in thread
* Re: [EXTERNAL] [PATCH v3 5/7] ti-ndk: Adding recipe for ti-ndk
2017-08-31 13:28 ` [EXTERNAL] " Jacob Stiffler
@ 2017-09-26 18:43 ` Denys Dmytriyenko
0 siblings, 0 replies; 13+ messages in thread
From: Denys Dmytriyenko @ 2017-09-26 18:43 UTC (permalink / raw)
To: Jacob Stiffler; +Cc: meta-ti
On Thu, Aug 31, 2017 at 09:28:45AM -0400, Jacob Stiffler wrote:
>
>
> On 8/30/2017 6:42 PM, Mahesh Radhakrishnan wrote:
> >Upstreaming recipe for TI RTOS Networking development kit
> >
> >Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
> >---
> >
> > v3 - Removed references to srcipk
> > v2 - Added summmary & merged in to a single recipe
>
> These files are not merged anymore.
Jake, Mahesh,
Should this be a single recipe? I assume so, as it's only used by RTOS, not
Linux. Is this critical to resolve? As it blocks multiple recipes depending
on ndk - transport, board, vps-lld, cmb-addon, and audk2g-addon...
> > recipes-ti/ndk/ti-ndk.inc | 21 +++++++++++++++++++++
> > recipes-ti/ndk/ti-ndk_2.25.01.11.bb | 13 +++++++++++++
> > 2 files changed, 34 insertions(+)
> > create mode 100644 recipes-ti/ndk/ti-ndk.inc
> > create mode 100644 recipes-ti/ndk/ti-ndk_2.25.01.11.bb
> >
> >diff --git a/recipes-ti/ndk/ti-ndk.inc b/recipes-ti/ndk/ti-ndk.inc
> >new file mode 100644
> >index 0000000..09d9ea0
> >--- /dev/null
> >+++ b/recipes-ti/ndk/ti-ndk.inc
> >@@ -0,0 +1,21 @@
> >+SUMMARY = "TI RTOS_Networking"
> >+HOMEPAGE = "http://software-dl.ti.com/dsps/dsps_public_sw/sdo_sb/targetcontent/ndk/index.html"
> >+SECTION = "devel"
> >+LICENSE = "BSD"
> >+
> >+require recipes-ti/includes/ti-paths.inc
> >+
> >+S = "${WORKDIR}/ndk_${PV}"
> >+
> >+SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/sdo_sb/targetcontent/ndk/${PV}/exports/ndk_${PV}.zip;name=ndkzip"
> >+
> >+do_install() {
> >+ CP_ARGS="-Prf --preserve=mode,timestamps --no-preserve=ownership"
> >+ install -d ${D}${NDK_INSTALL_DIR_RECIPE}
> >+ cp ${CP_ARGS} ${S}/* ${D}${NDK_INSTALL_DIR_RECIPE}
> >+}
> >+
> >+ALLOW_EMPTY_${PN} = "1"
> >+FILES_${PN}-dev += "${NDK_INSTALL_DIR_RECIPE}"
> >+
> >+INSANE_SKIP_${PN}-dev = "arch ldflags staticdev"
> >diff --git a/recipes-ti/ndk/ti-ndk_2.25.01.11.bb b/recipes-ti/ndk/ti-ndk_2.25.01.11.bb
> >new file mode 100644
> >index 0000000..d5d926b
> >--- /dev/null
> >+++ b/recipes-ti/ndk/ti-ndk_2.25.01.11.bb
> >@@ -0,0 +1,13 @@
> >+require ti-ndk.inc
> >+
> >+PV = "2_25_01_11"
> >+PR = "r0"
> >+
> >+LIC_FILES_CHKSUM = "file://ndk_${PV}_manifest.html;md5=80a8d9b76cf700929d3f5b6df09052d6"
> >+
> >+SRC_URI[ndkzip.md5sum] = "e42bfcc8c3a6d183d60f26ec01ccc79b"
> >+SRC_URI[ndkzip.sha256sum] = "a15bc9b570dc0628dd8b8c3665037a162610a6f86c5f17ebb6a329d3db60f071"
> >+
> >+INHIBIT_PACKAGE_STRIP = "1"
> >+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
> >+INHIBIT_SYSROOT_STRIP = "1"
>
> --
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti
^ permalink raw reply [flat|nested] 13+ messages in thread
end of thread, other threads:[~2017-09-26 18:44 UTC | newest]
Thread overview: 13+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2017-08-30 22:42 [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld Mahesh Radhakrishnan
2017-08-30 22:42 ` [PATCH v3 2/7] transport-rtos: Added transport recipes(bmet, nimu, nimu-icss) for rtos Mahesh Radhakrishnan
2017-08-30 22:42 ` [PATCH v3 3/7] vps-lld-rtos: Added rtos recipe for vps-lld Mahesh Radhakrishnan
2017-08-30 22:42 ` [PATCH v3 4/7] cmb-addon-rtos: Adding CMB rtos recipe Mahesh Radhakrishnan
2017-08-31 13:27 ` [EXTERNAL] " Jacob Stiffler
2017-08-30 22:42 ` [PATCH v3 5/7] ti-ndk: Adding recipe for ti-ndk Mahesh Radhakrishnan
2017-08-31 13:28 ` [EXTERNAL] " Jacob Stiffler
2017-09-26 18:43 ` Denys Dmytriyenko
2017-08-30 22:42 ` [PATCH v3 6/7] pruss-lld: Add rtos recipe & update the version to 1.0.0.7 Mahesh Radhakrishnan
2017-08-30 22:42 ` [PATCH v3 7/7] audk2g-addon-rtos: Adding rtos recipe for audio addons for k2g Mahesh Radhakrishnan
2017-08-31 13:30 ` [EXTERNAL] " Jacob Stiffler
2017-08-31 13:23 ` [EXTERNAL] [PATCH v3 1/7] pm-lld-rtos: Adding rtos recipe for pm-lld Jacob Stiffler
2017-08-31 16:30 ` Denys Dmytriyenko
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.