[PATCH 1/4] alsa-state: Add override to use with use-mainline-bsp

[PATCH 1/4] alsa-state: Add override to use with use-mainline-bsp

[Fabio Berton]

Add use-mainline-bsp override to install asound.conf file to machines
that use mainline bsp.

Change-Id: I13e61bbabb163eeb3e3408ba47e8cd4954b41ba6
Signed-off-by: Fabio Berton <fabio.berton@ossystems.com.br>
---
 recipes-bsp/alsa-state/alsa-state.bbappend | 2 ++
 1 file changed, 2 insertions(+)

diff --git a/recipes-bsp/alsa-state/alsa-state.bbappend b/recipes-bsp/alsa-state/alsa-state.bbappend
index a5134297..08e48599 100644
--- a/recipes-bsp/alsa-state/alsa-state.bbappend
+++ b/recipes-bsp/alsa-state/alsa-state.bbappend
@@ -1,6 +1,8 @@
 # Append path for freescale layer to include alsa-state asound.conf
 FILESEXTRAPATHS_prepend_mx6 := "${THISDIR}/${PN}/imx:"
 FILESEXTRAPATHS_prepend_mx7 := "${THISDIR}/${PN}/imx:"
+FILESEXTRAPATHS_prepend_use-mainline-bsp := "${THISDIR}/${PN}/imx:"
 
 PACKAGE_ARCH_mx6 = "${MACHINE_ARCH}"
 PACKAGE_ARCH_mx7 = "${MACHINE_ARCH}"
+PACKAGE_ARCH_use-mainline-bsp = "${MACHINE_ARCH}"
-- 
2.14.1

[PATCH 2/4] u-boot-fslc: Create u-boot-fslc-common include file

[Fabio Berton]

Use a common file to make easier update, maintain and create
others U-Boot recipes like U-Boot fw-utils.

Signed-off-by: Fabio Berton <fabio.berton@ossystems.com.br>
---
 .../{u-boot-fslc.inc => u-boot-fslc-common_2017.09.inc} | 16 +++++-----------
 recipes-bsp/u-boot/u-boot-fslc-mxsboot_2017.09.bb       | 17 ++++-------------
 recipes-bsp/u-boot/u-boot-fslc_2017.09.bb               | 12 ++++++++----
 3 files changed, 17 insertions(+), 28 deletions(-)
 rename recipes-bsp/u-boot/{u-boot-fslc.inc => u-boot-fslc-common_2017.09.inc} (66%)

diff --git a/recipes-bsp/u-boot/u-boot-fslc.inc b/recipes-bsp/u-boot/u-boot-fslc-common_2017.09.inc
similarity index 66%
rename from recipes-bsp/u-boot/u-boot-fslc.inc
rename to recipes-bsp/u-boot/u-boot-fslc-common_2017.09.inc
index 39ecc2cd..6173cda0 100644
--- a/recipes-bsp/u-boot/u-boot-fslc.inc
+++ b/recipes-bsp/u-boot/u-boot-fslc-common_2017.09.inc
@@ -1,4 +1,4 @@
-# Copyright (C) 2012-2016 O.S. Systems Software LTDA.
+# Copyright (C) 2012-2017 O.S. Systems Software LTDA.
 # Released under the MIT license (see COPYING.MIT for the terms)
 
 require recipes-bsp/u-boot/u-boot.inc
@@ -16,19 +16,13 @@ COMPATIBLE_MACHINE = "(mxs|mx5|mx6|mx7|vf|use-mainline-bsp)"
 DEPENDS_append = " dtc-native"
 DEPENDS_mxs += "elftosb-native openssl-native"
 
-PROVIDES += "u-boot"
+SRC_URI = "git://github.com/Freescale/u-boot-fslc.git;branch=${SRCBRANCH}"
 
-SRCBRANCH ??= "master"
+SRCREV = "9f164a1a01fceb53fc88ad474a5cda70f1c486c2"
+SRCBRANCH = "2017.09+fslc"
 
-SRC_URI = "git://github.com/Freescale/u-boot-fslc.git;branch=${SRCBRANCH}"
+PV = "v2017.09+git${SRCPV}"
 
 S = "${WORKDIR}/git"
 
-# FIXME: Allow linking of 'tools' binaries with native libraries
-#        used for generating the boot logo and other tools used
-#        during the build process.
-EXTRA_OEMAKE += 'HOSTCC="${BUILD_CC} ${BUILD_CPPFLAGS}" \
-                 HOSTLDFLAGS="${BUILD_LDFLAGS}" \
-                 HOSTSTRIP=true'
-
 PACKAGE_ARCH = "${MACHINE_ARCH}"
diff --git a/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2017.09.bb b/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2017.09.bb
index 0bbcd084..b67a53ce 100644
--- a/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2017.09.bb
+++ b/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2017.09.bb
@@ -1,20 +1,11 @@
+require u-boot-fslc-common_${PV}.inc
+
 DESCRIPTION = "U-boot bootloader mxsboot tool"
-LICENSE = "GPLv2+"
-LIC_FILES_CHKSUM = "file://Licenses/README;md5=a2c678cfd4a4d97135585cad908541c6"
 SECTION = "bootloader"
-DEPENDS = "openssl"
-PROVIDES = "u-boot-mxsboot"
-
-PV = "v2017.09+git${SRCPV}"
 
-SRCREV = "9f164a1a01fceb53fc88ad474a5cda70f1c486c2"
-SRCBRANCH = "2017.09+fslc"
+DEPENDS_append = " openssl"
 
-SRC_URI = "git://github.com/Freescale/u-boot-fslc.git;branch=${SRCBRANCH}"
-
-S = "${WORKDIR}/git"
-
-inherit fsl-u-boot-localversion
+PROVIDES = "u-boot-mxsboot"
 
 EXTRA_OEMAKE = 'HOSTCC="${CC} ${CPPFLAGS}" HOSTLDFLAGS="-L${libdir} -L${base_libdir}" HOSTSTRIP=true CONFIG_MX28=y'
 
diff --git a/recipes-bsp/u-boot/u-boot-fslc_2017.09.bb b/recipes-bsp/u-boot/u-boot-fslc_2017.09.bb
index b3fd47a6..3aff2fa7 100644
--- a/recipes-bsp/u-boot/u-boot-fslc_2017.09.bb
+++ b/recipes-bsp/u-boot/u-boot-fslc_2017.09.bb
@@ -1,6 +1,10 @@
-include u-boot-fslc.inc
+require u-boot-fslc-common_${PV}.inc
 
-PV = "v2017.09+git${SRCPV}"
+PROVIDES += "u-boot"
 
-SRCREV = "9f164a1a01fceb53fc88ad474a5cda70f1c486c2"
-SRCBRANCH = "2017.09+fslc"
+# FIXME: Allow linking of 'tools' binaries with native libraries
+#        used for generating the boot logo and other tools used
+#        during the build process.
+EXTRA_OEMAKE += 'HOSTCC="${BUILD_CC} ${BUILD_CPPFLAGS}" \
+                 HOSTLDFLAGS="${BUILD_LDFLAGS}" \
+                 HOSTSTRIP=true'
-- 
2.14.1

[PATCH 3/4] u-boot-fslc-fw-utils: Add recipe for version 2017.09

[Fabio Berton]

Signed-off-by: Fabio Berton <fabio.berton@ossystems.com.br>
---
 recipes-bsp/u-boot/u-boot-fslc-fw-utils_2017.09.bb | 45 ++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 recipes-bsp/u-boot/u-boot-fslc-fw-utils_2017.09.bb

diff --git a/recipes-bsp/u-boot/u-boot-fslc-fw-utils_2017.09.bb b/recipes-bsp/u-boot/u-boot-fslc-fw-utils_2017.09.bb
new file mode 100644
index 00000000..dd46bfec
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-fslc-fw-utils_2017.09.bb
@@ -0,0 +1,45 @@
+require u-boot-fslc-common_${PV}.inc
+
+SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
+
+DEPENDS_append = " mtd-utils"
+
+INSANE_SKIP_${PN} = "already-stripped"
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" V=1'
+EXTRA_OEMAKE_class-cross = 'ARCH=${TARGET_ARCH} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+
+inherit uboot-config
+
+do_compile () {
+    oe_runmake ${UBOOT_MACHINE}
+    oe_runmake env
+}
+
+do_install () {
+    install -d ${D}${base_sbindir}
+    install -d ${D}${sysconfdir}
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
+
+    if [ -e ${WORKDIR}/fw_env.config ]; then
+        install -m 0644 ${WORKDIR}/fw_env.config ${D}${sysconfdir}/fw_env.config
+    else
+        install -m 0644 ${S}/tools/env/fw_env.config ${D}${sysconfdir}/fw_env.config
+    fi
+}
+
+do_install_class-cross () {
+    install -d ${D}${bindir_cross}
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
+}
+
+SYSROOT_PREPROCESS_FUNCS_class-cross = "uboot_fw_utils_cross"
+uboot_fw_utils_cross() {
+    sysroot_stage_dir ${D}${bindir_cross} ${SYSROOT_DESTDIR}${bindir_cross}
+}
+
+RPROVIDES_${PN} += "u-boot-fw-utils"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+BBCLASSEXTEND = "cross"
-- 
2.14.1

[PATCH 4/4] imx6sllevk: Drop u-boot and kernel PREFERRED_VERSION

[Fabio Berton]

The line PREFERRED_PROVIDER_linux-imx ??= "4.1.15" is wrong, the
correct is use PREFERRED_VERSION to set version. But we can drop
this line because currently we have one linux-imx version.
Also drop preferred version to u-boot, 2016.03 is the only option.

Signed-off-by: Fabio Berton <fabio.berton@ossystems.com.br>
---
 conf/machine/imx6sllevk.conf | 3 ---
 1 file changed, 3 deletions(-)

diff --git a/conf/machine/imx6sllevk.conf b/conf/machine/imx6sllevk.conf
index 3a703659..84d1e319 100644
--- a/conf/machine/imx6sllevk.conf
+++ b/conf/machine/imx6sllevk.conf
@@ -27,6 +27,3 @@ XSERVER += "mesa-driver-swrast"
 
 PREFERRED_PROVIDER_u-boot = "u-boot-imx"
 PREFERRED_PROVIDER_virtual/bootloader = "u-boot-imx"
-
-PREFERRED_VERSION_u-boot ??= "2016.03"
-PREFERRED_PROVIDER_linux-imx ??= "4.1.15"
-- 
2.14.1