[meta-oe][PATCH 1/3] python3-pycups: add recipe

[meta-oe][PATCH 1/3] python3-pycups: add recipe

[Markus Volk]

This is a runtime dependency for system-config-printer

Signed-off-by: Markus Volk <f_l_k@t-online.de>
---
 meta-oe/recipes-printing/cups/python3-pycups.bb | 11 +++++++++++
 1 file changed, 11 insertions(+)
 create mode 100644 meta-oe/recipes-printing/cups/python3-pycups.bb

diff --git a/meta-oe/recipes-printing/cups/python3-pycups.bb b/meta-oe/recipes-printing/cups/python3-pycups.bb
new file mode 100644
index 000000000..6968170d9
--- /dev/null
+++ b/meta-oe/recipes-printing/cups/python3-pycups.bb
@@ -0,0 +1,11 @@
+SUMMARY = "CUPS bindings for Python"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=3961efb54421653518521529853444c4"
+
+RDEPENDS:${PN} = "python3"
+
+inherit setuptools3 pypi
+
+PV = "2.0.1"
+
+SRC_URI[sha256sum] = "e880d7d7147959ead5cb34764f08b97b41385b36eb8256e8af1ce163dbcccce8"
-- 
2.34.1

[meta-oe][PATCH 2/3] system-config-printer: add recipe

[Markus Volk]

The OpenPrinting gui for cups configuration

Signed-off-by: Markus Volk <f_l_k@t-online.de>
---
 .../system-config-printer_1.5.18.bb           | 36 +++++++++++++++++++
 1 file changed, 36 insertions(+)
 create mode 100644 meta-oe/recipes-printing/system-config-printer/system-config-printer_1.5.18.bb

diff --git a/meta-oe/recipes-printing/system-config-printer/system-config-printer_1.5.18.bb b/meta-oe/recipes-printing/system-config-printer/system-config-printer_1.5.18.bb
new file mode 100644
index 000000000..57b238929
--- /dev/null
+++ b/meta-oe/recipes-printing/system-config-printer/system-config-printer_1.5.18.bb
@@ -0,0 +1,36 @@
+DESCRIPTION = "a graphical user interface that allows the user to change print settings"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+SRC_URI = "git://github.com/OpenPrinting/system-config-printer.git;protocol=https;branch=master"
+
+SRCREV = "895d3dec50c93bfd4f142bac9bfcc13051bf84cb"
+S = "${WORKDIR}/git"
+
+inherit autotools gettext pkgconfig python3native features_check
+
+REQUIRED_DISTRO_FEATURES = "gobject-introspection-data"
+
+DEPENDS = "cups glib-2.0 libusb systemd xmlto-native intltool-native desktop-file-utils-native"
+
+do_configure:prepend() {
+    # This file is not provided if fetching from git but required for configure
+    touch ${S}/ChangeLog
+}
+
+FILES:${PN} += "${libdir} ${datadir}"
+
+RDEPENDS:${PN} = " \
+    dbus-x11 \
+    gtk+3 \
+    libnotify \
+    python3 \
+    python3-dbus \
+    python3-firewall \
+    python3-pycups \
+    python3-pycurl \
+    python3-pygobject \
+"
+
+# ignore 'requires /usr/bin/python3, but no providers found in RDEPENDS:system-config-printer? [file-rdeps]'
+INSANE_SKIP:${PN} = "file-rdeps"
-- 
2.34.1

[meta-oe][PATCH 3/3] blueman: add missing runtime dependency, add polkit rule

[Markus Volk]

Add a missing runtime dependency on python3-ctypes

Add a polkit rule to allow users of group wheel to use blueman without authentification

Signed-off-by: Markus Volk <f_l_k@t-online.de>
---
 .../blueman/blueman_2.3.5.bb                  | 28 ++++++++++++++++++-
 1 file changed, 27 insertions(+), 1 deletion(-)

diff --git a/meta-networking/recipes-connectivity/blueman/blueman_2.3.5.bb b/meta-networking/recipes-connectivity/blueman/blueman_2.3.5.bb
index 2343cec71..eb42e62f4 100644
--- a/meta-networking/recipes-connectivity/blueman/blueman_2.3.5.bb
+++ b/meta-networking/recipes-connectivity/blueman/blueman_2.3.5.bb
@@ -4,7 +4,7 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
 
 DEPENDS = "gtk+3 glib-2.0 bluez5 python3-pygobject python3-cython-native"
 
-inherit meson gettext systemd gsettings pkgconfig python3native gtk-icon-cache
+inherit meson gettext systemd gsettings pkgconfig python3native gtk-icon-cache useradd
 
 SRC_URI = " \
     git://github.com/blueman-project/blueman.git;protocol=https;branch=2-3-stable \
@@ -23,6 +23,7 @@ SYSTEMD_AUTO_ENABLE:${PN} = "disable"
 RRECOMMENDS:${PN} += "adwaita-icon-theme"
 RDEPENDS:${PN} += " \
     python3-core \
+    python3-ctypes \
     python3-dbus \
     python3-pygobject \
     python3-terminal \
@@ -58,3 +59,28 @@ do_install:append() {
                                               ${D}${bindir}/blueman-tray
 }
 
+do_install:append() {
+    install -d ${D}${datadir}/polkit-1/rules.d
+    cat >${D}${datadir}/polkit-1/rules.d/51-blueman.rules <<EOF
+/* Allow users in wheel group to use blueman feature requiring root without authentication */
+polkit.addRule(function(action, subject) {
+    if ((action.id == "org.blueman.network.setup" ||
+         action.id == "org.blueman.dhcp.client" ||
+         action.id == "org.blueman.rfkill.setstate" ||
+         action.id == "org.blueman.pppd.pppconnect") &&
+        subject.isInGroup("wheel")) {
+
+        return polkit.Result.YES;
+    }
+});
+EOF
+}
+
+USERADD_PACKAGES = "${PN}"
+USERADD_PARAM:${PN} = "--system --no-create-home --user-group --home-dir ${sysconfdir}/polkit-1 --shell /bin/nologin polkitd"
+
+do_install:append() {
+        # Fix up permissions on polkit rules.d to work with rpm4 constraints
+        chmod 700 ${D}/${datadir}/polkit-1/rules.d
+        chown polkitd:root ${D}/${datadir}/polkit-1/rules.d
+}
-- 
2.34.1

Re: [oe] [meta-oe][PATCH 2/3] system-config-printer: add recipe

[Khem Raj]

On Tue, Jan 31, 2023 at 9:09 AM Markus Volk <f_l_k@t-online.de> wrote:
>
> The OpenPrinting gui for cups configuration
>
> Signed-off-by: Markus Volk <f_l_k@t-online.de>
> ---
>  .../system-config-printer_1.5.18.bb           | 36 +++++++++++++++++++
>  1 file changed, 36 insertions(+)
>  create mode 100644 meta-oe/recipes-printing/system-config-printer/system-config-printer_1.5.18.bb
>
> diff --git a/meta-oe/recipes-printing/system-config-printer/system-config-printer_1.5.18.bb b/meta-oe/recipes-printing/system-config-printer/system-config-printer_1.5.18.bb
> new file mode 100644
> index 000000000..57b238929
> --- /dev/null
> +++ b/meta-oe/recipes-printing/system-config-printer/system-config-printer_1.5.18.bb
> @@ -0,0 +1,36 @@
> +DESCRIPTION = "a graphical user interface that allows the user to change print settings"
> +LICENSE = "GPL-2.0-only"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
> +
> +SRC_URI = "git://github.com/OpenPrinting/system-config-printer.git;protocol=https;branch=master"
> +
> +SRCREV = "895d3dec50c93bfd4f142bac9bfcc13051bf84cb"
> +S = "${WORKDIR}/git"
> +
> +inherit autotools gettext pkgconfig python3native features_check
> +
> +REQUIRED_DISTRO_FEATURES = "gobject-introspection-data"
> +
> +DEPENDS = "cups glib-2.0 libusb systemd xmlto-native intltool-native desktop-file-utils-native"
> +
> +do_configure:prepend() {
> +    # This file is not provided if fetching from git but required for configure
> +    touch ${S}/ChangeLog
> +}
> +
> +FILES:${PN} += "${libdir} ${datadir}"
> +
> +RDEPENDS:${PN} = " \
> +    dbus-x11 \
> +    gtk+3 \
> +    libnotify \
> +    python3 \
> +    python3-dbus \
> +    python3-firewall \
> +    python3-pycups \
> +    python3-pycurl \
> +    python3-pygobject \
> +"
> +
> +# ignore 'requires /usr/bin/python3, but no providers found in RDEPENDS:system-config-printer? [file-rdeps]'

maybe change this to

#!/usr/bin/env python3

> +INSANE_SKIP:${PN} = "file-rdeps"
> --
> 2.34.1
>
>
> -=-=-=-=-=-=-=-=-=-=-=-
> Links: You receive all messages sent to this group.
> View/Reply Online (#100882): https://lists.openembedded.org/g/openembedded-devel/message/100882
> Mute This Topic: https://lists.openembedded.org/mt/96656636/1997914
> Group Owner: openembedded-devel+owner@lists.openembedded.org
> Unsubscribe: https://lists.openembedded.org/g/openembedded-devel/unsub [raj.khem@gmail.com]
> -=-=-=-=-=-=-=-=-=-=-=-
>

Re: [oe] [meta-oe][PATCH 2/3] system-config-printer: add recipe

[Markus Volk]

[-- Attachment #1: Type: text/plain, Size: 247 bytes --]

Am Di, 31. Jan 2023 um 09:56:29 -0800 schrieb Khem Raj 
<raj.khem@gmail.com>:
> maybe change this to
> 
> #!/usr/bin/env python3

But that would be about 50 files in which the shebang would have to be 
changed. They are all '#!/usr/bin/python3'.


[-- Attachment #2: Type: text/html, Size: 409 bytes --]

Re: [oe] [meta-oe][PATCH 2/3] system-config-printer: add recipe

[Martin Jansa]

[-- Attachment #1: Type: text/plain, Size: 825 bytes --]

Doesn't python3-core in RDEPENDS:${PN} resolve that?

On Tue, Jan 31, 2023 at 7:46 PM Markus Volk <f_l_k@t-online.de> wrote:

> Am Di, 31. Jan 2023 um 09:56:29 -0800 schrieb Khem Raj <raj.khem@gmail.com
> >:
>
> maybe change this to #!/usr/bin/env python3
>
>
> But that would be about 50 files in which the shebang would have to be
> changed. They are all '#!/usr/bin/python3'.
>
> -=-=-=-=-=-=-=-=-=-=-=-
> Links: You receive all messages sent to this group.
> View/Reply Online (#100884):
> https://lists.openembedded.org/g/openembedded-devel/message/100884
> Mute This Topic: https://lists.openembedded.org/mt/96656636/3617156
> Group Owner: openembedded-devel+owner@lists.openembedded.org
> Unsubscribe: https://lists.openembedded.org/g/openembedded-devel/unsub [
> Martin.Jansa@gmail.com]
> -=-=-=-=-=-=-=-=-=-=-=-
>
>

[-- Attachment #2: Type: text/html, Size: 1818 bytes --]

Re: [oe] [meta-oe][PATCH 2/3] system-config-printer: add recipe

[Markus Volk]

[-- Attachment #1: Type: text/plain, Size: 160 bytes --]

Am Di, 31. Jan 2023 um 19:53:45 +0100 schrieb Martin Jansa 
<Martin.Jansa@gmail.com>:
> Doesn't python3-core in RDEPENDS:${PN} resolve that?

nice, it does :)


[-- Attachment #2: Type: text/html, Size: 263 bytes --]