All of lore.kernel.org
 help / color / mirror / Atom feed
* [PATCH 01/42] vim: split the common part into vim.inc
@ 2019-05-20 14:10 Alexander Kanavin
  2019-05-20 14:10 ` [PATCH 02/42] librepo: upgrade 1.9.6 -> 1.10.2 Alexander Kanavin
                   ` (40 more replies)
  0 siblings, 41 replies; 56+ messages in thread
From: Alexander Kanavin @ 2019-05-20 14:10 UTC (permalink / raw)
  To: openembedded-core

Previously vim-tiny would include the vim recipe wholesale;
this meant that they had to be upgraded in a single transaction
which devtool cannot cope with. This thwarted the latest AUH
run in particular.

Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com>
---
 meta/recipes-support/vim/vim-tiny_8.1.1240.bb |   2 +-
 meta/recipes-support/vim/vim.inc              | 141 +++++++++++++++++
 meta/recipes-support/vim/vim_8.1.1240.bb      | 142 +-----------------
 3 files changed, 143 insertions(+), 142 deletions(-)
 create mode 100644 meta/recipes-support/vim/vim.inc

diff --git a/meta/recipes-support/vim/vim-tiny_8.1.1240.bb b/meta/recipes-support/vim/vim-tiny_8.1.1240.bb
index 74464833adb..139e626e444 100644
--- a/meta/recipes-support/vim/vim-tiny_8.1.1240.bb
+++ b/meta/recipes-support/vim/vim-tiny_8.1.1240.bb
@@ -1,4 +1,4 @@
-require vim_${PV}.bb
+require vim.inc
 
 SUMMARY += " (with tiny features)"
 
diff --git a/meta/recipes-support/vim/vim.inc b/meta/recipes-support/vim/vim.inc
new file mode 100644
index 00000000000..f5c74684bfa
--- /dev/null
+++ b/meta/recipes-support/vim/vim.inc
@@ -0,0 +1,141 @@
+SUMMARY = "Vi IMproved - enhanced vi editor"
+SECTION = "console/utils"
+
+PROVIDES = "xxd"
+DEPENDS = "ncurses gettext-native"
+# vimdiff doesn't like busybox diff
+RSUGGESTS_${PN} = "diffutils"
+LICENSE = "vim"
+LIC_FILES_CHKSUM = "file://runtime/doc/uganda.txt;endline=287;md5=f1f82b42360005c70b8c19b0ef493f72"
+
+SRC_URI = "git://github.com/vim/vim.git \
+           file://disable_acl_header_check.patch \
+           file://vim-add-knob-whether-elf.h-are-checked.patch \
+           file://0001-src-Makefile-improve-reproducibility.patch \
+"
+SRCREV = "d96dbd6f95ea22f609042cc9c6272f14a21ff1a5"
+
+S = "${WORKDIR}/git"
+
+VIMDIR = "vim${@d.getVar('PV').split('.')[0]}${@d.getVar('PV').split('.')[1]}"
+
+inherit autotools-brokensep update-alternatives
+
+CLEANBROKEN = "1"
+
+# vim configure.in contains functions which got 'dropped' by autotools.bbclass
+do_configure () {
+    cd src
+    rm -f auto/*
+    touch auto/config.mk
+    aclocal
+    autoconf
+    cd ..
+    oe_runconf
+    touch src/auto/configure
+    touch src/auto/config.mk src/auto/config.h
+}
+
+do_compile() {
+    # We do not support fully / correctly the following locales.  Attempting
+    # to use these with msgfmt in order to update the ".desktop" files exposes
+    # this problem and leads to the compile failing.
+    for LOCALE in cs fr ko pl sk zh_CN zh_TW;do
+        echo -n > src/po/${LOCALE}.po
+    done
+    autotools_do_compile
+}
+
+#Available PACKAGECONFIG options are gtkgui, acl, x11, tiny
+PACKAGECONFIG ??= ""
+PACKAGECONFIG += " \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'acl selinux', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11 gtkgui', '', d)} \
+"
+PACKAGECONFIG_class-native = ""
+
+PACKAGECONFIG[gtkgui] = "--enable-gui=gtk2,--enable-gui=no,gtk+,"
+PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl,"
+PACKAGECONFIG[x11] = "--with-x,--without-x,xt,"
+PACKAGECONFIG[tiny] = "--with-features=tiny,--with-features=big,,"
+PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux,libselinux,"
+PACKAGECONFIG[elfutils] = "--enable-elf-check,,elfutils,"
+
+EXTRA_OECONF = " \
+    --disable-gpm \
+    --disable-gtktest \
+    --disable-xim \
+    --disable-netbeans \
+    --with-tlib=ncurses \
+    ac_cv_small_wchar_t=no \
+    vim_cv_getcwd_broken=no \
+    vim_cv_memmove_handles_overlap=yes \
+    vim_cv_stat_ignores_slash=no \
+    vim_cv_terminfo=yes \
+    vim_cv_tgetent=non-zero \
+    vim_cv_toupper_broken=no \
+    vim_cv_tty_group=world \
+    STRIP=/bin/true \
+"
+
+do_install() {
+    autotools_do_install
+
+    # Work around file-rdeps picking up csh, awk, perl or python as a dep
+    chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/vim132
+    chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/mve.awk
+    chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/*.pl
+    chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/*.py
+
+    # Install example vimrc from runtime files
+    install -m 0644 runtime/vimrc_example.vim ${D}/${datadir}/${BPN}/vimrc
+
+    # we use --with-features=big as default
+    mv ${D}${bindir}/${BPN} ${D}${bindir}/${BPN}.${BPN}
+
+    if ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'true', 'false', d)}; then
+	# The mouse being autoenabled is just annoying in xfce4-terminal (mouse
+	# drag make vim go into visual mode and there is no right click menu),
+	# delete the block.
+	sed -i '/the mouse works just fine/,+4d' ${D}/${datadir}/${BPN}/vimrc
+    fi
+}
+
+PARALLEL_MAKEINST = ""
+
+PACKAGES =+ "${PN}-common ${PN}-syntax ${PN}-help ${PN}-tutor ${PN}-vimrc ${PN}-tools"
+FILES_${PN}-syntax = "${datadir}/${BPN}/${VIMDIR}/syntax"
+FILES_${PN}-help = "${datadir}/${BPN}/${VIMDIR}/doc"
+FILES_${PN}-tutor = "${datadir}/${BPN}/${VIMDIR}/tutor ${bindir}/${BPN}tutor"
+FILES_${PN}-vimrc = "${datadir}/${BPN}/vimrc"
+FILES_${PN}-data = "${datadir}/${BPN}"
+FILES_${PN}-tools = "${datadir}/${BPN}/${VIMDIR}/tools"
+FILES_${PN}-common = " \
+    ${datadir}/${BPN}/${VIMDIR}/*.vim \
+    ${datadir}/${BPN}/${VIMDIR}/autoload \
+    ${datadir}/${BPN}/${VIMDIR}/colors \
+    ${datadir}/${BPN}/${VIMDIR}/compiler \
+    ${datadir}/${BPN}/${VIMDIR}/ftplugin \
+    ${datadir}/${BPN}/${VIMDIR}/indent \
+    ${datadir}/${BPN}/${VIMDIR}/keymap \
+    ${datadir}/${BPN}/${VIMDIR}/lang \
+    ${datadir}/${BPN}/${VIMDIR}/macros \
+    ${datadir}/${BPN}/${VIMDIR}/plugin \
+    ${datadir}/${BPN}/${VIMDIR}/print \
+    ${datadir}/${BPN}/${VIMDIR}/spell \
+    ${datadir}/icons \
+"
+
+RDEPENDS_${BPN} = "ncurses-terminfo-base"
+# Recommend that runtime data is installed along with vim
+RRECOMMENDS_${BPN} = "${PN}-syntax ${PN}-help ${PN}-tutor ${PN}-vimrc ${PN}-common"
+
+ALTERNATIVE_${PN} = "vi vim xxd"
+ALTERNATIVE_PRIORITY = "100"
+ALTERNATIVE_TARGET = "${bindir}/${BPN}.${BPN}"
+ALTERNATIVE_LINK_NAME[vi] = "${base_bindir}/vi"
+ALTERNATIVE_LINK_NAME[vim] = "${bindir}/vim"
+ALTERNATIVE_TARGET[xxd] = "${bindir}/xxd"
+ALTERNATIVE_LINK_NAME[xxd] = "${bindir}/xxd"
+
+BBCLASSEXTEND = "native"
diff --git a/meta/recipes-support/vim/vim_8.1.1240.bb b/meta/recipes-support/vim/vim_8.1.1240.bb
index f5c74684bfa..baaaacc0b77 100644
--- a/meta/recipes-support/vim/vim_8.1.1240.bb
+++ b/meta/recipes-support/vim/vim_8.1.1240.bb
@@ -1,141 +1 @@
-SUMMARY = "Vi IMproved - enhanced vi editor"
-SECTION = "console/utils"
-
-PROVIDES = "xxd"
-DEPENDS = "ncurses gettext-native"
-# vimdiff doesn't like busybox diff
-RSUGGESTS_${PN} = "diffutils"
-LICENSE = "vim"
-LIC_FILES_CHKSUM = "file://runtime/doc/uganda.txt;endline=287;md5=f1f82b42360005c70b8c19b0ef493f72"
-
-SRC_URI = "git://github.com/vim/vim.git \
-           file://disable_acl_header_check.patch \
-           file://vim-add-knob-whether-elf.h-are-checked.patch \
-           file://0001-src-Makefile-improve-reproducibility.patch \
-"
-SRCREV = "d96dbd6f95ea22f609042cc9c6272f14a21ff1a5"
-
-S = "${WORKDIR}/git"
-
-VIMDIR = "vim${@d.getVar('PV').split('.')[0]}${@d.getVar('PV').split('.')[1]}"
-
-inherit autotools-brokensep update-alternatives
-
-CLEANBROKEN = "1"
-
-# vim configure.in contains functions which got 'dropped' by autotools.bbclass
-do_configure () {
-    cd src
-    rm -f auto/*
-    touch auto/config.mk
-    aclocal
-    autoconf
-    cd ..
-    oe_runconf
-    touch src/auto/configure
-    touch src/auto/config.mk src/auto/config.h
-}
-
-do_compile() {
-    # We do not support fully / correctly the following locales.  Attempting
-    # to use these with msgfmt in order to update the ".desktop" files exposes
-    # this problem and leads to the compile failing.
-    for LOCALE in cs fr ko pl sk zh_CN zh_TW;do
-        echo -n > src/po/${LOCALE}.po
-    done
-    autotools_do_compile
-}
-
-#Available PACKAGECONFIG options are gtkgui, acl, x11, tiny
-PACKAGECONFIG ??= ""
-PACKAGECONFIG += " \
-    ${@bb.utils.filter('DISTRO_FEATURES', 'acl selinux', d)} \
-    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11 gtkgui', '', d)} \
-"
-PACKAGECONFIG_class-native = ""
-
-PACKAGECONFIG[gtkgui] = "--enable-gui=gtk2,--enable-gui=no,gtk+,"
-PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl,"
-PACKAGECONFIG[x11] = "--with-x,--without-x,xt,"
-PACKAGECONFIG[tiny] = "--with-features=tiny,--with-features=big,,"
-PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux,libselinux,"
-PACKAGECONFIG[elfutils] = "--enable-elf-check,,elfutils,"
-
-EXTRA_OECONF = " \
-    --disable-gpm \
-    --disable-gtktest \
-    --disable-xim \
-    --disable-netbeans \
-    --with-tlib=ncurses \
-    ac_cv_small_wchar_t=no \
-    vim_cv_getcwd_broken=no \
-    vim_cv_memmove_handles_overlap=yes \
-    vim_cv_stat_ignores_slash=no \
-    vim_cv_terminfo=yes \
-    vim_cv_tgetent=non-zero \
-    vim_cv_toupper_broken=no \
-    vim_cv_tty_group=world \
-    STRIP=/bin/true \
-"
-
-do_install() {
-    autotools_do_install
-
-    # Work around file-rdeps picking up csh, awk, perl or python as a dep
-    chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/vim132
-    chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/mve.awk
-    chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/*.pl
-    chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/*.py
-
-    # Install example vimrc from runtime files
-    install -m 0644 runtime/vimrc_example.vim ${D}/${datadir}/${BPN}/vimrc
-
-    # we use --with-features=big as default
-    mv ${D}${bindir}/${BPN} ${D}${bindir}/${BPN}.${BPN}
-
-    if ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'true', 'false', d)}; then
-	# The mouse being autoenabled is just annoying in xfce4-terminal (mouse
-	# drag make vim go into visual mode and there is no right click menu),
-	# delete the block.
-	sed -i '/the mouse works just fine/,+4d' ${D}/${datadir}/${BPN}/vimrc
-    fi
-}
-
-PARALLEL_MAKEINST = ""
-
-PACKAGES =+ "${PN}-common ${PN}-syntax ${PN}-help ${PN}-tutor ${PN}-vimrc ${PN}-tools"
-FILES_${PN}-syntax = "${datadir}/${BPN}/${VIMDIR}/syntax"
-FILES_${PN}-help = "${datadir}/${BPN}/${VIMDIR}/doc"
-FILES_${PN}-tutor = "${datadir}/${BPN}/${VIMDIR}/tutor ${bindir}/${BPN}tutor"
-FILES_${PN}-vimrc = "${datadir}/${BPN}/vimrc"
-FILES_${PN}-data = "${datadir}/${BPN}"
-FILES_${PN}-tools = "${datadir}/${BPN}/${VIMDIR}/tools"
-FILES_${PN}-common = " \
-    ${datadir}/${BPN}/${VIMDIR}/*.vim \
-    ${datadir}/${BPN}/${VIMDIR}/autoload \
-    ${datadir}/${BPN}/${VIMDIR}/colors \
-    ${datadir}/${BPN}/${VIMDIR}/compiler \
-    ${datadir}/${BPN}/${VIMDIR}/ftplugin \
-    ${datadir}/${BPN}/${VIMDIR}/indent \
-    ${datadir}/${BPN}/${VIMDIR}/keymap \
-    ${datadir}/${BPN}/${VIMDIR}/lang \
-    ${datadir}/${BPN}/${VIMDIR}/macros \
-    ${datadir}/${BPN}/${VIMDIR}/plugin \
-    ${datadir}/${BPN}/${VIMDIR}/print \
-    ${datadir}/${BPN}/${VIMDIR}/spell \
-    ${datadir}/icons \
-"
-
-RDEPENDS_${BPN} = "ncurses-terminfo-base"
-# Recommend that runtime data is installed along with vim
-RRECOMMENDS_${BPN} = "${PN}-syntax ${PN}-help ${PN}-tutor ${PN}-vimrc ${PN}-common"
-
-ALTERNATIVE_${PN} = "vi vim xxd"
-ALTERNATIVE_PRIORITY = "100"
-ALTERNATIVE_TARGET = "${bindir}/${BPN}.${BPN}"
-ALTERNATIVE_LINK_NAME[vi] = "${base_bindir}/vi"
-ALTERNATIVE_LINK_NAME[vim] = "${bindir}/vim"
-ALTERNATIVE_TARGET[xxd] = "${bindir}/xxd"
-ALTERNATIVE_LINK_NAME[xxd] = "${bindir}/xxd"
-
-BBCLASSEXTEND = "native"
+require vim.inc
-- 
2.17.1



^ permalink raw reply related	[flat|nested] 56+ messages in thread
end of thread, other threads:[~2019-05-22 10:09 UTC | newest]

Thread overview: 56+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2019-05-20 14:10 [PATCH 01/42] vim: split the common part into vim.inc Alexander Kanavin
2019-05-20 14:10 ` [PATCH 02/42] librepo: upgrade 1.9.6 -> 1.10.2 Alexander Kanavin
2019-05-20 14:10 ` [PATCH 03/42] libmodulemd: upgrade 2.2.3 -> 2.4.0 Alexander Kanavin
2019-05-21 14:41   ` Richard Purdie
2019-05-21 16:15     ` Alexander Kanavin
2019-05-20 14:10 ` [PATCH 04/42] createrepo-c: upgrade 0.12.2 -> 0.14.0 Alexander Kanavin
2019-05-20 14:10 ` [PATCH 05/42] libdazzle: upgrade 3.32.1 -> 3.32.2 Alexander Kanavin
2019-05-20 14:10 ` [PATCH 06/42] adwaita-icon-theme: upgrade 3.30.1 -> 3.32.0 Alexander Kanavin
2019-05-20 14:10 ` [PATCH 07/42] piglit: upgrade to latest revision Alexander Kanavin
2019-05-20 17:52   ` Khem Raj
2019-05-20 14:10 ` [PATCH 08/42] bison: upgrade 3.1 -> 3.3.2 Alexander Kanavin
2019-05-20 14:10 ` [PATCH 09/42] atk: upgrade 2.30.0 -> 2.32.0 Alexander Kanavin
2019-05-20 14:10 ` [PATCH 10/42] python3-mako: upgrade 1.0.9 -> 1.0.10 Alexander Kanavin
2019-05-20 14:10 ` [PATCH 11/42] nss: upgrade 3.43 -> 3.44 Alexander Kanavin
2019-05-20 14:10 ` [PATCH 12/42] go: update 1.12.1->1.12.5 Alexander Kanavin
2019-05-20 14:10 ` [PATCH 13/42] systemtap: upgrade 4.0 -> 4.1 Alexander Kanavin
2019-05-21 21:37   ` Victor Kamensky (kamensky)
2019-05-22 10:09     ` Alexander Kanavin
2019-05-20 14:10 ` [PATCH 14/42] gawk: upgrade 4.2.1 -> 5.0.0 Alexander Kanavin
2019-05-20 14:10 ` [PATCH 15/42] alsa-plugins: upgrade 1.1.8 -> 1.1.9 Alexander Kanavin
2019-05-20 14:10 ` [PATCH 16/42] alsa-utils: " Alexander Kanavin
2019-05-20 14:11 ` [PATCH 17/42] alsa-lib: " Alexander Kanavin
2019-05-20 14:11 ` [PATCH 18/42] libpcre2: upgrade 10.32 -> 10.33 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 19/42] lz4: upgrade 1.9.0 -> 1.9.1 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 20/42] libxcrypt: upgrade 4.4.4 -> 4.4.6 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 21/42] python3-pip: upgrade 19.0.3 -> 19.1.1 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 22/42] iproute2: upgrade 5.0.0 -> 5.1.0 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 23/42] pkgconf: upgrade 1.6.0 -> 1.6.1 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 24/42] at-spi2-core: upgrade 2.30.0 -> 2.32.1 Alexander Kanavin
2019-05-20 17:54   ` Khem Raj
2019-05-20 18:50     ` Alexander Kanavin
2019-05-20 14:11 ` [PATCH 25/42] at-spi2-atk: upgrade 2.30.0 -> 2.32.0 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 26/42] glib-networking: upgrade 2.60.1 -> 2.60.2 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 27/42] libsoup-2.4: upgrade 2.66.1 -> 2.66.2 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 28/42] x264: upgrade to latest revision Alexander Kanavin
2019-05-20 14:11 ` [PATCH 29/42] linux-firmware: " Alexander Kanavin
2019-05-20 17:56   ` Khem Raj
2019-05-20 18:02     ` Martin Jansa
2019-05-20 18:57       ` Alexander Kanavin
2019-05-20 14:11 ` [PATCH 30/42] python3-pbr: upgrade 5.1.3 -> 5.2.0 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 31/42] bash-completion: upgrade 2.8 -> 2.9 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 32/42] libdnf: upgrade 0.28.1 -> 0.33.0 Alexander Kanavin
2019-05-21 18:44   ` Richard Purdie
2019-05-21 19:00     ` Alexander Kanavin
2019-05-21 19:05       ` richard.purdie
2019-05-21 19:20         ` Alexander Kanavin
2019-05-20 14:11 ` [PATCH 33/42] gst-examples: upgrade to 1.16.0 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 34/42] acpica: upgrade 20190405 -> 20190509 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 35/42] freetype: upgrade 2.9.1 -> 2.10.0 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 36/42] dnf: upgrade 4.2.2 -> 4.2.6 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 37/42] usbutils: upgrade 010->012 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 38/42] gnu-config: Update to latest SHA Alexander Kanavin
2019-05-20 14:11 ` [PATCH 39/42] vim: Rework things so vim adds features not vim-tiny removes Alexander Kanavin
2019-05-20 14:11 ` [PATCH 40/42] webkitgtk: update to 2.24.2 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 41/42] epiphany: update to 3.32.2 Alexander Kanavin
2019-05-20 14:11 ` [PATCH 42/42] btrfs-tools: update to 5.1 Alexander Kanavin

This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.