* [meta-fsl-arm][PATCH 0/5 v2] Easy use of LOCALVERSION
@ 2014-09-01 12:23 Otavio Salvador
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 1/5] fsl-kernel-localversion: Easy LOCALVERSION handling Otavio Salvador
` (4 more replies)
0 siblings, 5 replies; 11+ messages in thread
From: Otavio Salvador @ 2014-09-01 12:23 UTC (permalink / raw)
To: meta-freescale; +Cc: Otavio Salvador
This patchset includes the improvements I was discussing with Zhenhua
Luo about avoid code duplication among Layerscape and i.MX. In the
patches are included the meta-fsl-arm rework patches for the current
recipes.
Same rework can be done for meta-fsl-arm-extra.
Otavio Salvador (5):
fsl-kernel-localversion: Easy LOCALVERSION handling
linux-imx.inc: Use the new fsl-kernel-localversion class
fsl-u-boot-localversion: Easy LOCALVERSION handling
u-boot-fslc: Use the new fsl-u-boot-localversion class
u-boot-imx: Use the new fsl-u-boot-localversion class
classes/fsl-kernel-localversion.bbclass | 39 +++++++++++++++++++++
classes/fsl-u-boot-localversion.bbclass | 27 ++++++++++++++
recipes-bsp/u-boot/u-boot-fslc-mxsboot_2014.07.bb | 2 ++
recipes-bsp/u-boot/u-boot-fslc.inc | 3 +-
recipes-bsp/u-boot/u-boot-imx_2009.08.bb | 5 ++-
recipes-bsp/u-boot/u-boot-imx_2013.04.bb | 4 +++
recipes-kernel/linux/linux-imx.inc | 28 +--------------
7 files changed, 79 insertions(+), 29 deletions(-)
create mode 100644 classes/fsl-kernel-localversion.bbclass
create mode 100644 classes/fsl-u-boot-localversion.bbclass
--
1.7.10.4
^ permalink raw reply [flat|nested] 11+ messages in thread
* [meta-fsl-arm][PATCH v2 1/5] fsl-kernel-localversion: Easy LOCALVERSION handling
2014-09-01 12:23 [meta-fsl-arm][PATCH 0/5 v2] Easy use of LOCALVERSION Otavio Salvador
@ 2014-09-01 12:23 ` Otavio Salvador
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 2/5] linux-imx.inc: Use the new fsl-kernel-localversion class Otavio Salvador
` (3 subsequent siblings)
4 siblings, 0 replies; 11+ messages in thread
From: Otavio Salvador @ 2014-09-01 12:23 UTC (permalink / raw)
To: meta-freescale; +Cc: Otavio Salvador
This class allow for easy extending of kernel recipes to easy the
LOCALVERSION handling, allowing to reuse of code between different
kernel recipes
The following options are supported:
SCMVERSION Puts the Git hash in kernel local version
LOCALVERSION Value used in LOCALVERSION (default to '+fslc')
This about avoid code duplication among Layerscape and i.MX.
Change-Id: I3999dbdc2cb761063fe5f83dea65ddb14adec80c
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
---
classes/fsl-kernel-localversion.bbclass | 39 +++++++++++++++++++++++++++++++
1 file changed, 39 insertions(+)
create mode 100644 classes/fsl-kernel-localversion.bbclass
diff --git a/classes/fsl-kernel-localversion.bbclass b/classes/fsl-kernel-localversion.bbclass
new file mode 100644
index 0000000..bb4bdf5
--- /dev/null
+++ b/classes/fsl-kernel-localversion.bbclass
@@ -0,0 +1,39 @@
+# Freescale Kernel LOCALVERSION extension
+#
+# This allow to easy reuse of code between different kernel recipes
+#
+# The following options are supported:
+#
+# SCMVERSION Puts the Git hash in kernel local version
+# LOCALVERSION Value used in LOCALVERSION (default to '+fslc')
+#
+# Copyright 2014 (C) O.S. Systems Software LTDA.
+
+SCMVERSION ??= "y"
+LOCALVERSION ??= "+fslc"
+
+kernel_conf_variable() {
+ CONF_SED_SCRIPT="$CONF_SED_SCRIPT /CONFIG_$1[ =]/d;"
+ if test "$2" = "n"
+ then
+ echo "# CONFIG_$1 is not set" >> ${S}/.config
+ else
+ echo "CONFIG_$1=$2" >> ${S}/.config
+ fi
+}
+
+do_configure_prepend() {
+ echo "" > ${S}/.config
+ CONF_SED_SCRIPT=""
+
+ kernel_conf_variable LOCALVERSION "\"${LOCALVERSION}\""
+ kernel_conf_variable LOCALVERSION_AUTO y
+
+ sed -e "${CONF_SED_SCRIPT}" < '${WORKDIR}/defconfig' >> '${S}/.config'
+
+ if [ "${SCMVERSION}" = "y" ]; then
+ # Add GIT revision to the local version
+ head=`git rev-parse --verify --short HEAD 2> /dev/null`
+ printf "%s%s" +g $head > ${S}/.scmversion
+ fi
+}
--
1.7.10.4
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [meta-fsl-arm][PATCH v2 2/5] linux-imx.inc: Use the new fsl-kernel-localversion class
2014-09-01 12:23 [meta-fsl-arm][PATCH 0/5 v2] Easy use of LOCALVERSION Otavio Salvador
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 1/5] fsl-kernel-localversion: Easy LOCALVERSION handling Otavio Salvador
@ 2014-09-01 12:23 ` Otavio Salvador
2014-09-01 13:07 ` Fabio Estevam
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 3/5] fsl-u-boot-localversion: Easy LOCALVERSION handling Otavio Salvador
` (2 subsequent siblings)
4 siblings, 1 reply; 11+ messages in thread
From: Otavio Salvador @ 2014-09-01 12:23 UTC (permalink / raw)
To: meta-freescale; +Cc: Otavio Salvador
Change-Id: Ib571e17c250473b923b31837954942ca5bacb61b
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
---
recipes-kernel/linux/linux-imx.inc | 28 +---------------------------
1 file changed, 1 insertion(+), 27 deletions(-)
diff --git a/recipes-kernel/linux/linux-imx.inc b/recipes-kernel/linux/linux-imx.inc
index 47566b0..dd4540e 100644
--- a/recipes-kernel/linux/linux-imx.inc
+++ b/recipes-kernel/linux/linux-imx.inc
@@ -4,7 +4,7 @@
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
-inherit kernel
+inherit kernel fsl-kernel-localversion
# Put a local version until we have a true SRCREV to point to
LOCALVERSION ?= "+yocto"
@@ -19,29 +19,3 @@ S = "${WORKDIR}/git"
# We need to pass it as param since kernel might support more then one
# machine, with different entry points
KERNEL_EXTRA_ARGS += "LOADADDR=${UBOOT_ENTRYPOINT}"
-
-kernel_conf_variable() {
- CONF_SED_SCRIPT="$CONF_SED_SCRIPT /CONFIG_$1[ =]/d;"
- if test "$2" = "n"
- then
- echo "# CONFIG_$1 is not set" >> ${S}/.config
- else
- echo "CONFIG_$1=$2" >> ${S}/.config
- fi
-}
-
-do_configure_prepend() {
- echo "" > ${S}/.config
- CONF_SED_SCRIPT=""
-
- kernel_conf_variable LOCALVERSION "\"${LOCALVERSION}\""
- kernel_conf_variable LOCALVERSION_AUTO y
-
- sed -e "${CONF_SED_SCRIPT}" < '${WORKDIR}/defconfig' >> '${S}/.config'
-
- if [ "${SCMVERSION}" = "y" ]; then
- # Add GIT revision to the local version
- head=`git rev-parse --verify --short HEAD 2> /dev/null`
- printf "%s%s" +g $head > ${S}/.scmversion
- fi
-}
--
1.7.10.4
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [meta-fsl-arm][PATCH v2 3/5] fsl-u-boot-localversion: Easy LOCALVERSION handling
2014-09-01 12:23 [meta-fsl-arm][PATCH 0/5 v2] Easy use of LOCALVERSION Otavio Salvador
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 1/5] fsl-kernel-localversion: Easy LOCALVERSION handling Otavio Salvador
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 2/5] linux-imx.inc: Use the new fsl-kernel-localversion class Otavio Salvador
@ 2014-09-01 12:23 ` Otavio Salvador
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 4/5] u-boot-fslc: Use the new fsl-u-boot-localversion class Otavio Salvador
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 5/5] u-boot-imx: " Otavio Salvador
4 siblings, 0 replies; 11+ messages in thread
From: Otavio Salvador @ 2014-09-01 12:23 UTC (permalink / raw)
To: meta-freescale; +Cc: Otavio Salvador
This class allow for easy extending of U-Boot recipes to easy the
LOCALVERSION handling, allowing to reuse of code between different
U-Boot recipes
The following options are supported:
SCMVERSION Puts the Git hash in U-Boot local version
LOCALVERSION Value used in LOCALVERSION (default to '+fslc')
This about avoid code duplication among Layerscape and i.MX.
Change-Id: Icec618092d1f70606051619b6f6118f50e7f1ba5
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
---
classes/fsl-u-boot-localversion.bbclass | 27 +++++++++++++++++++++++++++
1 file changed, 27 insertions(+)
create mode 100644 classes/fsl-u-boot-localversion.bbclass
diff --git a/classes/fsl-u-boot-localversion.bbclass b/classes/fsl-u-boot-localversion.bbclass
new file mode 100644
index 0000000..f7e0971
--- /dev/null
+++ b/classes/fsl-u-boot-localversion.bbclass
@@ -0,0 +1,27 @@
+# Freescale U-Boot LOCALVERSION extension
+#
+# This allow to easy reuse of code between different U-Boot recipes
+#
+# The following options are supported:
+#
+# SCMVERSION Puts the Git hash in U-Boot local version
+# LOCALVERSION Value used in LOCALVERSION (default to '+fslc')
+#
+# Copyright 2014 (C) O.S. Systems Software LTDA.
+
+SCMVERSION ??= "y"
+LOCALVERSION ??= "+fslc"
+
+UBOOT_LOCALVERSION = "${LOCALVERSION}"
+
+do_compile_prepend() {
+ if [ "${SCMVERSION}" = "y" ]; then
+ # Add GIT revision to the local version
+ head=`git rev-parse --verify --short HEAD 2> /dev/null`
+ printf "%s%s%s" "${UBOOT_LOCALVERSION}" +g $head > ${S}/.scmversion
+ printf "%s%s%s" "${UBOOT_LOCALVERSION}" +g $head > ${B}/.scmversion
+ else
+ printf "%s" "${UBOOT_LOCALVERSION}" > ${S}/.scmversion
+ printf "%s" "${UBOOT_LOCALVERSION}" > ${B}/.scmversion
+ fi
+}
--
1.7.10.4
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [meta-fsl-arm][PATCH v2 4/5] u-boot-fslc: Use the new fsl-u-boot-localversion class
2014-09-01 12:23 [meta-fsl-arm][PATCH 0/5 v2] Easy use of LOCALVERSION Otavio Salvador
` (2 preceding siblings ...)
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 3/5] fsl-u-boot-localversion: Easy LOCALVERSION handling Otavio Salvador
@ 2014-09-01 12:23 ` Otavio Salvador
2014-09-01 13:06 ` Fabio Estevam
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 5/5] u-boot-imx: " Otavio Salvador
4 siblings, 1 reply; 11+ messages in thread
From: Otavio Salvador @ 2014-09-01 12:23 UTC (permalink / raw)
To: meta-freescale; +Cc: Otavio Salvador
Change-Id: Ic6089ffad89648ec5f3d2f8247e33fd5dd0e7fea
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
---
recipes-bsp/u-boot/u-boot-fslc-mxsboot_2014.07.bb | 2 ++
recipes-bsp/u-boot/u-boot-fslc.inc | 3 ++-
2 files changed, 4 insertions(+), 1 deletion(-)
diff --git a/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2014.07.bb b/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2014.07.bb
index 3a1c6e4..b009068 100644
--- a/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2014.07.bb
+++ b/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2014.07.bb
@@ -13,6 +13,8 @@ SRC_URI = "git://github.com/Freescale/u-boot-imx.git;branch=${SRCBRANCH}"
S = "${WORKDIR}/git"
+inherit fsl-u-boot-localversion
+
EXTRA_OEMAKE = 'HOSTCC="${CC} ${CPPFLAGS}" HOSTLDFLAGS="-L${libdir} -L${base_libdir}" HOSTSTRIP=true CONFIG_MX28=y'
do_compile () {
diff --git a/recipes-bsp/u-boot/u-boot-fslc.inc b/recipes-bsp/u-boot/u-boot-fslc.inc
index 4ed19d6..a1e4de8 100644
--- a/recipes-bsp/u-boot/u-boot-fslc.inc
+++ b/recipes-bsp/u-boot/u-boot-fslc.inc
@@ -3,6 +3,8 @@
require recipes-bsp/u-boot/u-boot.inc
+inherit fsl-u-boot-localversion
+
DESCRIPTION = "U-boot bootloader for Freescale ARM platforms"
LICENSE = "GPLv2+"
LIC_FILES_CHKSUM = "file://Licenses/README;md5=025bf9f768cbcb1a165dbe1a110babfb"
@@ -26,4 +28,3 @@ EXTRA_OEMAKE += 'HOSTCC="${BUILD_CC} ${BUILD_CPPFLAGS}" \
HOSTSTRIP=true'
PACKAGE_ARCH = "${MACHINE_ARCH}"
-
--
1.7.10.4
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [meta-fsl-arm][PATCH v2 5/5] u-boot-imx: Use the new fsl-u-boot-localversion class
2014-09-01 12:23 [meta-fsl-arm][PATCH 0/5 v2] Easy use of LOCALVERSION Otavio Salvador
` (3 preceding siblings ...)
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 4/5] u-boot-fslc: Use the new fsl-u-boot-localversion class Otavio Salvador
@ 2014-09-01 12:23 ` Otavio Salvador
2014-09-01 13:06 ` Fabio Estevam
2014-09-01 13:43 ` Daiane Angolini
4 siblings, 2 replies; 11+ messages in thread
From: Otavio Salvador @ 2014-09-01 12:23 UTC (permalink / raw)
To: meta-freescale; +Cc: Otavio Salvador
Change-Id: Ic7e26635908cefe28c340cd9885e1efa0a009a16
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
---
recipes-bsp/u-boot/u-boot-imx_2009.08.bb | 5 ++++-
recipes-bsp/u-boot/u-boot-imx_2013.04.bb | 4 ++++
2 files changed, 8 insertions(+), 1 deletion(-)
diff --git a/recipes-bsp/u-boot/u-boot-imx_2009.08.bb b/recipes-bsp/u-boot/u-boot-imx_2009.08.bb
index 393e7f3..7b31cc8 100644
--- a/recipes-bsp/u-boot/u-boot-imx_2009.08.bb
+++ b/recipes-bsp/u-boot/u-boot-imx_2009.08.bb
@@ -54,7 +54,9 @@ UBOOT_MAKE_TARGET = "u-boot.bin"
S = "${WORKDIR}/git"
EXTRA_OEMAKE += 'HOSTSTRIP=true'
-PACKAGE_ARCH = "${MACHINE_ARCH}"
+inherit fsl-u-boot-localversion
+
+LOCALVERSION = "+imx"
do_compile_prepend() {
if [ "${@base_contains('DISTRO_FEATURES', 'ld-is-gold', 'ld-is-gold', '', d)}" = "ld-is-gold" ] ; then
@@ -63,3 +65,4 @@ do_compile_prepend() {
}
COMPATIBLE_MACHINE = "(imx28evk|mx5|mx6)"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
diff --git a/recipes-bsp/u-boot/u-boot-imx_2013.04.bb b/recipes-bsp/u-boot/u-boot-imx_2013.04.bb
index 1c0f828..867f0ed 100644
--- a/recipes-bsp/u-boot/u-boot-imx_2013.04.bb
+++ b/recipes-bsp/u-boot/u-boot-imx_2013.04.bb
@@ -14,5 +14,9 @@ SRCREV = "ce0ea2507c492d43bbf88f8609482a171b2d2003"
S = "${WORKDIR}/git"
+inherit fsl-u-boot-localversion
+
+LOCALVERSION = "+imx"
+
PACKAGE_ARCH = "${MACHINE_ARCH}"
COMPATIBLE_MACHINE = "(mx6)"
--
1.7.10.4
^ permalink raw reply related [flat|nested] 11+ messages in thread
* Re: [meta-fsl-arm][PATCH v2 4/5] u-boot-fslc: Use the new fsl-u-boot-localversion class
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 4/5] u-boot-fslc: Use the new fsl-u-boot-localversion class Otavio Salvador
@ 2014-09-01 13:06 ` Fabio Estevam
0 siblings, 0 replies; 11+ messages in thread
From: Fabio Estevam @ 2014-09-01 13:06 UTC (permalink / raw)
To: Otavio Salvador; +Cc: meta-freescale
On Mon, Sep 1, 2014 at 9:23 AM, Otavio Salvador <otavio@ossystems.com.br> wrote:
> Change-Id: Ic6089ffad89648ec5f3d2f8247e33fd5dd0e7fea
No commit log?
> Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
^ permalink raw reply [flat|nested] 11+ messages in thread
* Re: [meta-fsl-arm][PATCH v2 5/5] u-boot-imx: Use the new fsl-u-boot-localversion class
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 5/5] u-boot-imx: " Otavio Salvador
@ 2014-09-01 13:06 ` Fabio Estevam
2014-09-01 13:43 ` Daiane Angolini
1 sibling, 0 replies; 11+ messages in thread
From: Fabio Estevam @ 2014-09-01 13:06 UTC (permalink / raw)
To: Otavio Salvador; +Cc: meta-freescale
On Mon, Sep 1, 2014 at 9:23 AM, Otavio Salvador <otavio@ossystems.com.br> wrote:
> Change-Id: Ic7e26635908cefe28c340cd9885e1efa0a009a16
No commit log?
> Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
^ permalink raw reply [flat|nested] 11+ messages in thread
* Re: [meta-fsl-arm][PATCH v2 2/5] linux-imx.inc: Use the new fsl-kernel-localversion class
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 2/5] linux-imx.inc: Use the new fsl-kernel-localversion class Otavio Salvador
@ 2014-09-01 13:07 ` Fabio Estevam
0 siblings, 0 replies; 11+ messages in thread
From: Fabio Estevam @ 2014-09-01 13:07 UTC (permalink / raw)
To: Otavio Salvador; +Cc: meta-freescale
On Mon, Sep 1, 2014 at 9:23 AM, Otavio Salvador <otavio@ossystems.com.br> wrote:
> Change-Id: Ib571e17c250473b923b31837954942ca5bacb61b
No commit log?
> Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
^ permalink raw reply [flat|nested] 11+ messages in thread
* Re: [meta-fsl-arm][PATCH v2 5/5] u-boot-imx: Use the new fsl-u-boot-localversion class
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 5/5] u-boot-imx: " Otavio Salvador
2014-09-01 13:06 ` Fabio Estevam
@ 2014-09-01 13:43 ` Daiane Angolini
2014-09-01 13:55 ` Otavio Salvador
1 sibling, 1 reply; 11+ messages in thread
From: Daiane Angolini @ 2014-09-01 13:43 UTC (permalink / raw)
To: Otavio Salvador; +Cc: meta-freescale
On Mon, Sep 1, 2014 at 9:23 AM, Otavio Salvador <otavio@ossystems.com.br> wrote:
> Change-Id: Ic7e26635908cefe28c340cd9885e1efa0a009a16
> Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
> ---
> recipes-bsp/u-boot/u-boot-imx_2009.08.bb | 5 ++++-
> recipes-bsp/u-boot/u-boot-imx_2013.04.bb | 4 ++++
> 2 files changed, 8 insertions(+), 1 deletion(-)
>
> diff --git a/recipes-bsp/u-boot/u-boot-imx_2009.08.bb b/recipes-bsp/u-boot/u-boot-imx_2009.08.bb
> index 393e7f3..7b31cc8 100644
> --- a/recipes-bsp/u-boot/u-boot-imx_2009.08.bb
> +++ b/recipes-bsp/u-boot/u-boot-imx_2009.08.bb
> @@ -54,7 +54,9 @@ UBOOT_MAKE_TARGET = "u-boot.bin"
> S = "${WORKDIR}/git"
> EXTRA_OEMAKE += 'HOSTSTRIP=true'
>
> -PACKAGE_ARCH = "${MACHINE_ARCH}"
Why are you removing PACKAGE_ARCH from here?
Daiane
> +inherit fsl-u-boot-localversion
> +
> +LOCALVERSION = "+imx"
>
> do_compile_prepend() {
> if [ "${@base_contains('DISTRO_FEATURES', 'ld-is-gold', 'ld-is-gold', '', d)}" = "ld-is-gold" ] ; then
> @@ -63,3 +65,4 @@ do_compile_prepend() {
> }
>
> COMPATIBLE_MACHINE = "(imx28evk|mx5|mx6)"
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> diff --git a/recipes-bsp/u-boot/u-boot-imx_2013.04.bb b/recipes-bsp/u-boot/u-boot-imx_2013.04.bb
> index 1c0f828..867f0ed 100644
> --- a/recipes-bsp/u-boot/u-boot-imx_2013.04.bb
> +++ b/recipes-bsp/u-boot/u-boot-imx_2013.04.bb
> @@ -14,5 +14,9 @@ SRCREV = "ce0ea2507c492d43bbf88f8609482a171b2d2003"
>
> S = "${WORKDIR}/git"
>
> +inherit fsl-u-boot-localversion
> +
> +LOCALVERSION = "+imx"
> +
> PACKAGE_ARCH = "${MACHINE_ARCH}"
> COMPATIBLE_MACHINE = "(mx6)"
> --
> 1.7.10.4
>
> --
> _______________________________________________
> meta-freescale mailing list
> meta-freescale@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-freescale
^ permalink raw reply [flat|nested] 11+ messages in thread
* Re: [meta-fsl-arm][PATCH v2 5/5] u-boot-imx: Use the new fsl-u-boot-localversion class
2014-09-01 13:43 ` Daiane Angolini
@ 2014-09-01 13:55 ` Otavio Salvador
0 siblings, 0 replies; 11+ messages in thread
From: Otavio Salvador @ 2014-09-01 13:55 UTC (permalink / raw)
To: Daiane Angolini; +Cc: meta-freescale
On Mon, Sep 1, 2014 at 10:43 AM, Daiane Angolini <daiane.list@gmail.com> wrote:
> On Mon, Sep 1, 2014 at 9:23 AM, Otavio Salvador <otavio@ossystems.com.br> wrote:
>> Change-Id: Ic7e26635908cefe28c340cd9885e1efa0a009a16
>> Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
>> ---
>> recipes-bsp/u-boot/u-boot-imx_2009.08.bb | 5 ++++-
>> recipes-bsp/u-boot/u-boot-imx_2013.04.bb | 4 ++++
>> 2 files changed, 8 insertions(+), 1 deletion(-)
>>
>> diff --git a/recipes-bsp/u-boot/u-boot-imx_2009.08.bb b/recipes-bsp/u-boot/u-boot-imx_2009.08.bb
>> index 393e7f3..7b31cc8 100644
>> --- a/recipes-bsp/u-boot/u-boot-imx_2009.08.bb
>> +++ b/recipes-bsp/u-boot/u-boot-imx_2009.08.bb
>> @@ -54,7 +54,9 @@ UBOOT_MAKE_TARGET = "u-boot.bin"
>> S = "${WORKDIR}/git"
>> EXTRA_OEMAKE += 'HOSTSTRIP=true'
>>
>> -PACKAGE_ARCH = "${MACHINE_ARCH}"
>
> Why are you removing PACKAGE_ARCH from here?
>
> Daiane
>> +inherit fsl-u-boot-localversion
>> +
>> +LOCALVERSION = "+imx"
>>
>> do_compile_prepend() {
>> if [ "${@base_contains('DISTRO_FEATURES', 'ld-is-gold', 'ld-is-gold', '', d)}" = "ld-is-gold" ] ; then
>> @@ -63,3 +65,4 @@ do_compile_prepend() {
>> }
>>
>> COMPATIBLE_MACHINE = "(imx28evk|mx5|mx6)"
>> +PACKAGE_ARCH = "${MACHINE_ARCH}"
It was moved to the end of the file.
--
Otavio Salvador O.S. Systems
http://www.ossystems.com.br http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854 Mobile: +1 (347) 903-9750
^ permalink raw reply [flat|nested] 11+ messages in thread
end of thread, other threads:[~2014-09-01 13:55 UTC | newest]
Thread overview: 11+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2014-09-01 12:23 [meta-fsl-arm][PATCH 0/5 v2] Easy use of LOCALVERSION Otavio Salvador
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 1/5] fsl-kernel-localversion: Easy LOCALVERSION handling Otavio Salvador
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 2/5] linux-imx.inc: Use the new fsl-kernel-localversion class Otavio Salvador
2014-09-01 13:07 ` Fabio Estevam
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 3/5] fsl-u-boot-localversion: Easy LOCALVERSION handling Otavio Salvador
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 4/5] u-boot-fslc: Use the new fsl-u-boot-localversion class Otavio Salvador
2014-09-01 13:06 ` Fabio Estevam
2014-09-01 12:23 ` [meta-fsl-arm][PATCH v2 5/5] u-boot-imx: " Otavio Salvador
2014-09-01 13:06 ` Fabio Estevam
2014-09-01 13:43 ` Daiane Angolini
2014-09-01 13:55 ` Otavio Salvador
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.