[meta-oe][PATCH 1/2] meson: Add recipe for the meson build system

[meta-oe][PATCH 1/2] meson: Add recipe for the meson build system

[linus.svensson]

From: Linus Svensson <linussn@axis.com>

Meson is a build system designed to be fast and as user firendly as
possible. Find out more about meson at mesonbuild.com.

This patch is based on a prototype patch by
Ross Burton <ross.burton@intel.com>.

Signed-off-by: Linus Svensson <linussn@axis.com>
---
 meta-oe/recipes-devtools/meson/meson_0.36.0.bb | 15 +++++++++++++++
 1 file changed, 15 insertions(+)
 create mode 100644 meta-oe/recipes-devtools/meson/meson_0.36.0.bb

diff --git a/meta-oe/recipes-devtools/meson/meson_0.36.0.bb b/meta-oe/recipes-devtools/meson/meson_0.36.0.bb
new file mode 100644
index 0000000..1ec7e3e
--- /dev/null
+++ b/meta-oe/recipes-devtools/meson/meson_0.36.0.bb
@@ -0,0 +1,15 @@
+HOMEPAGE = "http://mesonbuild.com"
+SUMMARY = "A high performance build system"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://COPYING;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+SRC_URI = "https://github.com/mesonbuild/meson/releases/download/${PV}/${BP}.tar.gz"
+SRC_URI[md5sum] = "dfdd190c5f10a67bb40e6cf93944dd43"
+SRC_URI[sha256sum] = "dc087ec40dacb5e256e6ee6467f2d004faf4ef284d3c1ce5e89faa1e16540950"
+
+inherit setuptools3
+
+RDEPENDS_${PN} = "ninja python3-core python3-modules"
+
+BBCLASSEXTEND = "native"
-- 
2.1.4

[meta-oe][PATCH 2/2] meson.bbclass: Add meson.bbclass

[linus.svensson]

From: Linus Svensson <linussn@axis.com>

Add a class for packages that uses the meson build system.

Meson uses a cross-file that contain needed tools and information about
the host and target system. Such a file will be created in {WORKDIR}.

Meson only allows installation directories to be specified as relative
to prefix, except for sysconfdir, which can be absolute.

This patch is based on a prototype patch by
Ross Burton <ross.burton@intel.com>.

Signed-off-by: Linus Svensson <linussn@axis.com>
---
 meta-oe/classes/meson.bbclass | 86 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 86 insertions(+)
 create mode 100644 meta-oe/classes/meson.bbclass

diff --git a/meta-oe/classes/meson.bbclass b/meta-oe/classes/meson.bbclass
new file mode 100644
index 0000000..5a04134
--- /dev/null
+++ b/meta-oe/classes/meson.bbclass
@@ -0,0 +1,86 @@
+inherit python3native
+
+DEPENDS_append = " meson-native ninja-native"
+
+# As Meson enforces out-of-tree builds we can just use cleandirs
+B = "${WORKDIR}/build"
+do_configure[cleandirs] = "${B}"
+
+# Where the meson.build build configuration is
+MESON_SOURCEPATH = "${S}"
+
+# These variables in the environment override the *native* tools not the cross,
+# so they need to be unexported.
+CC[unexport] = "1"
+
+def noprefix(var, d):
+    return d.getVar(var, True).replace(d.getVar('prefix', True) + '/', '', 1)
+
+MESONOPTS = " --prefix ${prefix} \
+              --bindir ${@noprefix('bindir', d)} \
+              --datadir ${@noprefix('datadir', d)} \
+              --libdir ${@noprefix('libdir', d)} \
+              --libexecdir ${@noprefix('libexecdir', d)} \
+              --includedir ${@noprefix('includedir', d)} \
+              --mandir ${@noprefix('mandir', d)} \
+              --localedir ${@noprefix('localedir', d)} \
+              --sysconfdir ${sysconfdir}"
+
+MESON_C_ARGS = "${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
+
+MESON_HOST_ENDIAN = "${@bb.utils.contains('SITEINFO_ENDIANNESS', 'be', 'big', 'little', d)}"
+MESON_TARGET_ENDIAN = "${@bb.utils.contains('TUNE_FEATURES', 'bigendian', 'big', 'little', d)}"
+
+EXTRA_OEMESON += "${PACKAGECONFIG_CONFARGS}"
+
+def meson_array(var, d):
+    return "', '".join(d.getVar(var, True).split()).join(("'", "'"))
+
+addtask write_config before do_configure
+do_write_config[vardeps] += "MESON_C_ARGS TOOLCHAIN_OPTIONS"
+do_write_config() {
+    # This needs to be Py to split the args into single-element lists
+    cat >${WORKDIR}/meson.cross <<EOF
+[binaries]
+c = '${HOST_PREFIX}gcc'
+cpp = '${HOST_PREFIX}gcc'
+ar = '${HOST_PREFIX}ar'
+ld = '${HOST_PREFIX}ld'
+strip = '${HOST_PREFIX}strip'
+readelf = '${HOST_PREFIX}readelf'
+pkgconfig = 'pkg-config'
+
+[properties]
+c_args = [${@meson_array('MESON_C_ARGS', d)}]
+c_link_args = [${@meson_array('TOOLCHAIN_OPTIONS', d)}]
+
+[host_machine]
+system = '${HOST_OS}'
+cpu_family = '${HOST_ARCH}'
+cpu = '${HOST_ARCH}'
+endian = '${MESON_HOST_ENDIAN}'
+
+[target_machine]
+system = '${TARGET_OS}'
+cpu_family = '${TARGET_ARCH}'
+cpu = '${TARGET_ARCH}'
+endian = '${MESON_TARGET_ENDIAN}'
+EOF
+}
+
+meson_do_configure() {
+    if ! meson ${MESONOPTS} "${MESON_SOURCEPATH}" "${B}" --cross-file ${WORKDIR}/meson.cross ${EXTRA_OEMESON}; then
+        cat ${B}/meson-logs/meson-log.txt
+        bbfatal_log meson failed
+    fi
+}
+
+meson_do_compile() {
+    ninja ${PARALLEL_MAKE}
+}
+
+meson_do_install() {
+    DESTDIR='${D}' ninja ${PARALLEL_MAKEINST} install
+}
+
+EXPORT_FUNCTIONS do_configure do_compile do_install
-- 
2.1.4

Re: [meta-oe][PATCH 1/2] meson: Add recipe for the meson build system

[Martin Jansa]

> SRC_URI = "https://github.com/mesonbuild/meson/releases/
download/${PV}/${BP}.tar.gz"

I'm still not persuaded that the github tarballs aren't regenerated from
time to time.

Can you please use git fetcher instead of tarball?

On Wed, Feb 15, 2017 at 2:41 PM, <linus.svensson@axis.com> wrote:

> From: Linus Svensson <linussn@axis.com>
>
> Meson is a build system designed to be fast and as user firendly as
> possible. Find out more about meson at mesonbuild.com.
>
> This patch is based on a prototype patch by
> Ross Burton <ross.burton@intel.com>.
>
> Signed-off-by: Linus Svensson <linussn@axis.com>
> ---
>  meta-oe/recipes-devtools/meson/meson_0.36.0.bb | 15 +++++++++++++++
>  1 file changed, 15 insertions(+)
>  create mode 100644 meta-oe/recipes-devtools/meson/meson_0.36.0.bb
>
> diff --git a/meta-oe/recipes-devtools/meson/meson_0.36.0.bb
> b/meta-oe/recipes-devtools/meson/meson_0.36.0.bb
> new file mode 100644
> index 0000000..1ec7e3e
> --- /dev/null
> +++ b/meta-oe/recipes-devtools/meson/meson_0.36.0.bb
> @@ -0,0 +1,15 @@
> +HOMEPAGE = "http://mesonbuild.com"
> +SUMMARY = "A high performance build system"
> +
> +LICENSE = "Apache-2.0"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=3b83ef96387f14655fc854ddc3c6bd57"
> +
> +SRC_URI = "https://github.com/mesonbuild/meson/releases/
> download/${PV}/${BP}.tar.gz"
> +SRC_URI[md5sum] = "dfdd190c5f10a67bb40e6cf93944dd43"
> +SRC_URI[sha256sum] = "dc087ec40dacb5e256e6ee6467f2d0
> 04faf4ef284d3c1ce5e89faa1e16540950"
> +
> +inherit setuptools3
> +
> +RDEPENDS_${PN} = "ninja python3-core python3-modules"
> +
> +BBCLASSEXTEND = "native"
> --
> 2.1.4
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel
>

Re: [meta-oe][PATCH 1/2] meson: Add recipe for the meson build system

[Burton, Ross]

On 15 February 2017 at 13:43, Martin Jansa <martin.jansa@gmail.com> wrote:

> > SRC_URI = "https://github.com/mesonbuild/meson/releases/
> download/${PV}/${BP}.tar.gz"
>
> I'm still not persuaded that the github tarballs aren't regenerated from
> time to time.
>

Upstream also uploads pregenerated tarballs:

https://github.com/mesonbuild/meson/releases/download/0.38.1/meson-0.38.1.tar.gz

That would be preferable IMHO.

Ross

[meta-oe][PATCH 1/2] meson: Add recipe for the meson build system

[linus.svensson]

From: Linus Svensson <linussn@axis.com>

Meson is a build system designed to be fast and as user firendly as
possible. Find out more about meson at mesonbuild.com.

This patch is based on a prototype patch by
Ross Burton <ross.burton@intel.com>.

Signed-off-by: Linus Svensson <linussn@axis.com>
---
 meta/recipes-devtools/meson/meson_0.36.0.bb | 15 +++++++++++++++
 1 file changed, 15 insertions(+)
 create mode 100644 meta/recipes-devtools/meson/meson_0.36.0.bb

diff --git a/meta/recipes-devtools/meson/meson_0.36.0.bb b/meta/recipes-devtools/meson/meson_0.36.0.bb
new file mode 100644
index 0000000..1ec7e3e
--- /dev/null
+++ b/meta/recipes-devtools/meson/meson_0.36.0.bb
@@ -0,0 +1,15 @@
+HOMEPAGE = "http://mesonbuild.com"
+SUMMARY = "A high performance build system"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://COPYING;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+SRC_URI = "https://github.com/mesonbuild/meson/releases/download/${PV}/${BP}.tar.gz"
+SRC_URI[md5sum] = "dfdd190c5f10a67bb40e6cf93944dd43"
+SRC_URI[sha256sum] = "dc087ec40dacb5e256e6ee6467f2d004faf4ef284d3c1ce5e89faa1e16540950"
+
+inherit setuptools3
+
+RDEPENDS_${PN} = "ninja python3-core python3-modules"
+
+BBCLASSEXTEND = "native"
-- 
2.1.4