[PATCH v2 1/4] ti-paths.inc: added path for TI CGT6x 7.x.x

[PATCH v2 1/4] ti-paths.inc: added path for TI CGT6x 7.x.x

[Ivan Pang]

This directory path is for installing TI CGT6x 7.x.x as well as
invoking the installation from other recipes.

Signed-off-by: Ivan Pang <i-pang@ti.com>
---
 recipes-ti/includes/ti-paths.inc | 3 ++-
 1 file changed, 2 insertions(+), 1 deletion(-)

diff --git a/recipes-ti/includes/ti-paths.inc b/recipes-ti/includes/ti-paths.inc
index a7ea9a7..ebd4b8a 100644
--- a/recipes-ti/includes/ti-paths.inc
+++ b/recipes-ti/includes/ti-paths.inc
@@ -55,7 +55,7 @@ export VLIB_C66_INSTALL_DIR_RECIPE        = "${installdir}/ti-vlib-c66x-tree"
 export CG_XML_INSTALL_DIR_RECIPE     = "${installdir}/ti-cg-xml-tree"
 export OMP_INSTALL_DIR_RECIPE        = "${installdir}/ti-omp-tree"
 export MPM_INSTALL_DIR_RECIPE        = "${installdir}/ti-mpm-tree"
-
+export TI_CGT6X_7_INSTALL_DIR_RECIPE   = "${installdir}/cgt6x-7"
 
 # This is where the tools will end up in sysroot
 export BIOS_INSTALL_DIR       = "${STAGING_DIR_TARGET}${BIOS_INSTALL_DIR_RECIPE}"
@@ -101,6 +101,7 @@ export VLIB_C66_INSTALL_DIR        = "${STAGING_DIR_TARGET}${VLIB_C66_INSTALL_DI
 export CG_XML_INSTALL_DIR     = "${STAGING_DIR_NATIVE}${CG_XML_INSTALL_DIR_RECIPE}"
 export OMP_INSTALL_DIR        = "${STAGING_DIR_TARGET}${OMP_INSTALL_DIR_RECIPE}"
 export MPM_INSTALL_DIR        = "${STAGING_DIR_TARGET}${MPM_INSTALL_DIR_RECIPE}"
+export TI_CGT6X_7_INSTALL_DIR   = "${STAGING_DIR_NATIVE}${TI_CGT6X_7_INSTALL_DIR_RECIPE}"
 
 DSPSUFFIX_omapl137 = "x674"
 DSPSUFFIX_omapl138 = "x674"
-- 
1.9.1

[PATCH v2 2/4] ti-cgt6x-7: added recipe for TI CGT6x 7.x.x

[Ivan Pang]

This recipe specifically installs the 7.x.x series of TI CGT6x.

Signed-off-by: Ivan Pang <i-pang@ti.com>
---
 recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb | 37 +++++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb

diff --git a/recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb b/recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb
new file mode 100644
index 0000000..335e0ae
--- /dev/null
+++ b/recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb
@@ -0,0 +1,37 @@
+DESCRIPTION = "TI DSP Code Generation Tools"
+HOMEPAGE = "https://www-a.ti.com/downloads/sds_support/TICodegenerationTools/download.htm"
+LICENSE = "TI"
+
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=b6311962635a4f15630e36ec2d875eca"
+
+PE = "0"
+PR = "r0"
+
+S = "${WORKDIR}/c6000_7.4.16"
+
+inherit native
+require recipes-ti/includes/ti-paths.inc
+require recipes-ti/includes/ti-unpack.inc
+
+BINFILE = "ti_cgt_c6000_7.4.16_linux_installer_x86.bin"
+BINFILE_NAME = "cgt6x_7.4.16_x86_installer"
+TI_BIN_UNPK_ARGS = "--prefix ${WORKDIR} --mode unattended"
+TI_BIN_UNPK_CMDS=""
+
+SRC_URI = "http://install.source.dir.local/${BINFILE};name=${BINFILE_NAME}"
+
+SRC_URI[cgt6x_7.4.16_x86_installer.md5sum] = "21ca55c5b1f6b2d8d4fb7570d5eb5513"
+SRC_URI[cgt6x_7.4.16_x86_installer.sha256sum] = "baa0d1ef20397383f99f45068a6d160963a01419d42fbbb851263b54c91df82f"
+
+do_install() {
+    install -d ${D}/${TI_CGT6X_7_INSTALL_DIR_RECIPE}
+    cp -r ${WORKDIR}/c6000_7.4.16/. ${D}/${TI_CGT6X_7_INSTALL_DIR_RECIPE}
+}
+
+FILES_${PN} += "${TI_CGT6X_7_INSTALL_DIR_RECIPE}"
+
+INSANE_SKIP_${PN} += "arch staticdev"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
-- 
1.9.1

[PATCH v2 3/4] mad-utils-rtos: added recipe for MAD utils

[Ivan Pang]

This recipe adds the Multicore Application Deployment (MAD) utility
for c665x-evm and c667x-evm.

Signed-off-by: Ivan Pang <i-pang@ti.com>
---
 recipes-bsp/mad-utils/mad-utils-rtos_git.bb | 50 +++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 recipes-bsp/mad-utils/mad-utils-rtos_git.bb

diff --git a/recipes-bsp/mad-utils/mad-utils-rtos_git.bb b/recipes-bsp/mad-utils/mad-utils-rtos_git.bb
new file mode 100644
index 0000000..50045ce
--- /dev/null
+++ b/recipes-bsp/mad-utils/mad-utils-rtos_git.bb
@@ -0,0 +1,50 @@
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://README.txt;md5=44b2180aec0657f6b0e42e5611c0bafb"
+
+require recipes-ti/includes/ti-paths.inc
+
+DEPENDS = "ti-cgt6x-7-native"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "c66x"
+
+BRANCH = "master"
+SRC_URI = "git://git.ti.com/keystone-rtos/mad-utils.git;protocol=git;branch=${BRANCH}"
+SRCREV = "2458510f76eddfa837c2b83448965e233156944b"
+PR = "r0"
+
+S = "${WORKDIR}/git"
+
+export C6X_BASE_DIR="${TI_CGT6X_7_INSTALL_DIR}"
+PATH_prepend = "${TI_CGT6X_7_INSTALL_DIR}/bin:"
+
+DEVICE = ""
+DEVICE_c665x-evm = "C6657"
+DEVICE_c667x-evm = "C6678"
+
+ENDIAN = ""
+ENDIAN_c665x-evm = "little big"
+ENDIAN_c667x-evm = "little big"
+
+do_compile() {
+    cd mad-loader
+    for e in ${ENDIAN}
+    do
+        mkdir -p bin/${DEVICE}/${e}
+        make -C mal/malLib/build clean all DEVICE=${DEVICE} ENDIAN=${e} C_DIR=${C6X_BASE_DIR}
+        make -C mal/malApp/build clean all DEVICE=${DEVICE} ENDIAN=${e} C_DIR=${C6X_BASE_DIR}
+        cp mal/malApp/build/mal_app.exe bin/${DEVICE}/${e}
+        make -C nmlLoader/build clean all DEVICE=${DEVICE} ENDIAN=${e} C_DIR=${C6X_BASE_DIR}
+        cp nmlLoader/build/nml.exe bin/${DEVICE}/${e}
+    done
+    cd -
+}
+
+do_install() {
+    install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/mad-utils
+    cp -r * ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/mad-utils
+}
+
+FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/mad-utils"
+
+INSANE_SKIP_${PN} += "arch staticdev ldflags file-rdeps"
-- 
1.9.1

[PATCH v2 4/4] ibl-boot-rtos: added recipe for RTOS IBL

[Ivan Pang]

This recipe adds the Intermediate Bootloader (IBL) for c665x-evm
and c667x-evm.

Signed-off-by: Ivan Pang <i-pang@ti.com>
---
 recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb | 57 +++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb

diff --git a/recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb b/recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb
new file mode 100644
index 0000000..47c6ccd
--- /dev/null
+++ b/recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb
@@ -0,0 +1,57 @@
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://src/ibl.h;beginline=1;endline=34;md5=ee7d7a3305d1e524955996d1c5e31cb9"
+
+require recipes-ti/includes/ti-paths.inc
+
+DEPENDS = "ti-cgt6x-7-native"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "c66x"
+
+BRANCH = "master"
+SRC_URI = "git://git.ti.com/keystone-rtos/ibl.git;protocol=git;branch=${BRANCH}"
+SRCREV = "f7ed32cc8911e3353dd01080da9b725b44a12285"
+PR = "r0"
+
+S = "${WORKDIR}/git"
+
+PATH_prepend = "${TI_CGT6X_7_INSTALL_DIR}/bin:"
+
+IBLTARGETS = ""
+IBLTARGETS_c665x-evm = "evm_c6657_i2c"
+IBLTARGETS_c667x-evm = "evm_c6678_i2c"
+
+IBLENDIAN = ""
+IBLENDIAN_c665x-evm = "little big"
+IBLENDIAN_c667x-evm = "little big"
+
+export C6X_BASE_DIR="${TI_CGT6X_7_INSTALL_DIR}"
+export TOOLSC6X="${C6X_BASE_DIR}"
+export TOOLSC6XDOS="${C6X_BASE_DIR}"
+export TOOLSBIOSC6XDOS="${C6X_BASE_DIR}"
+export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
+
+do_compile() {
+    cd src/make
+    for t in ${IBLTARGETS}
+    do
+        for e in ${IBLENDIAN}
+        do
+            make ${t} ENDIAN=${e} I2C_BUS_ADDR=0x51
+        done
+    done
+    cd -
+}
+
+do_install() {
+    install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/ibl
+    cp -r * ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/ibl
+}
+
+FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+
+INSANE_SKIP_${PN} = "arch file-rdeps"
-- 
1.9.1

Re: [PATCH v2 2/4] ti-cgt6x-7: added recipe for TI CGT6x 7.x.x

[Jacob Stiffler]

ACK


On 7/25/2017 5:06 PM, Ivan Pang wrote:
> This recipe specifically installs the 7.x.x series of TI CGT6x.
>
> Signed-off-by: Ivan Pang <i-pang@ti.com>
> ---

In the future, it would be nice to list the changes between patch 
versions in this location.

The '--annotate' option to git-send-email will open a text editor on the 
patch to allow you to add this information.

>   recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb | 37 +++++++++++++++++++++++++
>   1 file changed, 37 insertions(+)
>   create mode 100644 recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb
>
> diff --git a/recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb b/recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb
> new file mode 100644
> index 0000000..335e0ae
> --- /dev/null
> +++ b/recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb
> @@ -0,0 +1,37 @@
> +DESCRIPTION = "TI DSP Code Generation Tools"
> +HOMEPAGE = "https://www-a.ti.com/downloads/sds_support/TICodegenerationTools/download.htm"
> +LICENSE = "TI"
> +
> +LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=b6311962635a4f15630e36ec2d875eca"
> +
> +PE = "0"
> +PR = "r0"
> +
> +S = "${WORKDIR}/c6000_7.4.16"
> +
> +inherit native
> +require recipes-ti/includes/ti-paths.inc
> +require recipes-ti/includes/ti-unpack.inc
> +
> +BINFILE = "ti_cgt_c6000_7.4.16_linux_installer_x86.bin"
> +BINFILE_NAME = "cgt6x_7.4.16_x86_installer"
> +TI_BIN_UNPK_ARGS = "--prefix ${WORKDIR} --mode unattended"
> +TI_BIN_UNPK_CMDS=""
> +
> +SRC_URI = "http://install.source.dir.local/${BINFILE};name=${BINFILE_NAME}"
> +
> +SRC_URI[cgt6x_7.4.16_x86_installer.md5sum] = "21ca55c5b1f6b2d8d4fb7570d5eb5513"
> +SRC_URI[cgt6x_7.4.16_x86_installer.sha256sum] = "baa0d1ef20397383f99f45068a6d160963a01419d42fbbb851263b54c91df82f"
> +
> +do_install() {
> +    install -d ${D}/${TI_CGT6X_7_INSTALL_DIR_RECIPE}
> +    cp -r ${WORKDIR}/c6000_7.4.16/. ${D}/${TI_CGT6X_7_INSTALL_DIR_RECIPE}
> +}
> +
> +FILES_${PN} += "${TI_CGT6X_7_INSTALL_DIR_RECIPE}"
> +
> +INSANE_SKIP_${PN} += "arch staticdev"
> +
> +INHIBIT_PACKAGE_STRIP = "1"
> +INHIBIT_SYSROOT_STRIP = "1"
> +INHIBIT_PACKAGE_DEBUG_SPLIT = "1"

Re: [PATCH v2 3/4] mad-utils-rtos: added recipe for MAD utils

[Jacob Stiffler]

ACK


On 7/25/2017 5:06 PM, Ivan Pang wrote:
> This recipe adds the Multicore Application Deployment (MAD) utility
> for c665x-evm and c667x-evm.
>
> Signed-off-by: Ivan Pang <i-pang@ti.com>
> ---
>   recipes-bsp/mad-utils/mad-utils-rtos_git.bb | 50 +++++++++++++++++++++++++++++
>   1 file changed, 50 insertions(+)
>   create mode 100644 recipes-bsp/mad-utils/mad-utils-rtos_git.bb
>
> diff --git a/recipes-bsp/mad-utils/mad-utils-rtos_git.bb b/recipes-bsp/mad-utils/mad-utils-rtos_git.bb
> new file mode 100644
> index 0000000..50045ce
> --- /dev/null
> +++ b/recipes-bsp/mad-utils/mad-utils-rtos_git.bb
> @@ -0,0 +1,50 @@
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://README.txt;md5=44b2180aec0657f6b0e42e5611c0bafb"
> +
> +require recipes-ti/includes/ti-paths.inc
> +
> +DEPENDS = "ti-cgt6x-7-native"
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +COMPATIBLE_MACHINE = "c66x"
> +
> +BRANCH = "master"
> +SRC_URI = "git://git.ti.com/keystone-rtos/mad-utils.git;protocol=git;branch=${BRANCH}"
> +SRCREV = "2458510f76eddfa837c2b83448965e233156944b"
> +PR = "r0"
> +
> +S = "${WORKDIR}/git"
> +
> +export C6X_BASE_DIR="${TI_CGT6X_7_INSTALL_DIR}"
> +PATH_prepend = "${TI_CGT6X_7_INSTALL_DIR}/bin:"
> +
> +DEVICE = ""
> +DEVICE_c665x-evm = "C6657"
> +DEVICE_c667x-evm = "C6678"
> +
> +ENDIAN = ""
> +ENDIAN_c665x-evm = "little big"
> +ENDIAN_c667x-evm = "little big"
> +
> +do_compile() {
> +    cd mad-loader
> +    for e in ${ENDIAN}
> +    do
> +        mkdir -p bin/${DEVICE}/${e}
> +        make -C mal/malLib/build clean all DEVICE=${DEVICE} ENDIAN=${e} C_DIR=${C6X_BASE_DIR}
> +        make -C mal/malApp/build clean all DEVICE=${DEVICE} ENDIAN=${e} C_DIR=${C6X_BASE_DIR}
> +        cp mal/malApp/build/mal_app.exe bin/${DEVICE}/${e}
> +        make -C nmlLoader/build clean all DEVICE=${DEVICE} ENDIAN=${e} C_DIR=${C6X_BASE_DIR}
> +        cp nmlLoader/build/nml.exe bin/${DEVICE}/${e}
> +    done
> +    cd -
> +}
> +
> +do_install() {
> +    install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/mad-utils
> +    cp -r * ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/mad-utils
> +}
> +
> +FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/mad-utils"
> +
> +INSANE_SKIP_${PN} += "arch staticdev ldflags file-rdeps"

Re: [PATCH v2 4/4] ibl-boot-rtos: added recipe for RTOS IBL

[Jacob Stiffler]

ACK


On 7/25/2017 5:06 PM, Ivan Pang wrote:
> This recipe adds the Intermediate Bootloader (IBL) for c665x-evm
> and c667x-evm.
>
> Signed-off-by: Ivan Pang <i-pang@ti.com>
> ---
>   recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb | 57 +++++++++++++++++++++++++++++++
>   1 file changed, 57 insertions(+)
>   create mode 100644 recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb
>
> diff --git a/recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb b/recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb
> new file mode 100644
> index 0000000..47c6ccd
> --- /dev/null
> +++ b/recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb
> @@ -0,0 +1,57 @@
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://src/ibl.h;beginline=1;endline=34;md5=ee7d7a3305d1e524955996d1c5e31cb9"
> +
> +require recipes-ti/includes/ti-paths.inc
> +
> +DEPENDS = "ti-cgt6x-7-native"
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +COMPATIBLE_MACHINE = "c66x"
> +
> +BRANCH = "master"
> +SRC_URI = "git://git.ti.com/keystone-rtos/ibl.git;protocol=git;branch=${BRANCH}"
> +SRCREV = "f7ed32cc8911e3353dd01080da9b725b44a12285"
> +PR = "r0"
> +
> +S = "${WORKDIR}/git"
> +
> +PATH_prepend = "${TI_CGT6X_7_INSTALL_DIR}/bin:"
> +
> +IBLTARGETS = ""
> +IBLTARGETS_c665x-evm = "evm_c6657_i2c"
> +IBLTARGETS_c667x-evm = "evm_c6678_i2c"
> +
> +IBLENDIAN = ""
> +IBLENDIAN_c665x-evm = "little big"
> +IBLENDIAN_c667x-evm = "little big"
> +
> +export C6X_BASE_DIR="${TI_CGT6X_7_INSTALL_DIR}"
> +export TOOLSC6X="${C6X_BASE_DIR}"
> +export TOOLSC6XDOS="${C6X_BASE_DIR}"
> +export TOOLSBIOSC6XDOS="${C6X_BASE_DIR}"
> +export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
> +
> +do_compile() {
> +    cd src/make
> +    for t in ${IBLTARGETS}
> +    do
> +        for e in ${IBLENDIAN}
> +        do
> +            make ${t} ENDIAN=${e} I2C_BUS_ADDR=0x51
> +        done
> +    done
> +    cd -
> +}
> +
> +do_install() {
> +    install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/ibl
> +    cp -r * ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/ibl
> +}
> +
> +FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
> +
> +INHIBIT_PACKAGE_STRIP = "1"
> +INHIBIT_SYSROOT_STRIP = "1"
> +INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
> +
> +INSANE_SKIP_${PN} = "arch file-rdeps"

Re: [PATCH v2 2/4] ti-cgt6x-7: added recipe for TI CGT6x 7.x.x

[Denys Dmytriyenko]

On Tue, Jul 25, 2017 at 04:06:39PM -0500, Ivan Pang wrote:
> This recipe specifically installs the 7.x.x series of TI CGT6x.
> 
> Signed-off-by: Ivan Pang <i-pang@ti.com>
> ---
>  recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb | 37 +++++++++++++++++++++++++
>  1 file changed, 37 insertions(+)
>  create mode 100644 recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb
> 
> diff --git a/recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb b/recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb
> new file mode 100644
> index 0000000..335e0ae
> --- /dev/null
> +++ b/recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb
> @@ -0,0 +1,37 @@
> +DESCRIPTION = "TI DSP Code Generation Tools"

Use SUMMARY for short one-line descriptions.


> +HOMEPAGE = "https://www-a.ti.com/downloads/sds_support/TICodegenerationTools/download.htm"
> +LICENSE = "TI"

Please use the proper name for the license:
http://arago-project.org/git/?p=meta-ti.git;a=tree;f=licenses;hb=refs/heads/morty


> +LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=b6311962635a4f15630e36ec2d875eca"
> +
> +PE = "0"
> +PR = "r0"

These are the defaults, please drop them, especially PE.


> +S = "${WORKDIR}/c6000_7.4.16"
> +
> +inherit native
> +require recipes-ti/includes/ti-paths.inc
> +require recipes-ti/includes/ti-unpack.inc
> +
> +BINFILE = "ti_cgt_c6000_7.4.16_linux_installer_x86.bin"
> +BINFILE_NAME = "cgt6x_7.4.16_x86_installer"
> +TI_BIN_UNPK_ARGS = "--prefix ${WORKDIR} --mode unattended"
> +TI_BIN_UNPK_CMDS=""
> +
> +SRC_URI = "http://install.source.dir.local/${BINFILE};name=${BINFILE_NAME}"
> +
> +SRC_URI[cgt6x_7.4.16_x86_installer.md5sum] = "21ca55c5b1f6b2d8d4fb7570d5eb5513"
> +SRC_URI[cgt6x_7.4.16_x86_installer.sha256sum] = "baa0d1ef20397383f99f45068a6d160963a01419d42fbbb851263b54c91df82f"
> +
> +do_install() {
> +    install -d ${D}/${TI_CGT6X_7_INSTALL_DIR_RECIPE}
> +    cp -r ${WORKDIR}/c6000_7.4.16/. ${D}/${TI_CGT6X_7_INSTALL_DIR_RECIPE}

This will give you host contamination warnings. Please adjust "cp" args 
accordingly to not preserve ownership of files, e.g.:

cp -rP --preserve=mode,links,timestamps --no-preserve=ownership


> +}
> +
> +FILES_${PN} += "${TI_CGT6X_7_INSTALL_DIR_RECIPE}"
> +
> +INSANE_SKIP_${PN} += "arch staticdev"
> +
> +INHIBIT_PACKAGE_STRIP = "1"
> +INHIBIT_SYSROOT_STRIP = "1"
> +INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti

Re: [PATCH v2 3/4] mad-utils-rtos: added recipe for MAD utils

[Denys Dmytriyenko]

On Tue, Jul 25, 2017 at 04:06:40PM -0500, Ivan Pang wrote:
> This recipe adds the Multicore Application Deployment (MAD) utility
> for c665x-evm and c667x-evm.
> 
> Signed-off-by: Ivan Pang <i-pang@ti.com>
> ---
>  recipes-bsp/mad-utils/mad-utils-rtos_git.bb | 50 +++++++++++++++++++++++++++++
>  1 file changed, 50 insertions(+)
>  create mode 100644 recipes-bsp/mad-utils/mad-utils-rtos_git.bb
> 
> diff --git a/recipes-bsp/mad-utils/mad-utils-rtos_git.bb b/recipes-bsp/mad-utils/mad-utils-rtos_git.bb
> new file mode 100644
> index 0000000..50045ce
> --- /dev/null
> +++ b/recipes-bsp/mad-utils/mad-utils-rtos_git.bb
> @@ -0,0 +1,50 @@

Missing SUMMARY/DESCRIPTION


> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://README.txt;md5=44b2180aec0657f6b0e42e5611c0bafb"
> +
> +require recipes-ti/includes/ti-paths.inc
> +
> +DEPENDS = "ti-cgt6x-7-native"
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +COMPATIBLE_MACHINE = "c66x"
> +
> +BRANCH = "master"
> +SRC_URI = "git://git.ti.com/keystone-rtos/mad-utils.git;protocol=git;branch=${BRANCH}"
> +SRCREV = "2458510f76eddfa837c2b83448965e233156944b"
> +PR = "r0"
> +
> +S = "${WORKDIR}/git"
> +
> +export C6X_BASE_DIR="${TI_CGT6X_7_INSTALL_DIR}"
> +PATH_prepend = "${TI_CGT6X_7_INSTALL_DIR}/bin:"
> +
> +DEVICE = ""
> +DEVICE_c665x-evm = "C6657"
> +DEVICE_c667x-evm = "C6678"
> +
> +ENDIAN = ""
> +ENDIAN_c665x-evm = "little big"
> +ENDIAN_c667x-evm = "little big"
> +
> +do_compile() {
> +    cd mad-loader
> +    for e in ${ENDIAN}
> +    do
> +        mkdir -p bin/${DEVICE}/${e}
> +        make -C mal/malLib/build clean all DEVICE=${DEVICE} ENDIAN=${e} C_DIR=${C6X_BASE_DIR}
> +        make -C mal/malApp/build clean all DEVICE=${DEVICE} ENDIAN=${e} C_DIR=${C6X_BASE_DIR}
> +        cp mal/malApp/build/mal_app.exe bin/${DEVICE}/${e}
> +        make -C nmlLoader/build clean all DEVICE=${DEVICE} ENDIAN=${e} C_DIR=${C6X_BASE_DIR}
> +        cp nmlLoader/build/nml.exe bin/${DEVICE}/${e}
> +    done
> +    cd -
> +}
> +
> +do_install() {
> +    install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/mad-utils
> +    cp -r * ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/mad-utils

Same comment about host contamination warning due to preserved ownership of 
files.


> +}
> +
> +FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/mad-utils"
> +
> +INSANE_SKIP_${PN} += "arch staticdev ldflags file-rdeps"
> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti

Re: [PATCH v2 4/4] ibl-boot-rtos: added recipe for RTOS IBL

[Denys Dmytriyenko]

On Tue, Jul 25, 2017 at 04:06:41PM -0500, Ivan Pang wrote:
> This recipe adds the Intermediate Bootloader (IBL) for c665x-evm
> and c667x-evm.

Same 2 comments as for patch #3.


> Signed-off-by: Ivan Pang <i-pang@ti.com>
> ---
>  recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb | 57 +++++++++++++++++++++++++++++++
>  1 file changed, 57 insertions(+)
>  create mode 100644 recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb
> 
> diff --git a/recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb b/recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb
> new file mode 100644
> index 0000000..47c6ccd
> --- /dev/null
> +++ b/recipes-bsp/ibl-boot/ibl-boot-rtos_git.bb
> @@ -0,0 +1,57 @@
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://src/ibl.h;beginline=1;endline=34;md5=ee7d7a3305d1e524955996d1c5e31cb9"
> +
> +require recipes-ti/includes/ti-paths.inc
> +
> +DEPENDS = "ti-cgt6x-7-native"
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +COMPATIBLE_MACHINE = "c66x"
> +
> +BRANCH = "master"
> +SRC_URI = "git://git.ti.com/keystone-rtos/ibl.git;protocol=git;branch=${BRANCH}"
> +SRCREV = "f7ed32cc8911e3353dd01080da9b725b44a12285"
> +PR = "r0"
> +
> +S = "${WORKDIR}/git"
> +
> +PATH_prepend = "${TI_CGT6X_7_INSTALL_DIR}/bin:"
> +
> +IBLTARGETS = ""
> +IBLTARGETS_c665x-evm = "evm_c6657_i2c"
> +IBLTARGETS_c667x-evm = "evm_c6678_i2c"
> +
> +IBLENDIAN = ""
> +IBLENDIAN_c665x-evm = "little big"
> +IBLENDIAN_c667x-evm = "little big"
> +
> +export C6X_BASE_DIR="${TI_CGT6X_7_INSTALL_DIR}"
> +export TOOLSC6X="${C6X_BASE_DIR}"
> +export TOOLSC6XDOS="${C6X_BASE_DIR}"
> +export TOOLSBIOSC6XDOS="${C6X_BASE_DIR}"
> +export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
> +
> +do_compile() {
> +    cd src/make
> +    for t in ${IBLTARGETS}
> +    do
> +        for e in ${IBLENDIAN}
> +        do
> +            make ${t} ENDIAN=${e} I2C_BUS_ADDR=0x51
> +        done
> +    done
> +    cd -
> +}
> +
> +do_install() {
> +    install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/ibl
> +    cp -r * ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/boot/ibl
> +}
> +
> +FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
> +
> +INHIBIT_PACKAGE_STRIP = "1"
> +INHIBIT_SYSROOT_STRIP = "1"
> +INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
> +
> +INSANE_SKIP_${PN} = "arch file-rdeps"
> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti

Re: [PATCH v2 2/4] ti-cgt6x-7: added recipe for TI CGT6x 7.x.x

[Denys Dmytriyenko]

SUMMARY is for short description (<80 characters), while DESCRIPTION is for
longer, more detailed explanation of the package.

Here's an example of properly defining those fields - autoconf recipe:
http://cgit.openembedded.org/openembedded-core/tree/meta/recipes-devtools/autoconf/autoconf.inc

SUMMARY = "A GNU tool that procude shell scripts to automatically configure software"
DESCRIPTION = "Autoconf is an extensible package of M4 macros that produce shell scripts to automatically \
configure software source code packages. Autoconf creates a configuration script for a package from a template \
file that lists the operating system features that the package can use, in the form of M4 macro calls."


That's how it gets into the binary package:

$ dpkg-deb -I autoconf_2.69-r11.38_armv7ahf-neon.ipk
...
 Package: autoconf
 Version: 2.69-r11.38
 Description: A GNU tool that procude shell scripts to automatically configure software
  Autoconf is an extensible package of M4 macros that produce shell scripts
  to automatically configure software source code packages. Autoconf
  creates a configuration script for a package from a template file that
  lists the operating system features that the package can use, in the form
  of M4 macro calls.
 Section: devel
 Priority: optional
...


When SUMMARY is not set, it defaults to "${PN} version ${PV}-${PR}", while
DESCRIPTION defaults to "${SUMMARY}."

http://cgit.openembedded.org/openembedded-core/tree/meta/conf/bitbake.conf#n225


Hence, if you don't set DESCRIPTION, you'll get:

$ dpkg-deb -I acl_2.2.52-r0.67_armv7ahf-neon.ipk
...
 Package: acl
 Version: 2.2.52-r0.67
 Description: Utilities for managing POSIX Access Control Lists
  Utilities for managing POSIX Access Control Lists.
 Section: libs
 Priority: optional
...


But the other way around, when DESCRIPTION is set, but not the SUMMARY, it's
not that nice:

$ dpkg-deb -I aif2-lld-test_1.2.0.1-r0.0.32_armv7ahf-neon.ipk
...
 Package: aif2-lld-test
 Version: 1.2.0.1-r0.0.32
 Description: aif2-lld-test version 1.2.0.1-r0.0
  TI Antenna Interface peripheral module low level driver test binaries
 Section: base
 Priority: optional
...


Moreover, standard sub-packages like ${PN}-dev, ${PN}-dbg etc. automatically
expand SUMMARY and DESCRIPTION fields, with short and long additions:
http://cgit.openembedded.org/openembedded-core/tree/meta/conf/bitbake.conf#n234


Compare to acl main package mentioned above:

...
 Package: acl-dev
 Version: 2.2.52-r0.67
 Description: Utilities for managing POSIX Access Control Lists - Development files
  Utilities for managing POSIX Access Control Lists.  This package contains
  symbolic links, header files, and related items necessary for software
  development.
 Section: devel
 Priority: optional
...


Historically, this distinction wasn't really enforced. Hence there are plenty
of recipes that use DESCRIPTION, but not SUMMARY. But with the continued
addition of tooling around Yocto Project to handle recipes and packages, this
becomes more important to enforce. There were several attempts to clean this
up upstream, e.g.:
http://cgit.openembedded.org/openembedded-core/commit/?id=ad17dfd31a2b97b3e610a0ea0889f5ecb2a63b97


I haven't done a thorough clean up of existing recipes in meta-ti or meta-arago 
yet, but I'm beginning to enforce this for newly submitted recipes now...

-- 
Denys


On Thu, Jul 27, 2017 at 04:16:42PM -0400, Denys Dmytriyenko wrote:
> On Tue, Jul 25, 2017 at 04:06:39PM -0500, Ivan Pang wrote:
> > This recipe specifically installs the 7.x.x series of TI CGT6x.
> > 
> > Signed-off-by: Ivan Pang <i-pang@ti.com>
> > ---
> >  recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb | 37 +++++++++++++++++++++++++
> >  1 file changed, 37 insertions(+)
> >  create mode 100644 recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb
> > 
> > diff --git a/recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb b/recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb
> > new file mode 100644
> > index 0000000..335e0ae
> > --- /dev/null
> > +++ b/recipes-ti/devtools/ti-cgt6x-7-native_7.4.16.bb
> > @@ -0,0 +1,37 @@
> > +DESCRIPTION = "TI DSP Code Generation Tools"
> 
> Use SUMMARY for short one-line descriptions.
> 
> 
> > +HOMEPAGE = "https://www-a.ti.com/downloads/sds_support/TICodegenerationTools/download.htm"
> > +LICENSE = "TI"
> 
> Please use the proper name for the license:
> http://arago-project.org/git/?p=meta-ti.git;a=tree;f=licenses;hb=refs/heads/morty
> 
> 
> > +LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=b6311962635a4f15630e36ec2d875eca"
> > +
> > +PE = "0"
> > +PR = "r0"
> 
> These are the defaults, please drop them, especially PE.
> 
> 
> > +S = "${WORKDIR}/c6000_7.4.16"
> > +
> > +inherit native
> > +require recipes-ti/includes/ti-paths.inc
> > +require recipes-ti/includes/ti-unpack.inc
> > +
> > +BINFILE = "ti_cgt_c6000_7.4.16_linux_installer_x86.bin"
> > +BINFILE_NAME = "cgt6x_7.4.16_x86_installer"
> > +TI_BIN_UNPK_ARGS = "--prefix ${WORKDIR} --mode unattended"
> > +TI_BIN_UNPK_CMDS=""
> > +
> > +SRC_URI = "http://install.source.dir.local/${BINFILE};name=${BINFILE_NAME}"
> > +
> > +SRC_URI[cgt6x_7.4.16_x86_installer.md5sum] = "21ca55c5b1f6b2d8d4fb7570d5eb5513"
> > +SRC_URI[cgt6x_7.4.16_x86_installer.sha256sum] = "baa0d1ef20397383f99f45068a6d160963a01419d42fbbb851263b54c91df82f"
> > +
> > +do_install() {
> > +    install -d ${D}/${TI_CGT6X_7_INSTALL_DIR_RECIPE}
> > +    cp -r ${WORKDIR}/c6000_7.4.16/. ${D}/${TI_CGT6X_7_INSTALL_DIR_RECIPE}
> 
> This will give you host contamination warnings. Please adjust "cp" args 
> accordingly to not preserve ownership of files, e.g.:
> 
> cp -rP --preserve=mode,links,timestamps --no-preserve=ownership
> 
> 
> > +}
> > +
> > +FILES_${PN} += "${TI_CGT6X_7_INSTALL_DIR_RECIPE}"
> > +
> > +INSANE_SKIP_${PN} += "arch staticdev"
> > +
> > +INHIBIT_PACKAGE_STRIP = "1"
> > +INHIBIT_SYSROOT_STRIP = "1"
> > +INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
> > -- 
> > 1.9.1
> > 
> > -- 
> > _______________________________________________
> > meta-ti mailing list
> > meta-ti@yoctoproject.org
> > https://lists.yoctoproject.org/listinfo/meta-ti
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti