* [rocko-next][PATCH 1/3] ti-sci-fw: separate SYSFW 2018.08b packaging into own recipe
@ 2018-09-27 23:28 Denys Dmytriyenko
2018-09-27 23:28 ` [rocko-next][PATCH 2/3] u-boot-k3-r5: SYSFW is now separate from R5 SPL Denys Dmytriyenko
2018-09-27 23:28 ` [rocko-next][PATCH 3/3] arago.conf: add ti-sci-fw into EXTRA_IMAGEDEPENDS for k3 Denys Dmytriyenko
0 siblings, 2 replies; 3+ messages in thread
From: Denys Dmytriyenko @ 2018-09-27 23:28 UTC (permalink / raw)
To: meta-arago
Signed-off-by: Denys Dmytriyenko <denys@ti.com>
---
.../ti-sci-fw/ti-sci-fw_2018.08b.bb | 58 +++++++++++++++++++
1 file changed, 58 insertions(+)
create mode 100644 meta-arago-distro/recipes-bsp/ti-sci-fw/ti-sci-fw_2018.08b.bb
diff --git a/meta-arago-distro/recipes-bsp/ti-sci-fw/ti-sci-fw_2018.08b.bb b/meta-arago-distro/recipes-bsp/ti-sci-fw/ti-sci-fw_2018.08b.bb
new file mode 100644
index 00000000..c2573b84
--- /dev/null
+++ b/meta-arago-distro/recipes-bsp/ti-sci-fw/ti-sci-fw_2018.08b.bb
@@ -0,0 +1,58 @@
+SUMMARY = "TI SCI firmware"
+
+LICENSE = "TI-TFL"
+LIC_FILES_CHKSUM = "file://LICENSE.ti;md5=b5aebf0668bdf95621259288c4a46d76"
+
+DEPENDS = "openssl-native u-boot-mkimage-native dtc-native"
+
+CLEANBROKEN = "1"
+
+COMPATIBLE_MACHINE = "k3"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+SRCREV = "463b1b4a50e8e361fa333f87caf74d2e05bc0a82"
+
+BRANCH ?= "ti-linux-firmware-4.1.y"
+
+SRC_URI = " \
+ git://git.ti.com/processor-firmware/ti-linux-firmware.git;protocol=git;branch=${BRANCH} \
+ git://bitbucket.itg.ti.com/scm/~a0797059/system-firmware-image-gen.git;protocol=http;branch=master;destsuffix=imggen;name=imggen \
+"
+
+SRCREV_imggen = "00f62b3e8b3b02a17b8d08686f1a907d6a395ff9"
+SRCREV_FORMAT = "imggen"
+
+S = "${WORKDIR}/git"
+
+SYSFW_TISCI_am65xx-evm = "ti-sci-firmware-am65x-gp.bin"
+SYSFW_BINARY = "sysfw.itb"
+SYSFW_IMAGE = "sysfw-${PV}.itb"
+
+CROSS_COMPILE_V7 = "${ELT_TARGET_SYS_ARMV7}-"
+PATH_prepend = "${TOOLCHAIN_PATH_ARMV7}/bin:"
+
+do_compile() {
+ cp ${S}/ti-sysfw/${SYSFW_TISCI} ${WORKDIR}/imggen/
+ cd ${WORKDIR}/imggen/
+ oe_runmake SYSFW_DL_URL=""
+}
+
+do_install() {
+ install -d ${D}/boot
+ install -m 644 ${WORKDIR}/imggen/${SYSFW_BINARY} ${D}/boot/${SYSFW_IMAGE}
+ ln -sf ${SYSFW_IMAGE} ${D}/boot/${SYSFW_BINARY}
+}
+
+FILES_${PN} = "/boot"
+
+inherit deploy
+
+do_deploy () {
+ install -d ${DEPLOYDIR}
+ install -m 644 ${WORKDIR}/imggen/${SYSFW_BINARY} ${DEPLOYDIR}/${SYSFW_IMAGE}
+ rm -f ${DEPLOYDIR}/${SYSFW_BINARY}
+ ln -sf ${SYSFW_IMAGE} ${DEPLOYDIR}/${SYSFW_BINARY}
+}
+
+addtask deploy before do_build after do_compile
--
2.17.1
^ permalink raw reply related [flat|nested] 3+ messages in thread
* [rocko-next][PATCH 2/3] u-boot-k3-r5: SYSFW is now separate from R5 SPL
2018-09-27 23:28 [rocko-next][PATCH 1/3] ti-sci-fw: separate SYSFW 2018.08b packaging into own recipe Denys Dmytriyenko
@ 2018-09-27 23:28 ` Denys Dmytriyenko
2018-09-27 23:28 ` [rocko-next][PATCH 3/3] arago.conf: add ti-sci-fw into EXTRA_IMAGEDEPENDS for k3 Denys Dmytriyenko
1 sibling, 0 replies; 3+ messages in thread
From: Denys Dmytriyenko @ 2018-09-27 23:28 UTC (permalink / raw)
To: meta-arago
Signed-off-by: Denys Dmytriyenko <denys@ti.com>
---
.../u-boot/u-boot-k3-r5_2018.01.bb | 29 -------------------
1 file changed, 29 deletions(-)
diff --git a/meta-arago-distro/recipes-bsp/u-boot/u-boot-k3-r5_2018.01.bb b/meta-arago-distro/recipes-bsp/u-boot/u-boot-k3-r5_2018.01.bb
index 04476ae4..dcd1e316 100644
--- a/meta-arago-distro/recipes-bsp/u-boot/u-boot-k3-r5_2018.01.bb
+++ b/meta-arago-distro/recipes-bsp/u-boot/u-boot-k3-r5_2018.01.bb
@@ -7,19 +7,6 @@ PKG_${PN}-dbg = "${PN}-dbg"
COMPATIBLE_MACHINE = "k3"
-SYSFW_VER = "2018.08b"
-SYSFW_TISCI_am65xx-evm = "ti-sci-firmware-am65x-gp.bin"
-SYSFW_BINARY = "sysfw.bin"
-SYSFW_IMAGE = "sysfw-${SYSFW_VER}.bin"
-
-SRCREV_sysfw = "463b1b4a50e8e361fa333f87caf74d2e05bc0a82"
-SYSFW_BRANCH = "ti-linux-firmware-4.1.y"
-SRCREV_FORMAT = "sysfw"
-
-SRC_URI += " \
- file://gen_x509_cert.sh \
- git://git.ti.com/processor-firmware/ti-linux-firmware.git;protocol=git;name=sysfw;branch=${SYSFW_BRANCH};destsuffix=fw"
-
CROSS_COMPILE_V7 = "${ELT_TARGET_SYS_ARMV7}-"
PATH_prepend = "${TOOLCHAIN_PATH_ARMV7}/bin:"
@@ -27,24 +14,8 @@ UBOOT_MACHINE_am65xx-evm = "am65x_evm_r5_defconfig"
EXTRA_OEMAKE = 'ARCH=arm CROSS_COMPILE=${CROSS_COMPILE_V7} CC="${CROSS_COMPILE_V7}gcc ${TOOLCHAIN_OPTIONS}" V=1'
EXTRA_OEMAKE += 'HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}"'
-EXTRA_OEMAKE += 'SYSFW=${WORKDIR}/${SYSFW_BINARY}'
UBOOT_BINARY = "tiboot3.bin"
UBOOT_IMAGE = "tiboot3-${MACHINE}-${PV}-${PR}.bin"
UBOOT_SYMLINK = "tiboot3-${MACHINE}.bin"
SPL_BINARY_k3 = ""
-
-do_configure_append() {
- ${WORKDIR}/gen_x509_cert.sh -m rom -c m3 -b ${WORKDIR}/fw/ti-sysfw/${SYSFW_TISCI} -o ${WORKDIR}/${SYSFW_BINARY} -l 0x40000
-}
-
-do_install_append() {
- install -m 644 ${WORKDIR}/${SYSFW_BINARY} ${D}/boot/${SYSFW_IMAGE}
- ln -sf ${SYSFW_IMAGE} ${D}/boot/${SYSFW_BINARY}
-}
-
-do_deploy_append() {
- install -m 644 ${WORKDIR}/${SYSFW_BINARY} ${DEPLOYDIR}/${SYSFW_IMAGE}
- rm -f ${DEPLOYDIR}/${SYSFW_BINARY}
- ln -sf ${SYSFW_IMAGE} ${DEPLOYDIR}/${SYSFW_BINARY}
-}
--
2.17.1
^ permalink raw reply related [flat|nested] 3+ messages in thread
* [rocko-next][PATCH 3/3] arago.conf: add ti-sci-fw into EXTRA_IMAGEDEPENDS for k3
2018-09-27 23:28 [rocko-next][PATCH 1/3] ti-sci-fw: separate SYSFW 2018.08b packaging into own recipe Denys Dmytriyenko
2018-09-27 23:28 ` [rocko-next][PATCH 2/3] u-boot-k3-r5: SYSFW is now separate from R5 SPL Denys Dmytriyenko
@ 2018-09-27 23:28 ` Denys Dmytriyenko
1 sibling, 0 replies; 3+ messages in thread
From: Denys Dmytriyenko @ 2018-09-27 23:28 UTC (permalink / raw)
To: meta-arago
Signed-off-by: Denys Dmytriyenko <denys@ti.com>
---
meta-arago-distro/conf/distro/arago.conf | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/meta-arago-distro/conf/distro/arago.conf b/meta-arago-distro/conf/distro/arago.conf
index 9b6a5e4c..1ba4dd92 100644
--- a/meta-arago-distro/conf/distro/arago.conf
+++ b/meta-arago-distro/conf/distro/arago.conf
@@ -123,7 +123,7 @@ PACKAGECONFIG_pn-glmark2 = "drm-gles2 wayland-gles2"
# Enable U-boot OPTEE config for K3
PACKAGECONFIG_append_pn-u-boot-ti-staging_k3 = " optee"
-EXTRA_IMAGEDEPENDS_append_k3 += " u-boot-k3-r5"
+EXTRA_IMAGEDEPENDS_append_k3 += " u-boot-k3-r5 ti-sci-fw"
# Enable UI and scripting for perf
PERF_FEATURES_ENABLE ?= "perf-scripting perf-tui"
--
2.17.1
^ permalink raw reply related [flat|nested] 3+ messages in thread
end of thread, other threads:[~2018-09-27 23:32 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2018-09-27 23:28 [rocko-next][PATCH 1/3] ti-sci-fw: separate SYSFW 2018.08b packaging into own recipe Denys Dmytriyenko
2018-09-27 23:28 ` [rocko-next][PATCH 2/3] u-boot-k3-r5: SYSFW is now separate from R5 SPL Denys Dmytriyenko
2018-09-27 23:28 ` [rocko-next][PATCH 3/3] arago.conf: add ti-sci-fw into EXTRA_IMAGEDEPENDS for k3 Denys Dmytriyenko
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.