[meta-oe][PATCH v2 1/3] libev: Add recipe for version 4.24

[meta-oe][PATCH v2 1/3] libev: Add recipe for version 4.24

[Fabio Berton]

Signed-off-by: Fabio Berton <fabio.berton@ossystems.com.br>
---
 meta-oe/recipes-connectivity/libev/libev_4.24.bb | 16 ++++++++++++++++
 1 file changed, 16 insertions(+)
 create mode 100644 meta-oe/recipes-connectivity/libev/libev_4.24.bb

diff --git a/meta-oe/recipes-connectivity/libev/libev_4.24.bb b/meta-oe/recipes-connectivity/libev/libev_4.24.bb
new file mode 100644
index 000000000..f236eacab
--- /dev/null
+++ b/meta-oe/recipes-connectivity/libev/libev_4.24.bb
@@ -0,0 +1,16 @@
+SUMMARY = "A full-featured and high-performance event loop that is loosely \
+modelled after libevent."
+HOMEPAGE = "http://software.schmorp.de/pkg/libev.html"
+LICENSE = "BSD-2-Clause | GPL-2.0+"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=d6ad416afd040c90698edcdf1cbee347"
+
+SRC_URI = "http://dist.schmorp.de/libev/Attic/${BP}.tar.gz"
+
+SRC_URI[md5sum] = "94459a5a22db041dec6f98424d6efe54"
+SRC_URI[sha256sum] = "973593d3479abdf657674a55afe5f78624b0e440614e2b8cb3a07f16d4d7f821"
+
+S = "${WORKDIR}/${PN}-${PV}"
+
+inherit autotools
+
+EXTRA_OECONF += "--with-pic"
-- 
2.11.0

[meta-oe][PATCH v2 2/3] libuv: Add recipe for version 1.10.2

[Fabio Berton]

Signed-off-by: Fabio Berton <fabio.berton@ossystems.com.br>
---
 meta-oe/recipes-connectivity/libuv/libuv_1.10.2.bb | 19 +++++++++++++++++++
 1 file changed, 19 insertions(+)
 create mode 100644 meta-oe/recipes-connectivity/libuv/libuv_1.10.2.bb

diff --git a/meta-oe/recipes-connectivity/libuv/libuv_1.10.2.bb b/meta-oe/recipes-connectivity/libuv/libuv_1.10.2.bb
new file mode 100644
index 000000000..fbdbeaa89
--- /dev/null
+++ b/meta-oe/recipes-connectivity/libuv/libuv_1.10.2.bb
@@ -0,0 +1,19 @@
+SUMMARY = "A multi-platform support library with a focus on asynchronous I/O"
+HOMEPAGE = "https://github.com/libuv/libuv"
+BUGTRACKER = "https://github.com/libuv/libuv/issues"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=bb5ea0d651f4c3519327171906045775"
+
+SRC_URI = "https://github.com/libuv/${PN}/archive/v${PV}.tar.gz"
+
+SRC_URI[md5sum] = "6e16d1d1ca464add0730d637effb1c1c"
+SRC_URI[sha256sum] = "2d740a2adea0f1a19058626f55a076ac41a4ac1f95d4e57cae0c8a634a6cd63b"
+
+S = "${WORKDIR}/${PN}-${PV}"
+
+inherit autotools
+
+do_configure() {
+    ${S}/autogen.sh || bbnote "${PN} failed to autogen.sh"
+    oe_runconf
+}
-- 
2.11.0

[meta-oe][PATCH v2 3/3] libwebsockets: Add recipe for version 2.1.0

[Fabio Berton]

Signed-off-by: Fabio Berton <fabio.berton@ossystems.com.br>
---
 .../libwebsockets/libwebsockets_2.1.0.bb           | 32 ++++++++++++++++++++++
 1 file changed, 32 insertions(+)
 create mode 100644 meta-oe/recipes-connectivity/libwebsockets/libwebsockets_2.1.0.bb

diff --git a/meta-oe/recipes-connectivity/libwebsockets/libwebsockets_2.1.0.bb b/meta-oe/recipes-connectivity/libwebsockets/libwebsockets_2.1.0.bb
new file mode 100644
index 000000000..316b38d3b
--- /dev/null
+++ b/meta-oe/recipes-connectivity/libwebsockets/libwebsockets_2.1.0.bb
@@ -0,0 +1,32 @@
+SUMMARY = "Canonical libwebsockets.org websocket library"
+HOMEPAGE = "https://libwebsockets.org/"
+LICENSE = "LGPL-2.1"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6"
+
+DEPENDS = "zlib"
+
+SRC_URI = "https://github.com/warmcat/libwebsockets/archive/v${PV}.tar.gz"
+
+SRC_URI[md5sum] = "4df3be57dee43aeebd54a3ed56568f50"
+SRC_URI[sha256sum] = "bcc96aaa609daae4d3f7ab1ee480126709ef4f6a8bf9c85de40aae48e38cce66"
+
+S = "${WORKDIR}/${PN}-${PV}"
+
+inherit cmake pkgconfig
+
+PACKAGECONFIG ?= "libuv client server http2 ssl"
+PACKAGECONFIG[libev] = "-DLWS_WITH_LIBEV=ON,-DLWS_WITH_LIBEV=OFF,libev"
+PACKAGECONFIG[libuv] = "-DLWS_WITH_LIBUV=ON,-DLWS_WITH_LIBUV=OFF,libuv"
+PACKAGECONFIG[client] = "-DLWS_WITHOUT_CLIENT=OFF,-DLWS_WITHOUT_CLIENT=ON,"
+PACKAGECONFIG[server] = "-DLWS_WITHOUT_SERVER=OFF,-DLWS_WITHOUT_SERVER=ON,"
+PACKAGECONFIG[http2] = "-DLWS_WITH_HTTP2=ON,-DLWS_WITH_HTTP2=OFF,"
+PACKAGECONFIG[ipv6] = "-DLWS_IPV6=ON,-DLWS_IPV6=OFF,"
+PACKAGECONFIG[ssl] = "-DLWS_WITH_SSL=ON,-DLWS_WITH_SSL=OFF,openssl"
+PACKAGECONFIG[testapps] = "-DLWS_WITHOUT_TESTAPPS=OFF,-DLWS_WITHOUT_TESTAPPS=ON,"
+
+PACKAGES =+ "${PN}-testapps"
+
+FILES_${PN}-dev += "${libdir}/cmake/libwebsockets/*.cmake"
+FILES_${PN}-testapps += "${datadir}/libwebsockets-test-server/*"
+
+RDEPENDS_${PN} += "zlib"
-- 
2.11.0

Re: [meta-oe][PATCH v2 1/3] libev: Add recipe for version 4.24

[Khem Raj]

On Wed, Feb 8, 2017 at 10:13 AM, Fabio Berton
<fabio.berton@ossystems.com.br> wrote:
> Signed-off-by: Fabio Berton <fabio.berton@ossystems.com.br>
> ---
>  meta-oe/recipes-connectivity/libev/libev_4.24.bb | 16 ++++++++++++++++
>  1 file changed, 16 insertions(+)
>  create mode 100644 meta-oe/recipes-connectivity/libev/libev_4.24.bb
>
> diff --git a/meta-oe/recipes-connectivity/libev/libev_4.24.bb b/meta-oe/recipes-connectivity/libev/libev_4.24.bb
> new file mode 100644
> index 000000000..f236eacab
> --- /dev/null
> +++ b/meta-oe/recipes-connectivity/libev/libev_4.24.bb
> @@ -0,0 +1,16 @@
> +SUMMARY = "A full-featured and high-performance event loop that is loosely \
> +modelled after libevent."
> +HOMEPAGE = "http://software.schmorp.de/pkg/libev.html"
> +LICENSE = "BSD-2-Clause | GPL-2.0+"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=d6ad416afd040c90698edcdf1cbee347"
> +
> +SRC_URI = "http://dist.schmorp.de/libev/Attic/${BP}.tar.gz"
> +
> +SRC_URI[md5sum] = "94459a5a22db041dec6f98424d6efe54"
> +SRC_URI[sha256sum] = "973593d3479abdf657674a55afe5f78624b0e440614e2b8cb3a07f16d4d7f821"
> +
> +S = "${WORKDIR}/${PN}-${PV}"
> +
> +inherit autotools
> +
> +EXTRA_OECONF += "--with-pic"

this looks good. I also have an after thought where libevent will
conflict with libev when it comes to who provides event.h file. So we
need to note that conflict down as well. May be a follow up. It wont
show up as much when we have rss now however SDKs and dev images will
show this up where we will unify the rootfs.

Re: [meta-oe][PATCH v2 3/3] libwebsockets: Add recipe for version 2.1.0

[Andre McCurdy]

On Wed, Feb 8, 2017 at 10:13 AM, Fabio Berton
<fabio.berton@ossystems.com.br> wrote:
> Signed-off-by: Fabio Berton <fabio.berton@ossystems.com.br>
> ---
>  .../libwebsockets/libwebsockets_2.1.0.bb           | 32 ++++++++++++++++++++++
>  1 file changed, 32 insertions(+)
>  create mode 100644 meta-oe/recipes-connectivity/libwebsockets/libwebsockets_2.1.0.bb
>
> diff --git a/meta-oe/recipes-connectivity/libwebsockets/libwebsockets_2.1.0.bb b/meta-oe/recipes-connectivity/libwebsockets/libwebsockets_2.1.0.bb
> new file mode 100644
> index 000000000..316b38d3b
> --- /dev/null
> +++ b/meta-oe/recipes-connectivity/libwebsockets/libwebsockets_2.1.0.bb
> @@ -0,0 +1,32 @@
> +SUMMARY = "Canonical libwebsockets.org websocket library"
> +HOMEPAGE = "https://libwebsockets.org/"
> +LICENSE = "LGPL-2.1"
> +LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6"

GPL-2.0 looks wrong given that LICENSE is LGPL and not GPL?

Define LIC_FILES_CHKSUM in terms of a file from within the
libwebsockets source tree instead.

> +
> +DEPENDS = "zlib"
> +
> +SRC_URI = "https://github.com/warmcat/libwebsockets/archive/v${PV}.tar.gz"
> +
> +SRC_URI[md5sum] = "4df3be57dee43aeebd54a3ed56568f50"
> +SRC_URI[sha256sum] = "bcc96aaa609daae4d3f7ab1ee480126709ef4f6a8bf9c85de40aae48e38cce66"
> +
> +S = "${WORKDIR}/${PN}-${PV}"

That's the default, so doesn't need to be specified.

> +inherit cmake pkgconfig
> +
> +PACKAGECONFIG ?= "libuv client server http2 ssl"
> +PACKAGECONFIG[libev] = "-DLWS_WITH_LIBEV=ON,-DLWS_WITH_LIBEV=OFF,libev"
> +PACKAGECONFIG[libuv] = "-DLWS_WITH_LIBUV=ON,-DLWS_WITH_LIBUV=OFF,libuv"
> +PACKAGECONFIG[client] = "-DLWS_WITHOUT_CLIENT=OFF,-DLWS_WITHOUT_CLIENT=ON,"
> +PACKAGECONFIG[server] = "-DLWS_WITHOUT_SERVER=OFF,-DLWS_WITHOUT_SERVER=ON,"
> +PACKAGECONFIG[http2] = "-DLWS_WITH_HTTP2=ON,-DLWS_WITH_HTTP2=OFF,"
> +PACKAGECONFIG[ipv6] = "-DLWS_IPV6=ON,-DLWS_IPV6=OFF,"
> +PACKAGECONFIG[ssl] = "-DLWS_WITH_SSL=ON,-DLWS_WITH_SSL=OFF,openssl"
> +PACKAGECONFIG[testapps] = "-DLWS_WITHOUT_TESTAPPS=OFF,-DLWS_WITHOUT_TESTAPPS=ON,"

Maybe sort this list of PACKAGECONFIG options (unless the current
order has some special significance?).

> +
> +PACKAGES =+ "${PN}-testapps"
> +
> +FILES_${PN}-dev += "${libdir}/cmake/libwebsockets/*.cmake"

The "convention" in various other recipes seems to be simply:

  FILES_${PN}-dev += "${libdir}/cmake"

> +FILES_${PN}-testapps += "${datadir}/libwebsockets-test-server/*"
> +
> +RDEPENDS_${PN} += "zlib"

Explicitly defining a runtime dependency on a library isn't normally
required since it will be detected automatically. If it is required in
this case then please explain why in the commit message.

> 2.11.0
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

Re: [meta-oe][PATCH v2 1/3] libev: Add recipe for version 4.24

[Andre McCurdy]

On Wed, Feb 8, 2017 at 10:53 AM, Khem Raj <raj.khem@gmail.com> wrote:
> On Wed, Feb 8, 2017 at 10:13 AM, Fabio Berton
> <fabio.berton@ossystems.com.br> wrote:
>> Signed-off-by: Fabio Berton <fabio.berton@ossystems.com.br>
>> ---
>>  meta-oe/recipes-connectivity/libev/libev_4.24.bb | 16 ++++++++++++++++
>>  1 file changed, 16 insertions(+)
>>  create mode 100644 meta-oe/recipes-connectivity/libev/libev_4.24.bb
>>
>> diff --git a/meta-oe/recipes-connectivity/libev/libev_4.24.bb b/meta-oe/recipes-connectivity/libev/libev_4.24.bb
>> new file mode 100644
>> index 000000000..f236eacab
>> --- /dev/null
>> +++ b/meta-oe/recipes-connectivity/libev/libev_4.24.bb
>> @@ -0,0 +1,16 @@
>> +SUMMARY = "A full-featured and high-performance event loop that is loosely \
>> +modelled after libevent."
>> +HOMEPAGE = "http://software.schmorp.de/pkg/libev.html"
>> +LICENSE = "BSD-2-Clause | GPL-2.0+"
>> +LIC_FILES_CHKSUM = "file://LICENSE;md5=d6ad416afd040c90698edcdf1cbee347"
>> +
>> +SRC_URI = "http://dist.schmorp.de/libev/Attic/${BP}.tar.gz"
>> +
>> +SRC_URI[md5sum] = "94459a5a22db041dec6f98424d6efe54"
>> +SRC_URI[sha256sum] = "973593d3479abdf657674a55afe5f78624b0e440614e2b8cb3a07f16d4d7f821"
>> +
>> +S = "${WORKDIR}/${PN}-${PV}"
>> +
>> +inherit autotools
>> +
>> +EXTRA_OECONF += "--with-pic"
>
> this looks good. I also have an after thought where libevent will
> conflict with libev when it comes to who provides event.h file.

The libevent header <event.h> is deprecated and everything should be
using <event2/event.h> instead. So the simple fix would be for
libevent to stop installing the legacy header.

> So we
> need to note that conflict down as well. May be a follow up. It wont
> show up as much when we have rss now however SDKs and dev images will
> show this up where we will unify the rootfs.
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

Re: [meta-oe][PATCH v2 3/3] libwebsockets: Add recipe for version 2.1.0

[Fabio Berton]

Hi Andre,

On Wed, Feb 8, 2017 at 6:16 PM, Andre McCurdy <armccurdy@gmail.com> wrote:

> On Wed, Feb 8, 2017 at 10:13 AM, Fabio Berton
> <fabio.berton@ossystems.com.br> wrote:
> > Signed-off-by: Fabio Berton <fabio.berton@ossystems.com.br>
> > ---
> >  .../libwebsockets/libwebsockets_2.1.0.bb           | 32
> ++++++++++++++++++++++
> >  1 file changed, 32 insertions(+)
> >  create mode 100644 meta-oe/recipes-connectivity/libwebsockets/
> libwebsockets_2.1.0.bb
> >
> > diff --git a/meta-oe/recipes-connectivity/libwebsockets/lib
> websockets_2.1.0.bb b/meta-oe/recipes-connectivity/libwebsockets/lib
> websockets_2.1.0.bb
> > new file mode 100644
> > index 000000000..316b38d3b
> > --- /dev/null
> > +++ b/meta-oe/recipes-connectivity/libwebsockets/libwebsockets_2.1.0.bb
> > @@ -0,0 +1,32 @@
> > +SUMMARY = "Canonical libwebsockets.org websocket library"
> > +HOMEPAGE = "https://libwebsockets.org/"
> > +LICENSE = "LGPL-2.1"
> > +LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/GPL-2.0;md5=
> 801f80980d171dd6425610833a22dbe6"
>
> GPL-2.0 looks wrong given that LICENSE is LGPL and not GPL?
>
> Define LIC_FILES_CHKSUM in terms of a file from within the
> libwebsockets source tree instead.
>
> ​Ok, I missed this part.​


> > +
> > +DEPENDS = "zlib"
> > +
> > +SRC_URI = "https://github.com/warmcat/libwebsockets/archive/v${PV}.
> tar.gz"
> > +
> > +SRC_URI[md5sum] = "4df3be57dee43aeebd54a3ed56568f50"
> > +SRC_URI[sha256sum] = "bcc96aaa609daae4d3f7ab1ee48012
> 6709ef4f6a8bf9c85de40aae48e38cce66"
> > +
> > +S = "${WORKDIR}/${PN}-${PV}"
>
> That's the default, so doesn't need to be specified.
>
> > +inherit cmake pkgconfig
> > +
> > +PACKAGECONFIG ?= "libuv client server http2 ssl"
> > +PACKAGECONFIG[libev] = "-DLWS_WITH_LIBEV=ON,-DLWS_WITH_LIBEV=OFF,libev"
> > +PACKAGECONFIG[libuv] = "-DLWS_WITH_LIBUV=ON,-DLWS_WITH_LIBUV=OFF,libuv"
> > +PACKAGECONFIG[client] = "-DLWS_WITHOUT_CLIENT=OFF,-
> DLWS_WITHOUT_CLIENT=ON,"
> > +PACKAGECONFIG[server] = "-DLWS_WITHOUT_SERVER=OFF,-
> DLWS_WITHOUT_SERVER=ON,"
> > +PACKAGECONFIG[http2] = "-DLWS_WITH_HTTP2=ON,-DLWS_WITH_HTTP2=OFF,"
> > +PACKAGECONFIG[ipv6] = "-DLWS_IPV6=ON,-DLWS_IPV6=OFF,"
> > +PACKAGECONFIG[ssl] = "-DLWS_WITH_SSL=ON,-DLWS_WITH_SSL=OFF,openssl"
> > +PACKAGECONFIG[testapps] = "-DLWS_WITHOUT_TESTAPPS=OFF,-
> DLWS_WITHOUT_TESTAPPS=ON,"
>
> Maybe sort this list of PACKAGECONFIG options (unless the current
> order has some special significance?).
>
> > +
> > +PACKAGES =+ "${PN}-testapps"
> > +
> > +FILES_${PN}-dev += "${libdir}/cmake/libwebsockets/*.cmake"
>
> The "convention" in various other recipes seems to be simply:
>
>   FILES_${PN}-dev += "${libdir}/cmake"
>
> > +FILES_${PN}-testapps += "${datadir}/libwebsockets-test-server/*"
> > +
> > +RDEPENDS_${PN} += "zlib"
>
> Explicitly defining a runtime dependency on a library isn't normally
> required since it will be detected automatically. If it is required in
> this case then please explain why in the commit message.
>
> ​You rigth, I don't need to explicitly define ​

​RDEPENDS​.

> > 2.11.0
> >
> > --
> > _______________________________________________
> > Openembedded-devel mailing list
> > Openembedded-devel@lists.openembedded.org
> > http://lists.openembedded.org/mailman/listinfo/openembedded-devel
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel
>