Re: [oe] [meta-oe][PATCH] firmwared: add recipe

["Khem Raj" <raj.khem@gmail.com>]

On Fri, Dec 4, 2020 at 9:05 AM Robert Karszniewicz
<r.karszniewicz@phytec.de> wrote:
>
> This program is needed for loading external firmware via Linux' fallback
> mechanism.
>

Please add it to packagegroup-meta-oe as well.

> Signed-off-by: Robert Karszniewicz <r.karszniewicz@phytec.de>
> ---
> I wasn't sure which subdirectory to put it in, but I picked recipes-bsp.
> Thanks.
>
>  .../firmwared/firmwared/firmwared.service          |  9 +++++++
>  meta-oe/recipes-bsp/firmwared/firmwared_git.bb     | 29 ++++++++++++++++++++++
>  2 files changed, 38 insertions(+)
>  create mode 100644 meta-oe/recipes-bsp/firmwared/firmwared/firmwared.service
>  create mode 100644 meta-oe/recipes-bsp/firmwared/firmwared_git.bb
>
> diff --git a/meta-oe/recipes-bsp/firmwared/firmwared/firmwared.service b/meta-oe/recipes-bsp/firmwared/firmwared/firmwared.service
> new file mode 100644
> index 000000000000..c2106a25168c
> --- /dev/null
> +++ b/meta-oe/recipes-bsp/firmwared/firmwared/firmwared.service
> @@ -0,0 +1,9 @@
> +[Unit]
> +Description=Linux Firmware Loader Daemon
> +
> +[Service]
> +Type=simple
> +ExecStart=@BINDIR@/firmwared -d /lib/firmware
> +
> +[Install]
> +WantedBy=multi-user.target
> diff --git a/meta-oe/recipes-bsp/firmwared/firmwared_git.bb b/meta-oe/recipes-bsp/firmwared/firmwared_git.bb
> new file mode 100644
> index 000000000000..3b2a8070bdd3
> --- /dev/null
> +++ b/meta-oe/recipes-bsp/firmwared/firmwared_git.bb
> @@ -0,0 +1,29 @@
> +SUMMARY = "Linux Firmware Loader Daemon"
> +DESCRIPTION = "The Linux Firmware Loader Daemon monitors the kernel for \
> +firmware requests and uploads the firmware blobs it has via the sysfs \
> +interface."
> +HOMEPAGE = "https://github.com/teg/firmwared"
> +PR = "r0"

remove PR setting

> +LICENSE = "Apache-2.0"
> +LIC_FILES_CHKSUM = "file://LICENSE-APACHE;md5=7b486c2338d225a1405d979ed2c15ce8 \
> +                    file://COPYING;md5=daa868b8e1ae17d03228a1145b4060da"
> +
> +SRC_URI = "git://github.com/teg/firmwared.git \
> +           file://firmwared.service"
> +
> +PV = "1+git${SRCPV}"

Lets start with 0+git.... if there is no official version released yet.

> +SRCREV = "2e6b5db43d63a5c0283a4cae9a6a20b7ad107a04"
> +
> +S = "${WORKDIR}/git"
> +
> +DEPENDS = "glib-2.0 systemd"

Does it depend on systemd at runtime ? if so lets also add

inherit features_check
REQUIRED_DISTRO_FEATURES = "systemd"

> +
> +inherit pkgconfig autotools systemd
> +
> +SYSTEMD_SERVICE_${PN} = "firmwared.service"
> +
> +do_install_append() {
> +    install -d ${D}${systemd_unitdir}/system
> +    install -m 0644 ${WORKDIR}/firmwared.service ${D}${systemd_unitdir}/system
> +    sed -i -e 's,@BINDIR@,${bindir},g' ${D}${systemd_unitdir}/system/firmwared.service
> +}
> --
> 2.7.4
>
>
> 
>