Sam Nelson : hplib: Add recipe for TI high performance library

* Sam Nelson : hplib: Add recipe for TI high performance library
@ 2015-01-21 20:38 Arago Project git
  0 siblings, 0 replies; 2+ messages in thread
From: Arago Project git @ 2015-01-21 20:38 UTC (permalink / raw)
  To: meta-ti

Module: meta-ti
Branch: daisy
Commit: db6bdcd044fceb1f3f923418670faf20ed536be0
URL:    http://arago-project.org/git/meta-ti.git?a=commit;h=db6bdcd044fceb1f3f923418670faf20ed536be0

Author: Sam Nelson <sam.nelson@ti.com>
Date:   Sat Jan 10 09:07:09 2015 +0000

hplib: Add recipe for TI high performance library

- Provides high performance library, kernel module, user space libraries
  and test binaries
- Supports devices k2h, k2k, k2l & k2e

Signed-off-by: Sam Nelson <sam.nelson@ti.com>
Signed-off-by: Denys Dmytriyenko <denys@ti.com>

---

 recipes-bsp/hplib/hplib-mod_git.bb  |   20 ++++++++++++++++++++
 recipes-bsp/hplib/hplib-test_git.bb |   30 ++++++++++++++++++++++++++++++
 recipes-bsp/hplib/hplib.inc         |   10 ++++++++++
 recipes-bsp/hplib/hplib_git.bb      |   30 ++++++++++++++++++++++++++++++
 4 files changed, 90 insertions(+), 0 deletions(-)

diff --git a/recipes-bsp/hplib/hplib-mod_git.bb b/recipes-bsp/hplib/hplib-mod_git.bb
new file mode 100644
index 0000000..acef1ce
--- /dev/null
+++ b/recipes-bsp/hplib/hplib-mod_git.bb
@@ -0,0 +1,20 @@
+DESCRIPTION = "TI High Performance Library kernel module"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://${WORKDIR}/git/ti/runtime/hplib/module/COPYING.txt;md5=c1c4d3453cddc5b7f0ce84a277e66779"
+
+DEPENDS = "hplib"
+
+include hplib.inc
+
+# This package builds a kernel module, use kernel PR as base and append a local
+MACHINE_KERNEL_PR_append = "a+gitr${SRCPV}"
+PR = "${MACHINE_KERNEL_PR}"
+
+S ="${WORKDIR}/git/ti/runtime/hplib/module"
+EXTRA_OEMAKE = "KDIR=${STAGING_KERNEL_DIR} PDK_INSTALL_PATH=${STAGING_INCDIR}"
+
+inherit module
+
+do_install () {
+	oe_runmake install INSTALL_MOD_PATH="${D}"
+}
diff --git a/recipes-bsp/hplib/hplib-test_git.bb b/recipes-bsp/hplib/hplib-test_git.bb
new file mode 100644
index 0000000..574fa2a
--- /dev/null
+++ b/recipes-bsp/hplib/hplib-test_git.bb
@@ -0,0 +1,30 @@
+DESCRIPTION = "TI High performance library test binaries"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${WORKDIR}/git/ti/runtime/hplib/src/COPYING.txt;md5=b7982a377c680ad71ca2fbb735982462"
+
+DEPENDS = "common-csl-ip qmss-lld sa-lld pktlib hplib"
+
+include hplib.inc
+
+CHOICELIST = "yes no"
+
+S = "${WORKDIR}/git/ti/runtime/hplib"
+
+EXTRA_OEMAKE += '-f makefile_armv7 PDK_INSTALL_PATH=${STAGING_INCDIR}'
+
+do_compile () {
+	for device in ${DEVICELIST}
+	do
+		for choice in ${CHOICELIST}
+		do
+			oe_runmake tests HPLIB_SRC_DIR=${S} USEDYNAMIC_LIB=$choice DEVICE="$device"
+		done
+	done
+}
+
+do_install () {
+	for device in ${DEVICELIST}
+	do
+		oe_runmake installbin INSTALL_INC_BASE_DIR=${D}${includedir} INSTALL_LIB_BASE_DIR=${D}${libdir} INSTALL_BIN_BASE_DIR=${D}${bindir} DEVICE="$device"
+	done
+}
diff --git a/recipes-bsp/hplib/hplib.inc b/recipes-bsp/hplib/hplib.inc
new file mode 100644
index 0000000..99254d1
--- /dev/null
+++ b/recipes-bsp/hplib/hplib.inc
@@ -0,0 +1,10 @@
+COMPATIBLE_MACHINE = "keystone"
+
+DEVICELIST = "k2h k2k k2l k2e"
+
+BRANCH = "master"
+SRC_URI = "git://git.ti.com/keystone-rtos/hplib.git;protocol=git;branch=${BRANCH}"
+
+# Below Commit ID corresponds to "DEV.HPLIB.01.01.00.04"
+SRCREV = "89d847bb8155f5727867d82f96978f89ea0a7d13"
+PV = "01.01.00.04"
diff --git a/recipes-bsp/hplib/hplib_git.bb b/recipes-bsp/hplib/hplib_git.bb
new file mode 100644
index 0000000..fbb3004
--- /dev/null
+++ b/recipes-bsp/hplib/hplib_git.bb
@@ -0,0 +1,30 @@
+DESCRIPTION = "TI High performance libraries"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${WORKDIR}/git/ti/runtime/hplib/src/COPYING.txt;md5=b7982a377c680ad71ca2fbb735982462"
+
+DEPENDS = "common-csl-ip rm-lld qmss-lld sa-lld pktlib"
+
+include hplib.inc
+
+CHOICELIST = "yes no"
+
+S = "${WORKDIR}/git/ti/runtime/hplib"
+
+EXTRA_OEMAKE += "-f makefile_armv7 PDK_INSTALL_PATH=${STAGING_INCDIR}"
+
+do_compile () {
+	for device in ${DEVICELIST}
+	do
+		for choice in ${CHOICELIST}
+		do
+			oe_runmake lib HPLIB_SRC_DIR=${S} USEDYNAMIC_LIB=$choice DEVICE="$device"
+		done
+	done
+}
+
+do_install () {
+	for device in ${DEVICELIST}
+	do
+		oe_runmake install INSTALL_INC_BASE_DIR=${D}${includedir} INSTALL_LIB_BASE_DIR=${D}${libdir} INSTALL_BIN_BASE_DIR=${D}${bindir} DEVICE="$device"
+	done
+}



^ permalink raw reply related	[flat|nested] 2+ messages in thread