[meta-rockchip] [PATCH v2 0/3] Add video codec recipes

[meta-rockchip] [PATCH v2 0/3] Add video codec recipes

[ayaka]

Those packages are the userspace libraries for the Rockchip
Android video codec driver.

Also a minimal image used for verified the media framework is included.

ayaka (3):
  recipes-multimedia: add Rockchip MPP library
  recipes-multimedia: add gstreamer rockchip support
  recipes-multimedia: images: rockchip media image

 .../gstreamer/gstreamer1.0-rockchip.inc            | 40 ++++++++++++++++++++++
 .../gstreamer/gstreamer1.0-rockchip_20170412.bb    |  9 +++++
 .../gstreamer/gstreamer1.0-rockchip_git.bb         | 13 +++++++
 recipes-multimedia/images/rockchip-media-image.bb  | 21 ++++++++++++
 recipes-multimedia/rockchip-mpp/rockchip-mpp.inc   | 21 ++++++++++++
 .../rockchip-mpp/rockchip-mpp_20170412.bb          |  9 +++++
 .../rockchip-mpp/rockchip-mpp_git.bb               | 16 +++++++++
 7 files changed, 129 insertions(+)
 create mode 100644 recipes-multimedia/gstreamer/gstreamer1.0-rockchip.inc
 create mode 100644 recipes-multimedia/gstreamer/gstreamer1.0-rockchip_20170412.bb
 create mode 100644 recipes-multimedia/gstreamer/gstreamer1.0-rockchip_git.bb
 create mode 100644 recipes-multimedia/images/rockchip-media-image.bb
 create mode 100644 recipes-multimedia/rockchip-mpp/rockchip-mpp.inc
 create mode 100644 recipes-multimedia/rockchip-mpp/rockchip-mpp_20170412.bb
 create mode 100644 recipes-multimedia/rockchip-mpp/rockchip-mpp_git.bb

-- 
2.7.4

[meta-rockchip] [PATCH v2 1/3] recipes-multimedia: add Rockchip MPP library

[ayaka]

MPP means Media Process Platform. The MPP is a middleware
for the other video encoder/decoder interface, translating
the video information into the hardware registers.

Signed-off-by: ayaka <ayaka@soulik.info>
---
 recipes-multimedia/rockchip-mpp/rockchip-mpp.inc    | 21 +++++++++++++++++++++
 .../rockchip-mpp/rockchip-mpp_20170412.bb           |  9 +++++++++
 recipes-multimedia/rockchip-mpp/rockchip-mpp_git.bb | 16 ++++++++++++++++
 3 files changed, 46 insertions(+)
 create mode 100644 recipes-multimedia/rockchip-mpp/rockchip-mpp.inc
 create mode 100644 recipes-multimedia/rockchip-mpp/rockchip-mpp_20170412.bb
 create mode 100644 recipes-multimedia/rockchip-mpp/rockchip-mpp_git.bb

diff --git a/recipes-multimedia/rockchip-mpp/rockchip-mpp.inc b/recipes-multimedia/rockchip-mpp/rockchip-mpp.inc
new file mode 100644
index 0000000..6a45637
--- /dev/null
+++ b/recipes-multimedia/rockchip-mpp/rockchip-mpp.inc
@@ -0,0 +1,21 @@
+# Copyright (C) 2016 - 2017 Randy Li <ayaka@soulik.info>
+# Released under the GNU GENERAL PUBLIC LICENSE Version 2
+# (see COPYING.GPLv2 for the terms)
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://inc/rk_mpi.h;beginline=4;endline=14;md5=acbba394ae5639b0c786f60c1f48e3d6"
+
+inherit pkgconfig cmake
+
+EXTRA_OECMAKE = "     \
+    -DRKPLATFORM=ON   \
+    -DHAVE_DRM=ON     \
+"
+
+PACKAGES = "${PN}-dbg ${PN}-staticdev ${PN}-dev ${PN} rockchip-vpu"
+FILES_rockchip-vpu = "${libdir}/lib*vpu${SOLIBS}"
+FILES_${PN} = "${libdir}/lib*mpp${SOLIBS}"
+FILES_${PN}-dev = "${libdir}/lib*${SOLIBSDEV} ${includedir} ${libdir}/pkgconfig"
+SECTION_${PN}-dev = "devel"
+FILES_${PN}-staticdev = "${libdir}/*.a"
+SECTION_${PN}-staticdev = "devel"
diff --git a/recipes-multimedia/rockchip-mpp/rockchip-mpp_20170412.bb b/recipes-multimedia/rockchip-mpp/rockchip-mpp_20170412.bb
new file mode 100644
index 0000000..501306a
--- /dev/null
+++ b/recipes-multimedia/rockchip-mpp/rockchip-mpp_20170412.bb
@@ -0,0 +1,9 @@
+# Copyright (C) 2016 - 2017 Randy Li <ayaka@soulik.info>
+# Released under the GNU GENERAL PUBLIC LICENSE Version 2
+# (see COPYING.GPLv2 for the terms)
+include rockchip-mpp.inc
+
+TAG = "release_${PV}"
+SRC_URI = "git://github.com/rockchip-linux/mpp.git;tag=${TAG};nobranch=1"
+
+S = "${WORKDIR}/git"
diff --git a/recipes-multimedia/rockchip-mpp/rockchip-mpp_git.bb b/recipes-multimedia/rockchip-mpp/rockchip-mpp_git.bb
new file mode 100644
index 0000000..23f3f15
--- /dev/null
+++ b/recipes-multimedia/rockchip-mpp/rockchip-mpp_git.bb
@@ -0,0 +1,16 @@
+# Copyright (C) 2016 - 2017 Randy Li <ayaka@soulik.info>
+# Released under the GNU GENERAL PUBLIC LICENSE Version 2
+# (see COPYING.GPLv2 for the terms)
+
+DEFAULT_PREFERENCE = "-1"
+
+include rockchip-mpp.inc
+DEPENDS = "git-replacement-native"
+
+FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
+FILESPATH_prepend := "${THISDIR}/${PN}:"
+
+SRCREV = "${AUTOREV}"
+SRC_URI = "git://github.com/rockchip-linux/mpp.git;branch=develop"
+
+S = "${WORKDIR}/git"
-- 
2.7.4

[meta-rockchip] [PATCH v2 2/3] recipes-multimedia: add gstreamer rockchip support

[ayaka]

This Gstreamer plugin provides a encoder and decoder plugin
for Gstreamer through the Rockchip MPP library.

Signed-off-by: ayaka <ayaka@soulik.info>
---
 .../gstreamer/gstreamer1.0-rockchip.inc            | 40 ++++++++++++++++++++++
 .../gstreamer/gstreamer1.0-rockchip_20170412.bb    |  9 +++++
 .../gstreamer/gstreamer1.0-rockchip_git.bb         | 13 +++++++
 3 files changed, 62 insertions(+)
 create mode 100644 recipes-multimedia/gstreamer/gstreamer1.0-rockchip.inc
 create mode 100644 recipes-multimedia/gstreamer/gstreamer1.0-rockchip_20170412.bb
 create mode 100644 recipes-multimedia/gstreamer/gstreamer1.0-rockchip_git.bb

diff --git a/recipes-multimedia/gstreamer/gstreamer1.0-rockchip.inc b/recipes-multimedia/gstreamer/gstreamer1.0-rockchip.inc
new file mode 100644
index 0000000..0bd70ab
--- /dev/null
+++ b/recipes-multimedia/gstreamer/gstreamer1.0-rockchip.inc
@@ -0,0 +1,40 @@
+# Copyright (C) 2016 - 2017 Randy Li <ayaka@soulik.info>
+# Released under the GNU GENERAL PUBLIC LICENSE Version 2
+# (see COPYING.GPLv2 for the terms)
+
+require recipes-multimedia/gstreamer/gstreamer1.0-plugins.inc
+
+DESCRIPTION = "GStreamer 1.0 plugins for Rockchip platforms"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=6d1e4aa87f6192354d3de840cf774d93"
+DEPENDS += "gstreamer1.0-plugins-base rockchip-mpp"
+
+SRC_URI_remove = " \
+    file://0001-introspection.m4-prefix-pkgconfig-paths-with-PKG_CON.patch \
+"
+
+FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
+FILESPATH_prepend := "${THISDIR}/${PN}:"
+
+inherit gettext autotools pkgconfig
+
+PACKAGECONFIG ??= " \
+    mpp             \
+"
+PACKAGECONFIG[mpp]    = "--enable-rockchipmpp,--disable-rockchipmpp,rockchip-mpp"
+PACKAGECONFIG[vpudec] = "--enable-vpudec,--disable-vpudec,rockchip-vpu"
+PACKAGECONFIG[drm]    = "--enable-drmrockchip,--disable-drmrockchip,libdrm-rockchip"
+PACKAGECONFIG[egl]    = "--enable-armmali,--disable-armmali,arm-mali"
+
+EXTRA_OECONF += "    \
+    --disable-kms    \
+"
+EXTRA_OECONF_remove = "--disable-gtk-doc"
+
+do_configure[prefuncs] = " delete_pkg_m4_file"
+
+do_configure() {
+    NOCONFIGURE=true ${S}/autogen.sh
+    oe_runconf
+}
diff --git a/recipes-multimedia/gstreamer/gstreamer1.0-rockchip_20170412.bb b/recipes-multimedia/gstreamer/gstreamer1.0-rockchip_20170412.bb
new file mode 100644
index 0000000..e3fecaf
--- /dev/null
+++ b/recipes-multimedia/gstreamer/gstreamer1.0-rockchip_20170412.bb
@@ -0,0 +1,9 @@
+# Copyright (C) 2016 - 2017 Randy Li <ayaka@soulik.info>
+# Released under the GNU GENERAL PUBLIC LICENSE Version 2
+# (see COPYING.GPLv2 for the terms)
+include gstreamer1.0-rockchip.inc
+
+TAG = "release_${PV}"
+SRC_URI = "git://github.com/rockchip-linux/gstreamer-rockchip.git;tag=${TAG};nobranch=1"
+
+S = "${WORKDIR}/git"
diff --git a/recipes-multimedia/gstreamer/gstreamer1.0-rockchip_git.bb b/recipes-multimedia/gstreamer/gstreamer1.0-rockchip_git.bb
new file mode 100644
index 0000000..bd20121
--- /dev/null
+++ b/recipes-multimedia/gstreamer/gstreamer1.0-rockchip_git.bb
@@ -0,0 +1,13 @@
+# Copyright (C) 2016 - 2017 Randy Li <ayaka@soulik.info>
+# Released under the GNU GENERAL PUBLIC LICENSE Version 2
+# (see COPYING.GPLv2 for the terms)
+
+DEFAULT_PREFERENCE = "-1"
+
+include gstreamer1.0-rockchip.inc
+
+SRCBRANCH ?= "develop"
+SRCREV = "${AUTOREV}"
+SRC_URI = "git://github.com/rockchip-linux/gstreamer-rockchip.git;branch=develop"
+
+S = "${WORKDIR}/git"
-- 
2.7.4

[meta-rockchip] [PATCH v2 3/3] recipes-multimedia: images: rockchip media image

[ayaka]

A image for debugging the hardware video encoder/decoder.
I also use this image for developing the Gstreamer.

Signed-off-by: ayaka <ayaka@soulik.info>
---
 recipes-multimedia/images/rockchip-media-image.bb | 21 +++++++++++++++++++++
 1 file changed, 21 insertions(+)
 create mode 100644 recipes-multimedia/images/rockchip-media-image.bb

diff --git a/recipes-multimedia/images/rockchip-media-image.bb b/recipes-multimedia/images/rockchip-media-image.bb
new file mode 100644
index 0000000..ea993c1
--- /dev/null
+++ b/recipes-multimedia/images/rockchip-media-image.bb
@@ -0,0 +1,21 @@
+# Copyright (C) 2017 Randy Li <ayaka@soulik.info>
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+include recipes-core/images/core-image-minimal.bb
+
+LICENSE = "MIT"
+DESCRIPTION = "Multimedia image for Rockchip devices."
+
+IMAGE_FEATURES_append = " package-management ssh-server-dropbear"
+IMAGE_INSTALL_append = " gdbserver gstreamer1.0-rockchip      \
+ gstreamer1.0-meta-base gstreamer1.0-meta-video gstreamer1.0-meta-audio \
+ gstreamer1.0-plugins-good-isomp4 gstreamer1.0-plugins-good-multifile \
+ gstreamer1.0-plugins-good-imagefreeze \
+ gstreamer1.0-plugins-bad-autoconvert  gstreamer1.0-plugins-bad-camerabin2 \
+ gstreamer1.0-plugins-bad-kmssink gstreamer1.0-plugins-bad-rawparse \
+ gstreamer1.0-plugins-bad-videoparsersbad \
+ gstreamer1.0-plugins-bad-mpegtsdemux \
+ gstreamer1.0-meta-debug \
+"
+
+TOOLCHAIN_HOST_TASK += "nativesdk-cmake"
-- 
2.7.4

Re: [meta-rockchip] [PATCH v2 1/3] recipes-multimedia: add Rockchip MPP library

[Romain Perier]

Hello,


Le 12/04/2017 à 18:05, ayaka a écrit :
> MPP means Media Process Platform. The MPP is a middleware
> for the other video encoder/decoder interface, translating
> the video information into the hardware registers.
>
> Signed-off-by: ayaka <ayaka@soulik.info>

Please Signed-off-by with your Real name please "FirstName LastName
<ayaka@soulik.info>"

> ---
>  recipes-multimedia/rockchip-mpp/rockchip-mpp.inc    | 21 +++++++++++++++++++++
>  .../rockchip-mpp/rockchip-mpp_20170412.bb           |  9 +++++++++
>  recipes-multimedia/rockchip-mpp/rockchip-mpp_git.bb | 16 ++++++++++++++++
>  3 files changed, 46 insertions(+)
>  create mode 100644 recipes-multimedia/rockchip-mpp/rockchip-mpp.inc
>  create mode 100644 recipes-multimedia/rockchip-mpp/rockchip-mpp_20170412.bb
>  create mode 100644 recipes-multimedia/rockchip-mpp/rockchip-mpp_git.bb
>
> diff --git a/recipes-multimedia/rockchip-mpp/rockchip-mpp.inc b/recipes-multimedia/rockchip-mpp/rockchip-mpp.inc
> new file mode 100644
> index 0000000..6a45637
> --- /dev/null
> +++ b/recipes-multimedia/rockchip-mpp/rockchip-mpp.inc
> @@ -0,0 +1,21 @@
> +# Copyright (C) 2016 - 2017 Randy Li <ayaka@soulik.info>
> +# Released under the GNU GENERAL PUBLIC LICENSE Version 2
> +# (see COPYING.GPLv2 for the terms)
> +
> +LICENSE = "Apache-2.0"
> +LIC_FILES_CHKSUM = "file://inc/rk_mpi.h;beginline=4;endline=14;md5=acbba394ae5639b0c786f60c1f48e3d6"
> +
> +inherit pkgconfig cmake
> +
> +EXTRA_OECMAKE = "     \
> +    -DRKPLATFORM=ON   \
> +    -DHAVE_DRM=ON     \
> +"
> +
> +PACKAGES = "${PN}-dbg ${PN}-staticdev ${PN}-dev ${PN} rockchip-vpu"

The recipe is named rockchip-mpp, so don't create a package with another
name, it might be confusing and it's not standard.
I suggest "rockchip-mpp-vpu" or "rockchip-mpp-vpu_plugin" or something
like this.

> +FILES_rockchip-vpu = "${libdir}/lib*vpu${SOLIBS}"
> +FILES_${PN} = "${libdir}/lib*mpp${SOLIBS}"
> +FILES_${PN}-dev = "${libdir}/lib*${SOLIBSDEV} ${includedir} ${libdir}/pkgconfig"
> +SECTION_${PN}-dev = "devel"
> +FILES_${PN}-staticdev = "${libdir}/*.a"
> +SECTION_${PN}-staticdev = "devel"
> diff --git a/recipes-multimedia/rockchip-mpp/rockchip-mpp_20170412.bb b/recipes-multimedia/rockchip-mpp/rockchip-mpp_20170412.bb
> new file mode 100644
> index 0000000..501306a
> --- /dev/null
> +++ b/recipes-multimedia/rockchip-mpp/rockchip-mpp_20170412.bb
> @@ -0,0 +1,9 @@
> +# Copyright (C) 2016 - 2017 Randy Li <ayaka@soulik.info>
> +# Released under the GNU GENERAL PUBLIC LICENSE Version 2
> +# (see COPYING.GPLv2 for the terms)
> +include rockchip-mpp.inc
> +
> +TAG = "release_${PV}"
> +SRC_URI = "git://github.com/rockchip-linux/mpp.git;tag=${TAG};nobranch=1"
> +
> +S = "${WORKDIR}/git"
> diff --git a/recipes-multimedia/rockchip-mpp/rockchip-mpp_git.bb b/recipes-multimedia/rockchip-mpp/rockchip-mpp_git.bb
> new file mode 100644
> index 0000000..23f3f15
> --- /dev/null
> +++ b/recipes-multimedia/rockchip-mpp/rockchip-mpp_git.bb
> @@ -0,0 +1,16 @@
> +# Copyright (C) 2016 - 2017 Randy Li <ayaka@soulik.info>
> +# Released under the GNU GENERAL PUBLIC LICENSE Version 2
> +# (see COPYING.GPLv2 for the terms)
> +
> +DEFAULT_PREFERENCE = "-1"
> +
> +include rockchip-mpp.inc
> +DEPENDS = "git-replacement-native"
> +
> +FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
> +FILESPATH_prepend := "${THISDIR}/${PN}:"
> +
> +SRCREV = "${AUTOREV}"
> +SRC_URI = "git://github.com/rockchip-linux/mpp.git;branch=develop"
> +
> +S = "${WORKDIR}/git"
The rest looks good, I need to test it.

Re: [meta-rockchip] [PATCH v2 0/3] Add video codec recipes

[Romain Perier]

Hello,


Android video codec driver ? could you be more precise ? yocto/poky is
linux-based, we don't want

stuffs for android...


Trevor: what do you think about integrating this ?


ayaka:  Please Use a real name in the author of each commit and
signed-off-by your commits with You real name.


Thanks,

Romain


Le 12/04/2017 à 18:05, ayaka a écrit :
> Those packages are the userspace libraries for the Rockchip
> Android video codec driver.
>
> Also a minimal image used for verified the media framework is included.
>
> ayaka (3):
>   recipes-multimedia: add Rockchip MPP library
>   recipes-multimedia: add gstreamer rockchip support
>   recipes-multimedia: images: rockchip media image
>
>  .../gstreamer/gstreamer1.0-rockchip.inc            | 40 ++++++++++++++++++++++
>  .../gstreamer/gstreamer1.0-rockchip_20170412.bb    |  9 +++++
>  .../gstreamer/gstreamer1.0-rockchip_git.bb         | 13 +++++++
>  recipes-multimedia/images/rockchip-media-image.bb  | 21 ++++++++++++
>  recipes-multimedia/rockchip-mpp/rockchip-mpp.inc   | 21 ++++++++++++
>  .../rockchip-mpp/rockchip-mpp_20170412.bb          |  9 +++++
>  .../rockchip-mpp/rockchip-mpp_git.bb               | 16 +++++++++
>  7 files changed, 129 insertions(+)
>  create mode 100644 recipes-multimedia/gstreamer/gstreamer1.0-rockchip.inc
>  create mode 100644 recipes-multimedia/gstreamer/gstreamer1.0-rockchip_20170412.bb
>  create mode 100644 recipes-multimedia/gstreamer/gstreamer1.0-rockchip_git.bb
>  create mode 100644 recipes-multimedia/images/rockchip-media-image.bb
>  create mode 100644 recipes-multimedia/rockchip-mpp/rockchip-mpp.inc
>  create mode 100644 recipes-multimedia/rockchip-mpp/rockchip-mpp_20170412.bb
>  create mode 100644 recipes-multimedia/rockchip-mpp/rockchip-mpp_git.bb
>

Re: [meta-rockchip] [PATCH v2 2/3] recipes-multimedia: add gstreamer rockchip support

[Romain Perier]

Hello,


Le 12/04/2017 à 18:05, ayaka a écrit :
> This Gstreamer plugin provides a encoder and decoder plugin
> for Gstreamer through the Rockchip MPP library.
>
> Signed-off-by: ayaka <ayaka@soulik.info>
> ---
>  .../gstreamer/gstreamer1.0-rockchip.inc            | 40 ++++++++++++++++++++++
>  .../gstreamer/gstreamer1.0-rockchip_20170412.bb    |  9 +++++
>  .../gstreamer/gstreamer1.0-rockchip_git.bb         | 13 +++++++
>  3 files changed, 62 insertions(+)
>  create mode 100644 recipes-multimedia/gstreamer/gstreamer1.0-rockchip.inc
>  create mode 100644 recipes-multimedia/gstreamer/gstreamer1.0-rockchip_20170412.bb
>  create mode 100644 recipes-multimedia/gstreamer/gstreamer1.0-rockchip_git.bb
>
> diff --git a/recipes-multimedia/gstreamer/gstreamer1.0-rockchip.inc b/recipes-multimedia/gstreamer/gstreamer1.0-rockchip.inc
> new file mode 100644
> index 0000000..0bd70ab
> --- /dev/null
> +++ b/recipes-multimedia/gstreamer/gstreamer1.0-rockchip.inc
> @@ -0,0 +1,40 @@
> +# Copyright (C) 2016 - 2017 Randy Li <ayaka@soulik.info>
> +# Released under the GNU GENERAL PUBLIC LICENSE Version 2
> +# (see COPYING.GPLv2 for the terms)
> +
> +require recipes-multimedia/gstreamer/gstreamer1.0-plugins.inc
> +
> +DESCRIPTION = "GStreamer 1.0 plugins for Rockchip platforms"
> +
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=6d1e4aa87f6192354d3de840cf774d93"
> +DEPENDS += "gstreamer1.0-plugins-base rockchip-mpp"
> +
> +SRC_URI_remove = " \
> +    file://0001-introspection.m4-prefix-pkgconfig-paths-with-PKG_CON.patch \
I suggest to add a comment if you remove this patch (explain why)
> +"
> +
> +FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
> +FILESPATH_prepend := "${THISDIR}/${PN}:"
> +
> +inherit gettext autotools pkgconfig

autotools and pkgconfig are already inherited by gstreamer1.0-plugins.inc

> +
> +PACKAGECONFIG ??= " \
> +    mpp             \
> +"
> +PACKAGECONFIG[mpp]    = "--enable-rockchipmpp,--disable-rockchipmpp,rockchip-mpp"
> +PACKAGECONFIG[vpudec] = "--enable-vpudec,--disable-vpudec,rockchip-vpu"
> +PACKAGECONFIG[drm]    = "--enable-drmrockchip,--disable-drmrockchip,libdrm-rockchip"
> +PACKAGECONFIG[egl]    = "--enable-armmali,--disable-armmali,arm-mali"
> +
> +EXTRA_OECONF += "    \
> +    --disable-kms    \

Why do you disable kms ?

> +"
> +EXTRA_OECONF_remove = "--disable-gtk-doc"
> +
> +do_configure[prefuncs] = " delete_pkg_m4_file"
comments ?
> +
> +do_configure() {
> +    NOCONFIGURE=true ${S}/autogen.sh
> +    oe_runconf
> +}
> diff --git a/recipes-multimedia/gstreamer/gstreamer1.0-rockchip_20170412.bb b/recipes-multimedia/gstreamer/gstreamer1.0-rockchip_20170412.bb
> new file mode 100644
> index 0000000..e3fecaf
> --- /dev/null
> +++ b/recipes-multimedia/gstreamer/gstreamer1.0-rockchip_20170412.bb
> @@ -0,0 +1,9 @@
> +# Copyright (C) 2016 - 2017 Randy Li <ayaka@soulik.info>
> +# Released under the GNU GENERAL PUBLIC LICENSE Version 2
> +# (see COPYING.GPLv2 for the terms)
> +include gstreamer1.0-rockchip.inc
> +
> +TAG = "release_${PV}"
> +SRC_URI = "git://github.com/rockchip-linux/gstreamer-rockchip.git;tag=${TAG};nobranch=1"
> +
> +S = "${WORKDIR}/git"
> diff --git a/recipes-multimedia/gstreamer/gstreamer1.0-rockchip_git.bb b/recipes-multimedia/gstreamer/gstreamer1.0-rockchip_git.bb
> new file mode 100644
> index 0000000..bd20121
> --- /dev/null
> +++ b/recipes-multimedia/gstreamer/gstreamer1.0-rockchip_git.bb
> @@ -0,0 +1,13 @@
> +# Copyright (C) 2016 - 2017 Randy Li <ayaka@soulik.info>
> +# Released under the GNU GENERAL PUBLIC LICENSE Version 2
> +# (see COPYING.GPLv2 for the terms)
> +
> +DEFAULT_PREFERENCE = "-1"
What is this variable ?
> +
> +include gstreamer1.0-rockchip.inc
> +
> +SRCBRANCH ?= "develop"
> +SRCREV = "${AUTOREV}"
> +SRC_URI = "git://github.com/rockchip-linux/gstreamer-rockchip.git;branch=develop"
> +
> +S = "${WORKDIR}/git"

That's globally a good work, thanks for this, please send a v2 with
modifications, and include your real name in all patches.

Thanks,
Romain

Re: [meta-rockchip] [PATCH v2 3/3] recipes-multimedia: images: rockchip media image

[Romain Perier]

Hello,


Le 12/04/2017 à 18:05, ayaka a écrit :
> A image for debugging the hardware video encoder/decoder.
> I also use this image for developing the Gstreamer.
>
> Signed-off-by: ayaka <ayaka@soulik.info>
> ---
>  recipes-multimedia/images/rockchip-media-image.bb | 21 +++++++++++++++++++++
>  1 file changed, 21 insertions(+)
>  create mode 100644 recipes-multimedia/images/rockchip-media-image.bb
>
> diff --git a/recipes-multimedia/images/rockchip-media-image.bb b/recipes-multimedia/images/rockchip-media-image.bb
> new file mode 100644
> index 0000000..ea993c1
> --- /dev/null
> +++ b/recipes-multimedia/images/rockchip-media-image.bb
> @@ -0,0 +1,21 @@
> +# Copyright (C) 2017 Randy Li <ayaka@soulik.info>
> +# Released under the MIT license (see COPYING.MIT for the terms)
> +
> +include recipes-core/images/core-image-minimal.bb
> +
> +LICENSE = "MIT"
> +DESCRIPTION = "Multimedia image for Rockchip devices."
> +
> +IMAGE_FEATURES_append = " package-management ssh-server-dropbear"
> +IMAGE_INSTALL_append = " gdbserver gstreamer1.0-rockchip      \
> + gstreamer1.0-meta-base gstreamer1.0-meta-video gstreamer1.0-meta-audio \
> + gstreamer1.0-plugins-good-isomp4 gstreamer1.0-plugins-good-multifile \
> + gstreamer1.0-plugins-good-imagefreeze \
> + gstreamer1.0-plugins-bad-autoconvert  gstreamer1.0-plugins-bad-camerabin2 \
> + gstreamer1.0-plugins-bad-kmssink gstreamer1.0-plugins-bad-rawparse \
> + gstreamer1.0-plugins-bad-videoparsersbad \
> + gstreamer1.0-plugins-bad-mpegtsdemux \
> + gstreamer1.0-meta-debug \
> +"
> +
> +TOOLCHAIN_HOST_TASK += "nativesdk-cmake"
Clearly a NAK here. I don't want yet another image for this, that's a
bsp meta layer, it is supposed to contain the recipes and rules to
propose support for Rockchip SocS in in yocto/oe and its reference
distros. But it is also supposed to be minimal, I don't want "all the
world"  in meta-rockchip, to be honest :)

I am not fan to have recipes or rules for development...

Trevor, as a co-maintainer, what is your point about this ? (always welcome)

Regards,
Romain

Re: [meta-rockchip] [PATCH v2 2/3] recipes-multimedia: add gstreamer rockchip support

[Trevor Woerner]

On Sat 2017-05-13 @ 06:16:06 PM, Romain Perier wrote:
> > +DEFAULT_PREFERENCE = "-1"
> What is this variable ?

http://www.yoctoproject.org/docs/current/ref-manual/ref-manual.html#var-DEFAULT_PREFERENCE

Re: [meta-rockchip] [PATCH v2 2/3] recipes-multimedia: add gstreamer rockchip support

[Khem Raj]

On Wed, Apr 12, 2017 at 9:05 AM, ayaka <ayaka@soulik.info> wrote:
> +SRC_URI_remove = " \
> +    file://0001-introspection.m4-prefix-pkgconfig-paths-with-PKG_CON.patch \
> +"

i see that you are doing this change below in a function which probably
is ok but I see some duplication here. Either remove this patch and upstream
the change or adapt the patch for your recipe

> +
> +FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
> +FILESPATH_prepend := "${THISDIR}/${PN}:"
> +

this seems redundant

Re: [meta-rockchip] [PATCH v2 3/3] recipes-multimedia: images: rockchip media image

[Trevor Woerner]

On Sat 2017-05-13 @ 06:20:35 PM, Romain Perier wrote:
> Clearly a NAK here. I don't want yet another image for this, that's a
> bsp meta layer, it is supposed to contain the recipes and rules to
> propose support for Rockchip SocS in in yocto/oe and its reference
> distros. But it is also supposed to be minimal, I don't want "all the
> world"  in meta-rockchip, to be honest :)
> 
> I am not fan to have recipes or rules for development...
> 
> Trevor, as a co-maintainer, what is your point about this ? (always welcome)

It's not uncommon for BSP layers to include sample image recipes
(meta-raspberrypi, for example, includes rpi-test-image, rpi-basic-image, and
rpi-hwup-image). These sample images act as a sort of example, or
documentation for others to follow. They're a way to show off what can be
done.

This recipe could act as an example should anyone want to integrate gstreamer
support for a rockchip in their image (assuming this image builds and works).

I'm not opposed to it being there, as long as it's benign and works.

Re: [meta-rockchip] [PATCH v2 3/3] recipes-multimedia: images: rockchip media image

[Khem Raj]

On Mon, May 15, 2017 at 9:33 AM, Trevor Woerner <twoerner@gmail.com> wrote:
> On Sat 2017-05-13 @ 06:20:35 PM, Romain Perier wrote:
>> Clearly a NAK here. I don't want yet another image for this, that's a
>> bsp meta layer, it is supposed to contain the recipes and rules to
>> propose support for Rockchip SocS in in yocto/oe and its reference
>> distros. But it is also supposed to be minimal, I don't want "all the
>> world"  in meta-rockchip, to be honest :)
>>
>> I am not fan to have recipes or rules for development...
>>
>> Trevor, as a co-maintainer, what is your point about this ? (always welcome)
>
> It's not uncommon for BSP layers to include sample image recipes
> (meta-raspberrypi, for example, includes rpi-test-image, rpi-basic-image, and
> rpi-hwup-image). These sample images act as a sort of example, or
> documentation for others to follow. They're a way to show off what can be
> done.
>
> This recipe could act as an example should anyone want to integrate gstreamer
> support for a rockchip in their image (assuming this image builds and works).

you could also make a packagegroup and leave it there and let end user to
include the packagegroup in his/her image

>
> I'm not opposed to it being there, as long as it's benign and works.
> --
> _______________________________________________
> yocto mailing list
> yocto@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/yocto

Re: [meta-rockchip] [PATCH v2 3/3] recipes-multimedia: images: rockchip media image

[Andre McCurdy]

 On Mon, May 15, 2017 at 10:23 AM, Khem Raj <raj.khem@gmail.com> wrote:
> On Mon, May 15, 2017 at 9:33 AM, Trevor Woerner <twoerner@gmail.com> wrote:
>> On Sat 2017-05-13 @ 06:20:35 PM, Romain Perier wrote:
>>> Clearly a NAK here. I don't want yet another image for this, that's a
>>> bsp meta layer, it is supposed to contain the recipes and rules to
>>> propose support for Rockchip SocS in in yocto/oe and its reference
>>> distros. But it is also supposed to be minimal, I don't want "all the
>>> world"  in meta-rockchip, to be honest :)
>>>
>>> I am not fan to have recipes or rules for development...
>>>
>>> Trevor, as a co-maintainer, what is your point about this ? (always welcome)
>>
>> It's not uncommon for BSP layers to include sample image recipes
>> (meta-raspberrypi, for example, includes rpi-test-image, rpi-basic-image, and
>> rpi-hwup-image). These sample images act as a sort of example, or
>> documentation for others to follow. They're a way to show off what can be
>> done.
>>
>> This recipe could act as an example should anyone want to integrate gstreamer
>> support for a rockchip in their image (assuming this image builds and works).
>
> you could also make a packagegroup and leave it there and let end user to
> include the packagegroup in his/her image

It looks like the COMMERCIAL_AUDIO_PLUGINS and
COMMERCIAL_VIDEO_PLUGINS hooks could be used to add machine specific
plugins to the existing gstreamer1.0-meta-audio and
gstreamer1.0-meta-video package groups?

>>
>> I'm not opposed to it being there, as long as it's benign and works.
>> --
>> _______________________________________________
>> yocto mailing list
>> yocto@yoctoproject.org
>> https://lists.yoctoproject.org/listinfo/yocto
> --
> _______________________________________________
> yocto mailing list
> yocto@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/yocto