[PATCH 0/5] Enable VPN support in ConnMan

[PATCH 0/5] Enable VPN support in ConnMan

[Jukka Rissanen]

Hi,

this patchset enables OpenVPN, vpnc, L2TP and PPTP VPN
technogies in ConnMan and fixes this bug
https://bugzilla.yoctoproject.org/show_bug.cgi?id=4456

The VPN support is activated if DISTRO_FEATURES contains
vpn string.

Cheers,
Jukka


Jukka Rissanen (5):
  connman: Enable VPN support
  connman: Add OpenVPN support
  connman: Add vpnc support
  connman: Add L2TP support
  connman: Add PPTP support

 meta/recipes-connectivity/connman/connman.inc | 42 +++++++++++++++++++++++++--
 1 file changed, 40 insertions(+), 2 deletions(-)

-- 
1.7.11.7

[PATCH 1/5] connman: Enable VPN support

[Jukka Rissanen]

If DISTRO_FEATURES contains vpn, then enable vpn support in ConnMan.

Signed-off-by: Jukka Rissanen <jukka.rissanen@linux.intel.com>
---
 meta/recipes-connectivity/connman/connman.inc | 27 +++++++++++++++++++++++++--
 1 file changed, 25 insertions(+), 2 deletions(-)

diff --git a/meta/recipes-connectivity/connman/connman.inc b/meta/recipes-connectivity/connman/connman.inc
index afc361c..3f01803 100644
--- a/meta/recipes-connectivity/connman/connman.inc
+++ b/meta/recipes-connectivity/connman/connman.inc
@@ -49,6 +49,8 @@ INITSCRIPT_PARAMS = "start 05 5 2 3 . stop 22 0 1 6 ."
 SYSTEMD_SERVICE_${PN} = "connman.service"
 SYSTEMD_WIRED_SETUP = "ExecStartPre=-/usr/lib/connman/wired-setup"
 
+SYSTEMD_SERVICE_${PN} += " ${@base_contains('DISTRO_FEATURES', 'vpn', 'connman-vpn.service', '', d)}"
+
 # IMPORTANT: because xuser is shared with rootless X, please make sure the
 # USERADD_PARAM is in sync with the one in xserver-nodm-init.bb
 USERADD_PACKAGES = "${PN}"
@@ -67,6 +69,10 @@ do_configure_append () {
 # both this and the xuser patch can be dropped.
 do_compile_append() {
 	sed -i -e s:deny:allow:g src/connman-dbus.conf
+
+	if ${@base_contains('DISTRO_FEATURES','vpn','true','false',d)}; then
+		sed -i -e s:deny:allow:g vpn/vpn-dbus.conf
+	fi
 }
 
 do_install_append() {
@@ -80,12 +86,17 @@ do_install_append() {
 	install -m 0755 ${S}/tools/wispr ${D}${bindir}
 	install -m 0755 ${B}/client/connmanctl ${D}${bindir}
 
-	# We don't need to package an empty directory
-	rmdir ${D}${libdir}/connman/scripts
+	# We don't need to package an empty directory if vpn is not in use
+	if ${@base_contains('DISTRO_FEATURES','vpn','false','true',d)}; then
+		rmdir ${D}${libdir}/connman/scripts
+	fi
 
 	# Automake 1.12 won't install empty directories, but we need the
 	# plugins directory to be present for ownership
 	mkdir -p ${D}${libdir}/connman/plugins
+	if ${@base_contains('DISTRO_FEATURES','vpn','true','false',d)}; then
+		mkdir -p ${D}${libdir}/connman/plugins-vpn
+	fi
 }
 
 # These used to be plugins, but now they are core
@@ -120,6 +131,17 @@ python populate_packages_prepend() {
             rdepends = map(lambda x: multilib_prefix + x,  depmap[plugintype].split())
             bb.note( "Adding rdependency on %s to %s" % ( rdepends, package ) )
             d.setVar("RDEPENDS_%s" % package, " ".join(rdepends))
+
+    packages = []
+    plugin_dir = d.expand('${libdir}/connman/plugins-vpn/')
+    plugin_name = d.expand('${PN}-plugin-vpn-%s')
+    do_split_packages(d, plugin_dir, '^(.*).so$', plugin_name, '${PN} VPN plugin for %s', extra_depends='', hook=hook, prepend=True )
+    for (file, package) in packages:
+        plugintype = package.split( '-' )[-1]
+        if plugintype in depmap:
+            rdepends = map(lambda x: multilib_prefix + x,  depmap[plugintype].split())
+            bb.note( "Adding rdependency on %s to %s" % ( rdepends, package ) )
+            d.setVar("RDEPENDS_%s" % package, " ".join(rdepends))
 }
 
 PACKAGES =+ "${PN}-tools ${PN}-tests ${PN}-client"
@@ -133,6 +155,7 @@ FILES_${PN}-client = "${bindir}/connmanctl"
 
 FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*.so.* \
             ${libdir}/connman/plugins \
+            ${libdir}/connman/plugins-vpn \
             ${sysconfdir} ${sharedstatedir} ${localstatedir} \
             ${base_bindir}/* ${base_sbindir}/* ${base_libdir}/*.so* ${datadir}/${PN} \
             ${datadir}/dbus-1/system-services/*"
-- 
1.7.11.7

[PATCH 2/5] connman: Add OpenVPN support

[Jukka Rissanen]

Signed-off-by: Jukka Rissanen <jukka.rissanen@linux.intel.com>
---
 meta/recipes-connectivity/connman/connman.inc | 4 ++++
 1 file changed, 4 insertions(+)

diff --git a/meta/recipes-connectivity/connman/connman.inc b/meta/recipes-connectivity/connman/connman.inc
index 3f01803..e8e41ed 100644
--- a/meta/recipes-connectivity/connman/connman.inc
+++ b/meta/recipes-connectivity/connman/connman.inc
@@ -36,12 +36,14 @@ PACKAGECONFIG ??= "\
                    ${@base_contains('DISTRO_FEATURES', 'wifi','wifi', '', d)} \
                    ${@base_contains('DISTRO_FEATURES', 'bluetooth','bluetooth', '', d)} \
                    ${@base_contains('DISTRO_FEATURES', '3g','3g', '', d)} \
+                   ${@base_contains('DISTRO_FEATURES', 'vpn','openvpn', '', d)} \
 "
 
 PACKAGECONFIG[wifi] = "--enable-wifi, --disable-wifi, wpa-supplicant"
 PACKAGECONFIG[bluetooth] = "--enable-bluetooth, --disable-bluetooth, bluez4"
 PACKAGECONFIG[3g] = "--enable-ofono, --disable-ofono, ofono"
 PACKAGECONFIG[tist] = "--enable-tist,--disable-tist,"
+PACKAGECONFIG[openvpn] = "--enable-openvpn,--disable-openvpn, openvpn"
 
 INITSCRIPT_NAME = "connman"
 INITSCRIPT_PARAMS = "start 05 5 2 3 . stop 22 0 1 6 ."
@@ -163,3 +165,5 @@ FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*.so.* \
 FILES_${PN}-dbg += "${libdir}/connman/*/.debug"
 
 FILES_${PN}-dev += "${libdir}/connman/*/*.la"
+
+FILES_${PN}-plugin-vpn-openvpn += "${libdir}/connman/scripts/openvpn-script"
-- 
1.7.11.7

[PATCH 3/5] connman: Add vpnc support

[Jukka Rissanen]

Signed-off-by: Jukka Rissanen <jukka.rissanen@linux.intel.com>
---
 meta/recipes-connectivity/connman/connman.inc | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/meta/recipes-connectivity/connman/connman.inc b/meta/recipes-connectivity/connman/connman.inc
index e8e41ed..4917f94 100644
--- a/meta/recipes-connectivity/connman/connman.inc
+++ b/meta/recipes-connectivity/connman/connman.inc
@@ -37,6 +37,7 @@ PACKAGECONFIG ??= "\
                    ${@base_contains('DISTRO_FEATURES', 'bluetooth','bluetooth', '', d)} \
                    ${@base_contains('DISTRO_FEATURES', '3g','3g', '', d)} \
                    ${@base_contains('DISTRO_FEATURES', 'vpn','openvpn', '', d)} \
+                   ${@base_contains('DISTRO_FEATURES', 'vpn','vpnc', '', d)} \
 "
 
 PACKAGECONFIG[wifi] = "--enable-wifi, --disable-wifi, wpa-supplicant"
@@ -44,6 +45,7 @@ PACKAGECONFIG[bluetooth] = "--enable-bluetooth, --disable-bluetooth, bluez4"
 PACKAGECONFIG[3g] = "--enable-ofono, --disable-ofono, ofono"
 PACKAGECONFIG[tist] = "--enable-tist,--disable-tist,"
 PACKAGECONFIG[openvpn] = "--enable-openvpn,--disable-openvpn, openvpn"
+PACKAGECONFIG[vpnc] = "--enable-vpnc,--disable-vpnc, vpnc"
 
 INITSCRIPT_NAME = "connman"
 INITSCRIPT_PARAMS = "start 05 5 2 3 . stop 22 0 1 6 ."
@@ -167,3 +169,4 @@ FILES_${PN}-dbg += "${libdir}/connman/*/.debug"
 FILES_${PN}-dev += "${libdir}/connman/*/*.la"
 
 FILES_${PN}-plugin-vpn-openvpn += "${libdir}/connman/scripts/openvpn-script"
+FILES_${PN}-plugin-vpn-vpnc += "${libdir}/connman/scripts/openconnect-script"
-- 
1.7.11.7

[PATCH 4/5] connman: Add L2TP support

[Jukka Rissanen]

Signed-off-by: Jukka Rissanen <jukka.rissanen@linux.intel.com>
---
 meta/recipes-connectivity/connman/connman.inc | 4 ++++
 1 file changed, 4 insertions(+)

diff --git a/meta/recipes-connectivity/connman/connman.inc b/meta/recipes-connectivity/connman/connman.inc
index 4917f94..43b363b 100644
--- a/meta/recipes-connectivity/connman/connman.inc
+++ b/meta/recipes-connectivity/connman/connman.inc
@@ -38,6 +38,7 @@ PACKAGECONFIG ??= "\
                    ${@base_contains('DISTRO_FEATURES', '3g','3g', '', d)} \
                    ${@base_contains('DISTRO_FEATURES', 'vpn','openvpn', '', d)} \
                    ${@base_contains('DISTRO_FEATURES', 'vpn','vpnc', '', d)} \
+                   ${@base_contains('DISTRO_FEATURES', 'vpn','l2tp', '', d)} \
 "
 
 PACKAGECONFIG[wifi] = "--enable-wifi, --disable-wifi, wpa-supplicant"
@@ -46,6 +47,7 @@ PACKAGECONFIG[3g] = "--enable-ofono, --disable-ofono, ofono"
 PACKAGECONFIG[tist] = "--enable-tist,--disable-tist,"
 PACKAGECONFIG[openvpn] = "--enable-openvpn,--disable-openvpn, openvpn"
 PACKAGECONFIG[vpnc] = "--enable-vpnc,--disable-vpnc, vpnc"
+PACKAGECONFIG[l2tp] = "--enable-l2tp,--disable-l2tp, xl2tpd"
 
 INITSCRIPT_NAME = "connman"
 INITSCRIPT_PARAMS = "start 05 5 2 3 . stop 22 0 1 6 ."
@@ -170,3 +172,5 @@ FILES_${PN}-dev += "${libdir}/connman/*/*.la"
 
 FILES_${PN}-plugin-vpn-openvpn += "${libdir}/connman/scripts/openvpn-script"
 FILES_${PN}-plugin-vpn-vpnc += "${libdir}/connman/scripts/openconnect-script"
+FILES_${PN}-plugin-vpn-l2tp += "${libdir}/connman/scripts/libppp-plugin.so*"
+INSANE_SKIP_${PN}-plugin-vpn-l2tp += "dev-so"
-- 
1.7.11.7

[PATCH 5/5] connman: Add PPTP support

[Jukka Rissanen]

Signed-off-by: Jukka Rissanen <jukka.rissanen@linux.intel.com>
---
 meta/recipes-connectivity/connman/connman.inc | 4 ++++
 1 file changed, 4 insertions(+)

diff --git a/meta/recipes-connectivity/connman/connman.inc b/meta/recipes-connectivity/connman/connman.inc
index 43b363b..d9ab234 100644
--- a/meta/recipes-connectivity/connman/connman.inc
+++ b/meta/recipes-connectivity/connman/connman.inc
@@ -39,6 +39,7 @@ PACKAGECONFIG ??= "\
                    ${@base_contains('DISTRO_FEATURES', 'vpn','openvpn', '', d)} \
                    ${@base_contains('DISTRO_FEATURES', 'vpn','vpnc', '', d)} \
                    ${@base_contains('DISTRO_FEATURES', 'vpn','l2tp', '', d)} \
+                   ${@base_contains('DISTRO_FEATURES', 'vpn','pptp', '', d)} \
 "
 
 PACKAGECONFIG[wifi] = "--enable-wifi, --disable-wifi, wpa-supplicant"
@@ -48,6 +49,7 @@ PACKAGECONFIG[tist] = "--enable-tist,--disable-tist,"
 PACKAGECONFIG[openvpn] = "--enable-openvpn,--disable-openvpn, openvpn"
 PACKAGECONFIG[vpnc] = "--enable-vpnc,--disable-vpnc, vpnc"
 PACKAGECONFIG[l2tp] = "--enable-l2tp,--disable-l2tp, xl2tpd"
+PACKAGECONFIG[pptp] = "--enable-pptp,--disable-pptp, pptp-linux"
 
 INITSCRIPT_NAME = "connman"
 INITSCRIPT_PARAMS = "start 05 5 2 3 . stop 22 0 1 6 ."
@@ -174,3 +176,5 @@ FILES_${PN}-plugin-vpn-openvpn += "${libdir}/connman/scripts/openvpn-script"
 FILES_${PN}-plugin-vpn-vpnc += "${libdir}/connman/scripts/openconnect-script"
 FILES_${PN}-plugin-vpn-l2tp += "${libdir}/connman/scripts/libppp-plugin.so*"
 INSANE_SKIP_${PN}-plugin-vpn-l2tp += "dev-so"
+FILES_${PN}-plugin-vpn-pptp += "${libdir}/connman/scripts/libppp-plugin.so*"
+INSANE_SKIP_${PN}-plugin-vpn-pptp += "dev-so"
-- 
1.7.11.7

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Burton, Ross]

Hi Jukka,

On 10 May 2013 13:33, Jukka Rissanen <jukka.rissanen@linux.intel.com> wrote:
> this patchset enables OpenVPN, vpnc, L2TP and PPTP VPN
> technogies in ConnMan and fixes this bug
> https://bugzilla.yoctoproject.org/show_bug.cgi?id=4456

I've chatted with Jukka online already, but I'll put this on the list
for clarity.

The VPN plugins are missing runtime-dependencies on the relevant VPN
clients.  As they're split out already the dependency can be
per-plugin.

It's potentially nicer to not have built-time dependencies on the VPN
clients, but just specify the paths to the client binaries directly.

I'm not convinced there's a need for a "vpn" DISTRO_FEATURE as it
seems quite specific to connman.  Adding the packageconfig options but
not using them in the default value should be fine, and then distros
that want to enable the VPN options can do so using, erm
PACKAGECONFIG_pn-connman_append = " openvpn" (something like that,
anyway).

Ross

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Saul Wold]

On 05/10/2013 05:33 AM, Jukka Rissanen wrote:
> Hi,
>
> this patchset enables OpenVPN, vpnc, L2TP and PPTP VPN
> technogies in ConnMan and fixes this bug
> https://bugzilla.yoctoproject.org/show_bug.cgi?id=4456
>
> The VPN support is activated if DISTRO_FEATURES contains
> vpn string.
>

This also create a dependency on the meta-openembedded layer, I am not 
sure we want to do that.

Sau!

> Cheers,
> Jukka
>
>
> Jukka Rissanen (5):
>    connman: Enable VPN support
>    connman: Add OpenVPN support
>    connman: Add vpnc support
>    connman: Add L2TP support
>    connman: Add PPTP support
>
>   meta/recipes-connectivity/connman/connman.inc | 42 +++++++++++++++++++++++++--
>   1 file changed, 40 insertions(+), 2 deletions(-)
>

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Philip Balister]

On 05/10/2013 06:22 PM, Saul Wold wrote:
> On 05/10/2013 05:33 AM, Jukka Rissanen wrote:
>> Hi,
>>
>> this patchset enables OpenVPN, vpnc, L2TP and PPTP VPN
>> technogies in ConnMan and fixes this bug
>> https://bugzilla.yoctoproject.org/show_bug.cgi?id=4456
>>
>> The VPN support is activated if DISTRO_FEATURES contains
>> vpn string.
>>
> 
> This also create a dependency on the meta-openembedded layer, I am not
> sure we want to do that.

If the default setting does not add the dependency it should be OK? What
packages in meta-oe are needed? Does this suggest they should move to
oe-core?

Philip

> 
> Sau!
> 
>> Cheers,
>> Jukka
>>
>>
>> Jukka Rissanen (5):
>>    connman: Enable VPN support
>>    connman: Add OpenVPN support
>>    connman: Add vpnc support
>>    connman: Add L2TP support
>>    connman: Add PPTP support
>>
>>   meta/recipes-connectivity/connman/connman.inc | 42
>> +++++++++++++++++++++++++--
>>   1 file changed, 40 insertions(+), 2 deletions(-)
>>
> 
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core
> 
> 

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Otavio Salvador]

On Sat, May 11, 2013 at 10:59 AM, Philip Balister <philip@balister.org> wrote:
> On 05/10/2013 06:22 PM, Saul Wold wrote:
>> On 05/10/2013 05:33 AM, Jukka Rissanen wrote:
>>> The VPN support is activated if DISTRO_FEATURES contains
>>> vpn string.
>>>
>>
>> This also create a dependency on the meta-openembedded layer, I am not
>> sure we want to do that.
>
> If the default setting does not add the dependency it should be OK? What
> packages in meta-oe are needed? Does this suggest they should move to
> oe-core?

I think so, it'd be good to have it in oe-core and allow use of vpn :)

--
Otavio Salvador                             O.S. Systems
E-mail: otavio@ossystems.com.br  http://www.ossystems.com.br
Mobile: +55 53 9981-7854              http://projetos.ossystems.com.br

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Saul Wold]

On 05/12/2013 06:27 AM, Otavio Salvador wrote:
> On Sat, May 11, 2013 at 10:59 AM, Philip Balister <philip@balister.org> wrote:
>> On 05/10/2013 06:22 PM, Saul Wold wrote:
>>> On 05/10/2013 05:33 AM, Jukka Rissanen wrote:
>>>> The VPN support is activated if DISTRO_FEATURES contains
>>>> vpn string.
>>>>
>>>
>>> This also create a dependency on the meta-openembedded layer, I am not
>>> sure we want to do that.
>>
>> If the default setting does not add the dependency it should be OK? What
>> packages in meta-oe are needed? Does this suggest they should move to
>> oe-core?
>
> I think so, it'd be good to have it in oe-core and allow use of vpn :)
>
I would like to see what the full dependency set looks like for these, 
clearly there is the vpnc, openvpn, l2tp and pptp recipes, but what else 
and what licenses are they under.

Sau!

> --
> Otavio Salvador                             O.S. Systems
> E-mail: otavio@ossystems.com.br  http://www.ossystems.com.br
> Mobile: +55 53 9981-7854              http://projetos.ossystems.com.br
>
>

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Khem Raj]

On May 12, 2013, at 8:40 AM, Saul Wold <sgw@linux.intel.com> wrote:

> On 05/12/2013 06:27 AM, Otavio Salvador wrote:
>> On Sat, May 11, 2013 at 10:59 AM, Philip Balister <philip@balister.org> wrote:
>>> On 05/10/2013 06:22 PM, Saul Wold wrote:
>>>> On 05/10/2013 05:33 AM, Jukka Rissanen wrote:
>>>>> The VPN support is activated if DISTRO_FEATURES contains
>>>>> vpn string.
>>>>> 
>>>> 
>>>> This also create a dependency on the meta-openembedded layer, I am not
>>>> sure we want to do that.
>>> 
>>> If the default setting does not add the dependency it should be OK? What
>>> packages in meta-oe are needed? Does this suggest they should move to
>>> oe-core?
>> 
>> I think so, it'd be good to have it in oe-core and allow use of vpn :)
>> 


why not in meta-networking ? these seems apt for that layer. You do not need VPN packages to test oe-core functionality 
OE core should get thinner not thicker.

> I would like to see what the full dependency set looks like for these, clearly there is the vpnc, openvpn, l2tp and pptp recipes, but what else and what licenses are they under.
> 
> Sau!
> 
>> --
>> Otavio Salvador                             O.S. Systems
>> E-mail: otavio@ossystems.com.br  http://www.ossystems.com.br
>> Mobile: +55 53 9981-7854              http://projetos.ossystems.com.br
>> 
>> 
> 
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Phil Blundell]

On Sun, 2013-05-12 at 08:40 -0700, Saul Wold wrote:
> On 05/12/2013 06:27 AM, Otavio Salvador wrote:
> > On Sat, May 11, 2013 at 10:59 AM, Philip Balister <philip@balister.org> wrote:
> >> On 05/10/2013 06:22 PM, Saul Wold wrote:
> >>> On 05/10/2013 05:33 AM, Jukka Rissanen wrote:
> >>>> The VPN support is activated if DISTRO_FEATURES contains
> >>>> vpn string.
> >>>>
> >>>
> >>> This also create a dependency on the meta-openembedded layer, I am not
> >>> sure we want to do that.
> >>
> >> If the default setting does not add the dependency it should be OK? What
> >> packages in meta-oe are needed? Does this suggest they should move to
> >> oe-core?
> >
> > I think so, it'd be good to have it in oe-core and allow use of vpn :)
> >
> I would like to see what the full dependency set looks like for these, 
> clearly there is the vpnc, openvpn, l2tp and pptp recipes, but what else 
> and what licenses are they under.

I don't think we necessarily want openvpn, l2tpd and suchlike in
oe-core.  None of those things seem very "core" to me (in an embedded
context) and testing them seems like it would be a bit of a challenge.

Equally, we certainly don't want to have dependencies in oe-core
pointing to packages in meta-oe or any other layer, since this would
make it impossible to test oe-core in isolation.  So I would be inclined
to say that the right way to deal with this is for those connman bits to
go in a .bbappend which lives in the same layer as the recipes in
question.

p.

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Paul Eggleton]

On Sunday 12 May 2013 19:54:50 Phil Blundell wrote:
> On Sun, 2013-05-12 at 08:40 -0700, Saul Wold wrote:
> > On 05/12/2013 06:27 AM, Otavio Salvador wrote:
> > > I think so, it'd be good to have it in oe-core and allow use of vpn :)
> > 
> > I would like to see what the full dependency set looks like for these,
> > clearly there is the vpnc, openvpn, l2tp and pptp recipes, but what else
> > and what licenses are they under.
> 
> I don't think we necessarily want openvpn, l2tpd and suchlike in
> oe-core.  None of those things seem very "core" to me (in an embedded
> context) and testing them seems like it would be a bit of a challenge.

I agree, these don't belong in OE-Core. We already have them in meta-
networking.

> Equally, we certainly don't want to have dependencies in oe-core
> pointing to packages in meta-oe or any other layer, since this would
> make it impossible to test oe-core in isolation.  So I would be inclined
> to say that the right way to deal with this is for those connman bits to
> go in a .bbappend which lives in the same layer as the recipes in
> question.

That doesn't work well for software layers - it is not a good thing for 
various recipes to get rebuilt just because you add meta-oe to your 
configuration for example.

The protocol we've established is to add PACKAGECONFIG options to enable the 
dependencies but have them disabled by default; these can be enabled as 
desired in distro or local configuration when the layer satisfying the 
dependency is also enabled.

Cheers,
Paul

-- 

Paul Eggleton
Intel Open Source Technology Centre

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Saul Wold]

On 05/12/2013 10:55 PM, Paul Eggleton wrote:
> On Sunday 12 May 2013 19:54:50 Phil Blundell wrote:
>> On Sun, 2013-05-12 at 08:40 -0700, Saul Wold wrote:
>>> On 05/12/2013 06:27 AM, Otavio Salvador wrote:
>>>> I think so, it'd be good to have it in oe-core and allow use of vpn :)
>>>
>>> I would like to see what the full dependency set looks like for these,
>>> clearly there is the vpnc, openvpn, l2tp and pptp recipes, but what else
>>> and what licenses are they under.
>>
>> I don't think we necessarily want openvpn, l2tpd and suchlike in
>> oe-core.  None of those things seem very "core" to me (in an embedded
>> context) and testing them seems like it would be a bit of a challenge.
>
> I agree, these don't belong in OE-Core. We already have them in meta-
> networking.
>
This is what I get for replying to an email while traveling overseas and 
not being 100% clear about my points.

I was more interested in the dependencies then actually thinking about 
including them in OE-Core,that was not my intent.

This would would allow us to better understand if those recipes not in 
meta-networking could be moved from meta-oe to meta-networking. 
Currently, I think vpnc and pptp are in meta-networking, not the other 2.

>> Equally, we certainly don't want to have dependencies in oe-core
>> pointing to packages in meta-oe or any other layer, since this would
>> make it impossible to test oe-core in isolation.  So I would be inclined
>> to say that the right way to deal with this is for those connman bits to
>> go in a .bbappend which lives in the same layer as the recipes in
>> question.
>
> That doesn't work well for software layers - it is not a good thing for
> various recipes to get rebuilt just because you add meta-oe to your
> configuration for example.
>
> The protocol we've established is to add PACKAGECONFIG options to enable the
> dependencies but have them disabled by default; these can be enabled as
> desired in distro or local configuration when the layer satisfying the
> dependency is also enabled.
>
This is correct and I talked with RP about this to verify, having these 
kind of dependencies use PACKAGECONFIG and being disabled by default in 
OE-Core make sense and is vaild recipe, a Distro or local configuration 
can then enable and require the additional layers whether it's meta-oe 
or meta-networking as needed.

Sau!

> Cheers,
> Paul
>

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Paul Eggleton]

On Monday 13 May 2013 11:00:56 Saul Wold wrote:
> On 05/12/2013 10:55 PM, Paul Eggleton wrote:
> > On Sunday 12 May 2013 19:54:50 Phil Blundell wrote:
> >> On Sun, 2013-05-12 at 08:40 -0700, Saul Wold wrote:
> >>> On 05/12/2013 06:27 AM, Otavio Salvador wrote:
> >>>> I think so, it'd be good to have it in oe-core and allow use of vpn :)
> >>> 
> >>> I would like to see what the full dependency set looks like for these,
> >>> clearly there is the vpnc, openvpn, l2tp and pptp recipes, but what else
> >>> and what licenses are they under.
> >> 
> >> I don't think we necessarily want openvpn, l2tpd and suchlike in
> >> oe-core.  None of those things seem very "core" to me (in an embedded
> >> context) and testing them seems like it would be a bit of a challenge.
> > 
> > I agree, these don't belong in OE-Core. We already have them in meta-
> > networking.
> 
> This is what I get for replying to an email while traveling overseas and
> not being 100% clear about my points.
> 
> I was more interested in the dependencies then actually thinking about
> including them in OE-Core,that was not my intent.
> 
> This would would allow us to better understand if those recipes not in
> meta-networking could be moved from meta-oe to meta-networking.
> Currently, I think vpnc and pptp are in meta-networking, not the other 2.

They are all in meta-networking (xl2tpd, pptp-linux and vpnc have always been 
there, openvpn got moved in mid-April).

Cheers,
Paul

-- 

Paul Eggleton
Intel Open Source Technology Centre

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Saul Wold]

On 05/13/2013 11:33 AM, Paul Eggleton wrote:
> On Monday 13 May 2013 11:00:56 Saul Wold wrote:
>> On 05/12/2013 10:55 PM, Paul Eggleton wrote:
>>> On Sunday 12 May 2013 19:54:50 Phil Blundell wrote:
>>>> On Sun, 2013-05-12 at 08:40 -0700, Saul Wold wrote:
>>>>> On 05/12/2013 06:27 AM, Otavio Salvador wrote:
>>>>>> I think so, it'd be good to have it in oe-core and allow use of vpn :)
>>>>>
>>>>> I would like to see what the full dependency set looks like for these,
>>>>> clearly there is the vpnc, openvpn, l2tp and pptp recipes, but what else
>>>>> and what licenses are they under.
>>>>
>>>> I don't think we necessarily want openvpn, l2tpd and suchlike in
>>>> oe-core.  None of those things seem very "core" to me (in an embedded
>>>> context) and testing them seems like it would be a bit of a challenge.
>>>
>>> I agree, these don't belong in OE-Core. We already have them in meta-
>>> networking.
>>
>> This is what I get for replying to an email while traveling overseas and
>> not being 100% clear about my points.
>>
>> I was more interested in the dependencies then actually thinking about
>> including them in OE-Core,that was not my intent.
>>
>> This would would allow us to better understand if those recipes not in
>> meta-networking could be moved from meta-oe to meta-networking.
>> Currently, I think vpnc and pptp are in meta-networking, not the other 2.
>
> They are all in meta-networking (xl2tpd, pptp-linux and vpnc have always been
> there, openvpn got moved in mid-April).
>
I guess I did not have the latest meta-oe, I was looking in the wrong 
place again!  Looks like this can work out.

Sau!

> Cheers,
> Paul
>

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Phil Blundell]

On Sun, 2013-05-12 at 20:55 +0100, Paul Eggleton wrote:
> That doesn't work well for software layers - it is not a good thing for 
> various recipes to get rebuilt just because you add meta-oe to your 
> configuration for example.
> 
> The protocol we've established is to add PACKAGECONFIG options to enable the 
> dependencies but have them disabled by default; these can be enabled as 
> desired in distro or local configuration when the layer satisfying the 
> dependency is also enabled.

That doesn't seem totally ideal either, since it means that oe-core ends
up containing a bunch of "joke" PACKAGECONFIG options that will break
your build if you enable them (unless you add some other layer at the
same time).  Personally I would have thought that unnecessary rebuilds
of the handful of packages that this would affect were probably the
lesser of the two evils, though obviously it's not my choice to make.

p.

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Burton, Ross]

On 13 May 2013 12:02, Phil Blundell <pb@pbcl.net> wrote:
> That doesn't seem totally ideal either, since it means that oe-core ends
> up containing a bunch of "joke" PACKAGECONFIG options that will break
> your build if you enable them (unless you add some other layer at the
> same time).  Personally I would have thought that unnecessary rebuilds
> of the handful of packages that this would affect were probably the
> lesser of the two evils, though obviously it's not my choice to make.

The problem with bbappends is that they break every time the package
in oe-core changes version.  Swings and roundabouts really, though I
prefer PACKAGECONFIG statements in oe-core that can be optionally
enabled with linkage to other layers.

Ross

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Phil Blundell]

On Mon, 2013-05-13 at 12:06 +0100, Burton, Ross wrote:
> The problem with bbappends is that they break every time the package
> in oe-core changes version.  

True, that is a nuisance.  Of course, now that (in most cases) we keep
only one version of any given recipe in oe-core, there is no
particularly compelling reason to go on encoding PV into all the
filenames.  Perhaps we should consider not doing that unless there are
special circumstances, which would certainly make life easier for folks
with .bbappends.

> I prefer PACKAGECONFIG statements in oe-core that can be optionally
> enabled with linkage to other layers.

Okay, fair enough then.

p.

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Tomas Frydrych]

On 13/05/13 12:06, Burton, Ross wrote:
> The problem with bbappends is that they break every time the package
> in oe-core changes version.

I see this as a good thing; if I maintain a bbappend, I want to know
when the base package changes its a version, and I get an immediate
error due to bbappend to a non-existent file.

Tomas

-- 
http://sleepfive.com

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Burton, Ross]

On 13 May 2013 12:32, Tomas Frydrych <tf+lists.yocto@r-finger.com> wrote:
> On 13/05/13 12:06, Burton, Ross wrote:
>> The problem with bbappends is that they break every time the package
>> in oe-core changes version.
>
> I see this as a good thing; if I maintain a bbappend, I want to know
> when the base package changes its a version, and I get an immediate
> error due to bbappend to a non-existent file.

The counter-argument is that meta-fsl-arm and meta-fsm-ppc for example
have a number of .bbappends, and it seems to be a regular occurrence
for the autobuilder to break because oe-core upgraded but the BSP
didn't follow in sync.

Allowing non-versioned appends would mean the developer can pick what
their preference is, which seems like a good idea.

Ross

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Phil Blundell]

On Mon, 2013-05-13 at 12:32 +0100, Tomas Frydrych wrote:
> On 13/05/13 12:06, Burton, Ross wrote:
> > The problem with bbappends is that they break every time the package
> > in oe-core changes version.
> 
> I see this as a good thing; if I maintain a bbappend, I want to know
> when the base package changes its a version, and I get an immediate
> error due to bbappend to a non-existent file.

Personally, for the .bbappends that I maintain, I would much rather not
have to go around renaming a bunch of files every time I merge a new
version of oe-core and all the recipes get upgraded. 

But, if you enjoy the errors, you could easily enough get them back even
if the filenames didn't change:

python() {
    tolerable_pvs = [ '1.0', '1.1', '1.2' ]
    pv = d.getVar('PV', True)
    if not pv in tolerable_pvs:
        bb.fatal("encountered intolerable version %s of underlying recipe, please adjust me accordingly" % pv)
}

or something.  One could wrap that in some extra sugar and put it in
base.bbclass if having the boilerplate in each .bbappend is unappealing.

p.

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Tomas Frydrych]

On 13/05/13 15:53, Phil Blundell wrote:
> On Mon, 2013-05-13 at 12:32 +0100, Tomas Frydrych wrote:
>> On 13/05/13 12:06, Burton, Ross wrote:
>>> The problem with bbappends is that they break every time the package
>>> in oe-core changes version.
>>
>> I see this as a good thing; if I maintain a bbappend, I want to know
>> when the base package changes its a version, and I get an immediate
>> error due to bbappend to a non-existent file.
> 
> Personally, for the .bbappends that I maintain, I would much rather not
> have to go around renaming a bunch of files every time I merge a new
> version of oe-core and all the recipes get upgraded. 
> 
> But, if you enjoy the errors, you could easily enough get them back even
> if the filenames didn't change:
> 
> python() {
>     tolerable_pvs = [ '1.0', '1.1', '1.2' ]
>     pv = d.getVar('PV', True)
>     if not pv in tolerable_pvs:
>         bb.fatal("encountered intolerable version %s of underlying recipe, please adjust me accordingly" % pv)
> }
> 
> or something.  One could wrap that in some extra sugar and put it in
> base.bbclass if having the boilerplate in each .bbappend is unappealing.

I do like this approach; I'd probably wrap it in a class and let the
bbappend maintainer to decide if their bbappend deserves this or not.


Tomas

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Richard Purdie]

On Tue, 2013-05-14 at 10:22 +0100, Tomas Frydrych wrote:
> On 13/05/13 15:53, Phil Blundell wrote:
> > On Mon, 2013-05-13 at 12:32 +0100, Tomas Frydrych wrote:
> >> On 13/05/13 12:06, Burton, Ross wrote:
> >>> The problem with bbappends is that they break every time the package
> >>> in oe-core changes version.
> >>
> >> I see this as a good thing; if I maintain a bbappend, I want to know
> >> when the base package changes its a version, and I get an immediate
> >> error due to bbappend to a non-existent file.
> > 
> > Personally, for the .bbappends that I maintain, I would much rather not
> > have to go around renaming a bunch of files every time I merge a new
> > version of oe-core and all the recipes get upgraded. 
> > 
> > But, if you enjoy the errors, you could easily enough get them back even
> > if the filenames didn't change:
> > 
> > python() {
> >     tolerable_pvs = [ '1.0', '1.1', '1.2' ]
> >     pv = d.getVar('PV', True)
> >     if not pv in tolerable_pvs:
> >         bb.fatal("encountered intolerable version %s of underlying recipe, please adjust me accordingly" % pv)
> > }
> > 
> > or something.  One could wrap that in some extra sugar and put it in
> > base.bbclass if having the boilerplate in each .bbappend is unappealing.
> 
> I do like this approach; I'd probably wrap it in a class and let the
> bbappend maintainer to decide if their bbappend deserves this or not.

I'd take a patch adding this form of function to the core. I'd also take
a patch to have bitbake do some primitive wildcard (% along the lines of
PREFERRED_VERSION?) type match on the bbappend filenames. It will add in
a few new interesting corner cases such as one bbappend matching
multiple recipes. We have to keep in mind bitbake has no knowledge of
the filename format, that is metadata defined.

Cheers,

Richard

Re: [PATCH 0/5] Enable VPN support in ConnMan

[Phil Blundell]

On Tue, 2013-05-14 at 13:18 +0300, Richard Purdie wrote:
> I'd also take
> a patch to have bitbake do some primitive wildcard (% along the lines of
> PREFERRED_VERSION?) type match on the bbappend filenames.

I do still think that, as far as oe-core goes at least, simply
discontinuing the practice of putting PV in the filenames would be an
easier and better plan.  This would: not require any bitbake changes,
avoid the need for a .inc in most cases, discourage the common mistake
of adding a new version and forgetting to remove the old one, and make
it easier to follow the git history because there wouldn't be renames
all over the place.  

But it appears that I am in a minority of one in favouring this plan and
I guess wildcarded .bbappends are the next best thing.  Your proposal
above sounds like a reasonable enough idea; having % in .bbappend
filenames will look a bit weird but there doesn't seem to be any obvious
reason why it wouldn't work.

p.

libsoup missing DEPENDS

[Mike Looijmans]

I got the following build error once, on an attempt to fix it (and 
create a patch for OE-core) from the devshell, the problem magically 
disappeared:


| 
/home/mike/zynq/build/tmp-eglibc/work/armv7a-vfp-neon-oe-linux-gnueabi/libsoup-2.4/2.42.1-r0/temp/run.do_configure.26683: 
line 175: intltoolize: command not found
| ERROR: Function failed: do_configure (see 
/home/mike/zynq/build/tmp-eglibc/work/armv7a-vfp-neon-oe-linux-gnueabi/libsoup-2.4/2.42.1-r0/temp/log.do_configure.26683 
for further information)
ERROR: Task 420 
(/home/mike/zynq/oe-core/meta/recipes-support/libsoup/libsoup-2.4_2.42.1.bb, 
do_configure) failed with exit code '1'


I suspect libsoup-2.4_2.42.1.bb is lacking a dependency, I don't know 
what provides the "intltoolize" program though.

Mike.

Re: libsoup missing DEPENDS

[Burton, Ross]

On 14 May 2013 13:30, Mike Looijmans <mike.looijmans@topic.nl> wrote:
> I suspect libsoup-2.4_2.42.1.bb is lacking a dependency, I don't know what
> provides the "intltoolize" program though.

Yes, and it's "intltool".

Ross