* [meta-fsl-arm][PATCH v2 1/3] amd-gpu-x11-bin-mx51: only enable when x11 is in DISTRO_FEATURES
@ 2013-05-28 19:24 Eric Bénard
2013-05-28 19:24 ` [meta-fsl-arm][PATCH v2 2/3] amd-gpu-x11-bin-mx51: factorize the recipes Eric Bénard
` (2 more replies)
0 siblings, 3 replies; 5+ messages in thread
From: Eric Bénard @ 2013-05-28 19:24 UTC (permalink / raw)
To: meta-freescale
this prevent warnings and parse errors
Signed-off-by: Eric Bénard <eric@eukrea.com>
---
recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
index 2dee47a..8c3557b 100644
--- a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
+++ b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
@@ -84,5 +84,5 @@ FILES_lib2dz160-mx51-dbg = "${libdir}/.debug/lib2dz160${SOLIBS}"
FILES_lib2dz430-mx51 = "${libdir}/lib2dz430${SOLIBS}"
FILES_lib2dz430-mx51-dbg = "${libdir}/.debug/lib2dz430${SOLIBS}"
-COMPATIBLE_MACHINE = "(mx5)"
+COMPATIBLE_MACHINE = "{@base_contains('DISTRO_FEATURES', 'x11', '(mx5)', '', d)}"
PACKAGE_ARCH = "${MACHINE_ARCH}"
--
1.7.10.4
^ permalink raw reply related [flat|nested] 5+ messages in thread
* [meta-fsl-arm][PATCH v2 2/3] amd-gpu-x11-bin-mx51: factorize the recipes
2013-05-28 19:24 [meta-fsl-arm][PATCH v2 1/3] amd-gpu-x11-bin-mx51: only enable when x11 is in DISTRO_FEATURES Eric Bénard
@ 2013-05-28 19:24 ` Eric Bénard
2013-05-28 19:24 ` [meta-fsl-arm][PATCH v2 3/3] amd-gpu-bin-mx51: new recipe Eric Bénard
2013-05-29 17:34 ` [meta-fsl-arm][PATCH v2 1/3] amd-gpu-x11-bin-mx51: only enable when x11 is in DISTRO_FEATURES Otavio Salvador
2 siblings, 0 replies; 5+ messages in thread
From: Eric Bénard @ 2013-05-28 19:24 UTC (permalink / raw)
To: meta-freescale
this will allow easier addition of non x11 package
Signed-off-by: Eric Bénard <eric@eukrea.com>
---
recipes-graphics/amd-gpu-x11-bin/amd-gpu-mx51.inc | 82 ++++++++++++++++++++
.../amd-gpu-x11-bin-mx51_11.09.01.bb | 75 +-----------------
.../fix-linux-build-check.patch | 0
3 files changed, 84 insertions(+), 73 deletions(-)
create mode 100644 recipes-graphics/amd-gpu-x11-bin/amd-gpu-mx51.inc
rename recipes-graphics/amd-gpu-x11-bin/{amd-gpu-x11-bin-mx51 => files}/fix-linux-build-check.patch (100%)
diff --git a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-mx51.inc b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-mx51.inc
new file mode 100644
index 0000000..b081695
--- /dev/null
+++ b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-mx51.inc
@@ -0,0 +1,82 @@
+# Copyright (C) 2011, 2012 Freescale
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+LICENSE = "Proprietary"
+SECTION = "libs"
+
+# FIXME: Replace for correct AMD license
+LIC_FILES_CHKSUM = "file://usr/include/VG/openvg.h;endline=30;md5=b0109611dd76961057d4c45ae6519802"
+
+PROVIDES = "virtual/egl virtual/libgles1 virtual/libgles2"
+
+SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true \
+ file://fix-linux-build-check.patch"
+
+inherit fsl-eula-unpack
+
+# FIXME: All binaries lack GNU_HASH in elf binary but as we don't have
+# the source we cannot fix it. Disable the insane check for now.
+python populate_packages_prepend() {
+ for p in d.getVar('PACKAGES', True).split():
+ d.setVar("INSANE_SKIP_%s" % p, "ldflags")
+}
+
+do_install () {
+ install -d ${D}${libdir}
+ install -d ${D}${bindir}
+ install -d ${D}${includedir}
+
+ cp -axr ${S}/usr/bin/* ${D}${bindir}
+ cp -axf ${S}/usr/lib/* ${D}${libdir}
+ cp -axr ${S}/usr/include/* ${D}${includedir}
+
+ find ${D}${bindir} -type f -exec chmod 755 {} \;
+ find ${D}${libdir} -type f -exec chmod 644 {} \;
+ find ${D}${includedir} -type f -exec chmod 644 {} \;
+
+ # FIXME: Fix sonames of broken libraries
+ mv ${D}${libdir}/lib2dz160.so ${D}${libdir}/lib2dz160.so.0
+ mv ${D}${libdir}/lib2dz430.so ${D}${libdir}/lib2dz430.so.0
+
+ # FIXME: Remove unkown files
+ rm -r ${D}${libdir}/libcsi.a \
+ ${D}${libdir}/libres.a
+}
+
+PACKAGES =+ "libgsl-fsl-mx51 libgsl-fsl-mx51-dev libgsl-fsl-mx51-dbg \
+ libegl-mx51 libegl-mx51-dev libegl-mx51-dbg \
+ libgles-mx51 libgles-mx51-dev libgles-mx51-dbg \
+ libgles2-mx51 libgles2-mx51-dev libgles2-mx51-dbg \
+ libopenvg-mx51 libopenvg-mx51-dev libopenvg-mx51-dbg \
+ lib2dz160-mx51 lib2dz160-mx51-dbg \
+ lib2dz430-mx51 lib2dz430-mx51-dbg"
+
+FILES_${PN}-dbg = "${bindir}/.debug/*"
+
+FILES_libgsl-fsl-mx51 = "${libdir}/libgsl-fsl${SOLIBS}"
+FILES_libgsl-fsl-mx51-dev = "${libdir}/libgsl-fsl${SOLIBSDEV}"
+FILES_libgsl-fsl-mx51-dbg = "${libdir}/.debug/libgsl-fsl${SOLIBS}"
+
+FILES_libegl-mx51 = "${libdir}/libEGL${SOLIBS}"
+FILES_libegl-mx51-dev = "${includedir}/EGL ${includedir}/KHR ${libdir}/libEGL${SOLIBSDEV}"
+FILES_libegl-mx51-dbg = "${libdir}/.debug/libEGL${SOLIBS}"
+
+FILES_libgles-mx51 = "${libdir}/libGLESv1*${SOLIBS}"
+FILES_libgles-mx51-dev = "${includedir}/GLES ${libdir}/libGLESv1*${SOLIBSDEV}"
+FILES_libgles-mx51-dbg = "${libdir}/.debug/libGLESv1*${SOLIBS}"
+
+FILES_libgles2-mx51 = "${libdir}/libGLESv2${SOLIBS}"
+FILES_libgles2-mx51-dev = "${includedir}/GLES2 ${libdir}/libGLESv2${SOLIBSDEV}"
+FILES_libgles2-mx51-dbg = "${libdir}/.debug/libGLESv2${SOLIBS}"
+
+FILES_libopenvg-mx51 = "${libdir}/libOpenVG${SOLIBS}"
+FILES_libopenvg-mx51-dev = "${includedir}/VG ${libdir}/libOpenVG${SOLIBSDEV}"
+FILES_libopenvg-mx51-dbg = "${libdir}/.debug/libOpenVG${SOLIBS}"
+
+FILES_lib2dz160-mx51 = "${libdir}/lib2dz160${SOLIBS}"
+FILES_lib2dz160-mx51-dbg = "${libdir}/.debug/lib2dz160${SOLIBS}"
+
+FILES_lib2dz430-mx51 = "${libdir}/lib2dz430${SOLIBS}"
+FILES_lib2dz430-mx51-dbg = "${libdir}/.debug/lib2dz430${SOLIBS}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
diff --git a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
index 8c3557b..68f472d 100644
--- a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
+++ b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
@@ -2,87 +2,16 @@
# Released under the MIT license (see COPYING.MIT for the terms)
DESCRIPTION = "GPU driver and apps for x11 on mx51"
-LICENSE = "Proprietary"
-SECTION = "libs"
PR = "r12"
# FIXME: Replace for correct AMD license
LIC_FILES_CHKSUM = "file://usr/include/VG/openvg.h;endline=30;md5=b0109611dd76961057d4c45ae6519802"
DEPENDS = "virtual/libx11 libxrender"
-PROVIDES = "virtual/egl virtual/libgles1 virtual/libgles2"
+include amd-gpu-mx51.inc
-SRC_URI = "${FSL_MIRROR}/amd-gpu-x11-bin-mx51-${PV}.bin;fsl-eula=true \
- file://fix-linux-build-check.patch"
SRC_URI[md5sum] = "54391a4e670b597d06d01253fb217cad"
SRC_URI[sha256sum] = "c7a6fa03b7aa2a375556c59908876554ba720c1e744baba2debb84a408f790db"
-inherit fsl-eula-unpack
-
-# FIXME: All binaries lack GNU_HASH in elf binary but as we don't have
-# the source we cannot fix it. Disable the insane check for now.
-python populate_packages_prepend() {
- for p in d.getVar('PACKAGES', True).split():
- d.setVar("INSANE_SKIP_%s" % p, "ldflags")
-}
-
-do_install () {
- install -d ${D}${libdir}
- install -d ${D}${bindir}
- install -d ${D}${includedir}
-
- cp -axr ${S}/usr/bin/* ${D}${bindir}
- cp -axf ${S}/usr/lib/* ${D}${libdir}
- cp -axr ${S}/usr/include/* ${D}${includedir}
-
- find ${D}${bindir} -type f -exec chmod 755 {} \;
- find ${D}${libdir} -type f -exec chmod 644 {} \;
- find ${D}${includedir} -type f -exec chmod 644 {} \;
-
- # FIXME: Fix sonames of broken libraries
- mv ${D}${libdir}/lib2dz160.so ${D}${libdir}/lib2dz160.so.0
- mv ${D}${libdir}/lib2dz430.so ${D}${libdir}/lib2dz430.so.0
-
- # FIXME: Remove unkown files
- rm -r ${D}${libdir}/libcsi.a \
- ${D}${libdir}/libres.a
-}
-
-PACKAGES =+ "libgsl-fsl-mx51 libgsl-fsl-mx51-dev libgsl-fsl-mx51-dbg \
- libegl-mx51 libegl-mx51-dev libegl-mx51-dbg \
- libgles-mx51 libgles-mx51-dev libgles-mx51-dbg \
- libgles2-mx51 libgles2-mx51-dev libgles2-mx51-dbg \
- libopenvg-mx51 libopenvg-mx51-dev libopenvg-mx51-dbg \
- lib2dz160-mx51 lib2dz160-mx51-dbg \
- lib2dz430-mx51 lib2dz430-mx51-dbg"
-
-FILES_${PN}-dbg = "${bindir}/.debug/*"
-
-FILES_libgsl-fsl-mx51 = "${libdir}/libgsl-fsl${SOLIBS}"
-FILES_libgsl-fsl-mx51-dev = "${libdir}/libgsl-fsl${SOLIBSDEV}"
-FILES_libgsl-fsl-mx51-dbg = "${libdir}/.debug/libgsl-fsl${SOLIBS}"
-
-FILES_libegl-mx51 = "${libdir}/libEGL${SOLIBS}"
-FILES_libegl-mx51-dev = "${includedir}/EGL ${includedir}/KHR ${libdir}/libEGL${SOLIBSDEV}"
-FILES_libegl-mx51-dbg = "${libdir}/.debug/libEGL${SOLIBS}"
-
-FILES_libgles-mx51 = "${libdir}/libGLESv1*${SOLIBS}"
-FILES_libgles-mx51-dev = "${includedir}/GLES ${libdir}/libGLESv1*${SOLIBSDEV}"
-FILES_libgles-mx51-dbg = "${libdir}/.debug/libGLESv1*${SOLIBS}"
-
-FILES_libgles2-mx51 = "${libdir}/libGLESv2${SOLIBS}"
-FILES_libgles2-mx51-dev = "${includedir}/GLES2 ${libdir}/libGLESv2${SOLIBSDEV}"
-FILES_libgles2-mx51-dbg = "${libdir}/.debug/libGLESv2${SOLIBS}"
-
-FILES_libopenvg-mx51 = "${libdir}/libOpenVG${SOLIBS}"
-FILES_libopenvg-mx51-dev = "${includedir}/VG ${libdir}/libOpenVG${SOLIBSDEV}"
-FILES_libopenvg-mx51-dbg = "${libdir}/.debug/libOpenVG${SOLIBS}"
-
-FILES_lib2dz160-mx51 = "${libdir}/lib2dz160${SOLIBS}"
-FILES_lib2dz160-mx51-dbg = "${libdir}/.debug/lib2dz160${SOLIBS}"
-
-FILES_lib2dz430-mx51 = "${libdir}/lib2dz430${SOLIBS}"
-FILES_lib2dz430-mx51-dbg = "${libdir}/.debug/lib2dz430${SOLIBS}"
-
COMPATIBLE_MACHINE = "{@base_contains('DISTRO_FEATURES', 'x11', '(mx5)', '', d)}"
-PACKAGE_ARCH = "${MACHINE_ARCH}"
+
diff --git a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51/fix-linux-build-check.patch b/recipes-graphics/amd-gpu-x11-bin/files/fix-linux-build-check.patch
similarity index 100%
rename from recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51/fix-linux-build-check.patch
rename to recipes-graphics/amd-gpu-x11-bin/files/fix-linux-build-check.patch
--
1.7.10.4
^ permalink raw reply related [flat|nested] 5+ messages in thread
* [meta-fsl-arm][PATCH v2 3/3] amd-gpu-bin-mx51: new recipe
2013-05-28 19:24 [meta-fsl-arm][PATCH v2 1/3] amd-gpu-x11-bin-mx51: only enable when x11 is in DISTRO_FEATURES Eric Bénard
2013-05-28 19:24 ` [meta-fsl-arm][PATCH v2 2/3] amd-gpu-x11-bin-mx51: factorize the recipes Eric Bénard
@ 2013-05-28 19:24 ` Eric Bénard
2013-05-29 17:36 ` Otavio Salvador
2013-05-29 17:34 ` [meta-fsl-arm][PATCH v2 1/3] amd-gpu-x11-bin-mx51: only enable when x11 is in DISTRO_FEATURES Otavio Salvador
2 siblings, 1 reply; 5+ messages in thread
From: Eric Bénard @ 2013-05-28 19:24 UTC (permalink / raw)
To: meta-freescale
this provides the GPU libraries for framebuffer
Signed-off-by: Eric Bénard <eric@eukrea.com>
---
.../amd-gpu-x11-bin/amd-gpu-bin-mx51_11.09.01.bb | 15 +++++++++++++++
.../amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb | 2 ++
2 files changed, 17 insertions(+)
create mode 100644 recipes-graphics/amd-gpu-x11-bin/amd-gpu-bin-mx51_11.09.01.bb
diff --git a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-bin-mx51_11.09.01.bb b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-bin-mx51_11.09.01.bb
new file mode 100644
index 0000000..442bacc
--- /dev/null
+++ b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-bin-mx51_11.09.01.bb
@@ -0,0 +1,15 @@
+# Copyright (C) 2011, 2012 Freescale
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "GPU driver and apps for frambuffer on mx51"
+
+PR = "r0"
+
+RCONFLICTS_${PN} = "amd-gpu-x11-bin-mx51"
+
+include amd-gpu-mx51.inc
+
+SRC_URI[md5sum] = "9f9b5f67b595721a08793aae8bd8fc46"
+SRC_URI[sha256sum] = "f0db68a764b5fb199729e7435f606b8d12b61ca97990336c647b7e81f4a584d9"
+
+COMPATIBLE_MACHINE = "(mx5)"
diff --git a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
index 68f472d..6502c2e 100644
--- a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
+++ b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
@@ -8,6 +8,8 @@ PR = "r12"
LIC_FILES_CHKSUM = "file://usr/include/VG/openvg.h;endline=30;md5=b0109611dd76961057d4c45ae6519802"
DEPENDS = "virtual/libx11 libxrender"
+RCONFLICTS_${PN} = "amd-gpu-bin-mx51"
+
include amd-gpu-mx51.inc
SRC_URI[md5sum] = "54391a4e670b597d06d01253fb217cad"
--
1.7.10.4
^ permalink raw reply related [flat|nested] 5+ messages in thread
* Re: [meta-fsl-arm][PATCH v2 1/3] amd-gpu-x11-bin-mx51: only enable when x11 is in DISTRO_FEATURES
2013-05-28 19:24 [meta-fsl-arm][PATCH v2 1/3] amd-gpu-x11-bin-mx51: only enable when x11 is in DISTRO_FEATURES Eric Bénard
2013-05-28 19:24 ` [meta-fsl-arm][PATCH v2 2/3] amd-gpu-x11-bin-mx51: factorize the recipes Eric Bénard
2013-05-28 19:24 ` [meta-fsl-arm][PATCH v2 3/3] amd-gpu-bin-mx51: new recipe Eric Bénard
@ 2013-05-29 17:34 ` Otavio Salvador
2 siblings, 0 replies; 5+ messages in thread
From: Otavio Salvador @ 2013-05-29 17:34 UTC (permalink / raw)
To: Eric Bénard; +Cc: meta-freescale
[-- Attachment #1: Type: text/plain, Size: 1317 bytes --]
On Tue, May 28, 2013 at 4:24 PM, Eric Bénard <eric@eukrea.com> wrote:
> this prevent warnings and parse errors
>
> Signed-off-by: Eric Bénard <eric@eukrea.com>
> ---
> recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb | 2
> +-
> 1 file changed, 1 insertion(+), 1 deletion(-)
>
> diff --git a/recipes-graphics/amd-gpu-x11-bin/
> amd-gpu-x11-bin-mx51_11.09.01.bb b/recipes-graphics/amd-gpu-x11-bin/
> amd-gpu-x11-bin-mx51_11.09.01.bb
> index 2dee47a..8c3557b 100644
> --- a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
> +++ b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
> @@ -84,5 +84,5 @@ FILES_lib2dz160-mx51-dbg =
> "${libdir}/.debug/lib2dz160${SOLIBS}"
> FILES_lib2dz430-mx51 = "${libdir}/lib2dz430${SOLIBS}"
> FILES_lib2dz430-mx51-dbg = "${libdir}/.debug/lib2dz430${SOLIBS}"
>
> -COMPATIBLE_MACHINE = "(mx5)"
> +COMPATIBLE_MACHINE = "{@base_contains('DISTRO_FEATURES', 'x11', '(mx5)',
> '', d)}"
> PACKAGE_ARCH = "${MACHINE_ARCH}"
>
This is wrong; you need '${@...}' convention for the inline python code to
be run.
--
Otavio Salvador O.S. Systems
http://www.ossystems.com.br http://projetos.ossystems.com.br
Mobile: +55 (53) 9981-7854 Mobile: +1 (347) 903-9750
[-- Attachment #2: Type: text/html, Size: 2393 bytes --]
^ permalink raw reply [flat|nested] 5+ messages in thread
* Re: [meta-fsl-arm][PATCH v2 3/3] amd-gpu-bin-mx51: new recipe
2013-05-28 19:24 ` [meta-fsl-arm][PATCH v2 3/3] amd-gpu-bin-mx51: new recipe Eric Bénard
@ 2013-05-29 17:36 ` Otavio Salvador
0 siblings, 0 replies; 5+ messages in thread
From: Otavio Salvador @ 2013-05-29 17:36 UTC (permalink / raw)
To: Eric Bénard; +Cc: meta-freescale
[-- Attachment #1: Type: text/plain, Size: 2447 bytes --]
On Tue, May 28, 2013 at 4:24 PM, Eric Bénard <eric@eukrea.com> wrote:
> this provides the GPU libraries for framebuffer
>
> Signed-off-by: Eric Bénard <eric@eukrea.com>
> ---
> .../amd-gpu-x11-bin/amd-gpu-bin-mx51_11.09.01.bb | 15
> +++++++++++++++
> .../amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb | 2 ++
> 2 files changed, 17 insertions(+)
> create mode 100644 recipes-graphics/amd-gpu-x11-bin/
> amd-gpu-bin-mx51_11.09.01.bb
>
> diff --git a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-bin-mx51_11.09.01.bbb/recipes-graphics/amd-gpu-x11-bin/
> amd-gpu-bin-mx51_11.09.01.bb
> new file mode 100644
> index 0000000..442bacc
> --- /dev/null
> +++ b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-bin-mx51_11.09.01.bb
> @@ -0,0 +1,15 @@
> +# Copyright (C) 2011, 2012 Freescale
> +# Released under the MIT license (see COPYING.MIT for the terms)
> +
> +DESCRIPTION = "GPU driver and apps for frambuffer on mx51"
> +
> +PR = "r0"
>
This is not needed anymore as we use PRServer now.
> +RCONFLICTS_${PN} = "amd-gpu-x11-bin-mx51"
>
This should be moved after SRC_URI as it is a runtime thing.
> +include amd-gpu-mx51.inc
> +
> +SRC_URI[md5sum] = "9f9b5f67b595721a08793aae8bd8fc46"
> +SRC_URI[sha256sum] =
> "f0db68a764b5fb199729e7435f606b8d12b61ca97990336c647b7e81f4a584d9"
> +
> +COMPATIBLE_MACHINE = "(mx5)"
> diff --git a/recipes-graphics/amd-gpu-x11-bin/
> amd-gpu-x11-bin-mx51_11.09.01.bb b/recipes-graphics/amd-gpu-x11-bin/
> amd-gpu-x11-bin-mx51_11.09.01.bb
> index 68f472d..6502c2e 100644
> --- a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
> +++ b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
> @@ -8,6 +8,8 @@ PR = "r12"
> LIC_FILES_CHKSUM =
> "file://usr/include/VG/openvg.h;endline=30;md5=b0109611dd76961057d4c45ae6519802"
> DEPENDS = "virtual/libx11 libxrender"
>
> +RCONFLICTS_${PN} = "amd-gpu-bin-mx51"
>
Same here.
> include amd-gpu-mx51.inc
>
> SRC_URI[md5sum] = "54391a4e670b597d06d01253fb217cad"
> --
> 1.7.10.4
>
> _______________________________________________
> meta-freescale mailing list
> meta-freescale@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-freescale
>
--
Otavio Salvador O.S. Systems
http://www.ossystems.com.br http://projetos.ossystems.com.br
Mobile: +55 (53) 9981-7854 Mobile: +1 (347) 903-9750
[-- Attachment #2: Type: text/html, Size: 4459 bytes --]
^ permalink raw reply [flat|nested] 5+ messages in thread
end of thread, other threads:[~2013-05-29 17:36 UTC | newest]
Thread overview: 5+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2013-05-28 19:24 [meta-fsl-arm][PATCH v2 1/3] amd-gpu-x11-bin-mx51: only enable when x11 is in DISTRO_FEATURES Eric Bénard
2013-05-28 19:24 ` [meta-fsl-arm][PATCH v2 2/3] amd-gpu-x11-bin-mx51: factorize the recipes Eric Bénard
2013-05-28 19:24 ` [meta-fsl-arm][PATCH v2 3/3] amd-gpu-bin-mx51: new recipe Eric Bénard
2013-05-29 17:36 ` Otavio Salvador
2013-05-29 17:34 ` [meta-fsl-arm][PATCH v2 1/3] amd-gpu-x11-bin-mx51: only enable when x11 is in DISTRO_FEATURES Otavio Salvador
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.