[meta-processor-sdk][PATCH v3 1/7] recipes-apps : add evse-hmi demo

[meta-processor-sdk][PATCH v3 1/7] recipes-apps : add evse-hmi demo

[Manisha Agrawal]

Signed-off-by: Manisha Agrawal <manisha.agrawal@ti.com>
---
 recipes-apps/evse-hmi/evse-hmi_git.bb | 23 +++++++++++++++++++++++
 1 file changed, 23 insertions(+)
 create mode 100755 recipes-apps/evse-hmi/evse-hmi_git.bb

diff --git a/recipes-apps/evse-hmi/evse-hmi_git.bb b/recipes-apps/evse-hmi/evse-hmi_git.bb
new file mode 100755
index 0000000..abd4e90
--- /dev/null
+++ b/recipes-apps/evse-hmi/evse-hmi_git.bb
@@ -0,0 +1,23 @@
+SUMMARY = "HMI demo for electronic vehicle charging station (EVSE) using QT QWidget tools"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://main.cpp;beginline=1;endline=33;md5=a9cde3921a8be42ed79ab74661799104"
+
+inherit qt-provider
+
+PV = "1.0"
+PR = "r0"
+
+BRANCH = "master"
+SRC_URI = "git://git.ti.com/sitara-linux/evse-hmi.git;protocol=git;branch=${BRANCH}"
+
+SRCREV = "a257dfc05db311c74cb50838ff5b9e2cfb87dbfe"
+
+S = "${WORKDIR}/git"
+
+CREATE_SRCIPK_evse-hmi = "1"                                                                               
+SRCIPK_INSTALL_DIR_evse-hmi = "example-applications/${PN}-${PV}"
+
+do_install() {
+    install -d ${D}${bindir}
+    install -m 755 evse_hmi ${D}${bindir}
+}
-- 
2.13.0

[meta-processor-sdk][PATCH v3 2/7] recipes-apps : add protection-relays-hmi demo

[Manisha Agrawal]

Signed-off-by: Manisha Agrawal <manisha.agrawal@ti.com>
---
 .../protection-relays-hmi_git.bb                   | 23 ++++++++++++++++++++++
 1 file changed, 23 insertions(+)
 create mode 100755 recipes-apps/protection-relays-hmi/protection-relays-hmi_git.bb

diff --git a/recipes-apps/protection-relays-hmi/protection-relays-hmi_git.bb b/recipes-apps/protection-relays-hmi/protection-relays-hmi_git.bb
new file mode 100755
index 0000000..a6ece91
--- /dev/null
+++ b/recipes-apps/protection-relays-hmi/protection-relays-hmi_git.bb
@@ -0,0 +1,23 @@
+SUMMARY = "HMI demo for Prectection Relays using QT QWidget tools"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://main.cpp;beginline=1;endline=33;md5=a9cde3921a8be42ed79ab74661799104"
+
+inherit qt-provider
+
+PV = "1.0"
+PR = "r0"
+
+BRANCH = "master"
+SRC_URI = "git://git.ti.com/sitara-linux/protection-relays-hmi.git;protocol=git;branch=${BRANCH}"
+
+SRCREV = "c8764aaba365302090179b6720cbfc994e169842"
+
+S = "${WORKDIR}/git"
+
+CREATE_SRCIPK_protection-relays-hmi = "1"
+SRCIPK_INSTALL_DIR_protection-relays-hmi = "example-applications/${PN}-${PV}"
+
+do_install() {
+    install -d ${D}${bindir}
+    install -m 755 protection_relays_hmi ${D}${bindir}
+}
-- 
2.13.0

[meta-processor-sdk][PATCH v3 3/7] matrix-gui-submenus : create hmi sub menu

[Manisha Agrawal]

Signed-off-by: Manisha Agrawal <manisha.agrawal@ti.com>
---
 recipes-core/matrix/matrix-gui-submenus.bbappend | 11 +++++++++++
 1 file changed, 11 insertions(+)
 create mode 100644 recipes-core/matrix/matrix-gui-submenus.bbappend

diff --git a/recipes-core/matrix/matrix-gui-submenus.bbappend b/recipes-core/matrix/matrix-gui-submenus.bbappend
new file mode 100644
index 0000000..681f22e
--- /dev/null
+++ b/recipes-core/matrix/matrix-gui-submenus.bbappend
@@ -0,0 +1,11 @@
+PR_append = ".tisdk2"
+
+SUBMENUS_append = " \
+    hmi_submenu \
+"
+
+PACKAGES_append = " \
+    ${PN}-hmi \
+"
+
+FILES_${PN}-hmi = "${MATRIX_APP_DIR}/hmi_submenu/*"   
-- 
2.13.0

[meta-processor-sdk][PATCH v3 4/7] matrix-gui-hmi-demos : hmi demo descriptions for matrix

[Manisha Agrawal]

Signed-off-by: Manisha Agrawal <manisha.agrawal@ti.com>
---
 recipes-core/matrix/matrix-gui-hmi-demos_2.0.bb | 36 +++++++++++++++++++++++++
 1 file changed, 36 insertions(+)
 create mode 100755 recipes-core/matrix/matrix-gui-hmi-demos_2.0.bb

diff --git a/recipes-core/matrix/matrix-gui-hmi-demos_2.0.bb b/recipes-core/matrix/matrix-gui-hmi-demos_2.0.bb
new file mode 100755
index 0000000..1ed5a5e
--- /dev/null
+++ b/recipes-core/matrix/matrix-gui-hmi-demos_2.0.bb
@@ -0,0 +1,36 @@
+SUMMARY = "HMI demo descriptions for Matrix v2"
+HOMEPAGE = "https://gitorious.org/matrix-gui-v2/matrix-gui-v2-apps"
+
+require recipes-core/matrix/matrix-gui-apps-git.inc
+SRCREV = "094736065e1a15a49da19ef4c5a100aa763c41d1"
+
+PR = "${INC_PR}.0"
+
+inherit allarch
+
+S = "${WORKDIR}/git/hmi_apps"
+
+# Make sure machinevision submenu and app images has been installed
+HMI_RDEPENDS += "matrix-gui-apps-images matrix-gui-submenus-hmi"
+
+FILES_${PN} += "${MATRIX_BASE_DIR}/*"
+
+PACKAGES = "matrix-hmi-demo-evse \
+	    matrix-hmi-demo-protection-relays\
+"
+
+RDEPENDS_matrix-hmi-demo-evse = " \
+    ${HMI_RDEPENDS} \
+    evse-hmi \
+"
+
+RDEPENDS_matrix-hmi-demo-protection-relays = " \
+    ${HMI_RDEPENDS} \
+    protection-relays-hmi \
+"
+
+FILES_matrix-hmi-demo-evse    = "${MATRIX_APP_DIR}/hmi_evse/*"
+FILES_matrix-hmi-demo-evse  += "${bindir}/runHmiEvse.sh"
+
+FILES_matrix-hmi-demo-protection-relays   = "${MATRIX_APP_DIR}/hmi_protection_relays/*"
+FILES_matrix-hmi-demo-protection-relays  += "${bindir}/runHmiProtectionRelays.sh"
-- 
2.13.0

[meta-processor-sdk][PATCH v3 5/7] packagegroup-arago-tisdk-matrix : add hmi demos

[Manisha Agrawal]

Add evse-hmi and protection-relays-hmi demo

Signed-off-by: Manisha Agrawal <manisha.agrawal@ti.com>
---
 .../packagegroups/packagegroup-arago-tisdk-matrix.bbappend         | 7 +++++++
 1 file changed, 7 insertions(+)

diff --git a/recipes-core/packagegroups/packagegroup-arago-tisdk-matrix.bbappend b/recipes-core/packagegroups/packagegroup-arago-tisdk-matrix.bbappend
index b7c6816..abef996 100644
--- a/recipes-core/packagegroups/packagegroup-arago-tisdk-matrix.bbappend
+++ b/recipes-core/packagegroups/packagegroup-arago-tisdk-matrix.bbappend
@@ -7,15 +7,22 @@ MATRIX_SGX_DEMOS_remove_omap-a15 = " \
 MATRIX_COMMON_APPS_remove = " \
     matrix-gui-oprofile-demos \
 "
+MATRIX_APPS_append_ti33x += " \
+    matrix-hmi-demo-evse            \
+    matrix-hmi-demo-protection-relays \
+"
+
 
 MATRIX_APPS_append_omap-a15 += " \
     matrix-gui-apps-dual-camera \
     matrix-gui-apps-image-gallery \
     matrix-multimedia-demo-audiocapture \
+    matrix-hmi-demo-evse            \
 "
 
 MATRIX_APPS_append_ti43x = " \
     matrix-multimedia-demo-audiocapture \
+    matrix-hmi-demo-evse            \
 "
 
 MATRIX_TOUCH_APPS_keystone = ""
-- 
2.13.0

[meta-processor-sdk][PATCH v3 6/7] packagegroup-arago-tisdk-hmi: add hmi specific packagegroups

[Manisha Agrawal]

Signed-off-by: Manisha Agrawal <manisha.agrawal@ti.com>
---
 .../packagegroup-arago-tisdk-hmi-sdk-host.bb       | 27 ++++++++++++++++++++
 .../packagegroups/packagegroup-arago-tisdk-hmi.bb  | 29 ++++++++++++++++++++++
 2 files changed, 56 insertions(+)
 create mode 100755 recipes-core/packagegroups/packagegroup-arago-tisdk-hmi-sdk-host.bb
 create mode 100755 recipes-core/packagegroups/packagegroup-arago-tisdk-hmi.bb

diff --git a/recipes-core/packagegroups/packagegroup-arago-tisdk-hmi-sdk-host.bb b/recipes-core/packagegroups/packagegroup-arago-tisdk-hmi-sdk-host.bb
new file mode 100755
index 0000000..2aafcd3
--- /dev/null
+++ b/recipes-core/packagegroups/packagegroup-arago-tisdk-hmi-sdk-host.bb
@@ -0,0 +1,27 @@
+SUMMARY = "Task to add HMI related sources into the SDK"
+LICENSE = "MIT"
+PR = "r0"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit packagegroup
+
+HMI = ""
+
+HMI_append_ti43x = " \
+    evse-hmi-src \
+"
+
+HMI_append_ti33x = " \
+    evse-hmi-src \ 
+    protection-relays-hmi-src \
+"
+
+
+HMI_append_omap-a15 = " \
+    evse-hmi-src \
+"
+
+RDEPENDS_${PN} = "\
+    ${HMI} \
+"
diff --git a/recipes-core/packagegroups/packagegroup-arago-tisdk-hmi.bb b/recipes-core/packagegroups/packagegroup-arago-tisdk-hmi.bb
new file mode 100755
index 0000000..125443a
--- /dev/null
+++ b/recipes-core/packagegroups/packagegroup-arago-tisdk-hmi.bb
@@ -0,0 +1,29 @@
+SUMMARY = "Task to add HMI related packages"
+LICENSE = "MIT"
+PR = "r0"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit packagegroup
+
+HMI = " \
+"
+
+
+HMI_append_ti33x = " \
+    evse-hmi \
+    protection-relays-hmi \
+"
+
+HMI_append_ti43x = " \
+    evse-hmi \
+"
+
+HMI_append_omap-a15 = " \
+    evse-hmi \
+"
+
+
+RDEPENDS_${PN} = "\
+	${HMI} \
+"
-- 
2.13.0

[meta-processor-sdk][PATCH v3 7/7] tisdk-rootfs-image: add evse-hmi packagegroup

[Manisha Agrawal]

Signed-off-by: Manisha Agrawal <manisha.agrawal@ti.com>
---
 recipes-core/images/tisdk-rootfs-image.bbappend | 15 +++++++++++++--
 1 file changed, 13 insertions(+), 2 deletions(-)

diff --git a/recipes-core/images/tisdk-rootfs-image.bbappend b/recipes-core/images/tisdk-rootfs-image.bbappend
index d4b08cc..e97ce61 100644
--- a/recipes-core/images/tisdk-rootfs-image.bbappend
+++ b/recipes-core/images/tisdk-rootfs-image.bbappend
@@ -1,4 +1,15 @@
 PR_append = ".tisdk4"
 
-IMAGE_INSTALL_append_ti43x = " packagegroup-arago-tisdk-graphics"
-IMAGE_INSTALL_append_ti33x = " packagegroup-arago-tisdk-graphics"
+IMAGE_INSTALL_append_ti43x = " 
+	packagegroup-arago-tisdk-graphics \
+        packagegroup-arago-tisdk-hmi \
+"
+IMAGE_INSTALL_append_ti33x = " 
+  	packagegroup-arago-tisdk-graphics \
+        packagegroup-arago-tisdk-hmi \
+"
+
+
+IMAGE_INSTALL_append_omap-a15 = " 
+  	packagegroup-arago-tisdk-hmi \
+"
-- 
2.13.0

Re: [meta-processor-sdk][PATCH v3 1/7] recipes-apps : add evse-hmi demo

[Jacob Stiffler]

Can you use a commit log similar to what was used for meta-arago?


On 9/1/2017 5:17 PM, Manisha Agrawal wrote:
> Signed-off-by: Manisha Agrawal <manisha.agrawal@ti.com>
> ---
>   recipes-apps/evse-hmi/evse-hmi_git.bb | 23 +++++++++++++++++++++++
>   1 file changed, 23 insertions(+)
>   create mode 100755 recipes-apps/evse-hmi/evse-hmi_git.bb
>
> diff --git a/recipes-apps/evse-hmi/evse-hmi_git.bb b/recipes-apps/evse-hmi/evse-hmi_git.bb
> new file mode 100755
> index 0000000..abd4e90
> --- /dev/null
> +++ b/recipes-apps/evse-hmi/evse-hmi_git.bb
> @@ -0,0 +1,23 @@
> +SUMMARY = "HMI demo for electronic vehicle charging station (EVSE) using QT QWidget tools"
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://main.cpp;beginline=1;endline=33;md5=a9cde3921a8be42ed79ab74661799104"
> +
> +inherit qt-provider
> +
> +PV = "1.0"
> +PR = "r0"
> +
> +BRANCH = "master"
> +SRC_URI = "git://git.ti.com/sitara-linux/evse-hmi.git;protocol=git;branch=${BRANCH}"
> +
> +SRCREV = "a257dfc05db311c74cb50838ff5b9e2cfb87dbfe"
> +
> +S = "${WORKDIR}/git"
> +
> +CREATE_SRCIPK_evse-hmi = "1"
> +SRCIPK_INSTALL_DIR_evse-hmi = "example-applications/${PN}-${PV}"

You do not need variable overrides here as you are configuring this 
within the recipe.

You can use 'CREATE_SRCIPK = "1"', and 'SRCIPK_INSTALL_DIR = ...'

> +
> +do_install() {
> +    install -d ${D}${bindir}
> +    install -m 755 evse_hmi ${D}${bindir}
> +}

Re: [meta-processor-sdk][PATCH v3 7/7] tisdk-rootfs-image: add evse-hmi packagegroup

[Jacob Stiffler]

This does not parse.


On 9/1/2017 5:17 PM, Manisha Agrawal wrote:
> Signed-off-by: Manisha Agrawal <manisha.agrawal@ti.com>
> ---
>   recipes-core/images/tisdk-rootfs-image.bbappend | 15 +++++++++++++--
>   1 file changed, 13 insertions(+), 2 deletions(-)
>
> diff --git a/recipes-core/images/tisdk-rootfs-image.bbappend b/recipes-core/images/tisdk-rootfs-image.bbappend
> index d4b08cc..e97ce61 100644
> --- a/recipes-core/images/tisdk-rootfs-image.bbappend
> +++ b/recipes-core/images/tisdk-rootfs-image.bbappend
> @@ -1,4 +1,15 @@
>   PR_append = ".tisdk4"
>   
> -IMAGE_INSTALL_append_ti43x = " packagegroup-arago-tisdk-graphics"
> -IMAGE_INSTALL_append_ti33x = " packagegroup-arago-tisdk-graphics"
> +IMAGE_INSTALL_append_ti43x = "
Need to line continutation indicator "\"
> +	packagegroup-arago-tisdk-graphics \
> +        packagegroup-arago-tisdk-hmi \
> +"
> +IMAGE_INSTALL_append_ti33x = "
Need to line continutation indicator "\"
> +  	packagegroup-arago-tisdk-graphics \
> +        packagegroup-arago-tisdk-hmi \
> +"
> +
> +
> +IMAGE_INSTALL_append_omap-a15 = "
Need to line continutation indicator "\"
> +  	packagegroup-arago-tisdk-hmi \
> +"

Re: [meta-processor-sdk][PATCH v3 3/7] matrix-gui-submenus : create hmi sub menu

[Jacob Stiffler]

The name of this file needs to match the name of the upstream recipe 
(i.e. matrix-gui-submenus_2.0.bbappend).


On 9/1/2017 5:17 PM, Manisha Agrawal wrote:
> Signed-off-by: Manisha Agrawal <manisha.agrawal@ti.com>
> ---
>   recipes-core/matrix/matrix-gui-submenus.bbappend | 11 +++++++++++
>   1 file changed, 11 insertions(+)
>   create mode 100644 recipes-core/matrix/matrix-gui-submenus.bbappend
>
> diff --git a/recipes-core/matrix/matrix-gui-submenus.bbappend b/recipes-core/matrix/matrix-gui-submenus.bbappend
> new file mode 100644
> index 0000000..681f22e
> --- /dev/null
> +++ b/recipes-core/matrix/matrix-gui-submenus.bbappend
> @@ -0,0 +1,11 @@
> +PR_append = ".tisdk2"
> +
> +SUBMENUS_append = " \
> +    hmi_submenu \
> +"
> +
> +PACKAGES_append = " \
> +    ${PN}-hmi \
> +"
> +
> +FILES_${PN}-hmi = "${MATRIX_APP_DIR}/hmi_submenu/*"
s

Re: [meta-processor-sdk][PATCH v3 3/7] matrix-gui-submenus : create hmi sub menu

[Jacob Stiffler]

It appears that you also need to provide an updated SRCREV for this to 
build once the file is named correctly.


On 9/5/2017 9:53 AM, Jacob Stiffler wrote:
> The name of this file needs to match the name of the upstream recipe 
> (i.e. matrix-gui-submenus_2.0.bbappend).
>
>
> On 9/1/2017 5:17 PM, Manisha Agrawal wrote:
>> Signed-off-by: Manisha Agrawal <manisha.agrawal@ti.com>
>> ---
>>   recipes-core/matrix/matrix-gui-submenus.bbappend | 11 +++++++++++
>>   1 file changed, 11 insertions(+)
>>   create mode 100644 recipes-core/matrix/matrix-gui-submenus.bbappend
>>
>> diff --git a/recipes-core/matrix/matrix-gui-submenus.bbappend 
>> b/recipes-core/matrix/matrix-gui-submenus.bbappend
>> new file mode 100644
>> index 0000000..681f22e
>> --- /dev/null
>> +++ b/recipes-core/matrix/matrix-gui-submenus.bbappend
>> @@ -0,0 +1,11 @@
>> +PR_append = ".tisdk2"
>> +
>> +SUBMENUS_append = " \
>> +    hmi_submenu \
>> +"
>> +
>> +PACKAGES_append = " \
>> +    ${PN}-hmi \
>> +"
>> +
>> +FILES_${PN}-hmi = "${MATRIX_APP_DIR}/hmi_submenu/*"
> s

Re: [meta-processor-sdk][PATCH v3 5/7] packagegroup-arago-tisdk-matrix : add hmi demos

[Jacob Stiffler]

On 9/1/2017 5:17 PM, Manisha Agrawal wrote:
> Add evse-hmi and protection-relays-hmi demo
>
> Signed-off-by: Manisha Agrawal <manisha.agrawal@ti.com>
> ---
>   .../packagegroups/packagegroup-arago-tisdk-matrix.bbappend         | 7 +++++++
>   1 file changed, 7 insertions(+)
>
> diff --git a/recipes-core/packagegroups/packagegroup-arago-tisdk-matrix.bbappend b/recipes-core/packagegroups/packagegroup-arago-tisdk-matrix.bbappend
> index b7c6816..abef996 100644
> --- a/recipes-core/packagegroups/packagegroup-arago-tisdk-matrix.bbappend
> +++ b/recipes-core/packagegroups/packagegroup-arago-tisdk-matrix.bbappend
> @@ -7,15 +7,22 @@ MATRIX_SGX_DEMOS_remove_omap-a15 = " \
>   MATRIX_COMMON_APPS_remove = " \
>       matrix-gui-oprofile-demos \
>   "
> +MATRIX_APPS_append_ti33x += " \
You don't need to '+=' here as you are already using the '_append' override.

> +    matrix-hmi-demo-evse            \
> +    matrix-hmi-demo-protection-relays \
> +"
> +
>   
>   MATRIX_APPS_append_omap-a15 += " \
Same comment as above.

>       matrix-gui-apps-dual-camera \
>       matrix-gui-apps-image-gallery \
>       matrix-multimedia-demo-audiocapture \
> +    matrix-hmi-demo-evse            \
>   "
>   
>   MATRIX_APPS_append_ti43x = " \
>       matrix-multimedia-demo-audiocapture \
> +    matrix-hmi-demo-evse            \
>   "
>   
>   MATRIX_TOUCH_APPS_keystone = ""