* [PATCH 1/3] syslinux: rewrite recipe so only target code is x86-specific
@ 2020-12-10 15:02 Ross Burton
2020-12-10 15:02 ` [PATCH 2/3] wic-image-minimal: only depend on syslinux on x86 targets Ross Burton
` (2 more replies)
0 siblings, 3 replies; 4+ messages in thread
From: Ross Burton @ 2020-12-10 15:02 UTC (permalink / raw)
To: openembedded-core
Currently the syslinux recipe set COMPATIBLE_HOST to 32/64-bit x86.
Whilst this makes sense for the target binaries as syslinux is
x86-specific, this also affects the native recipe which should be able
to be built on non-x86 build hosts (for example, arm64 build host,
qemux86 target).
syslinux itself has a somewhat fragile build system but with care it is
possible to build the installer for native/nativesdk, and the bootloader
for target. Despite claims the documentation to the contrary, not all
of the bootloader is shipped precompiled in the tarball which does
complicate matters.
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
.../syslinux/syslinux_6.04-pre2.bb | 80 ++++++++++---------
1 file changed, 43 insertions(+), 37 deletions(-)
diff --git a/meta/recipes-devtools/syslinux/syslinux_6.04-pre2.bb b/meta/recipes-devtools/syslinux/syslinux_6.04-pre2.bb
index 3e7eef3a75..c233b3c39f 100644
--- a/meta/recipes-devtools/syslinux/syslinux_6.04-pre2.bb
+++ b/meta/recipes-devtools/syslinux/syslinux_6.04-pre2.bb
@@ -4,10 +4,7 @@ LICENSE = "GPLv2+"
LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
file://README;beginline=35;endline=41;md5=558f2c71cb1fb9ba511ccd4858e48e8a"
-# If you really want to run syslinux, you need mtools. We just want the
-# ldlinux.* stuff for now, so skip mtools-native
DEPENDS = "nasm-native util-linux e2fsprogs"
-PV = "6.04-pre2"
SRC_URI = "https://www.zytor.com/pub/syslinux/Testing/6.04/syslinux-${PV}.tar.xz \
file://syslinux-remove-clean-script.patch \
@@ -27,64 +24,73 @@ SRC_URI = "https://www.zytor.com/pub/syslinux/Testing/6.04/syslinux-${PV}.tar.xz
SRC_URI[md5sum] = "2b31c78f087f99179feb357da312d7ec"
SRC_URI[sha256sum] = "4441a5d593f85bb6e8d578cf6653fb4ec30f9e8f4a2315a3d8f2d0a8b3fadf94"
+RECIPE_NO_UPDATE_REASON = "6.04-pre3 is broken"
UPSTREAM_CHECK_URI = "https://www.zytor.com/pub/syslinux/"
UPSTREAM_CHECK_REGEX = "syslinux-(?P<pver>.+)\.tar"
UPSTREAM_VERSION_UNKNOWN = "1"
-COMPATIBLE_HOST = '(x86_64|i.86).*-(linux|freebsd.*)'
+# We can build the native parts anywhere, but the target has to be x86
+COMPATIBLE_HOST_class-target = '(x86_64|i.86).*-(linux|freebsd.*)'
+
# Don't let the sanity checker trip on the 32 bit real mode BIOS binaries
INSANE_SKIP_${PN}-misc = "arch"
INSANE_SKIP_${PN}-chain = "arch"
+# When building the installer, CC is used to link. When building the bootloader,
+# LD is used. However, these variables assume that GCC is used and break the
+# build, so unset them.
+TARGET_LDFLAGS = ""
+SECURITY_LDFLAGS = ""
+LDFLAGS_SECTION_REMOVAL = ""
+
EXTRA_OEMAKE = " \
BINDIR=${bindir} SBINDIR=${sbindir} LIBDIR=${libdir} \
DATADIR=${datadir} MANDIR=${mandir} INCDIR=${includedir} \
+ CC="${CC} ${CFLAGS} ${LDFLAGS}" \
+ LD="${LD} ${LDFLAGS}" \
+ OBJDUMP="${OBJDUMP}" \
+ OBJCOPY="${OBJCOPY}" \
+ AR="${AR}" \
+ STRIP="${STRIP}" \
+ NM="${NM}" \
+ RANLIB="${RANLIB}" \
"
+#
+# Tasks for native/nativesdk which just build the installer.
+#
do_configure() {
- # drop win32 targets or build fails
- sed -e 's,win32/\S*,,g' -i Makefile
-
- # clean installer executables included in source tarball
- oe_runmake clean firmware="efi32" EFIINC="${includedir}"
- # NOTE: There is a temporary work around above to specify
- # the efi32 as the firmware else the pre-built bios
- # files get erased contrary to the doc/distib.txt
- # In the future this should be "bios" and not "efi32".
+ oe_runmake firmware="bios" clean
}
do_compile() {
- # Make sure the recompile is OK.
- # Though the ${B} should always exist, still check it before find and rm.
- [ -d "${B}" ] && find ${B} -name '.*.d' -type f -exec rm -f {} \;
-
- # Rebuild only the installer; keep precompiled bootloaders
- # as per author's request (doc/distrib.txt)
- oe_runmake CC="${CC} ${CFLAGS}" \
- LD="${LD}" LDFLAGS="${LDFLAGS}" \
- OBJDUMP="${OBJDUMP}" \
- OBJCOPY="${OBJCOPY}" \
- AR="${AR}" \
- STRIP="${STRIP}" \
- NM="${NM}" \
- RANLIB="${RANLIB}" \
- firmware="bios" installer
+ oe_runmake firmware="bios" installer
}
do_install() {
- oe_runmake CC="${CC} ${CFLAGS}" LD="${LD}" \
- OBJDUMP="${OBJDUMP}" \
- OBJCOPY="${OBJCOPY}" \
- AR="${AR}" \
- STRIP="${STRIP}" \
- NM="${NM}" \
- RANLIB="${RANLIB}" \
- firmware="bios" install INSTALLROOT="${D}"
+ install -d ${D}${bindir}
+ install ${B}/bios/mtools/syslinux ${B}/bios/extlinux/extlinux ${D}${bindir}
+}
+
+#
+# Tasks for target which ship the precompiled bootloader and installer
+#
+do_configure_class-target() {
+ # No need to do anything as we're mostly shipping the precompiled binaries
+ :
+}
+
+do_compile_class-target() {
+ # No need to do anything as we're mostly shipping the precompiled binaries
+ :
+}
+
+do_install_class-target() {
+ oe_runmake firmware="bios" install INSTALLROOT="${D}"
install -d ${D}${datadir}/syslinux/
install -m 644 ${S}/bios/core/ldlinux.sys ${D}${datadir}/syslinux/
install -m 644 ${S}/bios/core/ldlinux.bss ${D}${datadir}/syslinux/
- install -m 755 ${S}/bios/linux/syslinux-nomtools ${D}${bindir}/
}
PACKAGES += "${PN}-nomtools ${PN}-extlinux ${PN}-mbr ${PN}-chain ${PN}-pxelinux ${PN}-isolinux ${PN}-misc"
--
2.25.1
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [PATCH 2/3] wic-image-minimal: only depend on syslinux on x86 targets
2020-12-10 15:02 [PATCH 1/3] syslinux: rewrite recipe so only target code is x86-specific Ross Burton
@ 2020-12-10 15:02 ` Ross Burton
2020-12-10 15:02 ` [PATCH 3/3] wic-tools: don't build syslinux-native for targets without syslinux Ross Burton
2020-12-14 13:38 ` [OE-core] [PATCH 1/3] syslinux: rewrite recipe so only target code is x86-specific Richard Purdie
2 siblings, 0 replies; 4+ messages in thread
From: Ross Burton @ 2020-12-10 15:02 UTC (permalink / raw)
To: openembedded-core
Following other examples, only depend on syslinux when targetting x86.
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
meta-selftest/recipes-test/images/wic-image-minimal.bb | 5 ++++-
1 file changed, 4 insertions(+), 1 deletion(-)
diff --git a/meta-selftest/recipes-test/images/wic-image-minimal.bb b/meta-selftest/recipes-test/images/wic-image-minimal.bb
index e1da203b59..1cb019898d 100644
--- a/meta-selftest/recipes-test/images/wic-image-minimal.bb
+++ b/meta-selftest/recipes-test/images/wic-image-minimal.bb
@@ -6,7 +6,10 @@ IMAGE_INSTALL = "packagegroup-core-boot"
IMAGE_FSTYPES = "wic"
-WKS_FILE_DEPENDS = "syslinux syslinux-native dosfstools-native mtools-native gptfdisk-native"
+WKS_FILE_DEPENDS = "dosfstools-native mtools-native gptfdisk-native"
+WKS_FILE_DEPENDS_append_x86 = " syslinux-native syslinux"
+WKS_FILE_DEPENDS_append_x86-64 = " syslinux-native syslinux"
+WKS_FILE_DEPENDS_append_x86-x32 = " syslinux-native syslinux"
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
--
2.25.1
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [PATCH 3/3] wic-tools: don't build syslinux-native for targets without syslinux
2020-12-10 15:02 [PATCH 1/3] syslinux: rewrite recipe so only target code is x86-specific Ross Burton
2020-12-10 15:02 ` [PATCH 2/3] wic-image-minimal: only depend on syslinux on x86 targets Ross Burton
@ 2020-12-10 15:02 ` Ross Burton
2020-12-14 13:38 ` [OE-core] [PATCH 1/3] syslinux: rewrite recipe so only target code is x86-specific Richard Purdie
2 siblings, 0 replies; 4+ messages in thread
From: Ross Burton @ 2020-12-10 15:02 UTC (permalink / raw)
To: openembedded-core
If we're not building syslinux, then there's no point building
syslinux-native.
Signed-off-by: Ross Burton <ross.burton@arm.com>
---
meta/recipes-core/meta/wic-tools.bb | 8 ++++----
1 file changed, 4 insertions(+), 4 deletions(-)
diff --git a/meta/recipes-core/meta/wic-tools.bb b/meta/recipes-core/meta/wic-tools.bb
index 3e7d0ed48d..f04f767646 100644
--- a/meta/recipes-core/meta/wic-tools.bb
+++ b/meta/recipes-core/meta/wic-tools.bb
@@ -3,14 +3,14 @@ SUMMARY = "A meta recipe to build native tools used by wic."
LICENSE = "MIT"
DEPENDS = "\
- parted-native syslinux-native gptfdisk-native dosfstools-native \
+ parted-native gptfdisk-native dosfstools-native \
mtools-native bmap-tools-native grub-native cdrtools-native \
btrfs-tools-native squashfs-tools-native pseudo-native \
e2fsprogs-native util-linux-native tar-native\
"
-DEPENDS_append_x86 = " syslinux grub-efi systemd-boot"
-DEPENDS_append_x86-64 = " syslinux grub-efi systemd-boot"
-DEPENDS_append_x86-x32 = " syslinux grub-efi"
+DEPENDS_append_x86 = " syslinux-native syslinux grub-efi systemd-boot"
+DEPENDS_append_x86-64 = " syslinux-native syslinux grub-efi systemd-boot"
+DEPENDS_append_x86-x32 = " syslinux-native syslinux grub-efi"
INHIBIT_DEFAULT_DEPS = "1"
--
2.25.1
^ permalink raw reply related [flat|nested] 4+ messages in thread
* Re: [OE-core] [PATCH 1/3] syslinux: rewrite recipe so only target code is x86-specific
2020-12-10 15:02 [PATCH 1/3] syslinux: rewrite recipe so only target code is x86-specific Ross Burton
2020-12-10 15:02 ` [PATCH 2/3] wic-image-minimal: only depend on syslinux on x86 targets Ross Burton
2020-12-10 15:02 ` [PATCH 3/3] wic-tools: don't build syslinux-native for targets without syslinux Ross Burton
@ 2020-12-14 13:38 ` Richard Purdie
2 siblings, 0 replies; 4+ messages in thread
From: Richard Purdie @ 2020-12-14 13:38 UTC (permalink / raw)
To: Ross Burton, openembedded-core; +Cc: Alejandro Hernandez
On Thu, 2020-12-10 at 15:02 +0000, Ross Burton wrote:
> Currently the syslinux recipe set COMPATIBLE_HOST to 32/64-bit x86.
> Whilst this makes sense for the target binaries as syslinux is
> x86-specific, this also affects the native recipe which should be able
> to be built on non-x86 build hosts (for example, arm64 build host,
> qemux86 target).
>
> syslinux itself has a somewhat fragile build system but with care it is
> possible to build the installer for native/nativesdk, and the bootloader
> for target. Despite claims the documentation to the contrary, not all
> of the bootloader is shipped precompiled in the tarball which does
> complicate matters.
>
> Signed-off-by: Ross Burton <ross.burton@arm.com>
> ---
> .../syslinux/syslinux_6.04-pre2.bb | 80 ++++++++++---------
> 1 file changed, 43 insertions(+), 37 deletions(-)
Something isn't quite right in this series:
https://autobuilder.yoctoproject.org/typhoon/#/builders/87/builds/1654/steps/14/logs/stdio
(and all the other selftests in that build)
Cheers,
Richard
^ permalink raw reply [flat|nested] 4+ messages in thread
end of thread, other threads:[~2020-12-14 13:38 UTC | newest]
Thread overview: 4+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2020-12-10 15:02 [PATCH 1/3] syslinux: rewrite recipe so only target code is x86-specific Ross Burton
2020-12-10 15:02 ` [PATCH 2/3] wic-image-minimal: only depend on syslinux on x86 targets Ross Burton
2020-12-10 15:02 ` [PATCH 3/3] wic-tools: don't build syslinux-native for targets without syslinux Ross Burton
2020-12-14 13:38 ` [OE-core] [PATCH 1/3] syslinux: rewrite recipe so only target code is x86-specific Richard Purdie
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.