[WIP][PATCH 00/20] Deterministic dependencies II

[WIP][PATCH 00/20] Deterministic dependencies II

[Martin Jansa]

WIP because verification build is still running and I must admit that I'm mostly
testing that all dependencies are correctly "disabled" and in the end deterministic.

I'm not testing if every possible combination of PACKAGECONFIG options provide sufficient
dependency tree.

But it would be nice to get some review in advance and be able to get this
in 1.5 if I manage to fix all possible review comments and/or issues discovered
in my builds in time.

The following changes since commit 7d93288117e7054472d8a01dde0b38bc0ff98c27:

  buildtools-tarball: Add python-pkgutil (2013-08-29 00:22:49 +0100)

are available in the git repository at:

  git://git.openembedded.org/openembedded-core-contrib jansa/deps
  http://cgit.openembedded.org/cgit.cgi/openembedded-core-contrib/log/?h=jansa/deps

Martin Jansa (20):
  gstreamer1.0-libav: Add PACKAGECONFIG for orc
  libunique: Add PACKAGECONFIG for dbus
  aspell: Add PACKAGECONFIG for curses
  xf86-input-synaptics: Add dependency on libxtst
  xdypinfo: Add dependency on libxcomposite
  libmatchbox: Add PACKAGECONFIG for png
  matchbox-wm: Add dependency on libxfixes and libxcursor
  telepathy-mission-control: Add PACKAGECONFIG for upower and
    connectivity
  tcl: Add dependency on zlib
  weston: Add PACKAGECONFIG for poppler
  wget: Add dependency on libpcre
  x11vnc: Add PACKAGECONFIG for xfixes, xinerama, xrandr and xdamage
  guile: Add PACKAGECONFIG for readline
  consolekit: Add patch to explicitly disable polkit when not enabled
  glib-networking: Add PACKAGECONFIG for p11-kit
  lame: Add dependency on ncurses
  librsvg: Fix dependencies for PACKAGECONFIG gdkpixbuf
  subversion: Add dependency on file for libmagic
  systemd: Add PACKAGECONFIG for cryptsetup
  qemu: Add PACKAGECONFIG for nss, uuid, tls and curses

 .../telepathy/telepathy-mission-control_5.15.0.bb  |  8 ++++
 .../glib-networking/glib-networking_2.36.2.bb      |  3 ++
 meta/recipes-core/systemd/systemd_206.bb           |  1 +
 meta/recipes-devtools/guile/guile_2.0.9.bb         |  3 ++
 meta/recipes-devtools/qemu/qemu.inc                |  4 ++
 .../subversion/subversion_1.7.10.bb                |  2 +-
 meta/recipes-devtools/tcltk/tcl_8.6.0.bb           |  2 +-
 meta/recipes-extended/wget/wget.inc                |  2 +-
 meta/recipes-gnome/librsvg/librsvg_2.32.1.bb       |  2 +-
 meta/recipes-gnome/libunique/libunique_1.1.6.bb    |  5 ++-
 .../libmatchbox/libmatchbox_1.11.bb                |  3 ++
 .../matchbox-wm/matchbox-wm_1.2.bb                 |  2 +-
 .../matchbox-wm/matchbox-wm_git.bb                 |  2 +-
 .../0001-configure-Allow-to-disable-poppler.patch  | 43 ++++++++++++++++++++++
 meta/recipes-graphics/wayland/weston_1.1.0.bb      |  2 +
 meta/recipes-graphics/x11vnc/x11vnc_0.9.13.bb      |  6 +++
 meta/recipes-graphics/xorg-app/xdpyinfo_1.3.1.bb   |  2 +-
 .../xorg-driver/xf86-input-synaptics_1.7.1.bb      |  2 +-
 .../xorg-driver/xf86-input-synaptics_git.bb        |  2 +-
 .../gstreamer/gstreamer1.0-libav.inc               |  1 +
 meta/recipes-multimedia/lame/lame_3.99.5.bb        |  2 +
 meta/recipes-support/aspell/aspell_0.60.6.1.bb     | 12 ++++--
 .../allow.to.disable.polkit.support.patch          | 33 +++++++++++++++++
 .../recipes-support/consolekit/consolekit_0.4.6.bb |  4 +-
 24 files changed, 132 insertions(+), 16 deletions(-)
 create mode 100644 meta/recipes-graphics/wayland/weston/0001-configure-Allow-to-disable-poppler.patch
 create mode 100644 meta/recipes-support/consolekit/consolekit/allow.to.disable.polkit.support.patch

-- 
1.8.3.2

[WIP][PATCH 01/20] gstreamer1.0-libav: Add PACKAGECONFIG for orc

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-multimedia/gstreamer/gstreamer1.0-libav.inc | 1 +
 1 file changed, 1 insertion(+)

diff --git a/meta/recipes-multimedia/gstreamer/gstreamer1.0-libav.inc b/meta/recipes-multimedia/gstreamer/gstreamer1.0-libav.inc
index c77a085..3d996bc 100644
--- a/meta/recipes-multimedia/gstreamer/gstreamer1.0-libav.inc
+++ b/meta/recipes-multimedia/gstreamer/gstreamer1.0-libav.inc
@@ -17,6 +17,7 @@ PACKAGECONFIG ??= " "
 PACKAGECONFIG[libav] = "--with-system-libav,,libav"
 PACKAGECONFIG[lgpl]  = "--enable-lgpl,,"
 PACKAGECONFIG[yasm]  = "--enable-yasm,--disable-yasm,yasm-native"
+PACKAGECONFIG[orc]  = "--enable-orc,--disable-orc,orc"
 
 
 GSTREAMER_1_0_DEBUG ?= "--disable-debug"
-- 
1.8.3.2

[WIP][PATCH 02/20] libunique: Add PACKAGECONFIG for dbus

[Martin Jansa]

* dbus-glib was missing in DEPENDS in order to enable dbus backend
  but because dbus was in DEPENDS lets enable this PACKAGECONFIG by
  default

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-gnome/libunique/libunique_1.1.6.bb | 5 ++++-
 1 file changed, 4 insertions(+), 1 deletion(-)

diff --git a/meta/recipes-gnome/libunique/libunique_1.1.6.bb b/meta/recipes-gnome/libunique/libunique_1.1.6.bb
index adb9525..31af658 100644
--- a/meta/recipes-gnome/libunique/libunique_1.1.6.bb
+++ b/meta/recipes-gnome/libunique/libunique_1.1.6.bb
@@ -12,7 +12,10 @@ SRC_URI[sha256sum] = "e5c8041cef8e33c55732f06a292381cb345db946cf792a4ae18aa5c66c
 
 PR = "r7"
 
-DEPENDS = "glib-2.0 gtk+ dbus"
+DEPENDS = "glib-2.0 gtk+"
+
+PACKAGECONFIG ??= "dbus"
+PACKAGECONFIG[dbus] = "--enable-dbus,--disable-dbus,dbus dbus-glib"
 
 LICENSE = "LGPLv2.1"
 LIC_FILES_CHKSUM = "file://COPYING;md5=2d5025d4aa3495befef8f17206a5b0a1"
-- 
1.8.3.2

[WIP][PATCH 03/20] aspell: Add PACKAGECONFIG for curses

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-support/aspell/aspell_0.60.6.1.bb | 12 ++++++++----
 1 file changed, 8 insertions(+), 4 deletions(-)

diff --git a/meta/recipes-support/aspell/aspell_0.60.6.1.bb b/meta/recipes-support/aspell/aspell_0.60.6.1.bb
index 64611cb..b196d96 100644
--- a/meta/recipes-support/aspell/aspell_0.60.6.1.bb
+++ b/meta/recipes-support/aspell/aspell_0.60.6.1.bb
@@ -1,12 +1,16 @@
-SRC_URI = "${GNU_MIRROR}/aspell/aspell-${PV}.tar.gz"
-
-SRC_URI[md5sum] = "e66a9c9af6a60dc46134fdacf6ce97d7"
-SRC_URI[sha256sum] = "f52583a83a63633701c5f71db3dc40aab87b7f76b29723aeb27941eff42df6e1"
 DESCRIPTION = "GNU Aspell spell-checker"
 SECTION = "console/utils"
 LICENSE="LGPLv2 | LGPLv2.1"
 LIC_FILES_CHKSUM = "file://COPYING;md5=7fbc338309ac38fefcd64b04bb903e34"
 PR = "r1"
+
+SRC_URI = "${GNU_MIRROR}/aspell/aspell-${PV}.tar.gz"
+SRC_URI[md5sum] = "e66a9c9af6a60dc46134fdacf6ce97d7"
+SRC_URI[sha256sum] = "f52583a83a63633701c5f71db3dc40aab87b7f76b29723aeb27941eff42df6e1"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[curses] = "--enable-curses,--disable-curses,ncurses"
+
 PACKAGES += "libaspell libpspell libpspell-dev aspell-utils"
 
 FILES_${PN}-dbg += "${libdir}/aspell-0.60/.debu*"
-- 
1.8.3.2

[WIP][PATCH 04/20] xf86-input-synaptics: Add dependency on libxtst

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-graphics/xorg-driver/xf86-input-synaptics_1.7.1.bb | 2 +-
 meta/recipes-graphics/xorg-driver/xf86-input-synaptics_git.bb   | 2 +-
 2 files changed, 2 insertions(+), 2 deletions(-)

diff --git a/meta/recipes-graphics/xorg-driver/xf86-input-synaptics_1.7.1.bb b/meta/recipes-graphics/xorg-driver/xf86-input-synaptics_1.7.1.bb
index 9125613..f678e8b 100644
--- a/meta/recipes-graphics/xorg-driver/xf86-input-synaptics_1.7.1.bb
+++ b/meta/recipes-graphics/xorg-driver/xf86-input-synaptics_1.7.1.bb
@@ -15,6 +15,6 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=55aacd3535a741824955c5eb8f061398"
 SRC_URI[md5sum] = "6505de717972b6a24b8eb13e69eb996c"
 SRC_URI[sha256sum] = "db5825660e1fb23190697f609bf75d4450fe707344a14298e1c9b47039bbb58e"
 
-DEPENDS += "libxi mtdev"
+DEPENDS += "libxi mtdev libxtst"
 
 FILES_${PN} += "${datadir}/X11/xorg.conf.d"
diff --git a/meta/recipes-graphics/xorg-driver/xf86-input-synaptics_git.bb b/meta/recipes-graphics/xorg-driver/xf86-input-synaptics_git.bb
index 73b8089..30c142c 100644
--- a/meta/recipes-graphics/xorg-driver/xf86-input-synaptics_git.bb
+++ b/meta/recipes-graphics/xorg-driver/xf86-input-synaptics_git.bb
@@ -15,4 +15,4 @@ PR = "${INC_PR}.1"
 SRC_URI = "git://anongit.freedesktop.org/git/xorg/driver/xf86-input-synaptics;protocol=git"
 S = "${WORKDIR}/git"
 
-DEPENDS += "libxi mtdev"
+DEPENDS += "libxi mtdev libxtst"
-- 
1.8.3.2

[WIP][PATCH 05/20] xdypinfo: Add dependency on libxcomposite

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-graphics/xorg-app/xdpyinfo_1.3.1.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta/recipes-graphics/xorg-app/xdpyinfo_1.3.1.bb b/meta/recipes-graphics/xorg-app/xdpyinfo_1.3.1.bb
index c853926..3688e1b 100644
--- a/meta/recipes-graphics/xorg-app/xdpyinfo_1.3.1.bb
+++ b/meta/recipes-graphics/xorg-app/xdpyinfo_1.3.1.bb
@@ -9,7 +9,7 @@ clients and the server, and the different types of screens and visuals \
 that are available."
 
 LIC_FILES_CHKSUM = "file://COPYING;md5=f3d09e6b9e203a1af489e16c708f4fb3"
-DEPENDS += "libxtst libxext libxxf86vm libxxf86dga libxxf86misc libxi libxrender libxinerama libdmx libxau"
+DEPENDS += "libxtst libxext libxxf86vm libxxf86dga libxxf86misc libxi libxrender libxinerama libdmx libxau libxcomposite"
 PE = "1"
 
 SRC_URI += "file://disable-xkb.patch"
-- 
1.8.3.2

Re: [WIP][PATCH 05/20] xdypinfo: Add dependency on libxcomposite

[Burton, Ross]

Typo (transposition in recipe name) in short log.

Ross

Re: [WIP][PATCH 05/20] xdypinfo: Add dependency on libxcomposite

[Martin Jansa]

[-- Attachment #1: Type: text/plain, Size: 232 bytes --]

On Mon, Sep 02, 2013 at 06:11:24PM +0100, Burton, Ross wrote:
> Typo (transposition in recipe name) in short log.

Thanks, fixed in jansa/deps branch.

> 
> Ross

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]

[WIP][PATCH 06/20] libmatchbox: Add PACKAGECONFIG for png

[Martin Jansa]

* enable it by default, because it's more likely that people were
  building libmatchbox after libpng than before
* with png disabled it also fails, because of missing csetjmp include
  | mbpixbuf.c:128:3: error: unknown type name 'jmp_buf'
  |    jmp_buf setjmp_buffer; /* for return to caller */

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-graphics/libmatchbox/libmatchbox_1.11.bb | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/meta/recipes-graphics/libmatchbox/libmatchbox_1.11.bb b/meta/recipes-graphics/libmatchbox/libmatchbox_1.11.bb
index 244a495..932e484 100644
--- a/meta/recipes-graphics/libmatchbox/libmatchbox_1.11.bb
+++ b/meta/recipes-graphics/libmatchbox/libmatchbox_1.11.bb
@@ -16,4 +16,7 @@ SRC_URI[sha256sum] = "254cab52e304a3512c8df4be59d690cf3921bbb68a28ede7fe26b93534
 
 inherit autotools pkgconfig
 
+PACKAGECONFIG ??= "png"
+PACKAGECONFIG[png] = "--enable-png,--disable-png,libpng"
+
 EXTRA_OECONF = "--enable-jpeg --enable-expat --enable-xsettings --enable-startup-notification"
-- 
1.8.3.2

Re: [WIP][PATCH 06/20] libmatchbox: Add PACKAGECONFIG for png

[Burton, Ross]

On 29 August 2013 17:02, Martin Jansa <martin.jansa@gmail.com> wrote:
> * with png disabled it also fails, because of missing csetjmp include
>   | mbpixbuf.c:128:3: error: unknown type name 'jmp_buf'
>   |    jmp_buf setjmp_buffer; /* for return to caller */

FWIW, I've just fixed this in libmatchbox.

Ross

Re: [WIP][PATCH 06/20] libmatchbox: Add PACKAGECONFIG for png

[Burton, Ross]

On 29 August 2013 17:02, Martin Jansa <martin.jansa@gmail.com> wrote:
> +PACKAGECONFIG ??= "png"

For completeness consider adding "jpeg", although I doubt anyone
actually uses the JPEG support...

Ross

Re: [WIP][PATCH 06/20] libmatchbox: Add PACKAGECONFIG for png

[Martin Jansa]

[-- Attachment #1: Type: text/plain, Size: 382 bytes --]

On Mon, Sep 02, 2013 at 03:02:39PM +0100, Burton, Ross wrote:
> On 29 August 2013 17:02, Martin Jansa <martin.jansa@gmail.com> wrote:
> > +PACKAGECONFIG ??= "png"
> 
> For completeness consider adding "jpeg", although I doubt anyone
> actually uses the JPEG support...

jpeg is already in DEPENDS

> 
> Ross

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]

Re: [WIP][PATCH 06/20] libmatchbox: Add PACKAGECONFIG for png

[Burton, Ross]

On 3 September 2013 19:29, Martin Jansa <martin.jansa@gmail.com> wrote:
> On Mon, Sep 02, 2013 at 03:02:39PM +0100, Burton, Ross wrote:
>> On 29 August 2013 17:02, Martin Jansa <martin.jansa@gmail.com> wrote:
>> > +PACKAGECONFIG ??= "png"
>>
>> For completeness consider adding "jpeg", although I doubt anyone
>> actually uses the JPEG support...
>
> jpeg is already in DEPENDS

I meant as a PACKAGECONFIG option as it's an optional dependency (and
to be honest, jpeg could probably default to disabled).

Ross

[WIP][PATCH 07/20] matchbox-wm: Add dependency on libxfixes and libxcursor

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-graphics/matchbox-wm/matchbox-wm_1.2.bb | 2 +-
 meta/recipes-graphics/matchbox-wm/matchbox-wm_git.bb | 2 +-
 2 files changed, 2 insertions(+), 2 deletions(-)

diff --git a/meta/recipes-graphics/matchbox-wm/matchbox-wm_1.2.bb b/meta/recipes-graphics/matchbox-wm/matchbox-wm_1.2.bb
index 09e8b7c..b009c4b 100644
--- a/meta/recipes-graphics/matchbox-wm/matchbox-wm_1.2.bb
+++ b/meta/recipes-graphics/matchbox-wm/matchbox-wm_1.2.bb
@@ -1,7 +1,7 @@
 SECTION = "x11/wm"
 DESCRIPTION = "Matchbox window manager"
 LICENSE = "GPLv2.0+"
-DEPENDS = "libmatchbox virtual/libx11 libxext libxcomposite libxfixes xdamage libxrender startup-notification expat"
+DEPENDS = "libmatchbox virtual/libx11 libxext libxcomposite libxfixes libxcursor xdamage libxrender startup-notification expat"
 PR = "r5"
 
 SRC_URI = "http://downloads.yoctoproject.org/releases/matchbox/matchbox-window-manager/${PV}/matchbox-window-manager-${PV}.tar.bz2 \
diff --git a/meta/recipes-graphics/matchbox-wm/matchbox-wm_git.bb b/meta/recipes-graphics/matchbox-wm/matchbox-wm_git.bb
index 015fbc0..e2961b0 100644
--- a/meta/recipes-graphics/matchbox-wm/matchbox-wm_git.bb
+++ b/meta/recipes-graphics/matchbox-wm/matchbox-wm_git.bb
@@ -8,7 +8,7 @@ LIC_FILES_CHKSUM = "file://src/wm.h;endline=21;md5=a7e844465edbcf79c282369f93caa
                     file://src/wm.c;endline=21;md5=8dc9d24477d87ef5dfbc2e4927146aab"
 
 SECTION = "x11/wm"
-DEPENDS = "libmatchbox virtual/libx11 libxext libxrender startup-notification expat gconf"
+DEPENDS = "libmatchbox virtual/libx11 libxext libxrender startup-notification expat gconf libxcursor libxfixes"
 
 SRCREV = "29544f0e61cc281fc60061443a537271e1081b78"
 PV = "1.2+git${SRCPV}"
-- 
1.8.3.2

[WIP][PATCH 08/20] telepathy-mission-control: Add PACKAGECONFIG for upower and connectivity

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 .../telepathy/telepathy-mission-control_5.15.0.bb                 | 8 ++++++++
 1 file changed, 8 insertions(+)

diff --git a/meta/recipes-connectivity/telepathy/telepathy-mission-control_5.15.0.bb b/meta/recipes-connectivity/telepathy/telepathy-mission-control_5.15.0.bb
index b2736ca..ba80cc1 100644
--- a/meta/recipes-connectivity/telepathy/telepathy-mission-control_5.15.0.bb
+++ b/meta/recipes-connectivity/telepathy/telepathy-mission-control_5.15.0.bb
@@ -12,6 +12,14 @@ SRC_URI[sha256sum] = "88800d1b5f385e94b34721319ff4fe65c493632954d7229b36e57af5b4
 
 inherit autotools pkgconfig pythonnative
 
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[upower] = "--enable-upower,--disable-upower,upower"
+
+# to select connman or nm you need to use "connectivity" and "connman" or "nm", default is to disable both
+PACKAGECONFIG[connectvity] = ",--with-connectivity=no"
+PACKAGECONFIG[connman] = "--with-connectivity=connman,,connman"
+PACKAGECONFIG[nm] = "--with-connectivity=nm,,networkmanager"
+
 PACKAGES =+ " \
 	libmissioncontrol \
 	libmissioncontrol-config \
-- 
1.8.3.2

Re: [WIP][PATCH 08/20] telepathy-mission-control: Add PACKAGECONFIG for upower and connectivity

[Burton, Ross]

On 29 August 2013 17:02, Martin Jansa <martin.jansa@gmail.com> wrote:
> +PACKAGECONFIG[connman] = "--with-connectivity=connman,,connman"
> +PACKAGECONFIG[nm] = "--with-connectivity=nm,,networkmanager"

Were those meant to be runtime dependencies?  At least for connman a
build dependency doesn't make any sense (no headers).

Ross

Re: [WIP][PATCH 08/20] telepathy-mission-control: Add PACKAGECONFIG for upower and connectivity

[Martin Jansa]

[-- Attachment #1: Type: text/plain, Size: 748 bytes --]

On Mon, Sep 02, 2013 at 06:10:33PM +0100, Burton, Ross wrote:
> On 29 August 2013 17:02, Martin Jansa <martin.jansa@gmail.com> wrote:
> > +PACKAGECONFIG[connman] = "--with-connectivity=connman,,connman"
> > +PACKAGECONFIG[nm] = "--with-connectivity=nm,,networkmanager"
> 
> Were those meant to be runtime dependencies?  At least for connman a
> build dependency doesn't make any sense (no headers).

It is using pkg-config in build time to enable support for it:
http://cgit.collabora.com/git/user/cassidy/telepathy-mission-control/tree/configure.ac?h=offline-38366#n330

and it has to conditionally link with them (otherwise test-dependencies
script wouldn't detect it).

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]

Re: [WIP][PATCH 08/20] telepathy-mission-control: Add PACKAGECONFIG for upower and connectivity

[Burton, Ross]

On 3 September 2013 19:08, Martin Jansa <martin.jansa@gmail.com> wrote:
> It is using pkg-config in build time to enable support for it:
> http://cgit.collabora.com/git/user/cassidy/telepathy-mission-control/tree/configure.ac?h=offline-38366#n330
>
> and it has to conditionally link with them (otherwise test-dependencies
> script wouldn't detect it).

Ah, so mission-control is Doing It Wrong - that .pc file is for
connman plugins.  I'll harass upstream but I do wonder what the script
is detecting as there isn't anything like a libconnman.so to link
against.

Ross

Re: [WIP][PATCH 08/20] telepathy-mission-control: Add PACKAGECONFIG for upower and connectivity

[Burton, Ross]

On 3 September 2013 19:51, Burton, Ross <ross.burton@intel.com> wrote:
> Ah, so mission-control is Doing It Wrong - that .pc file is for
> connman plugins.  I'll harass upstream but I do wonder what the script
> is detecting as there isn't anything like a libconnman.so to link
> against.

So upstream has already fixed this by deleting all of the code and
using GLib instead.  A worthy approach, and when they release we can
ditch the PACKAGECONFIGs.

Ross

[WIP][PATCH 09/20] tcl: Add dependency on zlib

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-devtools/tcltk/tcl_8.6.0.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta/recipes-devtools/tcltk/tcl_8.6.0.bb b/meta/recipes-devtools/tcltk/tcl_8.6.0.bb
index 7273182..8d4df30 100644
--- a/meta/recipes-devtools/tcltk/tcl_8.6.0.bb
+++ b/meta/recipes-devtools/tcltk/tcl_8.6.0.bb
@@ -2,7 +2,7 @@ DESCRIPTION = "Tool Command Language"
 LICENSE = "BSD-3-Clause"
 SECTION = "devel/tcltk"
 HOMEPAGE = "http://tcl.sourceforge.net"
-DEPENDS = "tcl-native"
+DEPENDS = "tcl-native zlib"
 LIC_FILES_CHKSUM = "file://../license.terms;md5=3c6f62c07835353e36f0db550ccfb65a \
     file://../compat/license.terms;md5=3c6f62c07835353e36f0db550ccfb65a \
     file://../library/license.terms;md5=3c6f62c07835353e36f0db550ccfb65a \
-- 
1.8.3.2

[WIP][PATCH 10/20] weston: Add PACKAGECONFIG for poppler

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 .../0001-configure-Allow-to-disable-poppler.patch  | 43 ++++++++++++++++++++++
 meta/recipes-graphics/wayland/weston_1.1.0.bb      |  2 +
 2 files changed, 45 insertions(+)
 create mode 100644 meta/recipes-graphics/wayland/weston/0001-configure-Allow-to-disable-poppler.patch

diff --git a/meta/recipes-graphics/wayland/weston/0001-configure-Allow-to-disable-poppler.patch b/meta/recipes-graphics/wayland/weston/0001-configure-Allow-to-disable-poppler.patch
new file mode 100644
index 0000000..a8c1507
--- /dev/null
+++ b/meta/recipes-graphics/wayland/weston/0001-configure-Allow-to-disable-poppler.patch
@@ -0,0 +1,43 @@
+From d409b069a97e0d76016d3bfd34d6fae96dcf5d9d Mon Sep 17 00:00:00 2001
+From: Martin Jansa <Martin.Jansa@gmail.com>
+Date: Mon, 26 Aug 2013 00:51:31 +0200
+Subject: [PATCH] configure: Allow to disable poppler
+
+Upstream-Status: Pending
+
+Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
+---
+ configure.ac | 9 ++++++++-
+ 1 file changed, 8 insertions(+), 1 deletion(-)
+
+diff --git a/configure.ac b/configure.ac
+index d5fea9d..53e0c0b 100644
+--- a/configure.ac
++++ b/configure.ac
+@@ -221,6 +221,11 @@ if test x$enable_simple_egl_clients = xyes -a x$enable_egl = xyes; then
+                     [egl >= 7.10 glesv2 wayland-client wayland-egl wayland-cursor])
+ fi
+ 
++AC_ARG_ENABLE(poppler,
++              AS_HELP_STRING([--disable-poppler],
++                             [disable poppler support]),,
++              enable_popper=yes)
++
+ AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
+ AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
+ if test x$enable_clients = xyes; then
+@@ -229,8 +234,10 @@ if test x$enable_clients = xyes; then
+   PKG_CHECK_MODULES(CLIENT, [wayland-client cairo >= 1.10.0 xkbcommon wayland-cursor])
+   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client])
+ 
++  AS_IF([test "x$enable_poppler" != "no"], [
+   PKG_CHECK_MODULES(POPPLER, [poppler-glib glib-2.0 gobject-2.0 gio-2.0 ],
+-			     [have_poppler=yes], [have_poppler=no])
++			     [have_poppler=yes], [have_poppler=no])],
++  [have_poppler=no])
+   PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl >= 7.10 cairo-egl >= 1.11.3 $cairo_modules],
+ 		    [have_cairo_egl=yes], [have_cairo_egl=no])
+   AS_IF([test "x$have_cairo_egl" = "xyes"],
+-- 
+1.8.3.2
+
diff --git a/meta/recipes-graphics/wayland/weston_1.1.0.bb b/meta/recipes-graphics/wayland/weston_1.1.0.bb
index c7c64ad..cce876a 100644
--- a/meta/recipes-graphics/wayland/weston_1.1.0.bb
+++ b/meta/recipes-graphics/wayland/weston_1.1.0.bb
@@ -6,6 +6,7 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=275efac2559a224527bd4fd593d38466 \
                     file://src/compositor.c;endline=23;md5=aa98a8db03480fe7d500d0b1f4b8850c"
 
 SRC_URI = "http://wayland.freedesktop.org/releases/${BPN}-${PV}.tar.xz \
+           file://0001-configure-Allow-to-disable-poppler.patch \
            file://install-examples.patch \
            file://weston-launch-shell.patch \
            file://groups.patch \
@@ -49,6 +50,7 @@ PACKAGECONFIG[x11] = "--enable-x11-compositor,--disable-x11-compositor,virtual/l
 PACKAGECONFIG[headless] = "--enable-headless-compositor,--disable-headless-compositor"
 # Weston on framebuffer
 PACKAGECONFIG[fbdev] = "--enable-fbdev-compositor,--disable-fbdev-compositor,udev mtdev"
+PACKAGECONFIG[poppler] = "--enable-poppler,--disable-poppler,poppler"
 
 # Use cairo-gl or cairo-glesv2
 PACKAGECONFIG[gles] = "--with-cairo-glesv2,,virtual/libgles2"
-- 
1.8.3.2

[WIP][PATCH 11/20] wget: Add dependency on libpcre

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-extended/wget/wget.inc | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta/recipes-extended/wget/wget.inc b/meta/recipes-extended/wget/wget.inc
index de9b620..7af55c4 100644
--- a/meta/recipes-extended/wget/wget.inc
+++ b/meta/recipes-extended/wget/wget.inc
@@ -2,7 +2,7 @@ DESCRIPTION = "A console URL download utility featuring HTTP, FTP, and more."
 SECTION = "console/network"
 LICENSE = "GPLv3"
 LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
-DEPENDS = "openssl zlib"
+DEPENDS = "openssl zlib libpcre"
 
 INC_PR = "r16"
 
-- 
1.8.3.2

Re: [WIP][PATCH 11/20] wget: Add dependency on libpcre

[Randy MacLeod]

On 13-08-29 12:02 PM, Martin Jansa wrote:
> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
> ---
>   meta/recipes-extended/wget/wget.inc | 2 +-
>   1 file changed, 1 insertion(+), 1 deletion(-)
>
> diff --git a/meta/recipes-extended/wget/wget.inc b/meta/recipes-extended/wget/wget.inc
> index de9b620..7af55c4 100644
> --- a/meta/recipes-extended/wget/wget.inc
> +++ b/meta/recipes-extended/wget/wget.inc
> @@ -2,7 +2,7 @@ DESCRIPTION = "A console URL download utility featuring HTTP, FTP, and more."
>   SECTION = "console/network"
>   LICENSE = "GPLv3"
>   LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
> -DEPENDS = "openssl zlib"
> +DEPENDS = "openssl zlib libpcre"
>
>   INC_PR = "r16"
>
>


I haven't looked at the other patches yet but this seems
to be valid since my image construction failed with:

Computing transaction...error: Can't install wget-1.14-r16.0.0@core2: no 
package provides libpcre >= 8.33

-- 
# Randy MacLeod. SMTS, Linux, Wind River
Direct: 613.963.1350

Re: [WIP][PATCH 11/20] wget: Add dependency on libpcre

[Khem Raj]

On Fri, Sep 20, 2013 at 4:23 PM, Randy MacLeod
<randy.macleod@windriver.com> wrote:
> On 13-08-29 12:02 PM, Martin Jansa wrote:
>>
>> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
>> ---
>>   meta/recipes-extended/wget/wget.inc | 2 +-
>>   1 file changed, 1 insertion(+), 1 deletion(-)
>>
>> diff --git a/meta/recipes-extended/wget/wget.inc
>> b/meta/recipes-extended/wget/wget.inc
>> index de9b620..7af55c4 100644
>> --- a/meta/recipes-extended/wget/wget.inc
>> +++ b/meta/recipes-extended/wget/wget.inc
>> @@ -2,7 +2,7 @@ DESCRIPTION = "A console URL download utility featuring
>> HTTP, FTP, and more."
>>   SECTION = "console/network"
>>   LICENSE = "GPLv3"
>>   LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
>> -DEPENDS = "openssl zlib"
>> +DEPENDS = "openssl zlib libpcre"
>>
>>   INC_PR = "r16"
>>
>>
>
>
> I haven't looked at the other patches yet but this seems
> to be valid since my image construction failed with:
>
> Computing transaction...error: Can't install wget-1.14-r16.0.0@core2: no
> package provides libpcre >= 8.33


this is a typical floating dependency order case. it should be turned
into a PACKAGECONFIG, pcre is not a commonly shipped library and you
dont
want such hard dependency on it.


>
> --
> # Randy MacLeod. SMTS, Linux, Wind River
> Direct: 613.963.1350
>
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-core

[WIP][PATCH 12/20] x11vnc: Add PACKAGECONFIG for xfixes, xinerama, xrandr and xdamage

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-graphics/x11vnc/x11vnc_0.9.13.bb | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/meta/recipes-graphics/x11vnc/x11vnc_0.9.13.bb b/meta/recipes-graphics/x11vnc/x11vnc_0.9.13.bb
index 4b8bed4..7c404e3 100644
--- a/meta/recipes-graphics/x11vnc/x11vnc_0.9.13.bb
+++ b/meta/recipes-graphics/x11vnc/x11vnc_0.9.13.bb
@@ -18,5 +18,11 @@ SRC_URI = "${SOURCEFORGE_MIRROR}/libvncserver/x11vnc/${PV}/x11vnc-${PV}.tar.gz\
 SRC_URI[md5sum] = "a372ec4fe8211221547b1c108cf56e4c"
 SRC_URI[sha256sum] = "f6829f2e629667a5284de62b080b13126a0736499fe47cdb447aedb07a59f13b"
 
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[xfixes] = "--with-xfixes,--without-xfixes,libxfixes"
+PACKAGECONFIG[xinerama] = "--with-xinerama,--without-xinerama,libxinerama"
+PACKAGECONFIG[xrandr] = "--with-xrandr,--without-xrandr,libxrandr"
+PACKAGECONFIG[xdamage] = "--with-xdamage,--without-xdamage,libxdamage"
+
 inherit autotools
 
-- 
1.8.3.2

Re: [WIP][PATCH 12/20] x11vnc: Add PACKAGECONFIG for xfixes, xinerama, xrandr and xdamage

[Burton, Ross]

On 29 August 2013 17:02, Martin Jansa <martin.jansa@gmail.com> wrote:
> +PACKAGECONFIG ??= ""
> +PACKAGECONFIG[xfixes] = "--with-xfixes,--without-xfixes,libxfixes"
> +PACKAGECONFIG[xinerama] = "--with-xinerama,--without-xinerama,libxinerama"
> +PACKAGECONFIG[xrandr] = "--with-xrandr,--without-xrandr,libxrandr"
> +PACKAGECONFIG[xdamage] = "--with-xdamage,--without-xdamage,libxdamage"

xfixes/xdamage are incredibly useful for VNC servers.  Can you make
xfixes/xrandr/xdamage dependencies, leaving just xinerama a disabled
option.

Ross

[WIP][PATCH 13/20] guile: Add PACKAGECONFIG for readline

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-devtools/guile/guile_2.0.9.bb | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/meta/recipes-devtools/guile/guile_2.0.9.bb b/meta/recipes-devtools/guile/guile_2.0.9.bb
index 0dd61ff..0cbc216 100644
--- a/meta/recipes-devtools/guile/guile_2.0.9.bb
+++ b/meta/recipes-devtools/guile/guile_2.0.9.bb
@@ -40,6 +40,9 @@ RDEPENDS_${PN}_append_libc-glibc_class-target = "glibc-gconv-iso8859-1"
 
 EXTRA_OECONF += "${@['--without-libltdl-prefix --without-libgmp-prefix --without-libreadline-prefix', ''][bb.data.inherits_class('native',d)]}"
 
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[readline] = "--with-libreadline,--without-libreadline-support,readline"
+
 do_configure_prepend() {
 	mkdir -p po
 }
-- 
1.8.3.2

[WIP][PATCH 14/20] consolekit: Add patch to explicitly disable polkit when not enabled

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 .../allow.to.disable.polkit.support.patch          | 33 ++++++++++++++++++++++
 .../recipes-support/consolekit/consolekit_0.4.6.bb |  4 +--
 2 files changed, 35 insertions(+), 2 deletions(-)
 create mode 100644 meta/recipes-support/consolekit/consolekit/allow.to.disable.polkit.support.patch

diff --git a/meta/recipes-support/consolekit/consolekit/allow.to.disable.polkit.support.patch b/meta/recipes-support/consolekit/consolekit/allow.to.disable.polkit.support.patch
new file mode 100644
index 0000000..e1a868b
--- /dev/null
+++ b/meta/recipes-support/consolekit/consolekit/allow.to.disable.polkit.support.patch
@@ -0,0 +1,33 @@
+Polkit is autodetected from sysroot.
+
+We need to explicitly disable it to get deterministic behavior
+when following sequence is used:
+bitbake consolekit
+bitbake polkit
+bitbake consolekit
+
+Upstream-Status: Pending
+
+Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
+
+--- a/configure.ac	2013-08-26 15:43:00.770168252 +0200
++++ b/configure.ac	2013-08-26 15:45:15.816173094 +0200
+@@ -56,13 +56,16 @@
+   gthread-2.0 >= $GLIB_REQUIRED_VERSION
+ )
+ 
+-PKG_CHECK_MODULES(POLKIT,
++AC_ARG_ENABLE(polkit,
++	[AS_HELP_STRING([--enable-polkit],[build polkit support])],
++[PKG_CHECK_MODULES(POLKIT,
+   polkit-gobject-1 >= $POLKIT_REQUIRED_VERSION,
+   have_polkit=yes,
+   have_polkit=no)
+ if test "x$have_polkit" = "xyes" ; then
+        AC_DEFINE(HAVE_POLKIT, [], [Define if we have polkit])
+-fi
++fi], [have_polkit=no])
++  
+ AM_CONDITIONAL(HAVE_POLKIT, test x$have_polkit = xyes)
+ AC_SUBST(HAVE_POLKIT)
+ 
diff --git a/meta/recipes-support/consolekit/consolekit_0.4.6.bb b/meta/recipes-support/consolekit/consolekit_0.4.6.bb
index 63da028..7f05389 100644
--- a/meta/recipes-support/consolekit/consolekit_0.4.6.bb
+++ b/meta/recipes-support/consolekit/consolekit_0.4.6.bb
@@ -12,6 +12,7 @@ RDEPENDS_${PN} += "base-files"
 inherit autotools pkgconfig
 
 SRC_URI = "http://www.freedesktop.org/software/ConsoleKit/dist/ConsoleKit-${PV}.tar.xz \
+           file://allow.to.disable.polkit.support.patch \
            file://sepbuildfix.patch"
 
 SRC_URI[md5sum] = "611792b4d616253a5bdec9175f8b7678"
@@ -23,8 +24,7 @@ PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'pam', 'pam', '', d)} \
                    ${@base_contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)}"
 
 PACKAGECONFIG[pam] = "--enable-pam-module --with-pam-module-dir=${base_libdir}/security,--disable-pam-module,libpam"
-# No option to turn it on or off, so rely on the build dependency for now.
-PACKAGECONFIG[policykit] = ",,polkit"
+PACKAGECONFIG[policykit] = "--enable-polkit,--disable-polkit,polkit"
 PACKAGECONFIG[systemd] = "--with-systemdsystemunitdir=${systemd_unitdir}/system/,--with-systemdsystemunitdir="
 
 FILES_${PN} += "${localstatedir}/log/ConsoleKit ${exec_prefix}/lib/ConsoleKit \
-- 
1.8.3.2

[WIP][PATCH 15/20] glib-networking: Add PACKAGECONFIG for p11-kit

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-core/glib-networking/glib-networking_2.36.2.bb | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/meta/recipes-core/glib-networking/glib-networking_2.36.2.bb b/meta/recipes-core/glib-networking/glib-networking_2.36.2.bb
index 863a4eb..5200b94 100644
--- a/meta/recipes-core/glib-networking/glib-networking_2.36.2.bb
+++ b/meta/recipes-core/glib-networking/glib-networking_2.36.2.bb
@@ -13,6 +13,9 @@ SRC_URI = "${GNOME_MIRROR}/${BPN}/2.36/${BPN}-${PV}.tar.xz"
 SRC_URI[md5sum] = "fb9121742ed36d1723f296eea19dbb3c"
 SRC_URI[sha256sum] = "2108d55b0af3eea56ce256830bcaf1519d6337e0054ef2eff80f2c0ef0eb23f9"
 
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[pkcs11] = "--with-pkcs11,--without-pkcs11,p11-kit"
+
 EXTRA_OECONF = "--without-ca-certificates --without-gnome-proxy --without-libproxy"
 
 inherit autotools pkgconfig
-- 
1.8.3.2

[WIP][PATCH 16/20] lame: Add dependency on ncurses

[Martin Jansa]

* it's autodetected and configure doesn't allow to explicitly disable it

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-multimedia/lame/lame_3.99.5.bb | 2 ++
 1 file changed, 2 insertions(+)

diff --git a/meta/recipes-multimedia/lame/lame_3.99.5.bb b/meta/recipes-multimedia/lame/lame_3.99.5.bb
index 764fcc1..978636a 100644
--- a/meta/recipes-multimedia/lame/lame_3.99.5.bb
+++ b/meta/recipes-multimedia/lame/lame_3.99.5.bb
@@ -5,6 +5,8 @@ SECTION = "console/utils"
 LICENSE = "LGPLv2+"
 LICENSE_FLAGS = "commercial"
 
+DEPENDS = "ncurses"
+
 LIC_FILES_CHKSUM = "file://COPYING;md5=c46bda00ffbb0ba1dac22f8d087f54d9 \
                     file://include/lame.h;beginline=1;endline=20;md5=a2258182c593c398d15a48262130a92b \
 "
-- 
1.8.3.2

[WIP][PATCH 17/20] librsvg: Fix dependencies for PACKAGECONFIG gdkpixbuf

[Martin Jansa]

* without gtk+ or gdk-pixbuf available it gets disabled even with --enable-pixbuf-loader

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-gnome/librsvg/librsvg_2.32.1.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb b/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb
index 4818422..30846bf 100644
--- a/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb
+++ b/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb
@@ -29,7 +29,7 @@ PACKAGECONFIG ??= "croco gdkpixbuf"
 # Support embedded CSS stylesheets (recommended upstream)
 PACKAGECONFIG[croco] = "--with-croco,--without-croco,libcroco"
 # gdk-pixbuf loader
-PACKAGECONFIG[gdkpixbuf] = "--enable-pixbuf-loader,--disable-pixbuf-loader"
+PACKAGECONFIG[gdkpixbuf] = "--enable-pixbuf-loader,--disable-pixbuf-loader,gtk+ gdk-pixbuf"
 # GTK+ 2 theme engine
 PACKAGECONFIG[gtk] = "--enable-gtk-theme,--disable-gtk-theme,gtk+"
 
-- 
1.8.3.2

Re: [WIP][PATCH 17/20] librsvg: Fix dependencies for PACKAGECONFIG gdkpixbuf

[Saul Wold]

On 08/29/2013 09:03 AM, Martin Jansa wrote:
> * without gtk+ or gdk-pixbuf available it gets disabled even with --enable-pixbuf-loader
>
> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
> ---
>   meta/recipes-gnome/librsvg/librsvg_2.32.1.bb | 2 +-
>   1 file changed, 1 insertion(+), 1 deletion(-)
>
> diff --git a/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb b/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb
> index 4818422..30846bf 100644
> --- a/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb
> +++ b/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb
> @@ -29,7 +29,7 @@ PACKAGECONFIG ??= "croco gdkpixbuf"
>   # Support embedded CSS stylesheets (recommended upstream)
>   PACKAGECONFIG[croco] = "--with-croco,--without-croco,libcroco"
>   # gdk-pixbuf loader
> -PACKAGECONFIG[gdkpixbuf] = "--enable-pixbuf-loader,--disable-pixbuf-loader"
> +PACKAGECONFIG[gdkpixbuf] = "--enable-pixbuf-loader,--disable-pixbuf-loader,gtk+ gdk-pixbuf"

I think this needs to be a target only PACKAGECONFIG, as it will try to 
depend on gtk+-native when building the librsvg-native.

Sau!

>   # GTK+ 2 theme engine
>   PACKAGECONFIG[gtk] = "--enable-gtk-theme,--disable-gtk-theme,gtk+"
>
>

Re: [WIP][PATCH 17/20] librsvg: Fix dependencies for PACKAGECONFIG gdkpixbuf

[Martin Jansa]

[-- Attachment #1: Type: text/plain, Size: 1553 bytes --]

On Thu, Aug 29, 2013 at 10:49:03AM -0700, Saul Wold wrote:
> On 08/29/2013 09:03 AM, Martin Jansa wrote:
> > * without gtk+ or gdk-pixbuf available it gets disabled even with --enable-pixbuf-loader
> >
> > Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
> > ---
> >   meta/recipes-gnome/librsvg/librsvg_2.32.1.bb | 2 +-
> >   1 file changed, 1 insertion(+), 1 deletion(-)
> >
> > diff --git a/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb b/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb
> > index 4818422..30846bf 100644
> > --- a/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb
> > +++ b/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb
> > @@ -29,7 +29,7 @@ PACKAGECONFIG ??= "croco gdkpixbuf"
> >   # Support embedded CSS stylesheets (recommended upstream)
> >   PACKAGECONFIG[croco] = "--with-croco,--without-croco,libcroco"
> >   # gdk-pixbuf loader
> > -PACKAGECONFIG[gdkpixbuf] = "--enable-pixbuf-loader,--disable-pixbuf-loader"
> > +PACKAGECONFIG[gdkpixbuf] = "--enable-pixbuf-loader,--disable-pixbuf-loader,gtk+ gdk-pixbuf"
> 
> I think this needs to be a target only PACKAGECONFIG, as it will try to 
> depend on gtk+-native when building the librsvg-native.

Yes I've noticed it couple minutes after sending this patchset and it's
already fixed in branch (just not squashed yet - waiting for next
build).

Thanks for review

> 
> Sau!
> 
> >   # GTK+ 2 theme engine
> >   PACKAGECONFIG[gtk] = "--enable-gtk-theme,--disable-gtk-theme,gtk+"
> >
> >

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]

Re: [WIP][PATCH 17/20] librsvg: Fix dependencies for PACKAGECONFIG gdkpixbuf

[Richard Purdie]

On Thu, 2013-08-29 at 10:49 -0700, Saul Wold wrote:
> On 08/29/2013 09:03 AM, Martin Jansa wrote:
> > * without gtk+ or gdk-pixbuf available it gets disabled even with --enable-pixbuf-loader
> >
> > Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
> > ---
> >   meta/recipes-gnome/librsvg/librsvg_2.32.1.bb | 2 +-
> >   1 file changed, 1 insertion(+), 1 deletion(-)
> >
> > diff --git a/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb b/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb
> > index 4818422..30846bf 100644
> > --- a/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb
> > +++ b/meta/recipes-gnome/librsvg/librsvg_2.32.1.bb
> > @@ -29,7 +29,7 @@ PACKAGECONFIG ??= "croco gdkpixbuf"
> >   # Support embedded CSS stylesheets (recommended upstream)
> >   PACKAGECONFIG[croco] = "--with-croco,--without-croco,libcroco"
> >   # gdk-pixbuf loader
> > -PACKAGECONFIG[gdkpixbuf] = "--enable-pixbuf-loader,--disable-pixbuf-loader"
> > +PACKAGECONFIG[gdkpixbuf] = "--enable-pixbuf-loader,--disable-pixbuf-loader,gtk+ gdk-pixbuf"
> 
> I think this needs to be a target only PACKAGECONFIG, as it will try to 
> depend on gtk+-native when building the librsvg-native.

Also do we really need gtk for the pixbuf loader? gtk2 theme engine
pulls in gtk+ elsewhere?

Cheers,

Richard

Re: [WIP][PATCH 17/20] librsvg: Fix dependencies for PACKAGECONFIG gdkpixbuf

[Burton, Ross]

On 30 August 2013 15:59, Richard Purdie
<richard.purdie@linuxfoundation.org> wrote:
>> I think this needs to be a target only PACKAGECONFIG, as it will try to
>> depend on gtk+-native when building the librsvg-native.
>
> Also do we really need gtk for the pixbuf loader? gtk2 theme engine
> pulls in gtk+ elsewhere?

gdk-pixbuf should be sufficient.

Ross

[WIP][PATCH 18/20] subversion: Add dependency on file for libmagic

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-devtools/subversion/subversion_1.7.10.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta/recipes-devtools/subversion/subversion_1.7.10.bb b/meta/recipes-devtools/subversion/subversion_1.7.10.bb
index f77656b..4acd70b 100644
--- a/meta/recipes-devtools/subversion/subversion_1.7.10.bb
+++ b/meta/recipes-devtools/subversion/subversion_1.7.10.bb
@@ -1,6 +1,6 @@
 DESCRIPTION = "The Subversion (svn) client"
 SECTION = "console/network"
-DEPENDS = "apr-util neon sqlite3"
+DEPENDS = "apr-util neon sqlite3 file"
 RDEPENDS_${PN} = "neon"
 LICENSE = "Apache-2"
 HOMEPAGE = "http://subversion.tigris.org"
-- 
1.8.3.2

Re: [WIP][PATCH 18/20] subversion: Add dependency on file for libmagic

[Jonathan Liu]

On 30 August 2013 02:03, Martin Jansa <martin.jansa@gmail.com> wrote:
> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
> ---
>  meta/recipes-devtools/subversion/subversion_1.7.10.bb | 2 +-
>  1 file changed, 1 insertion(+), 1 deletion(-)
>
> diff --git a/meta/recipes-devtools/subversion/subversion_1.7.10.bb b/meta/recipes-devtools/subversion/subversion_1.7.10.bb
> index f77656b..4acd70b 100644
> --- a/meta/recipes-devtools/subversion/subversion_1.7.10.bb
> +++ b/meta/recipes-devtools/subversion/subversion_1.7.10.bb
> @@ -1,6 +1,6 @@
>  DESCRIPTION = "The Subversion (svn) client"
>  SECTION = "console/network"
> -DEPENDS = "apr-util neon sqlite3"
> +DEPENDS = "apr-util neon sqlite3 file"
>  RDEPENDS_${PN} = "neon"
>  LICENSE = "Apache-2"
>  HOMEPAGE = "http://subversion.tigris.org"
> --
> 1.8.3.2
>
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-core

Signed-off-by: Jonathan Liu <net147@gmail.com>

This fixes a subversion build error I was having a couple of weeks ago.

Regards,
Jonathan

[WIP][PATCH 19/20] systemd: Add PACKAGECONFIG for cryptsetup

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-core/systemd/systemd_206.bb | 1 +
 1 file changed, 1 insertion(+)

diff --git a/meta/recipes-core/systemd/systemd_206.bb b/meta/recipes-core/systemd/systemd_206.bb
index f05aa1b..0511813 100644
--- a/meta/recipes-core/systemd/systemd_206.bb
+++ b/meta/recipes-core/systemd/systemd_206.bb
@@ -50,6 +50,7 @@ DEPENDS += "libgcrypt"
 # Compress the journal
 PACKAGECONFIG[xz] = "--enable-xz,--disable-xz,xz"
 PACKAGECONFIG[tcp-wrappers] = "--enable-tcpwrap,--disable-tcpwrap,tcp-wrappers"
+PACKAGECONFIG[cryptsetup] = "--enable-libcryptsetup,--disable-libcryptsetup,cryptsetup"
 
 CACHED_CONFIGUREVARS = "ac_cv_path_KILL=${base_bindir}/kill"
 
-- 
1.8.3.2

[WIP][PATCH 20/20] qemu: Add PACKAGECONFIG for nss, uuid, tls and curses

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta/recipes-devtools/qemu/qemu.inc | 4 ++++
 1 file changed, 4 insertions(+)

diff --git a/meta/recipes-devtools/qemu/qemu.inc b/meta/recipes-devtools/qemu/qemu.inc
index 97e9b7b..c8a2182 100644
--- a/meta/recipes-devtools/qemu/qemu.inc
+++ b/meta/recipes-devtools/qemu/qemu.inc
@@ -82,6 +82,10 @@ do_install_append() {
 PACKAGECONFIG ??= ""
 PACKAGECONFIG[virtfs] = "--enable-virtfs --enable-attr,--disable-virtfs,libcap attr,"
 PACKAGECONFIG[aio] = "--enable-linux-aio,--disable-linux-aio,libaio,"
+PACKAGECONFIG[nss] = "--enable-smartcard-nss,--disable-smartcard-nss,nss,"
+PACKAGECONFIG[uuid] = "--enable-uuid,--disable-uuid,util-linux,"
+PACKAGECONFIG[tls] = "--enable-vnc-tls,--disable-vnc-tls,gnutls,"
+PACKAGECONFIG[curses] = "--enable-curses,--disable-curses,ncurses,"
 
 # Qemu target will not build in world build for ARM or Mips
 BROKEN_qemuarm = "1"
-- 
1.8.3.2

Re: [WIP][PATCH 00/20] Deterministic dependencies II

[Martin Jansa]

[-- Attachment #1: Type: text/plain, Size: 1056 bytes --]

On Thu, Aug 29, 2013 at 06:02:47PM +0200, Martin Jansa wrote:
> WIP because verification build is still running and I must admit that I'm mostly
> testing that all dependencies are correctly "disabled" and in the end deterministic.
> 
> I'm not testing if every possible combination of PACKAGECONFIG options provide sufficient
> dependency tree.
> 
> But it would be nice to get some review in advance and be able to get this
> in 1.5 if I manage to fix all possible review comments and/or issues discovered
> in my builds in time.

FYI: I didn't have time to finish this in last 2 weeks and will be very
busy for next 2 weeks so I'm OK with leaving this for 1.5.1 or something
like that after 1.5 release. I did some changes from review comments, so
the branch has slightly newer versions.

If you see something you really want to have in release please speak up
and review/confirm it for me.

The same does apply for longer meta-openembedded patchset with
dependencies.

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]

Re: [WIP][PATCH 00/20] Deterministic dependencies II

[Martin Jansa]

[-- Attachment #1: Type: text/plain, Size: 1684 bytes --]

On Tue, Sep 10, 2013 at 08:54:27PM +0200, Martin Jansa wrote:
> On Thu, Aug 29, 2013 at 06:02:47PM +0200, Martin Jansa wrote:
> > WIP because verification build is still running and I must admit that I'm mostly
> > testing that all dependencies are correctly "disabled" and in the end deterministic.
> > 
> > I'm not testing if every possible combination of PACKAGECONFIG options provide sufficient
> > dependency tree.
> > 
> > But it would be nice to get some review in advance and be able to get this
> > in 1.5 if I manage to fix all possible review comments and/or issues discovered
> > in my builds in time.
> 
> FYI: I didn't have time to finish this in last 2 weeks and will be very
> busy for next 2 weeks so I'm OK with leaving this for 1.5.1 or something
> like that after 1.5 release. I did some changes from review comments, so
> the branch has slightly newer versions.
> 
> If you see something you really want to have in release please speak up
> and review/confirm it for me.
> 
> The same does apply for longer meta-openembedded patchset with
> dependencies.

These patches:
pick 6467505 librsvg: Fix dependencies for PACKAGECONFIG gdkpixbuf
pick db92df6 libmatchbox: Add PACKAGECONFIG for png
pick 7c66af8 weston: Add PACKAGECONFIG for poppler
pick 6284f74 guile: Add PACKAGECONFIG for readline
pick 2cb5d37 consolekit: Add patch to explicitly disable polkit when not enabled
pick fa00e58 qemu: Add PACKAGECONFIG for nss, uuid, tls and curses

need a bit more work, but others are ready for merge (verified in last
test-dependencies build).

I'll send v2 in a minute.

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]