[meta-ti][dunfell][PATCH 1/3] recipies-ti: Add TI K3 Security Development Package

* [meta-ti][dunfell][PATCH 1/3] recipies-ti: Add TI K3 Security Development Package
@ 2022-08-12  1:41 Andrew Davis
  2022-08-12  1:41 ` [meta-ti][dunfell][PATCH 2/3] ti-sci-fw: Use ti-k3-secdev if TI_SECURE_DEV_PKG_K3 is not defined Andrew Davis
  2022-08-12  1:41 ` [meta-ti][dunfell][PATCH 3/3] conf: machine: am64xx-evm: Make HS-SE the default Andrew Davis
  0 siblings, 2 replies; 3+ messages in thread
From: Andrew Davis @ 2022-08-12  1:41 UTC (permalink / raw)
  To: Denys Dmytriyenko, Ryan Eatmon, meta-ti; +Cc: Andrew Davis

Signed-off-by: Andrew Davis <afd@ti.com>
---
 recipes-ti/includes/ti-paths.inc      |  2 ++
 recipes-ti/secdev/ti-k3-secdev_git.bb | 36 +++++++++++++++++++++++++++
 2 files changed, 38 insertions(+)
 create mode 100644 recipes-ti/secdev/ti-k3-secdev_git.bb

diff --git a/recipes-ti/includes/ti-paths.inc b/recipes-ti/includes/ti-paths.inc
index 52a93cf5..44731a4e 100644
--- a/recipes-ti/includes/ti-paths.inc
+++ b/recipes-ti/includes/ti-paths.inc
@@ -61,6 +61,7 @@ export TI_CGT6X_7_INSTALL_DIR_RECIPE   = "${installdir}/cgt6x-7"
 export GCC_LINARO_BAREMETAL_TOOLCHAIN_RECIPE          = "${installdir}/gcc-linaro-baremetal"
 export GCC_LINARO_BAREMETAL_AARCH64_TOOLCHAIN_RECIPE  = "${installdir}/gcc-linaro-baremetal-aarch64"
 export TI_CGT7X_INSTALL_DIR_RECIPE        = "${installdir}/cgt-c7x"
+export TI_K3_SECDEV_INSTALL_DIR_RECIPE = "${installdir}/ti-k3-secdev"
 
 
 # This is where the tools will end up in sysroot
@@ -116,6 +117,7 @@ export TI_CGT6X_7_INSTALL_DIR   = "${STAGING_DIR_NATIVE}${TI_CGT6X_7_INSTALL_DIR
 export GCC_LINARO_BAREMETAL_TOOLCHAIN         =  "${STAGING_DIR_NATIVE}${GCC_LINARO_BAREMETAL_TOOLCHAIN_RECIPE}"
 export GCC_LINARO_BAREMETAL_AARCH64_TOOLCHAIN =  "${STAGING_DIR_NATIVE}${GCC_LINARO_BAREMETAL_AARCH64_TOOLCHAIN_RECIPE}"
 export TI_CGT7X_INSTALL_DIR        = "${STAGING_DIR_NATIVE}${TI_CGT7X_INSTALL_DIR_RECIPE}"
+export TI_K3_SECDEV_INSTALL_DIR = "${STAGING_DIR_NATIVE}${TI_K3_SECDEV_INSTALL_DIR_RECIPE}"
 
 
 DSPSUFFIX_omapl137 = "x674"
diff --git a/recipes-ti/secdev/ti-k3-secdev_git.bb b/recipes-ti/secdev/ti-k3-secdev_git.bb
new file mode 100644
index 00000000..28dbe9ee
--- /dev/null
+++ b/recipes-ti/secdev/ti-k3-secdev_git.bb
@@ -0,0 +1,36 @@
+DESCRIPTION = "Security development tools for High-Security(HS) TI K3 processors."
+HOMEPAGE = "https://git.ti.com/cgit/security-development-tools/core-secdev-k3"
+SECTION = "devel"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://manifest/k3-secdev-0.2-manifest.html;md5=f632a78870cc64550078d7b3cbac0892"
+
+# Native host tool only
+COMPATIBLE_MACHINE = "null"
+COMPATIBLE_MACHINE_class-native = "(.*)"
+COMPATIBLE_MACHINE_class-nativesdk = "(.*)"
+
+GIT_URI = "git://git.ti.com/git/security-development-tools/core-secdev-k3.git"
+GIT_PROTOCOL = "https"
+GIT_BRANCH = "master"
+GIT_SRCREV = "eb2c4d734487e5095b94cef3fd7213ee71d9e016"
+
+SRC_URI = "${GIT_URI};protocol=${GIT_PROTOCOL};branch=${GIT_BRANCH}"
+SRCREV = "${GIT_SRCREV}"
+
+S = "${WORKDIR}/git"
+
+do_install() {
+    CP_ARGS="-Prf --preserve=mode,links,timestamps --no-preserve=ownership"
+    install -d ${D}${TI_K3_SECDEV_INSTALL_DIR_RECIPE}
+    cp ${CP_ARGS} ${S}/* ${D}${TI_K3_SECDEV_INSTALL_DIR_RECIPE}
+}
+
+FILES_${PN} += "${TI_K3_SECDEV_INSTALL_DIR_RECIPE}"
+
+INSANE_SKIP_${PN} = "arch ldflags file-rdeps"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+
+BBCLASSEXTEND = "native nativesdk"
-- 
2.36.1



^ permalink raw reply related	[flat|nested] 3+ messages in thread