All of lore.kernel.org
 help / color / mirror / Atom feed
* [rocko/master][PATCH v8 2/5] arm-compute-library: Machine Learning library for ARM.
@ 2018-09-14 18:26 Jacob Stiffler
  2018-09-14 18:26 ` [rocko/master][PATCH v8 4/5] armnn-tensorflow: tensorflow protobuf files for building tensorflow models in armnn Jacob Stiffler
  2018-09-14 18:26 ` [rocko/master][PATCH v8 5/5] armnn: ARM NN machine learning SDK Jacob Stiffler
  0 siblings, 2 replies; 4+ messages in thread
From: Jacob Stiffler @ 2018-09-14 18:26 UTC (permalink / raw)
  To: meta-arago

From: Qin Su <qsu@ti.com>

The ARM Computer Vision and Machine Learning library is a set of functions
optimised for both ARM CPUs and GPUs using SIMD technologies.

Signed-off-by: Qin Su <qsu@ti.com>
Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
Changes from v6:
* Add SUMMARY
* Add comment explaining that ARMNN expects a built source package of
  arm-compute-library.
* Install to ${datadir}/${BPN} instead of ${datadir}/${PN}
* Remove warnings by adding more INSANE_SKIPS
  - dev: dkip ldflags
  - source: skip ldflags, libdir, staticdev
* INHIBIT_DEBUG_SPLIT so that debug files are not removed from source
  package

Changes from previous versions:
* Add "_git" suffix to recipe name.
* Add version.
* Add branch option for SRC_URI.
* For installation, use install by looping over libraries.
* Remove unnecessary checksums for SRC_URI.
* Set armv7a as COMPATIBLE_MACHINE as this is hardcoded in
  EXTRA_OESCONS.

 .../arm-compute-library/arm-compute-library_git.bb | 48 ++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 meta-arago-extras/recipes-support/arm-compute-library/arm-compute-library_git.bb

diff --git a/meta-arago-extras/recipes-support/arm-compute-library/arm-compute-library_git.bb b/meta-arago-extras/recipes-support/arm-compute-library/arm-compute-library_git.bb
new file mode 100644
index 0000000..d9fa8b0
--- /dev/null
+++ b/meta-arago-extras/recipes-support/arm-compute-library/arm-compute-library_git.bb
@@ -0,0 +1,48 @@
+SUMMARY = "The ARM Computer Vision and Machine Learning library"
+DESCRIPTION = "The ARM Computer Vision and Machine Learning library is a set of functions optimised for both ARM CPUs and GPUs."
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e2c93841b20cd522af621cabaea3aef8"
+
+COMPATIBLE_MACHINE = "armv7a"
+
+SRC_URI = " \
+    git://github.com/ARM-software/ComputeLibrary.git;branch=${BRANCH} \
+"
+
+PV  = "18.05"
+
+BRANCH = "master"
+SRCREV = "e2542c9f35ca427286822cd0c9296f49914f78b0"
+
+S = "${WORKDIR}/git"
+
+do_compile_prepend() {
+    unset CC CXX
+}
+
+inherit scons
+
+EXTRA_OESCONS = "arch=armv7a extra_cxx_flags="-fPIC" benchmark_tests=1 validation_tests=0 neon=1 openmp=1 opencl=0"
+
+LIBS += "-larmpl_lp64_mp"
+
+do_install() {
+    CP_ARGS="-Prf --preserve=mode,timestamps --no-preserve=ownership"
+
+    install -d ${D}${libdir}
+    for lib in ${S}/build/*.so
+    do
+        install -m 0644 $lib ${D}${libdir}
+    done
+
+    # Install built source package as expected by ARMNN
+    install -d ${D}${datadir}/${BPN}
+    cp $CP_ARGS ${S}/. ${D}${datadir}/${BPN}
+}
+
+INSANE_SKIP_${PN}-dev = "dev-elf ldflags"
+
+PACKAGES =+ "${PN}-source"
+FILES_${PN}-source = "${datadir}/${BPN}"
+INSANE_SKIP_${PN}-source = "ldflags libdir staticdev"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
-- 
2.7.4



^ permalink raw reply related	[flat|nested] 4+ messages in thread
end of thread, other threads:[~2018-09-14 19:55 UTC | newest]

Thread overview: 4+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2018-09-14 18:26 [rocko/master][PATCH v8 2/5] arm-compute-library: Machine Learning library for ARM Jacob Stiffler
2018-09-14 18:26 ` [rocko/master][PATCH v8 4/5] armnn-tensorflow: tensorflow protobuf files for building tensorflow models in armnn Jacob Stiffler
2018-09-14 18:26 ` [rocko/master][PATCH v8 5/5] armnn: ARM NN machine learning SDK Jacob Stiffler
2018-09-14 19:54   ` Denys Dmytriyenko

This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.