[meta-oe][PATCH] valijson: Add recipe

[meta-oe][PATCH] valijson: Add recipe

[James Feist]

valijson is a header only c++ library for JSON
schema validation.

Signed-off-by: James Feist <james.feist@linux.intel.com>
---
 .../recipes-devtools/valijson/valijson_git.bb | 27 +++++++++++++++++++
 1 file changed, 27 insertions(+)
 create mode 100644 meta-oe/recipes-devtools/valijson/valijson_git.bb

diff --git a/meta-oe/recipes-devtools/valijson/valijson_git.bb b/meta-oe/recipes-devtools/valijson/valijson_git.bb
new file mode 100644
index 000000000..bcceb6884
--- /dev/null
+++ b/meta-oe/recipes-devtools/valijson/valijson_git.bb
@@ -0,0 +1,27 @@
+SUMMARY = "Header-only C++ library for JSON Schema validation"
+HOMEPAGE = "https://github.com/tristanpenman/valijson"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=015106c62262b2383f6c72063f0998f2"
+
+SRC_URI = "git://github.com/tristanpenman/valijson.git"
+PV = "0.1+git${SRCPV}"
+
+SRCREV = "c2f22fddf599d04dc33fcd7ed257c698a05345d9"
+
+S = "${WORKDIR}/git"
+
+inherit cmake
+
+EXTRA_OECMAKE = "-DINSTALL_HEADERS=1 -DBUILD_TESTS=0"
+
+# valijson is a header only C++ library, so the main package will be empty.
+
+RDEPENDS_${PN}-dev = ""
+
+BBCLASSEXTEND = "native nativesdk"
+
+# valijson expects json.hpp where nlohmann-json_git.bb installs
+# nlohmann/json.hpp, this allows usage via json.hpp
+do_install_append() {
+    ln -rs ${D}${includedir}/nlohmann/json.hpp ${D}${includedir}/json.hpp
+}
-- 
2.17.1

Re: [meta-oe][PATCH] valijson: Add recipe

[Peter Kjellerstedt]

> -----Original Message-----
> From: openembedded-devel-bounces@lists.openembedded.org <openembedded-
> devel-bounces@lists.openembedded.org> On Behalf Of James Feist
> Sent: den 9 oktober 2018 22:12
> To: openembedded-devel@lists.openembedded.org
> Subject: [oe] [meta-oe][PATCH] valijson: Add recipe
> 
> valijson is a header only c++ library for JSON
> schema validation.
> 
> Signed-off-by: James Feist <james.feist@linux.intel.com>
> ---
>  .../recipes-devtools/valijson/valijson_git.bb | 27 +++++++++++++++++++
>  1 file changed, 27 insertions(+)
>  create mode 100644 meta-oe/recipes-devtools/valijson/valijson_git.bb
> 
> diff --git a/meta-oe/recipes-devtools/valijson/valijson_git.bb b/meta-oe/recipes-devtools/valijson/valijson_git.bb
> new file mode 100644
> index 000000000..bcceb6884
> --- /dev/null
> +++ b/meta-oe/recipes-devtools/valijson/valijson_git.bb
> @@ -0,0 +1,27 @@
> +SUMMARY = "Header-only C++ library for JSON Schema validation"
> +HOMEPAGE = "https://github.com/tristanpenman/valijson"
> +LICENSE = "BSD"

Change "BSD" to "BSD-2-Clause".

> +LIC_FILES_CHKSUM = "file://LICENSE;md5=015106c62262b2383f6c72063f0998f2"
> +
> +SRC_URI = "git://github.com/tristanpenman/valijson.git"
> +PV = "0.1+git${SRCPV}"
> +
> +SRCREV = "c2f22fddf599d04dc33fcd7ed257c698a05345d9"
> +
> +S = "${WORKDIR}/git"
> +
> +inherit cmake
> +
> +EXTRA_OECMAKE = "-DINSTALL_HEADERS=1 -DBUILD_TESTS=0"
> +
> +# valijson is a header only C++ library, so the main package will be empty.
> +

I suggest removing this empty line to make it more clear that 
the comment above relates to the RDEPENDS line below.

> +RDEPENDS_${PN}-dev = ""
> +
> +BBCLASSEXTEND = "native nativesdk"
> +
> +# valijson expects json.hpp where nlohmann-json_git.bb installs
> +# nlohmann/json.hpp, this allows usage via json.hpp
> +do_install_append() {
> +    ln -rs ${D}${includedir}/nlohmann/json.hpp ${D}${includedir}/json.hpp

Since the prefix is the same in both cases, you can avoid the -r 
option by using:

    ln -s nlohmann/json.hpp ${D}${includedir}/json.hpp

> +}
> --
> 2.17.1

//Peter