[PATCH 1/6] arm-bsp/external-system: remove coreutils-native DEPENDS

[PATCH 1/6] arm-bsp/external-system: remove coreutils-native DEPENDS

[Ross Burton]

This recipe doesn't appear to actually need coreutils-native at all, and
using it exposes a bug in pseudo where cp crashes.

Change-Id: I2fbf9ee75165194866e4a14758ed06148340dc2b
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
 .../recipes-bsp/external-system/external-system_0.1.0.bb        | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta-arm-bsp/recipes-bsp/external-system/external-system_0.1.0.bb b/meta-arm-bsp/recipes-bsp/external-system/external-system_0.1.0.bb
index 84da7ce..a8052c6 100644
--- a/meta-arm-bsp/recipes-bsp/external-system/external-system_0.1.0.bb
+++ b/meta-arm-bsp/recipes-bsp/external-system/external-system_0.1.0.bb
@@ -2,7 +2,7 @@ SUMMARY = "External system Cortex-M3 Firmware"
 DESCRIPTION = "Firmware to be loaded and run in External System Harness in\
                support to the main application CPU."
 HOMEPAGE = "https://git.linaro.org/landing-teams/working/arm/external-system.git"
-DEPENDS = "coreutils-native gcc-arm-none-eabi-native"
+DEPENDS = "gcc-arm-none-eabi-native"
 LICENSE = "BSD-3-Clause"
 LIC_FILES_CHKSUM = "file://license.md;md5=e44b2531cd6ffe9dece394dbe988d9a0"
 
-- 
2.25.1

[PATCH 2/6] arm-bsp/boot-firmware: add firmware recipe for corstone700

[Ross Burton]

Previously corstone700 used the scp-firmware recipe to build
boot-firmware, which is based on scp-firmware but doesn't share the
build system.

As the differences are not insignificant, extract a dedicated
boot-firmware recipe.  Also set PV appropriately as boot-firmware now
has dated tags.

Change-Id: I3b60172e145be571aa465afb81473b9d79e9e425
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
 .../conf/machine/include/corstone700.inc      |  3 +-
 .../boot-firmware/boot-firmware_git.bb        | 62 +++++++++++++++++++
 .../scp-firmware/scp-firmware-corstone700.inc | 37 -----------
 .../scp-firmware/scp-firmware_%.bbappend      |  1 -
 4 files changed, 63 insertions(+), 40 deletions(-)
 create mode 100644 meta-arm-bsp/recipes-bsp/boot-firmware/boot-firmware_git.bb
 delete mode 100644 meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-corstone700.inc

diff --git a/meta-arm-bsp/conf/machine/include/corstone700.inc b/meta-arm-bsp/conf/machine/include/corstone700.inc
index 4aab85e..ab3e2a4 100644
--- a/meta-arm-bsp/conf/machine/include/corstone700.inc
+++ b/meta-arm-bsp/conf/machine/include/corstone700.inc
@@ -14,8 +14,7 @@ PREFERRED_VERSION_linux-yocto ?= "5.6%"
 PREFERRED_PROVIDER_virtual/trusted-firmware-a ?= "trusted-firmware-a"
 PREFERRED_VERSION_trusted-firmware-a ?= "2.3%"
 
-PREFERRED_PROVIDER_virtual/control-processor-firmware ?= "scp-firmware"
-PREFERRED_VERSION_control-processor-firmware ?= "2.6.0"
+PREFERRED_PROVIDER_virtual/control-processor-firmware ?= "boot-firmware"
 
 EXTRA_IMAGEDEPENDS += " \
                       virtual/trusted-firmware-a          \
diff --git a/meta-arm-bsp/recipes-bsp/boot-firmware/boot-firmware_git.bb b/meta-arm-bsp/recipes-bsp/boot-firmware/boot-firmware_git.bb
new file mode 100644
index 0000000..cd8ae3d
--- /dev/null
+++ b/meta-arm-bsp/recipes-bsp/boot-firmware/boot-firmware_git.bb
@@ -0,0 +1,62 @@
+SUMMARY = "Boot Processor firmware for Corstone700"
+DESCRIPTION = "Boot Processor firmware"
+
+LICENSE = "BSD-3-Clause & Apache-2.0"
+LIC_FILES_CHKSUM = "file://license.md;md5=e44b2531cd6ffe9dece394dbe988d9a0 \
+                    file://cmsis/LICENSE.txt;md5=e3fc50a88d0a364313df4b21ef20c29e"
+
+SRC_URI = "gitsm://git.linaro.org/landing-teams/working/arm/boot-firmware.git;protocol=https"
+# This is two commits on from CORSTONE-700-2020.02.10
+SRCREV = "a4dd1b60218b5172a94e6f44c96384b84a77588c"
+PV = "2020.02.10+git${SRCPV}"
+
+PROVIDES += "virtual/control-processor-firmware"
+
+DEPENDS = "virtual/arm-none-eabi-gcc-native virtual/trusted-firmware-a"
+
+inherit deploy
+
+B = "${WORKDIR}/build"
+S = "${WORKDIR}/git"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "(corstone700-*)"
+SCP_PLATFORM = "corstone-700"
+
+LDFLAGS[unexport] = "1"
+
+do_configure[noexec] = "1"
+
+EXTRA_OEMAKE = "PRODUCT='${SCP_PLATFORM}' \
+                BUILD_PATH=${B} \
+                CROSS_COMPILE='arm-none-eabi-' \
+                V=y \
+               "
+
+do_compile() {
+    oe_runmake -C ${S}/tools/spitoc CC=${BUILD_CC} all
+    oe_runmake -C ${S}
+}
+do_compile[cleandirs] += "${B}"
+
+do_install() {
+    install -D -p -m 0644 ${B}/product/${SCP_PLATFORM}/se_ramfw/release/bin/firmware.bin ${D}/firmware/se_ramfw.bin
+    install -D -p -m 0644 ${B}/product/${SCP_PLATFORM}/se_romfw/release/bin/firmware.bin ${D}/firmware/se_romfw.bin
+    ${S}/tools/spitoc/spitoc \
+        --seram ${D}/firmware/se_ramfw.bin \
+        --offset 1  \
+        --fip ${RECIPE_SYSROOT}/firmware/fip.bin-${TFA_PLATFORM} \
+        --offset  33 \
+        --out ${D}/firmware/spitoc.bin
+}
+
+FILES_${PN} = "/firmware"
+SYSROOT_DIRS += "/firmware"
+# Skip QA check for relocations in .text of elf binaries
+INSANE_SKIP_${PN} = "textrel"
+
+do_deploy() {
+    # Copy the images to deploy directory
+    cp -rf ${D}/firmware/* ${DEPLOYDIR}/
+}
+addtask deploy after do_install
diff --git a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-corstone700.inc b/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-corstone700.inc
deleted file mode 100644
index 16437c5..0000000
--- a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware-corstone700.inc
+++ /dev/null
@@ -1,37 +0,0 @@
-# Corstone700 specific SCP configurations and build instructions
-
-SUMMARY = "Boot Processor firmware"
-DESCRIPTION = "Boot Processor firmware"
-DEPENDS += "virtual/trusted-firmware-a"
-
-LIC_FILES_CHKSUM = "file://license.md;md5=e44b2531cd6ffe9dece394dbe988d9a0 \
-                    file://cmsis/LICENSE.txt;md5=e3fc50a88d0a364313df4b21ef20c29e"
-
-COMPATIBLE_MACHINE = "(corstone700-*)"
-SCP_PLATFORM = "corstone-700"
-
-# boot-firmware project is a fork of scp-firmware
-SRC_URI = "gitsm://git.linaro.org/landing-teams/working/arm/boot-firmware.git;protocol=https;branch=master"
-SRCREV = "a4dd1b60218b5172a94e6f44c96384b84a77588c"
-PV = "0.1.0~git${SRCPV}"
-
-B = "${WORKDIR}/build"
-
-EXTRA_OEMAKE = "PRODUCT='${SCP_PLATFORM}' \
-                BUILD_PATH=${B} \
-                CROSS_COMPILE='arm-none-eabi-' \
-               "
-do_compile_append() {
-   oe_runmake -C ${S}/tools/spitoc CC=${BUILD_CC} clean all
-}
-
-do_install() {
-    install -D -p -m 0644 ${B}/product/${SCP_PLATFORM}/se_ramfw/release/bin/firmware.bin ${D}/firmware/se_ramfw.bin
-    install -D -p -m 0644 ${B}/product/${SCP_PLATFORM}/se_romfw/release/bin/firmware.bin ${D}/firmware/se_romfw.bin
-    ${S}/tools/spitoc/spitoc \
-    --seram ${D}/firmware/se_ramfw.bin \
-    --offset 1  \
-    --fip ${RECIPE_SYSROOT}/firmware/fip.bin-${TFA_PLATFORM} \
-    --offset  33 \
-    --out ${D}/firmware/spitoc.bin
-}
diff --git a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware_%.bbappend b/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware_%.bbappend
index 8a68704..b760ba7 100644
--- a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware_%.bbappend
+++ b/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware_%.bbappend
@@ -6,6 +6,5 @@ MACHINE_SCP_REQUIRE_n1sdp = "scp-firmware-n1sdp.inc"
 MACHINE_SCP_REQUIRE_tc0 = "scp-firmware-tc0.inc"
 MACHINE_SCP_REQUIRE_juno = "scp-firmware-juno.inc"
 MACHINE_SCP_REQUIRE_sgi575 = "scp-firmware-sgi575.inc"
-MACHINE_SCP_REQUIRE_corstone700 = "scp-firmware-corstone700.inc"
 
 require ${MACHINE_SCP_REQUIRE}
-- 
2.25.1

[PATCH 3/6] arm-bsp/scp-firmware: add version to wildcard bbappend

[Ross Burton]

To prepare for a new version of scp-firmware, add a version to this
bbappend.

Change-Id: Ib6d79f2992783f2d582ca5804bc081912f9bb674
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
 .../{scp-firmware_%.bbappend => scp-firmware_2.6%.bbappend}       | 0
 1 file changed, 0 insertions(+), 0 deletions(-)
 rename meta-arm-bsp/recipes-bsp/scp-firmware/{scp-firmware_%.bbappend => scp-firmware_2.6%.bbappend} (100%)

diff --git a/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware_%.bbappend b/meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware_2.6%.bbappend
similarity index 100%
rename from meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware_%.bbappend
rename to meta-arm-bsp/recipes-bsp/scp-firmware/scp-firmware_2.6%.bbappend
-- 
2.25.1

[PATCH 4/6] arm-bsp/scp-firmware: explicitly select scp-firmware 2.6

[Ross Burton]

Explicitly select scp-firmware 2.6 in all the machines that use it.

Change-Id: I83d3214fff05e7cbbf182f1215e67da42ceb68f1
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
 meta-arm-bsp/conf/machine/juno.conf   | 1 +
 meta-arm-bsp/conf/machine/n1sdp.conf  | 2 ++
 meta-arm-bsp/conf/machine/sgi575.conf | 2 ++
 meta-arm-bsp/conf/machine/tc0.conf    | 5 +++--
 4 files changed, 8 insertions(+), 2 deletions(-)

diff --git a/meta-arm-bsp/conf/machine/juno.conf b/meta-arm-bsp/conf/machine/juno.conf
index 2f42dea..8cff6c4 100644
--- a/meta-arm-bsp/conf/machine/juno.conf
+++ b/meta-arm-bsp/conf/machine/juno.conf
@@ -20,6 +20,7 @@ SERIAL_CONSOLES = "115200;ttyAMA0"
 # Use kernel provided by yocto
 PREFERRED_PROVIDER_virtual/kernel ?= "linux-yocto"
 PREFERRED_VERSION_linux-yocto ?= "5.4%"
+PREFERRED_VERSION_scp-firmware ?= "2.6%"
 PREFERRED_VERSION_trusted-firmware-a ?= "2.3%"
 PREFERRED_VERSION_u-boot ?= "2020.07"
 
diff --git a/meta-arm-bsp/conf/machine/n1sdp.conf b/meta-arm-bsp/conf/machine/n1sdp.conf
index 230c912..1f11acd 100644
--- a/meta-arm-bsp/conf/machine/n1sdp.conf
+++ b/meta-arm-bsp/conf/machine/n1sdp.conf
@@ -31,6 +31,8 @@ PREFERRED_VERSION_trusted-firmware-a ?= "2.3%"
 EXTRA_IMAGEDEPENDS += "virtual/trusted-firmware-a"
 EXTRA_IMAGEDEPENDS += "virtual/control-processor-firmware"
 
+PREFERRED_VERSION_scp-firmware ?= "2.6%"
+
 #UEFI EDK2 firmware
 EXTRA_IMAGEDEPENDS += "virtual/uefi-firmware"
 
diff --git a/meta-arm-bsp/conf/machine/sgi575.conf b/meta-arm-bsp/conf/machine/sgi575.conf
index e6d447d..7714d0d 100644
--- a/meta-arm-bsp/conf/machine/sgi575.conf
+++ b/meta-arm-bsp/conf/machine/sgi575.conf
@@ -14,6 +14,8 @@ PREFERRED_VERSION_trusted-firmware-a ?= "2.2%"
 
 EXTRA_IMAGEDEPENDS += "virtual/trusted-firmware-a"
 
+PREFERRED_VERSION_scp-firmware ?= "2.6%"
+
 # Use kernel provided by linaro
 KERNEL_IMAGETYPE ?= "Image"
 PREFERRED_PROVIDER_virtual/kernel ?= "linux-yocto"
diff --git a/meta-arm-bsp/conf/machine/tc0.conf b/meta-arm-bsp/conf/machine/tc0.conf
index 7776dde..8d70aad 100644
--- a/meta-arm-bsp/conf/machine/tc0.conf
+++ b/meta-arm-bsp/conf/machine/tc0.conf
@@ -15,11 +15,12 @@ PREFERRED_VERSION_u-boot ?= "2020.07"
 # Trusted firmware A v2.3
 PREFERRED_PROVIDER_virtual/trusted-firmware-a ?= "trusted-firmware-a"
 PREFERRED_VERSION_trusted-firmware-a ?= "2.3%"
-PREFERRED_VERSION_linux-arm64-ack ?= "5.4"
-
 EXTRA_IMAGEDEPENDS += "virtual/trusted-firmware-a"
 
+PREFERRED_VERSION_scp-firmware ?= "2.6%"
+
 PREFERRED_PROVIDER_virtual/kernel ?= "linux-arm64-ack"
+PREFERRED_VERSION_linux-arm64-ack ?= "5.4"
 
 # Cannot use the default zImage on arm64
 KERNEL_IMAGETYPE = "Image"
-- 
2.25.1

[PATCH 5/6] arm/scp-firmware: Add SCP v2.7.0

[Ross Burton]

From: Jon Mason <jon.mason@arm.com>

Add the latest version of SCP.  Not adding an inc file between them,
since the older one should be removed ASAP.

Change-Id: I0a1e58ffdb6d0d405b199e498587fe410076fc08
Signed-off-by: Jon Mason <jon.mason@arm.com>
---
 .../scp-firmware/scp-firmware_2.7.0.bb        | 74 +++++++++++++++++++
 1 file changed, 74 insertions(+)
 create mode 100644 meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.7.0.bb

diff --git a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.7.0.bb b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.7.0.bb
new file mode 100644
index 0000000..13092f1
--- /dev/null
+++ b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.7.0.bb
@@ -0,0 +1,74 @@
+SUMMARY = "SCP and MCP Firmware"
+DESCRIPTION = "Firmware for SCP and MCP software reference implementation"
+HOMEPAGE = "https://github.com/ARM-software/SCP-firmware"
+
+LICENSE = "BSD-3-Clause & Apache-2.0"
+LIC_FILES_CHKSUM = "file://license.md;beginline=5;md5=9db9e3d2fb8d9300a6c3d15101b19731 \
+                    file://cmsis/LICENSE.txt;md5=e3fc50a88d0a364313df4b21ef20c29e"
+
+SRC_URI = "gitsm://github.com/ARM-software/SCP-firmware.git;protocol=https"
+SRCREV  = "2c4f3af270024b85e1b38fd963050c58f6e9b865"
+
+PROVIDES += "virtual/control-processor-firmware"
+
+SCP_BUILD_RELEASE   ?= "1"
+SCP_PLATFORM        ?= "invalid"
+SCP_COMPILER        ?= "arm-none-eabi"
+SCP_LOG_LEVEL       ?= "WARN"
+
+DEPENDS += "virtual/arm-none-eabi-gcc-native"
+
+SCP_BUILD_STR = "${@bb.utils.contains('SCP_BUILD_RELEASE', '1', 'release', 'debug', d)}"
+
+inherit deploy
+
+B = "${WORKDIR}/build"
+S = "${WORKDIR}/git"
+
+# Allow platform specific copying of only scp or both scp & mcp, default to both
+FW_TARGETS ?= "scp mcp"
+FW_INSTALL ?= "ramfw romfw"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE ?= "invalid"
+
+LDFLAGS[unexport] = "1"
+
+# No configure
+do_configure[noexec] = "1"
+
+EXTRA_OEMAKE = "V=1 \
+                BUILD_PATH='${B}' \
+                PRODUCT='${SCP_PLATFORM}' \
+                MODE='${SCP_BUILD_STR}' \
+                LOG_LEVEL='${SCP_LOG_LEVEL}' \
+                CC='${SCP_COMPILER}-gcc' \
+                AR='${SCP_COMPILER}-ar' \
+                SIZE='${SCP_COMPILER}-size' \
+                OBJCOPY='${SCP_COMPILER}-objcopy' \
+                "
+
+do_compile() {
+    oe_runmake -C "${S}"
+}
+do_compile[cleandirs] += "${B}"
+
+do_install() {
+     install -d ${D}/firmware
+     for FW in ${FW_TARGETS}; do
+        for TYPE in ${FW_INSTALL}; do
+           install -D "${B}/product/${SCP_PLATFORM}/${FW}_${TYPE}/${SCP_BUILD_STR}/bin/${FW}_${TYPE}.bin" "${D}/firmware/"
+        done
+     done
+}
+
+FILES_${PN} = "/firmware"
+SYSROOT_DIRS += "/firmware"
+# Skip QA check for relocations in .text of elf binaries
+INSANE_SKIP_${PN} = "textrel"
+
+do_deploy() {
+    # Copy the images to deploy directory
+    cp -rf ${D}/firmware/* ${DEPLOYDIR}/
+}
+addtask deploy after do_install
-- 
2.25.1

[PATCH 6/6] arm/scp-firmware: remove redundant python3native inherit

[Ross Burton]

Change-Id: I9df71eb6bb99bb4af48b77f50a1056027c8227a4
---
 meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.6.0.bb | 1 -
 1 file changed, 1 deletion(-)

diff --git a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.6.0.bb b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.6.0.bb
index f9510e4..ab31746 100644
--- a/meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.6.0.bb
+++ b/meta-arm/recipes-bsp/scp-firmware/scp-firmware_2.6.0.bb
@@ -21,7 +21,6 @@ DEPENDS += "virtual/arm-none-eabi-gcc-native"
 
 SCP_BUILD_STR = "${@bb.utils.contains('SCP_BUILD_RELEASE', '1', 'release', 'debug', d)}"
 
-inherit python3native
 inherit deploy
 
 B = "${WORKDIR}/build"
-- 
2.25.1