[meta-oe][PATCH] waylandpp: add recipe

[meta-oe][PATCH] waylandpp: add recipe

[Markus Volk]

This adds C++ bindings for Wayland as used e.g. in the Kodi project

Signed-off-by: Markus Volk <f_l_k@t-online.de>
---
 .../wayland/waylandpp_1.0.0.bb                | 37 +++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 meta-oe/recipes-graphics/wayland/waylandpp_1.0.0.bb

diff --git a/meta-oe/recipes-graphics/wayland/waylandpp_1.0.0.bb b/meta-oe/recipes-graphics/wayland/waylandpp_1.0.0.bb
new file mode 100644
index 000000000..f075f2a3a
--- /dev/null
+++ b/meta-oe/recipes-graphics/wayland/waylandpp_1.0.0.bb
@@ -0,0 +1,37 @@
+SUMMARY = " C++ binding for Wayland using the most modern C++ technology"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=3aae28cc66d61975114c2b14df215407"
+
+SRC_URI = "git://github.com/NilsBrause/waylandpp.git;protocol=https;branch=master"
+
+DEPENDS = "pugixml"
+DEPENDS:append:class-target = " waylandpp-native wayland virtual/egl virtual/libgles2"
+
+S = "${WORKDIR}/git"
+SRCREV = "4321ed5c7b4bffa41b8a2a13dc7f3ece1191f4f3"
+
+inherit cmake pkgconfig
+
+EXTRA_OECMAKE:class-native = " \
+	-DBUILD_SCANNER=ON \
+	-DBUILD_LIBRARIES=OFF \
+	-DBUILD_DOCUMENTATION=OFF \
+	-DCMAKE_BUILD_TYPE=Release \
+	-DCMAKE_VERBOSE_MAKEFILE=TRUE \
+"
+
+EXTRA_OECMAKE:class-target = " \
+	-DBUILD_SCANNER=ON \
+	-DBUILD_LIBRARIES=ON \
+	-DBUILD_DOCUMENTATION=OFF \
+	-DBUILD_EXAMPLES=OFF \
+	-DOPENGL_LIBRARY="-lEGL -lGLESv2" \
+	-DOPENGL_opengl_LIBRARY=-lEGL \
+	-DOPENGL_glx_LIBRARY=-lEGL \
+	-DWAYLAND_SCANNERPP="${STAGING_BINDIR_NATIVE}/wayland-scanner++" \
+	-DCMAKE_BUILD_TYPE=Release \
+	-DCMAKE_VERBOSE_MAKEFILE=TRUE \
+	-DCMAKE_EXE_LINKER_FLAGS="-Wl,--enable-new-dtags" \
+"
+
+BBCLASSEXTEND += "native nativesdk"
-- 
2.34.1