[PATCH] ofono: libqofono: Added libqofono recipe

* [PATCH] ofono: libqofono: Added libqofono recipe
@ 2013-09-30 17:16 Felipe F. Tonello
  2013-10-04 14:21 ` Martin Jansa
  0 siblings, 1 reply; 4+ messages in thread
From: Felipe F. Tonello @ 2013-09-30 17:16 UTC (permalink / raw)
  To: openembedded-devel

From: "Felipe F. Tonello" <eu@felipetonello.com>

libqofono is a Qt library for oFono that provides easy to use Qt library and
QML components to use oFono.

OBS: This recipe provides the Qt4 support only, but the library also works
with Qt5.

Signed-off-by: Felipe F. Tonello <eu@felipetonello.com>
---
 meta-oe/recipes-qt/libqofono/libqofono_0.4.bb | 88 +++++++++++++++++++++++++++
 1 file changed, 88 insertions(+)
 create mode 100644 meta-oe/recipes-qt/libqofono/libqofono_0.4.bb

diff --git a/meta-oe/recipes-qt/libqofono/libqofono_0.4.bb b/meta-oe/recipes-qt/libqofono/libqofono_0.4.bb
new file mode 100644
index 0000000..7c34db2
--- /dev/null
+++ b/meta-oe/recipes-qt/libqofono/libqofono_0.4.bb
@@ -0,0 +1,88 @@
+DESCRIPTION = "Qt Library for oFono"
+HOMEPAGE = "https://github.com/nemomobile/libqofono"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://README;endline=3;md5=8a15bce3921d1238d9a9f23828612947"
+
+SECTION = "qt/lib"
+
+PR = "r0"
+
+inherit qt4x11 pkgconfig
+
+RDEPENDS_${PN} = "ofono"
+RDEPENDS_${PN}-plugin = "${PN}"
+
+PROVIDES += "${PN}-plugin"
+
+PACKAGES =+ "${PN}-plugin ${PN}-plugin-dbg ${PN}-test"
+RRECOMMENDS_${PN} = "${PN}-plugin"
+
+BRANCH = "master"
+TAG = "${PV}"
+
+SRC_URI = " \
+  git://github.com/nemomobile/${PN}.git;branch=${BRANCH};tag=${TAG} \
+"
+
+S = "${WORKDIR}/git"
+
+QT_IMPORTS_DIR = "${libdir}/qt4/imports"
+PLUGINS_TARGET = "${QT_IMPORTS_DIR}/MeeGo/QOfono"
+
+FILES_${PN} = " \
+  ${libdir}/libqofono${SOLIBS} \
+"
+
+FILES_${PN}-dev = " \
+  ${includedir}/qofono/* \
+  ${includedir}/qofono/dbus/* \
+  ${libdir}/libqofono${SOLIBSDEV} \
+  ${libdir}/libqofono.prl \
+  ${libdir}/pkgconfig/qofono.pc \
+  ${datadir}/qt4/mkspecs/features/qofono.prf \
+"
+
+FILES_${PN}-plugin = " \
+  ${PLUGINS_TARGET}/qmldir \
+  ${PLUGINS_TARGET}/lib*.so \
+"
+
+FILES_${PN}-plugin-dbg = " \
+  ${PLUGINS_TARGET}/.debug \
+"
+
+FILES_${PN}-test = " \
+  /opt/ofonotest/bin/ofonotest \
+  /opt/ofonotest/qml/ofonotest \
+  ${libdir}/libqofono/tests/tst_qofonotest \
+"
+
+FILES_${PN}-dbg += " \
+  /opt/ofonotest/bin/.debug \
+  ${libdir}/libqofono/tests/.debug \
+"
+
+EXTRA_QMAKEVARS_PRE = " \
+  PREFIX=${prefix} \
+"
+
+do_configure_prepend() {
+  # Hack *.pro variables
+  find . -iname '*.pro' -exec sed -i -e 's,$$\[QT_INSTALL_IMPORTS\],${QT_IMPORTS_DIR},g' '{}' ';'
+  find . -iname '*.pro' -exec sed -i -e 's,$$\[QT_INSTALL_PREFIX\],$$INSTALL_ROOT$$PREFIX,g' '{}' ';'
+}
+
+do_install() {
+  cd ${S} && (INSTALL_ROOT=${D} oe_runmake install)
+
+  cd ${D}/${datadir}/qt4/mkspecs/features
+
+  sed -i -e '/DEPENDPATH.*/d' qofono.prf
+  sed -i -e '/INCLUDEPATH.*/d' qofono.prf
+  sed -i -e '/LIBS.*/d' qofono.prf
+
+  # to make it work with the SDK
+  echo 'DEPENDPATH += $(OE_QMAKE_INCDIR_QT)/../qofono' >> qofono.prf
+  echo 'INCLUDEPATH += $(OE_QMAKE_INCDIR_QT)/../qofono' >> qofono.prf
+  echo 'LIBS += -lqofono' >> qofono.prf
+}
-- 
1.8.3.1



^ permalink raw reply related	[flat|nested] 4+ messages in thread