[meta-python][meta-oe][PATCH 0/3] Add tuna recipe and dependencies

[meta-python][meta-oe][PATCH 0/3] Add tuna recipe and dependencies

[Erwann Roussy]

Tuna a is cui/gui tool for tuning of running processes.
It is helpful to show and change irq affinity on an embedded system.
This series add tuna recipe and its two dependencies.

[meta-python][PATCH 1/3] python3-schedutils: add recipe

[Erwann Roussy]

Signed-off-by: Erwann Roussy <erwann.roussy@savoirfairelinux.com>
---
 .../python/python3-schedutils_0.6.bb                 | 12 ++++++++++++
 1 file changed, 12 insertions(+)
 create mode 100644 meta-python/recipes-devtools/python/python3-schedutils_0.6.bb

diff --git a/meta-python/recipes-devtools/python/python3-schedutils_0.6.bb b/meta-python/recipes-devtools/python/python3-schedutils_0.6.bb
new file mode 100644
index 000000000..50868b9c4
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-schedutils_0.6.bb
@@ -0,0 +1,12 @@
+DESCRIPTION = "Python interface for the Linux scheduler functions etc."
+HOMEPAGE = "https://git.kernel.org/pub/scm/libs/python/python-schedutils/python-schedutils.git/"
+SECTION = "devel/python"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=8ca43cbc842c2336e835926c2166c28b"
+
+SRC_URI = "git://git.kernel.org/pub/scm/libs/python/python-schedutils/python-schedutils.git;branch=main"
+SRCREV = "46469f425f9844f355f6496785ee1ce993b58747"
+
+S = "${WORKDIR}/git"
+
+inherit setuptools3
-- 
2.25.1

[meta-python][PATCH 2/3] python3-linux-procfs: add recipe

[Erwann Roussy]

Signed-off-by: Erwann Roussy <erwann.roussy@savoirfairelinux.com>
---
 .../python/python3-linux-procfs_0.7.1.bb             | 12 ++++++++++++
 1 file changed, 12 insertions(+)
 create mode 100644 meta-python/recipes-devtools/python/python3-linux-procfs_0.7.1.bb

diff --git a/meta-python/recipes-devtools/python/python3-linux-procfs_0.7.1.bb b/meta-python/recipes-devtools/python/python3-linux-procfs_0.7.1.bb
new file mode 100644
index 000000000..9395a792f
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-linux-procfs_0.7.1.bb
@@ -0,0 +1,12 @@
+DESCRIPTION = "Python classes to extract information from the Linux kernel /proc files."
+HOMEPAGE = "https://git.kernel.org/pub/scm/libs/python/python-linux-procfs/python-linux-procfs.git/"
+SECTION = "devel/python"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=8ca43cbc842c2336e835926c2166c28b"
+
+SRC_URI = "git://git.kernel.org/pub/scm/libs/python/python-linux-procfs/python-linux-procfs.git;branch=main"
+SRCREV = "7f43598387e44e2da93ead2e075b7232429e4cc4"
+
+S = "${WORKDIR}/git"
+
+inherit setuptools3
-- 
2.25.1

[meta-oe][PATCH 3/3] tuna: add recipe

[Erwann Roussy]

Tuna is a cui/gui tool for tuning of running processes.
It is useful to see and changed irq affinity on an embedded board.

The chosen revision of tuna is the last commit to this day and not the
last release. This is due to the python3-ethtool module which was
required in the last release but isn't anymore. Tuna now has a built-in
module instead.

Despite tuna's homepage's dependencies section, python3-inet_diag isn't
required anymore.

Signed-off-by: Erwann Roussy <erwann.roussy@savoirfairelinux.com>
---
 meta-oe/recipes-support/tuna/tuna_git.bb | 25 ++++++++++++++++++++++++
 1 file changed, 25 insertions(+)
 create mode 100644 meta-oe/recipes-support/tuna/tuna_git.bb

diff --git a/meta-oe/recipes-support/tuna/tuna_git.bb b/meta-oe/recipes-support/tuna/tuna_git.bb
new file mode 100644
index 000000000..f698b2ea2
--- /dev/null
+++ b/meta-oe/recipes-support/tuna/tuna_git.bb
@@ -0,0 +1,25 @@
+SUMMARY = "cui/gui tool for tuning of running processes"
+HOMEPAGE = "https://rt.wiki.kernel.org/index.php/Tuna"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/GPL-2.0-only;md5=801f80980d171dd6425610833a22dbe6"
+
+SRC_URI = "git://git.kernel.org/pub/scm/utils/tuna/tuna.git;branch=main"
+
+SRCREV = "0681906e75e1c8166126bbfc2f3055e7507bfcb5"
+
+S = "${WORKDIR}/git"
+
+RDEPENDS:${PN} += " \
+    python3-io \
+    python3-linux-procfs \
+    python3-logging \
+    python3-schedutils \
+    python3-six \
+    "
+
+inherit setuptools3
+
+do_install:append() {
+    install -m 0755 -d ${D}${bindir}
+    install -m 0755 ${S}/tuna-cmd.py ${D}${bindir}/tuna
+}
-- 
2.25.1

Re: [oe] [meta-oe][PATCH 3/3] tuna: add recipe

[Khem Raj]

On Mon, Nov 28, 2022 at 7:21 AM Erwann Roussy
<erwann.roussy@savoirfairelinux.com> wrote:
>
> Tuna is a cui/gui tool for tuning of running processes.
> It is useful to see and changed irq affinity on an embedded board.
>
> The chosen revision of tuna is the last commit to this day and not the
> last release. This is due to the python3-ethtool module which was
> required in the last release but isn't anymore. Tuna now has a built-in
> module instead.
>
> Despite tuna's homepage's dependencies section, python3-inet_diag isn't
> required anymore.
>
> Signed-off-by: Erwann Roussy <erwann.roussy@savoirfairelinux.com>
> ---
>  meta-oe/recipes-support/tuna/tuna_git.bb | 25 ++++++++++++++++++++++++
>  1 file changed, 25 insertions(+)
>  create mode 100644 meta-oe/recipes-support/tuna/tuna_git.bb
>
> diff --git a/meta-oe/recipes-support/tuna/tuna_git.bb b/meta-oe/recipes-support/tuna/tuna_git.bb
> new file mode 100644
> index 000000000..f698b2ea2
> --- /dev/null
> +++ b/meta-oe/recipes-support/tuna/tuna_git.bb
> @@ -0,0 +1,25 @@
> +SUMMARY = "cui/gui tool for tuning of running processes"
> +HOMEPAGE = "https://rt.wiki.kernel.org/index.php/Tuna"
> +LICENSE = "GPL-2.0-only"
> +LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/GPL-2.0-only;md5=801f80980d171dd6425610833a22dbe6"
> +
> +SRC_URI = "git://git.kernel.org/pub/scm/utils/tuna/tuna.git;branch=main"
> +
> +SRCREV = "0681906e75e1c8166126bbfc2f3055e7507bfcb5"
> +
> +S = "${WORKDIR}/git"
> +
> +RDEPENDS:${PN} += " \
> +    python3-io \
> +    python3-linux-procfs \
> +    python3-logging \
> +    python3-schedutils \
> +    python3-six \
> +    "

it seems to depend on python3-linux-procfs which is in meta-python but
meta-oe does not depend on meta-python
as layer dependency, so perhaps it should be using dynamic layers or
perhaps should be moved to meta-python

> +
> +inherit setuptools3
> +
> +do_install:append() {
> +    install -m 0755 -d ${D}${bindir}
> +    install -m 0755 ${S}/tuna-cmd.py ${D}${bindir}/tuna
> +}
> --
> 2.25.1
>
>
> -=-=-=-=-=-=-=-=-=-=-=-
> Links: You receive all messages sent to this group.
> View/Reply Online (#99829): https://lists.openembedded.org/g/openembedded-devel/message/99829
> Mute This Topic: https://lists.openembedded.org/mt/95312027/1997914
> Group Owner: openembedded-devel+owner@lists.openembedded.org
> Unsubscribe: https://lists.openembedded.org/g/openembedded-devel/unsub [raj.khem@gmail.com]
> -=-=-=-=-=-=-=-=-=-=-=-
>