* [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
@ 2022-05-17 12:28 Ross Burton
2022-05-17 12:28 ` [PATCH 2/3] arm-toolchain/external-arm-toolchain: add back 10.3 Ross Burton
` (4 more replies)
0 siblings, 5 replies; 9+ messages in thread
From: Ross Burton @ 2022-05-17 12:28 UTC (permalink / raw)
To: meta-arm; +Cc: nd
We need to support multiple versions of external-arm-toolchain, partly as
different versions have different layouts on disk, and partly because
11.2 doesn't work on pre-Broadwell hardware.
Rename this recipe so the version is in the filename, and dynamically
set PKGV instead of PV so PREFERRED_VERSION is easier to use.
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
...-arm-toolchain.bb => external-arm-toolchain_11.2-2022.02.bb} | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
rename meta-arm-toolchain/recipes-devtools/external-arm-toolchain/{external-arm-toolchain.bb => external-arm-toolchain_11.2-2022.02.bb} (99%)
diff --git a/meta-arm-toolchain/recipes-devtools/external-arm-toolchain/external-arm-toolchain.bb b/meta-arm-toolchain/recipes-devtools/external-arm-toolchain/external-arm-toolchain_11.2-2022.02.bb
similarity index 99%
rename from meta-arm-toolchain/recipes-devtools/external-arm-toolchain/external-arm-toolchain.bb
rename to meta-arm-toolchain/recipes-devtools/external-arm-toolchain/external-arm-toolchain_11.2-2022.02.bb
index dcc8ebf0..0b2d3238 100644
--- a/meta-arm-toolchain/recipes-devtools/external-arm-toolchain/external-arm-toolchain.bb
+++ b/meta-arm-toolchain/recipes-devtools/external-arm-toolchain/external-arm-toolchain_11.2-2022.02.bb
@@ -51,7 +51,7 @@ PROVIDES += "\
virtual/libc-locale \
"
-PV = "${EAT_VER_MAIN}"
+PKGV = "${EAT_VER_MAIN}"
BINV = "${EAT_VER_GCC}"
--
2.25.1
^ permalink raw reply related [flat|nested] 9+ messages in thread
* [PATCH 2/3] arm-toolchain/external-arm-toolchain: add back 10.3
2022-05-17 12:28 [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe Ross Burton
@ 2022-05-17 12:28 ` Ross Burton
2022-05-17 12:28 ` [PATCH 3/3] CI: use external-arm-toolchain 10.3 Ross Burton
` (3 subsequent siblings)
4 siblings, 0 replies; 9+ messages in thread
From: Ross Burton @ 2022-05-17 12:28 UTC (permalink / raw)
To: meta-arm; +Cc: nd
Add back the 10.3 release of external-arm-toolchain.
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
.../external-arm-toolchain_10.3-2021.07.bb | 680 ++++++++++++++++++
1 file changed, 680 insertions(+)
create mode 100644 meta-arm-toolchain/recipes-devtools/external-arm-toolchain/external-arm-toolchain_10.3-2021.07.bb
diff --git a/meta-arm-toolchain/recipes-devtools/external-arm-toolchain/external-arm-toolchain_10.3-2021.07.bb b/meta-arm-toolchain/recipes-devtools/external-arm-toolchain/external-arm-toolchain_10.3-2021.07.bb
new file mode 100644
index 00000000..c0b5e6d5
--- /dev/null
+++ b/meta-arm-toolchain/recipes-devtools/external-arm-toolchain/external-arm-toolchain_10.3-2021.07.bb
@@ -0,0 +1,680 @@
+require recipes-core/glibc/glibc-package.inc
+
+require license.inc
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+LIC_FILES_CHKSUM = "\
+ file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302 \
+ file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420 \
+"
+
+PROVIDES += "\
+ linux-libc-headers \
+ virtual/${TARGET_PREFIX}gcc \
+ virtual/${TARGET_PREFIX}g++ \
+ virtual/${TARGET_PREFIX}gcc-initial \
+ virtual/${TARGET_PREFIX}binutils \
+ virtual/${TARGET_PREFIX}libc-for-gcc \
+ virtual/${TARGET_PREFIX}compilerlibs \
+ virtual/libc \
+ virtual/libintl \
+ virtual/libiconv \
+ virtual/crypt \
+ glibc-mtrace \
+ glibc-thread-db \
+ glibc \
+ libc-mtrace \
+ gcc-runtime \
+ libgcc \
+ libg2c \
+ libg2c-dev \
+ libssp \
+ libssp-dev \
+ libssp-staticdev \
+ libgfortran \
+ libgfortran-dev \
+ libgfortran-staticdev \
+ libmudflap \
+ libmudflap-dev \
+ libgomp \
+ libgomp-dev \
+ libgomp-staticdev \
+ libitm \
+ libitm-dev \
+ libitm-staticdev \
+ libquadmath \
+ libquadmath-dev \
+ libquadmath-staticdev \
+ virtual/linux-libc-headers \
+ libgcov-staticdev \
+ virtual/libc-locale \
+"
+
+PKGV = "${EAT_VER_MAIN}"
+
+BINV = "${EAT_VER_GCC}"
+
+SRC_URI = "file://SUPPORTED"
+
+do_install() {
+ # Add stubs for files OE-core expects
+ install -d ${S}/nscd/
+ touch ${S}/nscd/nscd.init
+ touch ${S}/nscd/nscd.conf
+ touch ${S}/nscd/nscd.service
+ touch ${S}/../makedbs.sh
+
+ install -d ${D}${base_libdir}
+ install -d ${D}${base_sbindir}
+ install -d ${D}${bindir}
+ install -d ${D}${sbindir}
+ install -d ${D}${libdir}
+ install -d ${D}${libexecdir}
+ install -d ${D}${datadir}
+ install -d ${D}${includedir}
+ install -d ${D}/include
+ install -d ${D}${libdir}/${TARGET_SYS}/${EAT_VER_GCC}
+ install -d ${D}${libdir}/gcc/${TARGET_SYS}/${EAT_VER_GCC}
+
+ CP_ARGS="-Prf --preserve=mode,timestamps --no-preserve=ownership"
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/${EAT_LIBDIR}/* ${D}${base_libdir}
+ if [ -d ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/${EAT_LIBDIR}/${EAT_TARGET_SYS} ]; then
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/${EAT_LIBDIR}/${EAT_TARGET_SYS}/* ${D}${base_libdir}
+ else
+ if [ -f ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/${EAT_LIBDIR}/ld-${EAT_VER_LIBC}.so ]; then
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/${EAT_LIBDIR}/* ${D}${base_libdir}
+ else
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/usr/${EAT_LIBDIR}/*.so* ${D}${base_libdir}
+ fi
+ fi
+ if [ -d ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/usr/${EAT_LIBDIR}/${EAT_TARGET_SYS} ]; then
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/usr/${EAT_LIBDIR}/${EAT_TARGET_SYS}/* ${D}${libdir}
+ else
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/usr/${EAT_LIBDIR}/* ${D}${libdir}
+ if [ ! -f ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/${EAT_LIBDIR}/ld-${EAT_VER_LIBC}.so ]; then
+ rm -rf ${D}${libdir}/*.so*
+ fi
+ fi
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/usr/share/* ${D}${datadir}
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/usr/include/* ${D}${includedir}
+ if [ -d ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/usr/include/${EAT_TARGET_SYS} ]; then
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/usr/include/${EAT_TARGET_SYS}/* ${D}${includedir}
+ rm -r ${D}${includedir}/${EAT_TARGET_SYS}
+ fi
+
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/include/* ${D}${includedir}
+ if [ -d ${D}${includedir}/c++/${EAT_VER_GCC}/${EAT_TARGET_SYS} ]; then
+ mv ${D}${includedir}/c++/${EAT_VER_GCC}/${EAT_TARGET_SYS} ${D}${includedir}/c++/${EAT_VER_GCC}/${TARGET_SYS}
+ fi
+ ln -sf ../usr/include/c++ ${D}/include/c++
+
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/usr/bin/* ${D}${bindir}
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/usr/sbin/* ${D}${sbindir}
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/${EAT_TARGET_SYS}/libc/sbin/* ${D}${base_sbindir}
+ rm -rf ${D}${bindir}/gdbserver
+ sed -i -e 's#/arm/tools/gnu/bash/4.2/rhe6-x86_64##' ${D}${bindir}/tzselect
+ sed -i -e 's#/arm/tools/gnu/bash/4.2/rhe6-x86_64##' ${D}${bindir}/ldd
+ sed -i -e 's#/usr/bin/bash#/bin/sh#' ${D}${bindir}/tzselect
+ sed -i -e 's#/usr/bin/bash#/bin/sh#' ${D}${bindir}/ldd
+ sed -i -e 's#/bin/bash#/bin/sh#' ${D}${bindir}/tzselect
+ sed -i -e 's#/bin/bash#/bin/sh#' ${D}${bindir}/ldd
+
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/lib/gcc/${EAT_TARGET_SYS}/${EAT_VER_GCC}/crt*.o ${D}${libdir}/${TARGET_SYS}/${EAT_VER_GCC}/
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/lib/gcc/${EAT_TARGET_SYS}/${EAT_VER_GCC}/libgcc* ${D}${libdir}/${TARGET_SYS}/${EAT_VER_GCC}/
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/lib/gcc/${EAT_TARGET_SYS}/${EAT_VER_GCC}/libgcov* ${D}${libdir}/gcc/${TARGET_SYS}/${EAT_VER_GCC}/
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/lib/gcc/${EAT_TARGET_SYS}/${EAT_VER_GCC}/include ${D}${libdir}/gcc/${TARGET_SYS}/${EAT_VER_GCC}/
+ cp ${CP_ARGS} ${EXTERNAL_TOOLCHAIN}/lib/gcc/${EAT_TARGET_SYS}/${EAT_VER_GCC}/finclude ${D}${libdir}/gcc/${TARGET_SYS}/${EAT_VER_GCC}/
+
+ # fix up the copied symlinks (they are still pointing to the multiarch directory)
+ linker_name="${@bb.utils.contains("TUNE_FEATURES", "aarch64", "ld-linux-aarch64.so.1", bb.utils.contains("TUNE_FEATURES", "callconvention-hard", "ld-linux-armhf.so.3", "ld-linux.so.3",d), d)}"
+ ln -sf ld-${EAT_VER_LIBC}.so ${D}${base_libdir}/${linker_name}
+ ln -sf ../../lib/librt.so.1 ${D}${libdir}/librt.so
+ ln -sf ../../lib/libcrypt.so.1 ${D}${libdir}/libcrypt.so
+ ln -sf ../../lib/libresolv.so.2 ${D}${libdir}/libresolv.so
+ ln -sf ../../lib/libnss_hesiod.so.2 ${D}${libdir}/libnss_hesiod.so
+ ln -sf ../../lib/libutil.so.1 ${D}${libdir}/libutil.so
+ ln -sf ../../lib/libBrokenLocale.so.1 ${D}${libdir}/libBrokenLocale.so
+ ln -sf ../../lib/libpthread.so.0 ${D}${libdir}/libpthread.so
+ ln -sf ../../lib/libthread_db.so.1 ${D}${libdir}/libthread_db.so
+ ln -sf ../../lib/libanl.so.1 ${D}${libdir}/libanl.so
+ ln -sf ../../lib/libdl.so.2 ${D}${libdir}/libdl.so
+ ln -sf ../../lib/libnss_db.so.2 ${D}${libdir}/libnss_db.so
+ ln -sf ../../lib/libnss_dns.so.2 ${D}${libdir}/libnss_dns.so
+ ln -sf ../../lib/libnss_files.so.2 ${D}${libdir}/libnss_files.so
+ ln -sf ../../lib/libnss_compat.so.2 ${D}${libdir}/libnss_compat.so
+ ln -sf ../../lib/libm.so.6 ${D}${libdir}/libm.so
+
+ # remove potential .so duplicates from base_libdir
+ # for all symlinks created above in libdir
+ rm -f ${D}${base_libdir}/librt.so
+ rm -f ${D}${base_libdir}/libcrypt.so
+ rm -f ${D}${base_libdir}/libresolv.so
+ rm -f ${D}${base_libdir}/libnss_hesiod.so
+ rm -f ${D}${base_libdir}/libutil.so
+ rm -f ${D}${base_libdir}/libBrokenLocale.so
+ rm -f ${D}${base_libdir}/libpthread.so
+ rm -f ${D}${base_libdir}/libthread_db.so
+ rm -f ${D}${base_libdir}/libanl.so
+ rm -f ${D}${base_libdir}/libdl.so
+ rm -f ${D}${base_libdir}/libnss_db.so
+ rm -f ${D}${base_libdir}/libnss_dns.so
+ rm -f ${D}${base_libdir}/libnss_files.so
+ rm -f ${D}${base_libdir}/libnss_compat.so
+ rm -f ${D}${base_libdir}/libm.so
+
+ # Move these completely to ${libdir} and delete duplicates in ${base_libdir}
+ for lib in asan atomic gfortran gomp itm lsan sanitizer stdc++ tsan ubsan; do
+ if [ -e ${D}${base_libdir}/lib${lib}.spec ] ; then
+ mv ${D}${base_libdir}/lib${lib}.spec ${D}${libdir}
+ fi
+ if [ -e ${D}${base_libdir}/lib${lib}.a ] ; then
+ mv ${D}${base_libdir}/lib${lib}.a ${D}${libdir}
+ fi
+ rm -f ${D}${base_libdir}/lib${lib}*
+ done
+
+ # Clean up duplicate libs that are both in base_libdir and libdir
+ rm -f ${D}${libdir}/libgcc*
+
+ # Besides ld-${EAT_VER_LIBC}.so, other libs can have duplicates like lib*-${EAT_VER_LIBC}.so
+ # Only remove them if both are regular files and are identical
+ for i in ${D}${base_libdir}/lib*-${EAT_VER_LIBC}.so; do
+ f=$(echo $i | sed 's/-${EAT_VER_LIBC}//')
+ l=$(ls $f.*)
+ if [ $(readlink -f $i ) = $l ]; then
+ echo "$i is a symlink of $l, keep it"
+ elif [ $(readlink -f $l ) = $i ]; then
+ echo "$l is a symlink of $i, keep it"
+ else
+ cmp -s $i $l
+ if [ $? -eq 0 ]; then
+ echo "$i is a duplicate of $l, remove it"
+ rm $i
+ else
+ echo "$i and $l are different files, keep them both"
+ fi
+ fi
+ done
+
+ if [ -d ${D}${base_libdir}/arm-linux-gnueabi ]; then
+ rm -rf ${D}${base_libdir}/arm-linux-gnueabi
+ fi
+
+ if [ -d ${D}${base_libdir}/ldscripts ]; then
+ rm -rf ${D}${base_libdir}/ldscripts
+ fi
+
+ # Provided by libnsl2
+ rm -rf ${D}${includedir}/rpcsvc/yppasswd.*
+ # Provided by quota
+ rm -rf ${D}${includedir}/rpcsvc/rquota.*
+
+ if [ -f ${D}${libdir}/libc.so ];then
+ sed -i -e "s# /${EAT_LIBDIR}/${EAT_TARGET_SYS}# ../../${EAT_LIBDIR}#g" -e "s# /usr/${EAT_LIBDIR}/# /usr/lib/#g" -e "s# /usr/${EAT_LIBDIR}/${EAT_TARGET_SYS}# .#g" -e "s# /${EAT_LIBDIR}/ld-linux# ../../${EAT_LIBDIR}/ld-linux#g" ${D}${libdir}/libc.so
+ sed -i -e "s# /${EAT_LIBDIR}/libc.so.6# /lib/libc.so.6#g" ${D}${libdir}/libc.so
+ sed -i -e "s# /lib# ../../lib#g" -e "s# /usr/lib# .#g" ${D}${libdir}/libc.so
+ fi
+
+ if [ -f ${D}${base_libdir}/libc.so ];then
+ sed -i -e "s# /${EAT_LIBDIR}/${EAT_TARGET_SYS}# ../../lib#g" -e "s# /usr/${EAT_LIBDIR}/${EAT_TARGET_SYS}# .#g" "s# /${EAT_LIBDIR}/# /lib/#g" ${D}${base_libdir}/libc.so
+ if [ -f ${D}${base_libdir}/libc.so.6 ]; then
+ sed -i -e "s# /usr/${EAT_LIBDIR}/libc.so.6# /lib/libc.so.6#g" "s# /${EAT_LIBDIR}/libc.so.6# /lib/libc.so.6#g" ${D}${base_libdir}/libc.so.6
+ fi
+ fi
+
+ # Remove if empty
+ rmdir ${D}${bindir} || true
+ rmdir ${D}${sbindir} || true
+ rmdir ${D}${base_sbindir} || true
+ rmdir ${D}${libexecdir} || true
+
+ # Remove unused /usr/share/info/dir
+ rm -f ${D}${infodir}/dir
+}
+
+# External toolchain doesn't provide multilib support so make corresponding
+# install API as an empty API to avoid an unnecessary errors.
+oe_multilib_header () {
+ return
+}
+
+PACKAGES_DYNAMIC = "^locale-base-.* \
+ ^glibc-gconv-.* ^glibc-charmap-.* ^glibc-localedata-.* ^glibc-binary-localedata-.* \
+ ^${MLPREFIX}glibc-gconv$"
+
+# PACKAGES is split up according to the 'source' recipes/includes in OE-core
+# Stylistic differences are kept to make copy/pasting easier.
+
+# From gcc-runtime.inc
+
+PACKAGES += "\
+ gcc-runtime-dbg \
+ libstdc++ \
+ libstdc++-precompile-dev \
+ libstdc++-dev \
+ libstdc++-staticdev \
+ libg2c \
+ libg2c-dev \
+ libssp \
+ libssp-dev \
+ libssp-staticdev \
+ libmudflap \
+ libmudflap-dev \
+ libmudflap-staticdev \
+ libquadmath \
+ libquadmath-dev \
+ libquadmath-staticdev \
+ libgomp \
+ libgomp-dev \
+ libgomp-staticdev \
+ libatomic \
+ libatomic-dev \
+ libatomic-staticdev \
+ libitm \
+ libitm-dev \
+ libitm-staticdev \
+"
+
+# From gcc-sanitizers.inc
+
+PACKAGES += "gcc-sanitizers gcc-sanitizers-dbg"
+PACKAGES += "libasan libubsan liblsan libtsan"
+PACKAGES += "libasan-dev libubsan-dev liblsan-dev libtsan-dev"
+PACKAGES += "libasan-staticdev libubsan-staticdev liblsan-staticdev libtsan-staticdev"
+
+# From libgfortran.inc:
+
+PACKAGES += "\
+ libgfortran-dbg \
+ libgfortran \
+ libgfortran-dev \
+ libgfortran-staticdev \
+"
+
+# libgcc.inc uses ${PN}, so replace that
+
+PACKAGES += "\
+ libgcc \
+ libgcc-dev \
+ libgcc-dbg \
+"
+
+# ... and the leftovers
+
+PACKAGES =+ "\
+ ${PN}-mtrace \
+ libgcov-staticdev \
+ linux-libc-headers \
+ linux-libc-headers-dev \
+"
+
+# Re-order PACKAGES list in order to shift ${PN}-dev towards the end as
+# it is meant to pick up remaining dev libraries and headers that aren't
+# picked up by other packages. And since some static libraries needs to
+# be packaged in ${PN}-dev, so we need to keep ${PN}-staticdev later in
+# order.
+
+PACKAGES := "${@oe.utils.str_filter_out('${PN}-dev', '${PACKAGES}', d)}"
+PACKAGES := "${@oe.utils.str_filter_out('${PN}-staticdev', '${PACKAGES}', d)}"
+PACKAGES += "\
+ ${PN}-dev \
+ ${PN}-staticdev \
+"
+
+INSANE_SKIP:${PN}-dbg = "staticdev"
+INSANE_SKIP:${PN}-utils += "ldflags"
+INSANE_SKIP:libstdc++ += "ldflags"
+INSANE_SKIP:libgfortran += "ldflags"
+INSANE_SKIP:libgcc += "ldflags dev-deps"
+INSANE_SKIP:libgcc-dev += "staticdev"
+INSANE_SKIP:libgfortran += "ldflags dev-deps"
+INSANE_SKIP:libstdc++ += "ldflags dev-deps"
+INSANE_SKIP:libatomic += "ldflags"
+INSANE_SKIP:libasan += "ldflags"
+INSANE_SKIP:libubsan += "ldflags"
+INSANE_SKIP:libssp += "ldflags"
+INSANE_SKIP:libgomp += "ldflags"
+INSANE_SKIP:libitm += "ldflags"
+INSANE_SKIP:gdbserver += "ldflags"
+
+# OE-core has literally listed 'glibc' in LIBC_DEPENDENCIES :/
+RPROVIDES:${PN} = "glibc rtld(GNU_HASH)"
+# Add runtime provides for the other libc* packages as well
+RPROVIDES:${PN}-dev = "glibc-dev"
+RPROVIDES:${PN}-doc = "glibc-doc"
+RPROVIDES:${PN}-dbg = "glibc-dbg"
+RPROVIDES:${PN}-pic = "glibc-pic"
+RPROVIDES:${PN}-utils = "glibc-utils"
+RPROVIDES:${PN}-mtrace = "glibc-mtrace libc-mtrace"
+
+PKG:${PN} = "glibc"
+PKG:${PN}-dev = "glibc-dev"
+PKG:${PN}-doc = "glibc-doc"
+PKG:${PN}-dbg = "glibc-dbg"
+PKG:${PN}-pic = "glibc-pic"
+PKG:${PN}-utils = "glibc-utils"
+PKG:${PN}-mtrace = "glibc-mtrace"
+PKG:${PN}-gconv = "glibc-gconv"
+PKG:${PN}-extra-nss = "glibc-extra-nss"
+PKG:${PN}-thread-db = "glibc-thread-db"
+PKG:${PN}-pcprofile = "glibc-pcprofile"
+PKG:${PN}-staticdev = "glibc-staticdev"
+
+PKGV = "${EAT_VER_LIBC}"
+PKGV:${PN} = "${EAT_VER_LIBC}"
+PKGV:${PN}-dev = "${EAT_VER_LIBC}"
+PKGV:${PN}-doc = "${EAT_VER_LIBC}"
+PKGV:${PN}-dbg = "${EAT_VER_LIBC}"
+PKGV:${PN}-pic = "${EAT_VER_LIBC}"
+PKGV:${PN}-utils = "${EAT_VER_LIBC}"
+PKGV:${PN}-mtrace = "${EAT_VER_LIBC}"
+PKGV:${PN}-gconv = "${EAT_VER_LIBC}"
+PKGV:${PN}-extra-nss = "${EAT_VER_LIBC}"
+PKGV:${PN}-thread-db = "${EAT_VER_LIBC}"
+PKGV:${PN}-pcprofile = "${EAT_VER_LIBC}"
+PKGV:${PN}-staticdev = "${EAT_VER_LIBC}"
+PKGV:catchsegv = "${EAT_VER_LIBC}"
+PKGV:glibc-extra-nss = "${EAT_VER_LIBC}"
+PKGV:glibc-thread-db = "${EAT_VER_LIBC}"
+
+PKGV:libmemusage = "${EAT_VER_LIBC}"
+PKGV:libsegfault = "${EAT_VER_LIBC}"
+PKGV:libsotruss = "${EAT_VER_LIBC}"
+PKGV:sln = "${EAT_VER_LIBC}"
+PKGV:nscd = "${EAT_VER_LIBC}"
+PKGV:ldd = "${EAT_VER_LIBC}"
+
+PKGV:libasan-dev = "${EAT_VER_GCC}"
+PKGV:libasan = "${EAT_VER_GCC}"
+PKGV:libasan-staticdev = "${EAT_VER_GCC}"
+PKGV:libatomic-dev = "${EAT_VER_GCC}"
+PKGV:libatomic = "${EAT_VER_GCC}"
+PKGV:libatomic-staticdev = "${EAT_VER_GCC}"
+PKGV:libg2c-dev = "${EAT_VER_GCC}"
+PKGV:libg2c = "${EAT_VER_GCC}"
+PKGV:libgcc-dev = "${EAT_VER_GCC}"
+PKGV:libgcc = "${EAT_VER_GCC}"
+PKGV:libgfortran-dbg = "${EAT_VER_GCC}"
+PKGV:libgfortran-dev = "${EAT_VER_GCC}"
+PKGV:libgfortran = "${EAT_VER_GCC}"
+PKGV:libgfortran-staticdev = "${EAT_VER_GCC}"
+PKGV:libgomp-dev = "${EAT_VER_GCC}"
+PKGV:libgomp = "${EAT_VER_GCC}"
+PKGV:libgomp-staticdev = "${EAT_VER_GCC}"
+PKGV:libitm-dev = "${EAT_VER_GCC}"
+PKGV:libitm = "${EAT_VER_GCC}"
+PKGV:libitm-staticdev = "${EAT_VER_GCC}"
+PKGV:liblsan-dev = "${EAT_VER_GCC}"
+PKGV:liblsan = "${EAT_VER_GCC}"
+PKGV:liblsan-staticdev = "${EAT_VER_GCC}"
+PKGV:libmudflap-dev = "${EAT_VER_GCC}"
+PKGV:libmudflap = "${EAT_VER_GCC}"
+PKGV:libmudflap-staticdev = "${EAT_VER_GCC}"
+PKGV:libquadmath-dev = "${EAT_VER_GCC}"
+PKGV:libquadmath = "${EAT_VER_GCC}"
+PKGV:libquadmath-staticdev = "${EAT_VER_GCC}"
+PKGV:libssp-dev = "${EAT_VER_GCC}"
+PKGV:libssp = "${EAT_VER_GCC}"
+PKGV:libssp-staticdev = "${EAT_VER_GCC}"
+PKGV:libstdc++-dbg = "${EAT_VER_GCC}"
+PKGV:libstdc++-dev = "${EAT_VER_GCC}"
+PKGV:libstdc++ = "${EAT_VER_GCC}"
+PKGV:libstdc++-precompile-dev = "${EAT_VER_GCC}"
+PKGV:libstdc++-staticdev = "${EAT_VER_GCC}"
+PKGV:libtsan-dev = "${EAT_VER_GCC}"
+PKGV:libtsan = "${EAT_VER_GCC}"
+PKGV:libtsan-staticdev = "${EAT_VER_GCC}"
+PKGV:libubsan-dev = "${EAT_VER_GCC}"
+PKGV:libubsan = "${EAT_VER_GCC}"
+PKGV:libubsan-staticdev = "${EAT_VER_GCC}"
+
+PKGV:linux-libc-headers-dev = "${EAT_VER_KERNEL}"
+PKGV:linux-libc-headers = "${EAT_VER_KERNEL}"
+
+PKGV:gdbserver = "${EAT_VER_GDBSERVER}"
+
+ALLOW_EMPTY:${PN}-mtrace = "1"
+FILES:${PN}-mtrace = "${bindir}/mtrace"
+
+FILES:libgcov-staticdev = "${libdir}/gcc/${TARGET_SYS}/${BINV}/libgcov.a"
+
+FILES:libsegfault = "${base_libdir}/libSegFault*"
+
+FILES:catchsegv = "${bindir}/catchsegv"
+RDEPENDS:catchsegv = "libsegfault"
+
+# From libgfortran.inc:
+
+FILES:libgfortran = "${libdir}/libgfortran.so.*"
+FILES:libgfortran-dev = "\
+ ${libdir}/libgfortran*.so \
+ ${libdir}/libgfortran.spec \
+ ${libdir}/libgfortran.la \
+ ${libdir}/gcc/${TARGET_SYS}/${BINV}/libgfortranbegin.* \
+ ${libdir}/gcc/${TARGET_SYS}/${BINV}/libcaf_single* \
+ ${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude/ \
+"
+FILES:libgfortran-staticdev = "${libdir}/libgfortran.a"
+
+
+# From gcc-sanitizers.inc:
+
+FILES:libasan += "${libdir}/libasan.so.*"
+FILES:libasan-dev += "\
+ ${libdir}/libasan_preinit.o \
+ ${libdir}/libasan.so \
+ ${libdir}/libasan.la \
+"
+FILES:libasan-staticdev += "${libdir}/libasan.a"
+
+FILES:libubsan += "${libdir}/libubsan.so.*"
+FILES:libubsan-dev += "\
+ ${libdir}/libubsan.so \
+ ${libdir}/libubsan.la \
+"
+FILES:libubsan-staticdev += "${libdir}/libubsan.a"
+
+FILES:liblsan += "${libdir}/liblsan.so.*"
+FILES:liblsan-dev += "\
+ ${libdir}/liblsan.so \
+ ${libdir}/liblsan.la \
+ ${libdir}/liblsan_preinit.o \
+"
+FILES:liblsan-staticdev += "${libdir}/liblsan.a"
+
+FILES:libtsan += "${libdir}/libtsan.so.*"
+FILES:libtsan-dev += "\
+ ${libdir}/libtsan.so \
+ ${libdir}/libtsan.la \
+ ${libdir}/libtsan_*.o \
+"
+FILES:libtsan-staticdev += "${libdir}/libtsan.a"
+
+FILES:gcc-sanitizers = "${libdir}/*.spec ${libdir}/gcc/${TARGET_SYS}/${BINV}/include/sanitizer/*.h"
+
+# From libgcc.inc:
+
+FILES:libgcc = "${base_libdir}/libgcc_s.so.1"
+
+FILES:libgcc-dev = "\
+ ${base_libdir}/libgcc*.so \
+ ${@oe.utils.conditional('BASETARGET_SYS', '${TARGET_SYS}', '', '${libdir}/${BASETARGET_SYS}', d)} \
+ ${libdir}/${TARGET_SYS}/${BINV}* \
+ ${libdir}/${TARGET_ARCH}${TARGET_VENDOR}* \
+ ${libdir}/gcc/${TARGET_SYS}/${BINV}/include \
+"
+
+FILES:linux-libc-headers = ""
+FILES:linux-libc-headers-dev = "\
+ ${includedir}/asm* \
+ ${includedir}/linux \
+ ${includedir}/mtd \
+ ${includedir}/rdma \
+ ${includedir}/scsi \
+ ${includedir}/sound \
+ ${includedir}/video \
+"
+FILES:${PN} += "\
+ ${libdir}/bin \
+ ${libdir}/locale \
+ ${libdir}/gconv/gconv-modules \
+ ${datadir}/zoneinfo \
+ ${base_libdir}/libcrypt*.so.* \
+ ${base_libdir}/libcrypt-*.so \
+ ${base_libdir}/libc.so.* \
+ ${base_libdir}/libc-*.so \
+ ${base_libdir}/libm.so.* \
+ ${base_libdir}/libmemusage.so \
+ ${base_libdir}/libm-*.so \
+ ${base_libdir}/ld*.so.* \
+ ${base_libdir}/ld-*.so \
+ ${base_libdir}/libpthread*.so.* \
+ ${base_libdir}/libpthread*.so \
+ ${base_libdir}/libpthread-*.so \
+ ${base_libdir}/libresolv*.so.* \
+ ${base_libdir}/libresolv-*.so \
+ ${base_libdir}/librt*.so.* \
+ ${base_libdir}/librt-*.so \
+ ${base_libdir}/libutil*.so.* \
+ ${base_libdir}/libutil-*.so \
+ ${base_libdir}/libnss_files*.so.* \
+ ${base_libdir}/libnss_files-*.so \
+ ${base_libdir}/libnss_compat*.so.* \
+ ${base_libdir}/libnss_compat-*.so \
+ ${base_libdir}/libnss_dns*.so.* \
+ ${base_libdir}/libnss_dns-*.so \
+ ${base_libdir}/libnss_nis*.so.* \
+ ${base_libdir}/libnss_nisplus-*.so \
+ ${base_libdir}/libnss_nisplus*.so.* \
+ ${base_libdir}/libnss_nis-*.so \
+ ${base_libdir}/libnss_hesiod*.so.* \
+ ${base_libdir}/libnss_hesiod-*.so \
+ ${base_libdir}/libdl*.so.* \
+ ${base_libdir}/libdl-*.so \
+ ${base_libdir}/libanl*.so.* \
+ ${base_libdir}/libanl-*.so \
+ ${base_libdir}/libBrokenLocale*.so.* \
+ ${base_libdir}/libBrokenLocale-*.so \
+ ${base_libdir}/libthread_db*.so.* \
+ ${base_libdir}/libthread_db-*.so \
+ ${base_libdir}/libmemusage.so \
+ ${base_libdir}/libSegFault.so \
+ ${base_libdir}/libpcprofile.so \
+ "
+
+FILES:${PN}-dbg += "${base_libdir}/debug"
+
+# From gcc-runtime.inc
+
+# include python debugging scripts
+FILES:gcc-runtime-dbg += "\
+ ${libdir}/libstdc++.so.*-gdb.py \
+ ${datadir}/gcc-${BINV}/python/libstdcxx \
+"
+
+FILES:libg2c = "${target_libdir}/libg2c.so.*"
+SUMMARY:libg2c = "Companion runtime library for g77"
+FILES:libg2c-dev = "\
+ ${libdir}/libg2c.so \
+ ${libdir}/libg2c.a \
+ ${libdir}/libfrtbegin.a \
+"
+SUMMARY:libg2c-dev = "Companion runtime library for g77 - development files"
+
+FILES:libstdc++ = "${libdir}/libstdc++.so.*"
+SUMMARY:libstdc++ = "GNU standard C++ library"
+FILES:libstdc++-dev = "\
+ /include/c++ \
+ ${includedir}/c++/ \
+ ${libdir}/libstdc++.so \
+ ${libdir}/libstdc++*.la \
+ ${libdir}/libsupc++.la \
+"
+SUMMARY:libstdc++-dev = "GNU standard C++ library - development files"
+
+FILES:libstdc++-staticdev = "\
+ ${libdir}/libstdc++*.a \
+ ${libdir}/libsupc++.a \
+"
+SUMMARY:libstdc++-staticdev = "GNU standard C++ library - static development files"
+
+FILES:libstdc++-precompile-dev = "${includedir}/c++/${TARGET_SYS}/bits/*.gch"
+SUMMARY:libstdc++-precompile-dev = "GNU standard C++ library - precompiled header files"
+
+FILES:libssp = "${libdir}/libssp.so.*"
+SUMMARY:libssp = "GNU stack smashing protection library"
+FILES:libssp-dev = "\
+ ${libdir}/libssp*.so \
+ ${libdir}/libssp*_nonshared.a \
+ ${libdir}/libssp*.la \
+ ${libdir}/gcc/${TARGET_SYS}/${BINV}/include/ssp \
+"
+SUMMARY:libssp-dev = "GNU stack smashing protection library - development files"
+FILES:libssp-staticdev = "${libdir}/libssp*.a"
+SUMMARY:libssp-staticdev = "GNU stack smashing protection library - static development files"
+
+FILES:libquadmath = "${libdir}/libquadmath*.so.*"
+SUMMARY:libquadmath = "GNU quad-precision math library"
+FILES:libquadmath-dev = "\
+ ${libdir}/gcc/${TARGET_SYS}/${BINV}/include/quadmath* \
+ ${libdir}/libquadmath*.so \
+ ${libdir}/libquadmath.la \
+"
+SUMMARY:libquadmath-dev = "GNU quad-precision math library - development files"
+FILES:libquadmath-staticdev = "${libdir}/libquadmath.a"
+SUMMARY:libquadmath-staticdev = "GNU quad-precision math library - static development files"
+
+# NOTE: mudflap has been removed as of gcc 4.9 and has been superseded by the address sanitiser
+FILES:libmudflap = "${libdir}/libmudflap*.so.*"
+SUMMARY:libmudflap = "Pointer debugging library for gcc"
+FILES:libmudflap-dev = "\
+ ${libdir}/libmudflap*.so \
+ ${libdir}/libmudflap.la \
+"
+SUMMARY:libmudflap-dev = "Pointer debugging library for gcc - development files"
+FILES:libmudflap-staticdev = "${libdir}/libmudflap.a"
+SUMMARY:libmudflap-staticdev = "Pointer debugging library for gcc - static development files"
+
+FILES:libgomp = "${libdir}/libgomp*${SOLIBS}"
+SUMMARY:libgomp = "GNU OpenMP parallel programming library"
+FILES:libgomp-dev = "\
+ ${libdir}/libgomp*${SOLIBSDEV} \
+ ${libdir}/libgomp*.la \
+ ${libdir}/libgomp.spec \
+ ${libdir}/gcc/${TARGET_SYS}/${BINV}/include/omp.h \
+ ${libdir}/gcc/${TARGET_SYS}/${BINV}/include/openacc.h \
+"
+SUMMARY:libgomp-dev = "GNU OpenMP parallel programming library - development files"
+FILES:libgomp-staticdev = "${libdir}/libgomp*.a"
+SUMMARY:libgomp-staticdev = "GNU OpenMP parallel programming library - static development files"
+
+FILES:libatomic = "${libdir}/libatomic.so.*"
+SUMMARY:libatomic = "GNU C++11 atomics support library"
+FILES:libatomic-dev = "\
+ ${libdir}/libatomic.so \
+ ${libdir}/libatomic.la \
+"
+SUMMARY:libatomic-dev = "GNU C++11 atomics support library - development files"
+FILES:libatomic-staticdev = "${libdir}/libatomic.a"
+SUMMARY:libatomic-staticdev = "GNU C++11 atomics support library - static development files"
+
+FILES:libitm = "${libdir}/libitm.so.*"
+SUMMARY:libitm = "GNU transactional memory support library"
+FILES:libitm-dev = "\
+ ${libdir}/libitm.so \
+ ${libdir}/libitm.la \
+ ${libdir}/libitm.spec \
+"
+SUMMARY:libitm-dev = "GNU transactional memory support library - development files"
+FILES:libitm-staticdev = "${libdir}/libitm.a"
+SUMMARY:libitm-staticdev = "GNU transactional memory support library - static development files"
+
+EAT_VER_MAIN ??= ""
+
+python () {
+ if not d.getVar("EAT_VER_MAIN", False):
+ raise bb.parse.SkipPackage("External ARM toolchain not configured (EAT_VER_MAIN not set).")
+ if d.getVar('TCLIBC', True) != "glibc":
+ raise bb.parse.SkipPackage("incompatible with %s" % d.getVar('TCLIBC', True))
+}
--
2.25.1
^ permalink raw reply related [flat|nested] 9+ messages in thread
* [PATCH 3/3] CI: use external-arm-toolchain 10.3
2022-05-17 12:28 [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe Ross Burton
2022-05-17 12:28 ` [PATCH 2/3] arm-toolchain/external-arm-toolchain: add back 10.3 Ross Burton
@ 2022-05-17 12:28 ` Ross Burton
2022-05-17 15:23 ` [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe Jon Mason
` (2 subsequent siblings)
4 siblings, 0 replies; 9+ messages in thread
From: Ross Burton @ 2022-05-17 12:28 UTC (permalink / raw)
To: meta-arm; +Cc: nd
The 11.2 release of the Arm GCC uses Broadwell-onwards instructions, but
our CI (and many other users) have pre-Broadwell hardware.
Until 11.3 is released which fixes this, go back to using 10.3 for our CI.
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
ci/external-gccarm.yml | 1 +
ci/get-binary-toolchains | 2 +-
2 files changed, 2 insertions(+), 1 deletion(-)
diff --git a/ci/external-gccarm.yml b/ci/external-gccarm.yml
index 2af8b5e8..84c2cfa2 100644
--- a/ci/external-gccarm.yml
+++ b/ci/external-gccarm.yml
@@ -5,4 +5,5 @@ local_conf_header:
cc: |
SKIP_RECIPE[gcc-cross-arm] = "Using external toolchain"
TCMODE = "external-arm"
+ PREFERRED_VERSION_external-arm-toolchain = "10.3-2021.07"
EXTERNAL_TOOLCHAIN = "${TOPDIR}/toolchains/${TARGET_ARCH}"
diff --git a/ci/get-binary-toolchains b/ci/get-binary-toolchains
index bfdd8c57..cd4c25ef 100755
--- a/ci/get-binary-toolchains
+++ b/ci/get-binary-toolchains
@@ -2,7 +2,7 @@
set -u
HOST_ARCH=$(uname -m)
-VER="11.2-2022.02"
+VER="10.3-2021.07"
DOWNLOAD_DIR=$1
TOOLCHAIN_DIR=$2
--
2.25.1
^ permalink raw reply related [flat|nested] 9+ messages in thread
* Re: [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
2022-05-17 12:28 [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe Ross Burton
2022-05-17 12:28 ` [PATCH 2/3] arm-toolchain/external-arm-toolchain: add back 10.3 Ross Burton
2022-05-17 12:28 ` [PATCH 3/3] CI: use external-arm-toolchain 10.3 Ross Burton
@ 2022-05-17 15:23 ` Jon Mason
2022-05-17 16:07 ` [meta-arm] " Sumit Garg
2022-05-18 20:29 ` Jon Mason
2022-05-23 15:42 ` Jon Mason
4 siblings, 1 reply; 9+ messages in thread
From: Jon Mason @ 2022-05-17 15:23 UTC (permalink / raw)
To: meta-arm, Ross Burton; +Cc: nd
On Tue, 17 May 2022 13:28:16 +0100, Ross Burton wrote:
> We need to support multiple versions of external-arm-toolchain, partly as
> different versions have different layouts on disk, and partly because
> 11.2 doesn't work on pre-Broadwell hardware.
>
> Rename this recipe so the version is in the filename, and dynamically
> set PKGV instead of PV so PREFERRED_VERSION is easier to use.
Applied, thanks!
[1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
commit: ac83feb7cd16265d4e8ee0ed50dba903306867e5
[2/3] arm-toolchain/external-arm-toolchain: add back 10.3
commit: 5fec85b41d7263dcc8aa15351beb7c19e2017849
[3/3] CI: use external-arm-toolchain 10.3
commit: 4c6ccb833c1ac379df3efa02136e03067d89ef3e
Best regards,
--
Jon Mason <jon.mason@arm.com>
^ permalink raw reply [flat|nested] 9+ messages in thread
* Re: [meta-arm] [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
2022-05-17 15:23 ` [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe Jon Mason
@ 2022-05-17 16:07 ` Sumit Garg
2022-05-17 16:50 ` Ross Burton
2022-05-22 19:15 ` Denys Dmytriyenko
0 siblings, 2 replies; 9+ messages in thread
From: Sumit Garg @ 2022-05-17 16:07 UTC (permalink / raw)
To: Jon Mason; +Cc: meta-arm, Ross Burton, nd, Denys Dmytriyenko
+ Denys
Hi Jon,
On Tue, 17 May 2022 at 20:54, Jon Mason <jdmason@kudzu.us> wrote:
>
> On Tue, 17 May 2022 13:28:16 +0100, Ross Burton wrote:
> > We need to support multiple versions of external-arm-toolchain, partly as
> > different versions have different layouts on disk, and partly because
> > 11.2 doesn't work on pre-Broadwell hardware.
> >
> > Rename this recipe so the version is in the filename, and dynamically
> > set PKGV instead of PV so PREFERRED_VERSION is easier to use.
>
> Applied, thanks!
>
> [1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
> commit: ac83feb7cd16265d4e8ee0ed50dba903306867e5
> [2/3] arm-toolchain/external-arm-toolchain: add back 10.3
> commit: 5fec85b41d7263dcc8aa15351beb7c19e2017849
Can you please revert these two patches? We don't need duplicates for
external-arm-toolchain recipe. The latest version supports both 11.2
and 10.3. So the only thing that's required is patch #3.
-Sumit
> [3/3] CI: use external-arm-toolchain 10.3
> commit: 4c6ccb833c1ac379df3efa02136e03067d89ef3e
>
> Best regards,
> --
> Jon Mason <jon.mason@arm.com>
>
> -=-=-=-=-=-=-=-=-=-=-=-
> Links: You receive all messages sent to this group.
> View/Reply Online (#3420): https://lists.yoctoproject.org/g/meta-arm/message/3420
> Mute This Topic: https://lists.yoctoproject.org/mt/91162100/1777089
> Group Owner: meta-arm+owner@lists.yoctoproject.org
> Unsubscribe: https://lists.yoctoproject.org/g/meta-arm/unsub [sumit.garg@linaro.org]
> -=-=-=-=-=-=-=-=-=-=-=-
>
^ permalink raw reply [flat|nested] 9+ messages in thread
* Re: [meta-arm] [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
2022-05-17 16:07 ` [meta-arm] " Sumit Garg
@ 2022-05-17 16:50 ` Ross Burton
2022-05-22 19:15 ` Denys Dmytriyenko
1 sibling, 0 replies; 9+ messages in thread
From: Ross Burton @ 2022-05-17 16:50 UTC (permalink / raw)
To: Sumit Garg, Jon Mason; +Cc: meta-arm, nd, Denys Dmytriyenko
[-- Attachment #1: Type: text/plain, Size: 1993 bytes --]
:facepalm:
Testing now, thanks.
Ross
From: Sumit Garg <sumit.garg@linaro.org>
Date: Tuesday, 17 May 2022 at 17:07
To: Jon Mason <jdmason@kudzu.us>
Cc: meta-arm@lists.yoctoproject.org <meta-arm@lists.yoctoproject.org>, Ross Burton <Ross.Burton@arm.com>, nd <nd@arm.com>, Denys Dmytriyenko <denis@denix.org>
Subject: Re: [meta-arm] [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
+ Denys
Hi Jon,
On Tue, 17 May 2022 at 20:54, Jon Mason <jdmason@kudzu.us> wrote:
>
> On Tue, 17 May 2022 13:28:16 +0100, Ross Burton wrote:
> > We need to support multiple versions of external-arm-toolchain, partly as
> > different versions have different layouts on disk, and partly because
> > 11.2 doesn't work on pre-Broadwell hardware.
> >
> > Rename this recipe so the version is in the filename, and dynamically
> > set PKGV instead of PV so PREFERRED_VERSION is easier to use.
>
> Applied, thanks!
>
> [1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
> commit: ac83feb7cd16265d4e8ee0ed50dba903306867e5
> [2/3] arm-toolchain/external-arm-toolchain: add back 10.3
> commit: 5fec85b41d7263dcc8aa15351beb7c19e2017849
Can you please revert these two patches? We don't need duplicates for
external-arm-toolchain recipe. The latest version supports both 11.2
and 10.3. So the only thing that's required is patch #3.
-Sumit
> [3/3] CI: use external-arm-toolchain 10.3
> commit: 4c6ccb833c1ac379df3efa02136e03067d89ef3e
>
> Best regards,
> --
> Jon Mason <jon.mason@arm.com>
>
> -=-=-=-=-=-=-=-=-=-=-=-
> Links: You receive all messages sent to this group.
> View/Reply Online (#3420): https://lists.yoctoproject.org/g/meta-arm/message/3420
> Mute This Topic: https://lists.yoctoproject.org/mt/91162100/1777089
> Group Owner: meta-arm+owner@lists.yoctoproject.org
> Unsubscribe: https://lists.yoctoproject.org/g/meta-arm/unsub [sumit.garg@linaro.org]
> -=-=-=-=-=-=-=-=-=-=-=-
>
[-- Attachment #2: Type: text/html, Size: 4854 bytes --]
^ permalink raw reply [flat|nested] 9+ messages in thread
* Re: [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
2022-05-17 12:28 [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe Ross Burton
` (2 preceding siblings ...)
2022-05-17 15:23 ` [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe Jon Mason
@ 2022-05-18 20:29 ` Jon Mason
2022-05-23 15:42 ` Jon Mason
4 siblings, 0 replies; 9+ messages in thread
From: Jon Mason @ 2022-05-18 20:29 UTC (permalink / raw)
To: meta-arm, Ross Burton; +Cc: nd
On Tue, 17 May 2022 13:28:16 +0100, Ross Burton wrote:
> We need to support multiple versions of external-arm-toolchain, partly as
> different versions have different layouts on disk, and partly because
> 11.2 doesn't work on pre-Broadwell hardware.
>
> Rename this recipe so the version is in the filename, and dynamically
> set PKGV instead of PV so PREFERRED_VERSION is easier to use.
Applied, thanks!
[1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
(no commit info)
[2/3] arm-toolchain/external-arm-toolchain: add back 10.3
(no commit info)
[3/3] CI: use external-arm-toolchain 10.3
commit: fc09cc0e8db287600625e64905170a6de24f2686
Best regards,
--
Jon Mason <jon.mason@arm.com>
^ permalink raw reply [flat|nested] 9+ messages in thread
* Re: [meta-arm] [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
2022-05-17 16:07 ` [meta-arm] " Sumit Garg
2022-05-17 16:50 ` Ross Burton
@ 2022-05-22 19:15 ` Denys Dmytriyenko
1 sibling, 0 replies; 9+ messages in thread
From: Denys Dmytriyenko @ 2022-05-22 19:15 UTC (permalink / raw)
To: Sumit Garg; +Cc: Jon Mason, meta-arm, Ross Burton, nd
On Tue, May 17, 2022 at 09:37:25PM +0530, Sumit Garg wrote:
> + Denys
>
> Hi Jon,
>
> On Tue, 17 May 2022 at 20:54, Jon Mason <jdmason@kudzu.us> wrote:
> >
> > On Tue, 17 May 2022 13:28:16 +0100, Ross Burton wrote:
> > > We need to support multiple versions of external-arm-toolchain, partly as
> > > different versions have different layouts on disk, and partly because
> > > 11.2 doesn't work on pre-Broadwell hardware.
> > >
> > > Rename this recipe so the version is in the filename, and dynamically
> > > set PKGV instead of PV so PREFERRED_VERSION is easier to use.
> >
> > Applied, thanks!
> >
> > [1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
> > commit: ac83feb7cd16265d4e8ee0ed50dba903306867e5
> > [2/3] arm-toolchain/external-arm-toolchain: add back 10.3
> > commit: 5fec85b41d7263dcc8aa15351beb7c19e2017849
>
> Can you please revert these two patches? We don't need duplicates for
> external-arm-toolchain recipe. The latest version supports both 11.2
> and 10.3. So the only thing that's required is patch #3.
Sorry, I was traveling last week and missed this. As Sumit correctly says, the
recipe is version agnostic on purpose and supports multiple versions of the
binary toolchain.
--
Denys
^ permalink raw reply [flat|nested] 9+ messages in thread
* Re: [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
2022-05-17 12:28 [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe Ross Burton
` (3 preceding siblings ...)
2022-05-18 20:29 ` Jon Mason
@ 2022-05-23 15:42 ` Jon Mason
4 siblings, 0 replies; 9+ messages in thread
From: Jon Mason @ 2022-05-23 15:42 UTC (permalink / raw)
To: meta-arm, Ross Burton; +Cc: nd
On Tue, 17 May 2022 13:28:16 +0100, Ross Burton wrote:
> We need to support multiple versions of external-arm-toolchain, partly as
> different versions have different layouts on disk, and partly because
> 11.2 doesn't work on pre-Broadwell hardware.
>
> Rename this recipe so the version is in the filename, and dynamically
> set PKGV instead of PV so PREFERRED_VERSION is easier to use.
Applied, thanks!
[1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe
(no commit info)
[2/3] arm-toolchain/external-arm-toolchain: add back 10.3
(no commit info)
[3/3] CI: use external-arm-toolchain 10.3
commit: fc09cc0e8db287600625e64905170a6de24f2686
Best regards,
--
Jon Mason <jon.mason@arm.com>
^ permalink raw reply [flat|nested] 9+ messages in thread
end of thread, other threads:[~2022-05-23 17:02 UTC | newest]
Thread overview: 9+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2022-05-17 12:28 [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe Ross Burton
2022-05-17 12:28 ` [PATCH 2/3] arm-toolchain/external-arm-toolchain: add back 10.3 Ross Burton
2022-05-17 12:28 ` [PATCH 3/3] CI: use external-arm-toolchain 10.3 Ross Burton
2022-05-17 15:23 ` [PATCH 1/3] arm-toolchain/external-arm-toolchain: set the version in the recipe Jon Mason
2022-05-17 16:07 ` [meta-arm] " Sumit Garg
2022-05-17 16:50 ` Ross Burton
2022-05-22 19:15 ` Denys Dmytriyenko
2022-05-18 20:29 ` Jon Mason
2022-05-23 15:42 ` Jon Mason
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.